sysdeps/i386/memcmp.S

   1 /* Compare two memory blocks for differences in the first COUNT bytes.
   2    Copyright (C) 1995, 1996, 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Library General Public License as
   7    published by the Free Software Foundation; either version 2 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Library General Public License for more details.
  14
  15    You should have received a copy of the GNU Library General Public
  16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  18    Boston, MA 02111-1307, USA.  */
  19
  20 #include <sysdep.h>
  21 #include "asm-syntax.h"
  22
  23 /*
  24    INPUT PARAMETERS:
  25    block1       (sp + 4)
  26    block2       (sp + 8)
  27    len          (sp + 12)
  28 */
  29
  30         .text
  31 ENTRY (memcmp)
  32         pushl %esi              /* Save callee-safe registers.  */
  33         movl %edi, %edx         /* Note that %edx is not used and can
  34                                    so be used to save %edi.  It's faster.  */
  35
  36         movl 8(%esp), %esi      /* Load address of block #1.  */
  37         movl 12(%esp), %edi     /* Load address of block #2.  */
  38         movl 16(%esp), %ecx     /* Load maximal length of compare area.  */
  39
  40         cld                     /* Set direction of comparison.  */
  41
  42         xorl %eax, %eax         /* Default result.  */
  43
  44         repe                    /* Compare at most %ecx bytes.  */
  45         cmpsb
  46         jz L(1)                 /* If even last byte was equal we return 0.  */
  47
  48         /* The memory blocks are not equal.  So result of the last
  49            subtraction is present in the carry flag.  It is set when
  50            the byte in block #2 is bigger.  In this case we have to
  51            return -1 (=0xffffffff), else 1.  */
  52         sbbl %eax, %eax         /* This is tricky.  %eax == 0 and carry is set
  53                                    or not depending on last subtraction.  */
  54
  55         /* At this point %eax == 0, if the byte of block #1 was bigger, and
  56            0xffffffff if the last byte of block #2 was bigger.  The later
  57            case is already correct but the former needs a little adjustment.
  58            Note that the following operation does not change 0xffffffff.  */
  59         orb $1, %al             /* Change 0 to 1.  */
  60
  61 L(1):   popl %esi               /* Restore registers.  */
  62         movl %edx, %edi
  63
  64         ret
  65 END (memcmp)
  66
  67 #undef bcmp
  68 weak_alias (memcmp, bcmp)