configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/],
   4   [glibc], [https://www.gnu.org/software/glibc/])
   5 AC_CONFIG_SRCDIR([include/features.h])
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_AUX_DIR([scripts])
   8
   9 ACX_PKGVERSION([GNU libc])
  10 ACX_BUGURL([https://www.gnu.org/software/libc/bugs.html])
  11 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  12                    [Package description])
  13 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  14                    [Bug reporting address])
  15
  16 # Glibc should not depend on any header files
  17 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  18   [m4_divert_text([DEFAULTS],
  19     [ac_includes_default='/* none */'])])
  20
  21 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  22 # here to work around the Autoconf issue discussed in
  23 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  24 AC_DEFUN([AC_PROG_CPP],
  25 [AC_REQUIRE([AC_PROG_CC])dnl
  26 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  27 _AC_ARG_VAR_CPPFLAGS()dnl
  28 # On Suns, sometimes $CPP names a directory.
  29 if test -n "$CPP" && test -d "$CPP"; then
  30   CPP=
  31 fi
  32 if test -z "$CPP"; then
  33   CPP="$CC -E"
  34 fi
  35 AC_SUBST(CPP)dnl
  36 ])# AC_PROG_CPP
  37
  38 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  39 # issue discussed in
  40 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  41 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  42
  43 dnl This is here so we can set $subdirs directly based on configure fragments.
  44 AC_CONFIG_SUBDIRS()
  45
  46 AC_CANONICAL_HOST
  47
  48 AC_PROG_CC
  49 if test $host != $build; then
  50   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  51 fi
  52 AC_SUBST(cross_compiling)
  53 AC_PROG_CPP
  54 AC_CHECK_TOOL(READELF, readelf, false)
  55
  56 # We need the C++ compiler only for testing.
  57 AC_PROG_CXX
  58 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  59 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  60 AC_LANG_PUSH([C++])
  61 # Default, dynamic case.
  62 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  63                [libc_cv_cxx_link_ok=yes],
  64                [libc_cv_cxx_link_ok=no])
  65 # Static case.
  66 old_LDFLAGS="$LDFLAGS"
  67 LDFLAGS="$LDFLAGS -static"
  68 AC_LINK_IFELSE([AC_LANG_SOURCE([
  69 #include <iostream>
  70
  71 int
  72 main()
  73 {
  74   std::cout << "Hello, world!";
  75   return 0;
  76 }
  77 ])],
  78                [],
  79                [libc_cv_cxx_link_ok=no])
  80 LDFLAGS="$old_LDFLAGS"
  81 AC_LANG_POP([C++])])
  82 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  83
  84 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  85   AC_MSG_ERROR([you must configure in a separate build directory])
  86 fi
  87
  88 # This will get text that should go into config.make.
  89 config_vars=
  90
  91 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  92 AC_ARG_WITH([gd],
  93             AS_HELP_STRING([--with-gd=DIR],
  94                            [find libgd include dir and library with prefix DIR]),
  95             [dnl
  96 case "$with_gd" in
  97 yes|''|no) ;;
  98 *) libgd_include="-I$withval/include"
  99    libgd_ldflags="-L$withval/lib" ;;
 100 esac
 101 ])
 102 AC_ARG_WITH([gd-include],
 103             AS_HELP_STRING([--with-gd-include=DIR],
 104                            [find libgd include files in DIR]),
 105             [dnl
 106 case "$with_gd_include" in
 107 ''|no) ;;
 108 *) libgd_include="-I$withval" ;;
 109 esac
 110 ])
 111 AC_ARG_WITH([gd-lib],
 112             AS_HELP_STRING([--with-gd-lib=DIR],
 113                            [find libgd library files in DIR]),
 114             [dnl
 115 case "$with_gd_lib" in
 116 ''|no) ;;
 117 *) libgd_ldflags="-L$withval" ;;
 118 esac
 119 ])
 120
 121 if test -n "$libgd_include"; then
 122   config_vars="$config_vars
 123 CFLAGS-memusagestat.c = $libgd_include"
 124 fi
 125 if test -n "$libgd_ldflags"; then
 126   config_vars="$config_vars
 127 libgd-LDFLAGS = $libgd_ldflags"
 128 fi
 129
 130 dnl Arguments to specify presence of other packages/features.
 131 AC_ARG_WITH([binutils],
 132             AS_HELP_STRING([--with-binutils=PATH],
 133                            [specify location of binutils (as and ld)]),
 134             [path_binutils=$withval],
 135             [path_binutils=''])
 136 AC_ARG_WITH([selinux],
 137             AS_HELP_STRING([--with-selinux],
 138                            [if building with SELinux support]),
 139             [with_selinux=$withval],
 140             [with_selinux=auto])
 141
 142 AC_ARG_WITH([headers],
 143             AS_HELP_STRING([--with-headers=PATH],
 144                            [location of system headers to use
 145                             (for example /usr/src/linux/include)
 146                             @<:@default=compiler default@:>@]),
 147             [sysheaders=$withval],
 148             [sysheaders=''])
 149 AC_SUBST(sysheaders)
 150
 151 AC_SUBST(use_default_link)
 152 AC_ARG_WITH([default-link],
 153             AS_HELP_STRING([--with-default-link],
 154                            [do not use explicit linker scripts]),
 155             [use_default_link=$withval],
 156             [use_default_link=default])
 157
 158 dnl Additional build flags injection.
 159 AC_ARG_WITH([nonshared-cflags],
 160             AS_HELP_STRING([--with-nonshared-cflags=CFLAGS],
 161                            [build nonshared libraries with additional CFLAGS]),
 162             [extra_nonshared_cflags=$withval],
 163             [extra_nonshared_cflags=])
 164 AC_SUBST(extra_nonshared_cflags)
 165
 166 AC_ARG_ENABLE([sanity-checks],
 167               AS_HELP_STRING([--disable-sanity-checks],
 168                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 169               [enable_sanity=$enableval],
 170               [enable_sanity=yes])
 171
 172 AC_ARG_ENABLE([shared],
 173               AS_HELP_STRING([--enable-shared],
 174                              [build shared library @<:@default=yes if GNU ld@:>@]),
 175               [shared=$enableval],
 176               [shared=yes])
 177 AC_ARG_ENABLE([profile],
 178               AS_HELP_STRING([--enable-profile],
 179                              [build profiled library @<:@default=no@:>@]),
 180               [profile=$enableval],
 181               [profile=no])
 182 AC_ARG_ENABLE([static-pie],
 183               AS_HELP_STRING([--enable-static-pie],
 184                              [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
 185               [static_pie=$enableval],
 186               [static_pie=no])
 187 AC_ARG_ENABLE([timezone-tools],
 188               AS_HELP_STRING([--disable-timezone-tools],
 189                              [do not install timezone tools @<:@default=install@:>@]),
 190               [enable_timezone_tools=$enableval],
 191               [enable_timezone_tools=yes])
 192 AC_SUBST(enable_timezone_tools)
 193
 194 AC_ARG_ENABLE([hardcoded-path-in-tests],
 195               AS_HELP_STRING([--enable-hardcoded-path-in-tests],
 196                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 197               [hardcoded_path_in_tests=$enableval],
 198               [hardcoded_path_in_tests=no])
 199 AC_SUBST(hardcoded_path_in_tests)
 200
 201 AC_ARG_ENABLE([hidden-plt],
 202               AS_HELP_STRING([--disable-hidden-plt],
 203                              [do not hide internal function calls to avoid PLT]),
 204               [hidden=$enableval],
 205               [hidden=yes])
 206 if test "x$hidden" = xno; then
 207   AC_DEFINE(NO_HIDDEN)
 208 fi
 209
 210 AC_ARG_ENABLE([bind-now],
 211               AS_HELP_STRING([--enable-bind-now],
 212                              [disable lazy relocations in DSOs]),
 213               [bindnow=$enableval],
 214               [bindnow=no])
 215 AC_SUBST(bindnow)
 216 if test "x$bindnow" = xyes; then
 217   AC_DEFINE(BIND_NOW)
 218 fi
 219
 220 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 221 dnl -fstack-protector-strong.
 222 AC_ARG_ENABLE([stack-protector],
 223               AS_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 224                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 225               [enable_stack_protector=$enableval],
 226               [enable_stack_protector=no])
 227 case "$enable_stack_protector" in
 228 all|yes|no|strong) ;;
 229 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 230 esac
 231
 232 dnl On some platforms we cannot use dynamic loading.  We must provide
 233 dnl static NSS modules.
 234 AC_ARG_ENABLE([static-nss],
 235               AS_HELP_STRING([--enable-static-nss],
 236                              [build static NSS modules @<:@default=no@:>@]),
 237               [static_nss=$enableval],
 238               [static_nss=no])
 239 dnl Enable static NSS also if we build no shared objects.
 240 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 241   static_nss=yes
 242   AC_DEFINE(DO_STATIC_NSS)
 243 fi
 244
 245 AC_ARG_ENABLE([force-install],
 246               AS_HELP_STRING([--disable-force-install],
 247                              [don't force installation of files from this package, even if they are older than the installed files]),
 248               [force_install=$enableval],
 249               [force_install=yes])
 250 AC_SUBST(force_install)
 251
 252 AC_ARG_ENABLE([maintainer-mode],
 253               AS_HELP_STRING([--enable-maintainer-mode],
 254                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 255               [maintainer=$enableval],
 256               [maintainer=no])
 257
 258 dnl On some platforms we allow dropping compatibility with all kernel
 259 dnl versions.
 260 AC_ARG_ENABLE([kernel],
 261               AS_HELP_STRING([--enable-kernel=VERSION],
 262                              [compile for compatibility with kernel not older than VERSION]),
 263               [minimum_kernel=$enableval],
 264               [])
 265 dnl Prevent unreasonable values.
 266 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 267   # Better nothing than this.
 268   minimum_kernel=""
 269 else
 270   if test "$minimum_kernel" = current; then
 271     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 272   fi
 273 fi
 274
 275 dnl For the development we sometimes want gcc to issue even more warnings.
 276 dnl This is not the default since many of the extra warnings are not
 277 dnl appropriate.
 278 AC_ARG_ENABLE([all-warnings],
 279               AS_HELP_STRING([--enable-all-warnings],
 280                              [enable all useful warnings gcc can issue]),
 281               [all_warnings=$enableval],
 282               [])
 283 AC_SUBST(all_warnings)
 284
 285 AC_ARG_ENABLE([werror],
 286               AS_HELP_STRING([--disable-werror],
 287                              [do not build with -Werror]),
 288               [enable_werror=$enableval],
 289               [enable_werror=yes])
 290 AC_SUBST(enable_werror)
 291
 292 AC_ARG_ENABLE([multi-arch],
 293               AS_HELP_STRING([--enable-multi-arch],
 294                              [enable single DSO with optimizations for multiple architectures]),
 295               [multi_arch=$enableval],
 296               [multi_arch=default])
 297
 298 AC_ARG_ENABLE([experimental-malloc],
 299               AS_HELP_STRING([--disable-experimental-malloc],
 300                              [disable experimental malloc features]),
 301               [experimental_malloc=$enableval],
 302               [experimental_malloc=yes])
 303 AC_SUBST(experimental_malloc)
 304
 305 AC_ARG_ENABLE([memory-tagging],
 306               AS_HELP_STRING([--enable-memory-tagging],
 307                              [enable memory tagging if supported by the architecture @<:@default=no@:>@]),
 308               [memory_tagging=$enableval],
 309               [memory_tagging=no])
 310 if test "$memory_tagging" = yes; then
 311   # Only enable this on architectures that support it.
 312   case $host_cpu in
 313     aarch64)
 314       AC_DEFINE(USE_MTAG)
 315       ;;
 316   esac
 317 fi
 318 AC_SUBST(memory_tagging)
 319
 320 AC_ARG_ENABLE([crypt],
 321               AS_HELP_STRING([--disable-crypt],
 322                              [do not build nor install the passphrase hashing library, libcrypt]),
 323               [build_crypt=$enableval],
 324               [build_crypt=yes])
 325 AC_SUBST(build_crypt)
 326
 327 AC_ARG_ENABLE([nss-crypt],
 328               AS_HELP_STRING([--enable-nss-crypt],
 329                              [enable libcrypt to use nss]),
 330               [nss_crypt=$enableval],
 331               [nss_crypt=no])
 332 if test x$build_libcrypt = xno && test x$nss_crypt = xyes; then
 333   AC_MSG_WARN([--enable-nss-crypt has no effect when libcrypt is disabled])
 334   nss_crypt=no
 335 fi
 336 if test x$nss_crypt = xyes; then
 337   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 338   if test $? -ne 0; then
 339     AC_MSG_ERROR([cannot find include directory with nss-config])
 340   fi
 341   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 342   if test $? -ne 0; then
 343     AC_MSG_ERROR([cannot find include directory with nspr-config])
 344   fi
 345   old_CFLAGS="$CFLAGS"
 346   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 347   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 348 #include <hasht.h>
 349 #include <nsslowhash.h>
 350 void f (void) { NSSLOW_Init (); }])],
 351              libc_cv_nss_crypt=yes,
 352              AC_MSG_ERROR([
 353 cannot find NSS headers with lowlevel hash function interfaces]))
 354   old_LIBS="$LIBS"
 355   old_LDFLAGS="$LDFLAGS"
 356   LIBS="$LIBS -lfreebl3"
 357   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 358 #include <hasht.h>
 359 #include <nsslowhash.h>],
 360                                   [NSSLOW_Init();])],
 361                  libc_cv_nss_crypt=yes,
 362                  AC_MSG_ERROR([
 363 cannot link program using lowlevel NSS hash functions]))
 364   # Check to see if there is a static NSS cryptographic library.
 365   # If there isn't then we can't link anything with libcrypt.a,
 366   # and that might mean disabling some static tests.
 367   LDFLAGS="$LDFLAGS -static"
 368   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 369 #include <hasht.h>
 370 #include <nsslowhash.h>],
 371                                   [NSSLOW_Init();])],
 372                  libc_cv_static_nss_crypt=yes,
 373                  libc_cv_static_nss_crypt=no)
 374   LDFLAGS="$old_LDFLAGS"
 375   CFLAGS="$old_CFLAGS"
 376   LIBS="$old_LIBS"
 377 else
 378   libc_cv_nss_crypt=no
 379   libc_cv_static_nss_crypt=no
 380 fi
 381 AC_SUBST(libc_cv_nss_crypt)
 382 AC_SUBST(libc_cv_static_nss_crypt)
 383
 384
 385 AC_ARG_ENABLE([systemtap],
 386               [AS_HELP_STRING([--enable-systemtap],
 387                [enable systemtap static probe points @<:@default=no@:>@])],
 388               [systemtap=$enableval],
 389               [systemtap=no])
 390 if test "x$systemtap" != xno; then
 391   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 392   old_CFLAGS="$CFLAGS"
 393   CFLAGS="-std=gnu11 $CFLAGS"
 394   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 395 void foo (int i, void *p)
 396 {
 397   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 398        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 399 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 400   CFLAGS="$old_CFLAGS"])
 401   if test $libc_cv_sdt = yes; then
 402     AC_DEFINE([USE_STAP_PROBE])
 403   elif test "x$systemtap" != xauto; then
 404     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 405   fi
 406 fi
 407
 408 AC_ARG_ENABLE([build-nscd],
 409               [AS_HELP_STRING([--disable-build-nscd],
 410                [disable building and installing the nscd daemon])],
 411               [build_nscd=$enableval],
 412               [build_nscd=default])
 413 AC_SUBST(build_nscd)
 414
 415 # Note the use of $use_nscd is near the bottom of the file.
 416 AC_ARG_ENABLE([nscd],
 417               [AS_HELP_STRING([--disable-nscd],
 418                [library functions will not contact the nscd daemon])],
 419               [use_nscd=$enableval],
 420               [use_nscd=yes])
 421
 422 AC_ARG_ENABLE([pt_chown],
 423               [AS_HELP_STRING([--enable-pt_chown],
 424                [Enable building and installing pt_chown])],
 425               [build_pt_chown=$enableval],
 426               [build_pt_chown=no])
 427 AC_SUBST(build_pt_chown)
 428 if test "$build_pt_chown" = yes; then
 429   AC_DEFINE(HAVE_PT_CHOWN)
 430 fi
 431
 432 AC_ARG_ENABLE([tunables],
 433               [AS_HELP_STRING([--enable-tunables],
 434                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 435               [have_tunables=$enableval],
 436               [have_tunables=yes])
 437 AC_SUBST(have_tunables)
 438 if test "$have_tunables" = yes; then
 439   AC_DEFINE(HAVE_TUNABLES)
 440 fi
 441
 442 # The abi-tags file uses a fairly simplistic model for name recognition that
 443 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 444 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 445 # This doesn't get used much beyond that, so it's fairly safe.
 446 case "$host_os" in
 447 linux*)
 448   ;;
 449 gnu*)
 450   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 451   ;;
 452 esac
 453
 454 AC_ARG_ENABLE([mathvec],
 455               [AS_HELP_STRING([--enable-mathvec],
 456               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 457               [build_mathvec=$enableval],
 458               [build_mathvec=notset])
 459
 460 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[]], [[
 461 #ifndef __CET__
 462 # error no CET compiler support
 463 #endif]])],
 464                [libc_cv_compiler_default_cet=yes],
 465                [libc_cv_compiler_default_cet=no])
 466
 467 AC_ARG_ENABLE([cet],
 468               AS_HELP_STRING([--enable-cet],
 469                              [enable Intel Control-flow Enforcement Technology (CET), x86 only]),
 470               [enable_cet=$enableval],
 471               [enable_cet=$libc_cv_compiler_default_cet])
 472
 473 AC_ARG_ENABLE([scv],
 474               AC_HELP_STRING([--disable-scv],
 475                              [syscalls will not use scv instruction, even if the kernel supports it, powerpc only]),
 476               [use_scv=$enableval],
 477               [use_scv=yes])
 478
 479 AS_IF([[test "$use_scv" != "no"]],[AC_DEFINE(USE_PPC_SCV)])
 480
 481 # We keep the original values in `$config_*' and never modify them, so we
 482 # can write them unchanged into config.make.  Everything else uses
 483 # $machine, $vendor, and $os, and changes them whenever convenient.
 484 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 485
 486 # Don't allow vendor == "unknown"
 487 test "$config_vendor" = unknown && config_vendor=
 488 config_os="`echo $config_os | sed 's/^unknown-//'`"
 489
 490 # Some configurations imply other options.
 491 elf=yes
 492
 493 # The configure fragment of a port can modify these to supplement
 494 # or override the table in the case statement below.  No fragment should
 495 # ever change the config_* variables, however.
 496 machine=$config_machine
 497 vendor=$config_vendor
 498 os=$config_os
 499 base_os=''
 500
 501 submachine=
 502 AC_ARG_WITH([cpu],
 503             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 504             [dnl
 505   case "$withval" in
 506   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 507   no) ;;
 508   *) submachine="$withval" ;;
 509   esac
 510 ])
 511
 512 # An preconfigure script can set this when it wants to disable the sanity
 513 # check below.
 514 libc_config_ok=no
 515
 516 # A preconfigure script for a system that may or may not use fpu
 517 # sysdeps directories sets this to a preprocessor conditional for
 518 # whether to use such directories.
 519 with_fp_cond=1
 520
 521 dnl Let sysdeps/*/preconfigure act here.
 522 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 523
 524
 525 ###
 526 ### By using the undocumented --enable-hacker-mode option for configure
 527 ### one can skip this test to make the configuration not fail for unsupported
 528 ### platforms.
 529 ###
 530 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 531   case "$machine-$host_os" in
 532   *-linux* | *-gnu*)
 533     ;;
 534   *)
 535     AC_MSG_ERROR([
 536 *** The GNU C library is currently unavailable for this platform.
 537 *** If you are interested in seeing glibc on this platform visit
 538 *** the "How to submit a new port" in the wiki:
 539 ***   https://sourceware.org/glibc/wiki/#Development
 540 *** and join the community!])
 541     ;;
 542   esac
 543 fi
 544
 545 # Set base_machine if not set by a preconfigure fragment.
 546 test -n "$base_machine" || base_machine=$machine
 547 AC_SUBST(base_machine)
 548
 549 # Determine whether to use fpu or nofpu sysdeps directories.
 550 AC_CACHE_CHECK([for use of fpu sysdeps directories],
 551                libc_cv_with_fp, [dnl
 552 cat > conftest.c <<EOF
 553 #if $with_fp_cond
 554 int dummy;
 555 #else
 556 # error "no hardware floating point"
 557 #endif
 558 EOF
 559 libc_cv_with_fp=no
 560 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
 561    1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 562   libc_cv_with_fp=yes
 563 fi
 564 rm -f conftest*])
 565 AC_SUBST(libc_cv_with_fp)
 566
 567 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 568 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 569                    [libc_cv_ssp=yes],
 570                    [libc_cv_ssp=no])
 571 ])
 572
 573 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 574 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 575                    [libc_cv_ssp_strong=yes],
 576                    [libc_cv_ssp_strong=no])
 577 ])
 578
 579 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 580 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 581                    [libc_cv_ssp_all=yes],
 582                    [libc_cv_ssp_all=no])
 583 ])
 584
 585 stack_protector=
 586 no_stack_protector=
 587 if test "$libc_cv_ssp" = yes; then
 588   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 589   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 590 fi
 591
 592 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 593   stack_protector="-fstack-protector"
 594   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 595 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 596   stack_protector="-fstack-protector-all"
 597   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 598 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 599   stack_protector="-fstack-protector-strong"
 600   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 601 else
 602   stack_protector="-fno-stack-protector"
 603   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 604 fi
 605 AC_SUBST(libc_cv_ssp)
 606 AC_SUBST(stack_protector)
 607 AC_SUBST(no_stack_protector)
 608
 609 if test -n "$stack_protector"; then
 610   dnl Don't run configure tests with stack-protection on, to avoid problems with
 611   dnl bootstrapping.
 612   no_ssp=-fno-stack-protector
 613 else
 614   no_ssp=
 615
 616   if test "$enable_stack_protector" != no; then
 617     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 618   fi
 619 fi
 620
 621 # For the multi-arch option we need support in the assembler & linker.
 622 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 623                libc_cv_ld_gnu_indirect_function, [dnl
 624 cat > conftest.S <<EOF
 625 .type foo,%gnu_indirect_function
 626 foo:
 627 .globl _start
 628 _start:
 629 .globl __start
 630 __start:
 631 .data
 632 #ifdef _LP64
 633 .quad foo
 634 #else
 635 .long foo
 636 #endif
 637 EOF
 638 libc_cv_ld_gnu_indirect_function=no
 639 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 640             -nostartfiles -nostdlib $no_ssp \
 641             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 642   # Do a link to see if the backend supports IFUNC relocs.
 643   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 644   LC_ALL=C $READELF -Wr conftest | grep -q 'IRELATIVE\|R_SPARC_JMP_IREL' && {
 645     libc_cv_ld_gnu_indirect_function=yes
 646   }
 647 fi
 648 rm -f conftest*])
 649
 650 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 651 AC_CACHE_CHECK([for gcc attribute ifunc support],
 652                libc_cv_gcc_indirect_function, [dnl
 653 cat > conftest.c <<EOF
 654 extern int func (int);
 655 int used_func (int a)
 656 {
 657   return a;
 658 }
 659 static void *resolver ()
 660 {
 661   return &used_func;
 662 }
 663 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 664 EOF
 665 libc_cv_gcc_indirect_function=no
 666 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 667    2>&AS_MESSAGE_LOG_FD ; then
 668   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 669     libc_cv_gcc_indirect_function=yes
 670   fi
 671 fi
 672 rm -f conftest*])
 673
 674 # Check if linker supports textrel relocation with ifunc (used on elf/tests).
 675 # Note that it relies on libc_cv_ld_gnu_indirect_function test above.
 676 AC_CACHE_CHECK([whether the linker supports textrels along with ifunc],
 677                libc_cv_textrel_ifunc, [dnl
 678 cat > conftest.S <<EOF
 679 .type foo,%gnu_indirect_function
 680 foo:
 681 .globl _start
 682 _start:
 683 .globl __start
 684 __start:
 685 .data
 686 #ifdef _LP64
 687 .quad foo
 688 #else
 689 .long foo
 690 #endif
 691 .text
 692 .globl address
 693 address:
 694 #ifdef _LP64
 695 .quad address
 696 #else
 697 .long address
 698 #endif
 699 EOF
 700 libc_cv_textrel_ifunc=no
 701 if test $libc_cv_ld_gnu_indirect_function = yes; then
 702    if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostartfiles -nostdlib $no_ssp -pie -o conftest conftest.S); then
 703      libc_cv_textrel_ifunc=yes
 704    fi
 705 fi
 706 rm -f conftest*])
 707 AC_SUBST(libc_cv_textrel_ifunc)
 708
 709 # Check if CC supports attribute retain as it is used in attribute_used_retain macro.
 710 AC_CACHE_CHECK([for GNU attribute retain support],
 711                libc_cv_gnu_retain, [dnl
 712 cat > conftest.c <<EOF
 713 static int var  __attribute__ ((used, retain, section ("__libc_atexit")));
 714 EOF
 715 libc_cv_gnu_retain=no
 716 if ${CC-cc} -Werror -c conftest.c -o /dev/null 1>&AS_MESSAGE_LOG_FD \
 717    2>&AS_MESSAGE_LOG_FD ; then
 718   libc_cv_gnu_retain=yes
 719 fi
 720 rm -f conftest*])
 721 if test $libc_cv_gnu_retain = yes; then
 722   AC_DEFINE(HAVE_GNU_RETAIN)
 723 fi
 724 LIBC_CONFIG_VAR([have-gnu-retain], [$libc_cv_gnu_retain])
 725
 726 # Check if gcc warns about alias for function with incompatible types.
 727 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 728                libc_cv_gcc_incompatible_alias, [dnl
 729 cat > conftest.c <<EOF
 730 int __redirect_foo (const void *s, int c);
 731
 732 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 733 __typeof (__redirect_foo) *foo_impl (void)
 734 {
 735   return 0;
 736 }
 737
 738 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 739 EOF
 740 libc_cv_gcc_incompatible_alias=yes
 741 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 742   libc_cv_gcc_incompatible_alias=no
 743 fi
 744 rm -f conftest*])
 745
 746 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 747   if test x"$multi_arch" = xyes; then
 748     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 749   else
 750     multi_arch=no
 751   fi
 752 fi
 753 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 754   # GCC 8+ emits a warning for alias with incompatible types and it might
 755   # fail to build ifunc resolvers aliases to either weak or internal
 756   # symbols.  Disables multiarch build in this case.
 757   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 758     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 759     if test x"$multi_arch" = xyes; then
 760       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 761     fi
 762     AC_MSG_WARN([Multi-arch is disabled.])
 763     multi_arch=no
 764   elif test x"$multi_arch" = xyes; then
 765     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 766 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 767   fi
 768 fi
 769 multi_arch_d=
 770 if test x"$multi_arch" != xno; then
 771   multi_arch_d=/multiarch
 772 fi
 773
 774 # Compute the list of sysdep directories for this configuration.
 775 # This can take a while to compute.
 776 sysdep_dir=$srcdir/sysdeps
 777 AC_MSG_CHECKING(sysdep dirs)
 778 dnl We need to use [ and ] for other purposes for a while now.
 779 changequote(,)dnl
 780 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 781 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 782
 783 test "x$base_os" != x || case "$os" in
 784 gnu*)
 785   base_os=mach/hurd ;;
 786 linux*)
 787   base_os=unix/sysv ;;
 788 esac
 789
 790 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 791 tail=$os
 792 ostry=$os
 793 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 794   ostry="$ostry /$o"
 795   tail=$o
 796 done
 797 o=`echo $tail | sed 's/[0-9]*$//'`
 798 if test $o != $tail; then
 799   ostry="$ostry /$o"
 800 fi
 801 # For linux-gnu, try linux-gnu, then linux.
 802 o=`echo $tail | sed 's/-.*$//'`
 803 if test $o != $tail; then
 804   ostry="$ostry /$o"
 805 fi
 806
 807 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 808 base=
 809 tail=$base_os
 810 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 811   set $b
 812   base="$base /$1"
 813   tail="$2"
 814 done
 815
 816 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 817 mach=
 818 tail=$machine${submachine:+/$submachine}
 819 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 820   set $m
 821   # Prepend the machine's FPU directory unless the architecture specific
 822   # preconfigure disables it.
 823   if test "$libc_cv_with_fp" = yes; then
 824     maybe_fpu=/fpu
 825   else
 826     maybe_fpu=/nofpu
 827   fi
 828   # For each machine term, try it with and then without /multiarch.
 829   for try_fpu in $maybe_fpu ''; do
 830     for try_multi in $multi_arch_d ''; do
 831       mach="$mach /$1$try_fpu$try_multi"
 832     done
 833   done
 834   tail="$2"
 835 done
 836
 837 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 838 changequote([,])dnl
 839
 840 # Find what sysdep directories exist.
 841 sysnames=
 842 for b in $base ''; do
 843   for m0 in $mach ''; do
 844     for v in /$vendor ''; do
 845       test "$v" = / && continue
 846       for o in /$ostry ''; do
 847         test "$o" = / && continue
 848         for m in $mach ''; do
 849           try_suffix="$m0$b$v$o$m"
 850           if test -n "$try_suffix"; then
 851             try_srcdir="${srcdir}/"
 852             try="sysdeps$try_suffix"
 853             test -n "$enable_debug_configure" &&
 854             echo "$0 [DEBUG]: try $try" >&2
 855             if test -d "$try_srcdir$try"; then
 856               sysnames="$sysnames $try"
 857               { test -n "$o" || test -n "$b"; } && os_used=t
 858               { test -n "$m" || test -n "$m0"; } && machine_used=t
 859               case x${m0:-$m} in
 860               x*/$submachine) submachine_used=t ;;
 861               esac
 862             fi
 863           fi
 864         done
 865       done
 866     done
 867   done
 868 done
 869
 870 # If the assembler supports gnu_indirect_function symbol type and the
 871 # architecture supports multi-arch, we enable multi-arch by default.
 872 case $sysnames in
 873 *"$multi_arch_d"*)
 874   ;;
 875 *)
 876   test x"$multi_arch" = xdefault && multi_arch=no
 877   ;;
 878 esac
 879 if test x"$multi_arch" != xno; then
 880   AC_DEFINE(USE_MULTIARCH)
 881 fi
 882 AC_SUBST(multi_arch)
 883
 884 if test -z "$os_used" && test "$os" != none; then
 885   AC_MSG_ERROR(Operating system $os is not supported.)
 886 fi
 887 if test -z "$machine_used" && test "$machine" != none; then
 888   AC_MSG_ERROR(The $machine is not supported.)
 889 fi
 890 if test -z "$submachine_used" && test -n "$submachine"; then
 891   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 892 fi
 893 AC_SUBST(submachine)
 894
 895 # We have now validated the configuration.
 896
 897 # Expand the list of system names into a full list of directories
 898 # from each element's parent name and Implies file (if present).
 899 set $sysnames
 900 names=
 901 while test $# -gt 0; do
 902   name=$1
 903   shift
 904
 905   case " $names " in *" $name "*)
 906     # Already in the list.
 907     continue
 908   esac
 909
 910   # Report each name as we discover it, so there is no long pause in output.
 911   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 912
 913   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 914
 915   case $name in
 916     /*) xsrcdir= ;;
 917     *)  xsrcdir=$srcdir/ ;;
 918   esac
 919   test -n "$enable_debug_configure" &&
 920   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 921
 922   for implies_file in Implies Implies-before Implies-after; do
 923     implies_type=`echo $implies_file | sed s/-/_/`
 924     eval ${implies_type}=
 925     if test -f $xsrcdir$name/$implies_file; then
 926       # Collect more names from the `Implies' file (removing comments).
 927       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 928       for x in $implied_candidate; do
 929         found=no
 930         if test -d $xsrcdir$name_base/$x; then
 931           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 932           found=yes
 933         fi
 934         try="sysdeps/$x"
 935         try_srcdir=$srcdir/
 936         test -n "$enable_debug_configure" &&
 937          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 938         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 939         then
 940           eval "${implies_type}=\"\$${implies_type} \$try\""
 941           found=yes
 942         fi
 943         if test $found = no; then
 944           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 945         fi
 946       done
 947     fi
 948   done
 949
 950   # Add NAME to the list of names.
 951   names="$names $name"
 952
 953   # Find the parent of NAME, using the empty string if it has none.
 954 changequote(,)dnl
 955   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 956 changequote([,])dnl
 957
 958   test -n "$enable_debug_configure" &&
 959     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 960 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 961
 962   # Add the names implied by NAME, and NAME's parent (if it has one), to
 963   # the list of names to be processed (the argument list).  We prepend the
 964   # implied names to the list and append the parent.  We want implied
 965   # directories to come before further directories inferred from the
 966   # configuration components; this ensures that for sysv4, unix/common
 967   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 968   # after sysv4).
 969   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 970   test -n "$sysnames" && set $sysnames
 971 done
 972
 973 # Add the default directories.
 974 default_sysnames="sysdeps/generic"
 975 sysnames="$names $default_sysnames"
 976 AC_SUBST(sysnames)
 977 # The other names were emitted during the scan.
 978 AC_MSG_RESULT($default_sysnames)
 979
 980
 981 ### Locate tools.
 982
 983 AC_PROG_INSTALL
 984 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 985   # The makefiles need to use a different form to find it in $srcdir.
 986   INSTALL='\$(..)./scripts/install-sh -c'
 987 fi
 988 AC_PROG_LN_S
 989
 990 LIBC_PROG_BINUTILS
 991
 992 # Accept binutils 2.25 or newer.
 993 AC_CHECK_PROG_VER(AS, $AS, --version,
 994                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 995                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 996                   AS=: critic_missing="$critic_missing as")
 997
 998 libc_cv_with_lld=no
 999 case $($LD --version) in
1000   "GNU gold"*)
1001   # Accept gold 1.14 or higher
1002     AC_CHECK_PROG_VER(LD, $LD, --version,
1003                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
1004                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
1005                     LD=: critic_missing="$critic_missing GNU gold")
1006     ;;
1007   "LLD"*)
1008   # Accept LLD 13.0.0 or higher
1009     AC_CHECK_PROG_VER(LD, $LD, --version,
1010                     [LLD.* \([0-9][0-9]*\.[0-9.]*\)],
1011                     [1[3-9].*|[2-9][0-9].*],
1012                     LD=: critic_missing="$critic_missing LLD")
1013     libc_cv_with_lld=yes
1014     ;;
1015   *)
1016     AC_CHECK_PROG_VER(LD, $LD, --version,
1017                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
1018                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
1019                     LD=: critic_missing="$critic_missing GNU ld")
1020     ;;
1021 esac
1022 LIBC_CONFIG_VAR([with-lld], [$libc_cv_with_lld])
1023
1024 # These programs are version sensitive.
1025 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
1026   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
1027   [[4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
1028
1029 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1030   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1031   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1032   MSGFMT=: aux_missing="$aux_missing msgfmt")
1033 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1034   [GNU texinfo.* \([0-9][0-9.]*\)],
1035   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1036   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1037 AC_CHECK_PROG_VER(SED, sed, --version,
1038   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1039   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1040   SED=: aux_missing="$aux_missing sed")
1041 AC_CHECK_PROG_VER(AWK, gawk, --version,
1042   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1043   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1044 AC_CHECK_PROG_VER(BISON, bison, --version,
1045   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1046   [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
1047
1048 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1049 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[]], [[
1050 #if !defined __GNUC__ || __GNUC__ < 6 || (__GNUC__ == 6 && __GNUC_MINOR__ < 2)
1051 #error insufficient compiler
1052 #endif]])],
1053                [libc_cv_compiler_ok=yes],
1054                [libc_cv_compiler_ok=no])])
1055 AS_IF([test $libc_cv_compiler_ok != yes],
1056       [critic_missing="$critic_missing compiler"])
1057
1058 AC_CHECK_TOOL(NM, nm, false)
1059
1060 if test "x$maintainer" = "xyes"; then
1061   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1062   case "x$AUTOCONF" in
1063   xno|x|x:) AUTOCONF=no ;;
1064   *)
1065     AC_CACHE_CHECK(dnl
1066   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1067     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1068       libc_cv_autoconf_works=yes
1069     else
1070       libc_cv_autoconf_works=no
1071     fi])
1072     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1073     ;;
1074   esac
1075   if test "x$AUTOCONF" = xno; then
1076     aux_missing="$aux_missing autoconf"
1077   fi
1078 else
1079   AUTOCONF=no
1080 fi
1081
1082 # Check for python3 if available, or else python.
1083 AC_CHECK_PROG_VER(PYTHON_PROG, python3 python, --version,
1084   [Python \([0-9][0-9.]*\)],
1085   [3.[4-9]*|3.[1-9][0-9]*|[4-9].*|[1-9][0-9]*],
1086   critic_missing="$critic_missing python")
1087 PYTHON="$PYTHON_PROG -B"
1088 AC_SUBST(PYTHON)
1089
1090 test -n "$critic_missing" && AC_MSG_ERROR([
1091 *** These critical programs are missing or too old:$critic_missing
1092 *** Check the INSTALL file for required versions.])
1093
1094 test -n "$aux_missing" && AC_MSG_WARN([
1095 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1096 *** some features or tests will be disabled.
1097 *** Check the INSTALL file for required versions.])
1098
1099 # if using special system headers, find out the compiler's sekrit
1100 # header directory and add that to the list.  NOTE: Only does the right
1101 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1102 if test -n "$sysheaders"; then
1103   SYSINCLUDES=-nostdinc
1104   for d in include include-fixed; do
1105     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1106     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1107   done
1108   SYSINCLUDES="$SYSINCLUDES \
1109 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1110   if test -n "$CXX"; then
1111     CXX_SYSINCLUDES=
1112     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1113     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1114       test "x$cxxheaders" != x &&
1115       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1116     done
1117   fi
1118 fi
1119 AC_SUBST(SYSINCLUDES)
1120 AC_SUBST(CXX_SYSINCLUDES)
1121
1122 # Obtain some C++ header file paths.  This is used to make a local
1123 # copy of those headers in Makerules.
1124 if test -n "$CXX"; then
1125   find_cxx_header () {
1126     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1127          | sed -n "\,$1:,{s/:\$//;p}"
1128   }
1129   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1130   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1131   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1132 fi
1133 AC_SUBST(CXX_CSTDLIB_HEADER)
1134 AC_SUBST(CXX_CMATH_HEADER)
1135 AC_SUBST(CXX_BITS_STD_ABS_H)
1136
1137 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1138 # since this would lead to problems installing/building glibc.
1139 # LD_LIBRARY_PATH contains the current directory if one of the following
1140 # is true:
1141 # - one of the terminals (":" and ";") is the first or last sign
1142 # - two terminals occur directly after each other
1143 # - the path contains an element with a dot in it
1144 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1145 changequote(,)dnl
1146 case ${LD_LIBRARY_PATH} in
1147   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1148     ld_library_path_setting="contains current directory"
1149     ;;
1150   *)
1151     ld_library_path_setting="ok"
1152     ;;
1153 esac
1154 changequote([,])dnl
1155 AC_MSG_RESULT($ld_library_path_setting)
1156 if test "$ld_library_path_setting" != "ok"; then
1157 AC_MSG_ERROR([
1158 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1159 *** building glibc. Please change the environment variable
1160 *** and run configure again.])
1161 fi
1162
1163 AC_PATH_PROG(BASH_SHELL, bash, no)
1164
1165 AC_PATH_PROG(PERL, perl, no)
1166 if test "$PERL" != no &&
1167    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1168   PERL=no
1169 fi
1170 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1171              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1172
1173 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1174 cat > conftest.s <<EOF
1175 .text
1176 foo:
1177 .set glibc_conftest_frobozz,foo
1178 .globl glibc_conftest_frobozz
1179 EOF
1180 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1181 # (but it doesn't work), so we must do a linking check to be sure.
1182 cat > conftest1.c <<\EOF
1183 extern int glibc_conftest_frobozz;
1184 void _start() { glibc_conftest_frobozz = 1; }
1185 EOF
1186 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1187             -nostartfiles -nostdlib $no_ssp \
1188             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1189   libc_cv_asm_set_directive=yes
1190 else
1191   libc_cv_asm_set_directive=no
1192 fi
1193 rm -f conftest*])
1194 if test $libc_cv_asm_set_directive = yes; then
1195   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1196 fi
1197
1198 AC_CACHE_CHECK(linker support for protected data symbol,
1199                libc_cv_protected_data,
1200                [cat > conftest.c <<EOF
1201                 int bar __attribute__ ((visibility ("protected"))) = 1;
1202 EOF
1203                 libc_cv_protected_data=no
1204                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1205                   cat > conftest.c <<EOF
1206                   extern int bar;
1207                   int main (void) { return bar; }
1208 EOF
1209                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1210                     libc_cv_protected_data=yes
1211                   fi
1212                 fi
1213                 rm -f conftest.*
1214                ])
1215 AC_SUBST(libc_cv_protected_data)
1216
1217 AC_CACHE_CHECK(linker support for INSERT in linker script,
1218                libc_cv_insert,
1219                [cat > conftest.c <<EOF
1220                 int __attribute__ ((section(".bar"))) bar = 0x12345678;
1221                 int test (void) { return bar; }
1222 EOF
1223                 cat > conftest.t <<EOF
1224                 SECTIONS
1225                 {
1226                   .bar : { *(.bar) }
1227                 }
1228                 INSERT AFTER .rela.dyn;
1229 EOF
1230                 libc_cv_insert=no
1231                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1232                   libc_cv_insert=yes
1233                 fi
1234                 rm -f conftest.*
1235                ])
1236 AC_SUBST(libc_cv_insert)
1237
1238 AC_CACHE_CHECK(for broken __attribute__((alias())),
1239                libc_cv_broken_alias_attribute,
1240                [cat > conftest.c <<EOF
1241                extern int foo (int x) __asm ("xyzzy");
1242                int bar (int x) { return x; }
1243                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1244                extern int dfoo;
1245                extern __typeof (dfoo) dfoo __asm ("abccb");
1246                int dfoo = 1;
1247 EOF
1248                libc_cv_broken_alias_attribute=yes
1249                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1250                  if grep 'xyzzy' conftest.s >/dev/null &&
1251                     grep 'abccb' conftest.s >/dev/null; then
1252                    libc_cv_broken_alias_attribute=no
1253                  fi
1254                fi
1255                rm -f conftest.c conftest.s
1256                ])
1257 if test $libc_cv_broken_alias_attribute = yes; then
1258   AC_MSG_ERROR(working alias attribute support required)
1259 fi
1260
1261 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1262                libc_cv_have_sdata_section,
1263                [echo "int i;" > conftest.c
1264                 libc_cv_have_sdata_section=no
1265                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1266                    | grep '\.sdata' >/dev/null; then
1267                   libc_cv_have_sdata_section=yes
1268                 fi
1269                 rm -f conftest.c conftest.so
1270                ])
1271 if test $libc_cv_have_sdata_section = yes; then
1272   AC_DEFINE(HAVE_SDATA_SECTION)
1273 fi
1274
1275 AC_CACHE_CHECK(for libunwind-support in compiler,
1276                libc_cv_cc_with_libunwind, [
1277   cat > conftest.c <<EOF
1278 int main (void) { return 0; }
1279 EOF
1280   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1281      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1282     libc_cv_cc_with_libunwind=yes
1283   else
1284     libc_cv_cc_with_libunwind=no
1285   fi
1286   rm -f conftest*])
1287 AC_SUBST(libc_cv_cc_with_libunwind)
1288 if test $libc_cv_cc_with_libunwind = yes; then
1289   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1290 fi
1291
1292 ASFLAGS_config=
1293 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1294                libc_cv_as_noexecstack, [dnl
1295 cat > conftest.c <<EOF
1296 void foo (void) { }
1297 EOF
1298 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1299                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1300    && grep .note.GNU-stack conftest.s >/dev/null \
1301    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1302                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1303 then
1304   libc_cv_as_noexecstack=yes
1305 else
1306   libc_cv_as_noexecstack=no
1307 fi
1308 rm -f conftest*])
1309 if test $libc_cv_as_noexecstack = yes; then
1310   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1311 fi
1312 AC_SUBST(ASFLAGS_config)
1313
1314 AC_CACHE_CHECK(for -z combreloc,
1315                libc_cv_z_combreloc, [dnl
1316 cat > conftest.c <<EOF
1317 extern int bar (int);
1318 extern int mumble;
1319 int foo (void) { return bar (mumble); }
1320 EOF
1321 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1322                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1323                         -nostdlib -nostartfiles
1324                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1325 then
1326 dnl The following test is a bit weak.  We must use a tool which can test
1327 dnl cross-platform since the gcc used can be a cross compiler.  Without
1328 dnl introducing new options this is not easily doable.  Instead use a tool
1329 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1330 dnl look for a section named .rel.dyn or .rela.dyn.
1331   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1332     libc_cv_z_combreloc=yes
1333   else
1334     libc_cv_z_combreloc=no
1335   fi
1336 else
1337   libc_cv_z_combreloc=no
1338 fi
1339 rm -f conftest*])
1340 if test "$libc_cv_z_combreloc" = yes; then
1341   AC_DEFINE(HAVE_Z_COMBRELOC)
1342 fi
1343 AC_SUBST(libc_cv_z_combreloc)
1344
1345 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1346                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1347 AC_SUBST(libc_cv_z_execstack)
1348
1349 LIBC_LINKER_FEATURE([-z start-stop-gc], [-Wl,-z,start-stop-gc],
1350                     [libc_cv_z_start_stop_gc=yes], [libc_cv_z_start_stop_gc=no])
1351 LIBC_CONFIG_VAR([have-z-start-stop-gc], [$libc_cv_z_start_stop_gc])
1352
1353 LIBC_LINKER_FEATURE([--depaudit], [-Wl,--depaudit,x],
1354                     [libc_cv_depaudit=yes], [libc_cv_depaudit=no])
1355 LIBC_CONFIG_VAR([have-depaudit], [$libc_cv_depaudit])
1356
1357 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1358                     [-Wl,--no-dynamic-linker],
1359                     [libc_cv_no_dynamic_linker=yes],
1360                     [libc_cv_no_dynamic_linker=no])
1361 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1362
1363 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1364 LIBC_TRY_CC_OPTION([-static-pie],
1365                    [libc_cv_static_pie=yes],
1366                    [libc_cv_static_pie=no])
1367 ])
1368 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1369
1370 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1371 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1372 ])
1373
1374 AC_SUBST(libc_cv_fpie)
1375
1376 AC_CACHE_CHECK(for --hash-style option,
1377                libc_cv_hashstyle, [dnl
1378 cat > conftest.c <<EOF
1379 int _start (void) { return 42; }
1380 EOF
1381 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1382                             -fPIC -shared -o conftest.so conftest.c
1383                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1384 then
1385   libc_cv_hashstyle=yes
1386 else
1387   libc_cv_hashstyle=no
1388 fi
1389 rm -f conftest*])
1390 AC_SUBST(libc_cv_hashstyle)
1391
1392 # The linker's default -shared behavior is good enough if it
1393 # does these things that our custom linker scripts ensure that
1394 # all allocated NOTE sections come first.
1395 if test "$use_default_link" = default; then
1396   AC_CACHE_CHECK([for sufficient default -shared layout],
1397                   libc_cv_use_default_link, [dnl
1398   libc_cv_use_default_link=no
1399   cat > conftest.s <<\EOF
1400           .section .note.a,"a",%note
1401           .balign 4
1402           .long 4,4,9
1403           .string "GNU"
1404           .string "foo"
1405           .section .note.b,"a",%note
1406           .balign 4
1407           .long 4,4,9
1408           .string "GNU"
1409           .string "bar"
1410 EOF
1411   if AC_TRY_COMMAND([dnl
1412   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1413        ac_try=`$READELF -S conftest.so | sed -n \
1414          ['${x;p;}
1415           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1416           t a
1417           b
1418           : a
1419           H']`
1420   then
1421     libc_seen_a=no libc_seen_b=no
1422     set -- $ac_try
1423     while test $# -ge 2 -a "$1" = NOTE; do
1424       case "$2" in
1425       .note.a) libc_seen_a=yes ;;
1426       .note.b) libc_seen_b=yes ;;
1427       esac
1428       shift 2
1429     done
1430     case "$libc_seen_a$libc_seen_b" in
1431     yesyes)
1432       libc_cv_use_default_link=yes
1433       ;;
1434     *)
1435       echo >&AS_MESSAGE_LOG_FD "\
1436 $libc_seen_a$libc_seen_b from:
1437 $ac_try"
1438       ;;
1439     esac
1440   fi
1441   rm -f conftest*])
1442   use_default_link=$libc_cv_use_default_link
1443 fi
1444
1445 AC_CACHE_CHECK(for GLOB_DAT reloc,
1446                libc_cv_has_glob_dat, [dnl
1447 cat > conftest.c <<EOF
1448 extern int mumble;
1449 int foo (void) { return mumble; }
1450 EOF
1451 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1452                         -fPIC -shared -o conftest.so conftest.c
1453                         -nostdlib -nostartfiles $no_ssp
1454                         1>&AS_MESSAGE_LOG_FD])
1455 then
1456 dnl look for GLOB_DAT relocation.
1457   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1458     libc_cv_has_glob_dat=yes
1459   else
1460     libc_cv_has_glob_dat=no
1461   fi
1462 else
1463   libc_cv_has_glob_dat=no
1464 fi
1465 rm -f conftest*])
1466 AC_SUBST(libc_cv_has_glob_dat)
1467
1468 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1469 cat > conftest.c <<EOF
1470 int foo;
1471 EOF
1472 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1473                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1474 then
1475   libc_cv_fno_toplevel_reorder=yes
1476 else
1477   libc_cv_fno_toplevel_reorder=no
1478 fi
1479 rm -f conftest*])
1480 if test $libc_cv_fno_toplevel_reorder = yes; then
1481   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1482 else
1483   fno_unit_at_a_time=-fno-unit-at-a-time
1484 fi
1485 AC_SUBST(fno_unit_at_a_time)
1486
1487 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1488 [dnl
1489 cat > conftest.c <<EOF
1490 __thread int i;
1491 void foo (void)
1492 {
1493   i = 10;
1494 }
1495 EOF
1496 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -fPIC -mtls-dialect=gnu2 -nostdlib -nostartfiles
1497                    conftest.c -o conftest 1>&AS_MESSAGE_LOG_FD])
1498 then
1499   libc_cv_mtls_dialect_gnu2=yes
1500 else
1501   libc_cv_mtls_dialect_gnu2=no
1502 fi
1503 rm -f conftest*])
1504 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1505 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1506
1507 AC_CACHE_CHECK(whether cc puts quotes around section names,
1508                libc_cv_have_section_quotes,
1509                [cat > conftest.c <<EOF
1510                 static const int foo
1511                 __attribute__ ((section ("bar"))) = 1;
1512 EOF
1513                 if ${CC-cc} -S conftest.c -o conftest.s; then
1514                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1515                     libc_cv_have_section_quotes=yes
1516                   else
1517                     libc_cv_have_section_quotes=no
1518                   fi
1519                 else
1520                   libc_cv_have_section_quotes=unknown
1521                 fi
1522                 rm -f conftest.{c,s}
1523                 ])
1524 if test $libc_cv_have_section_quotes = yes; then
1525   AC_DEFINE(HAVE_SECTION_QUOTES)
1526 fi
1527
1528 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1529 cat > conftest.c <<\EOF
1530 void zero (void *x)
1531 {
1532   __builtin_memset (x, 0, 1000);
1533 }
1534 EOF
1535 dnl
1536 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1537 then
1538   libc_cv_gcc_builtin_memset=no
1539 else
1540   libc_cv_gcc_builtin_memset=yes
1541 fi
1542 rm -f conftest* ])
1543 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1544   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1545 fi
1546
1547 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1548 cat > conftest.c <<\EOF
1549 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1550 char *foo (const char *a, const char *b)
1551 {
1552   return __builtin_strstr (a, b);
1553 }
1554 EOF
1555 dnl
1556 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1557 then
1558   libc_cv_gcc_builtin_redirection=yes
1559 else
1560   libc_cv_gcc_builtin_redirection=no
1561 fi
1562 rm -f conftest* ])
1563 if test "$libc_cv_gcc_builtin_redirection" = no; then
1564   AC_MSG_ERROR([support for the symbol redirection needed])
1565 fi
1566
1567 dnl Determine how to disable generation of FMA instructions.
1568 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1569                libc_cv_cc_nofma, [dnl
1570 libc_cv_cc_nofma=
1571 for opt in -ffp-contract=off -mno-fused-madd; do
1572   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1573 done])
1574 AC_SUBST(libc_cv_cc_nofma)
1575
1576 if test -n "$submachine"; then
1577   AC_CACHE_CHECK([for compiler option for CPU variant],
1578                  libc_cv_cc_submachine, [dnl
1579   libc_cv_cc_submachine=no
1580   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1581     LIBC_TRY_CC_OPTION([$opt], [
1582       libc_cv_cc_submachine="$opt"
1583       break], [])
1584   done])
1585   if test "x$libc_cv_cc_submachine" = xno; then
1586     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1587   fi
1588 fi
1589 AC_SUBST(libc_cv_cc_submachine)
1590
1591 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1592 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1593 cat > conftest.c <<EOF
1594 void
1595 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1596 foo (void) {}
1597 EOF
1598 libc_cv_cc_loop_to_function=no
1599 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1600 then
1601   libc_cv_cc_loop_to_function=yes
1602 fi
1603 rm -f conftest*])
1604 if test $libc_cv_cc_loop_to_function = yes; then
1605   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1606 fi
1607 AC_SUBST(libc_cv_cc_loop_to_function)
1608
1609 dnl Check whether we have the gd library available.
1610 AC_MSG_CHECKING(for libgd)
1611 if test "$with_gd" != "no"; then
1612   old_CFLAGS="$CFLAGS"
1613   CFLAGS="$CFLAGS $libgd_include"
1614   old_LDFLAGS="$LDFLAGS"
1615   LDFLAGS="$LDFLAGS $libgd_ldflags"
1616   old_LIBS="$LIBS"
1617   LIBS="$LIBS -lgd -lpng -lz -lm"
1618   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gd.h>]], [[gdImagePng (0, 0)]])],
1619                  [LIBGD=yes], [LIBGD=no])
1620   CFLAGS="$old_CFLAGS"
1621   LDFLAGS="$old_LDFLAGS"
1622   LIBS="$old_LIBS"
1623 else
1624   LIBGD=no
1625 fi
1626 AC_MSG_RESULT($LIBGD)
1627 AC_SUBST(LIBGD)
1628
1629 # SELinux detection
1630 if test x$with_selinux = xno ; then
1631   have_selinux=no;
1632 else
1633   # See if we have the SELinux library
1634   AC_CHECK_LIB(selinux, is_selinux_enabled,
1635                have_selinux=yes, have_selinux=no)
1636   if test x$with_selinux = xyes ; then
1637     if test x$have_selinux = xno ; then
1638       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1639     fi
1640   fi
1641 fi
1642 # Check if we're building with SELinux support.
1643 if test "x$have_selinux" = xyes; then
1644   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1645
1646   # See if we have the libaudit library
1647   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1648                have_libaudit=yes, have_libaudit=no)
1649   if test "x$have_libaudit" = xyes; then
1650     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1651   fi
1652   AC_SUBST(have_libaudit)
1653
1654   # See if we have the libcap library
1655   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1656   if test "x$have_libcap" = xyes; then
1657     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1658   fi
1659   AC_SUBST(have_libcap)
1660 fi
1661 AC_SUBST(have_selinux)
1662
1663 CPPUNDEFS=
1664 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1665 dnl Since we are building the implementations of the fortified functions here,
1666 dnl having the macro defined interacts very badly.
1667 dnl _FORTIFY_SOURCE requires compiler optimization level 1 (gcc -O1)
1668 dnl and above (see "man FEATURE_TEST_MACROS").
1669 dnl So do NOT replace AC_COMPILE_IFELSE with AC_PREPROC_IFELSE.
1670 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1671 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
1672 #ifdef _FORTIFY_SOURCE
1673 # error bogon
1674 #endif]])],
1675                 [libc_cv_predef_fortify_source=no],
1676                 [libc_cv_predef_fortify_source=yes])])
1677 if test $libc_cv_predef_fortify_source = yes; then
1678   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1679 fi
1680 AC_SUBST(CPPUNDEFS)
1681
1682 dnl Starting with binutils 2.35, GAS can attach multiple symbol versions
1683 dnl to one symbol (PR 23840).
1684 AC_CACHE_CHECK(whether the assembler requires one version per symbol,
1685                libc_cv_symver_needs_alias, [dnl
1686   cat > conftest.s <<EOF
1687         .text
1688 testfunc:
1689         .globl testfunc
1690         .symver testfunc, testfunc1@VERSION1
1691         .symver testfunc, testfunc1@VERSION2
1692 EOF
1693   libc_cv_symver_needs_alias=no
1694   if ${CC-cc} $ASFLAGS -c conftest.s 2>&AS_MESSAGE_LOG_FD; then
1695     libc_cv_symver_needs_alias=no
1696   else
1697     libc_cv_symver_needs_alias=yes
1698   fi
1699   rm conftest.*
1700 ])
1701 if test "$libc_cv_symver_needs_alias" = yes; then
1702   AC_DEFINE(SYMVER_NEEDS_ALIAS)
1703 fi
1704
1705 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1706                libc_cv_builtin_trap, [dnl
1707 libc_cv_builtin_trap=no
1708 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[__builtin_trap ()]])],[
1709 libc_undefs=`$NM -u conftest.o |
1710   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1711     2>&AS_MESSAGE_LOG_FD` || {
1712   AC_MSG_ERROR([confusing output from $NM -u])
1713 }
1714 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1715 if test -z "$libc_undefs"; then
1716   libc_cv_builtin_trap=yes
1717 fi],[])])
1718 if test $libc_cv_builtin_trap = yes; then
1719   AC_DEFINE([HAVE_BUILTIN_TRAP])
1720 fi
1721
1722 dnl C++ feature tests.
1723 AC_LANG_PUSH([C++])
1724
1725 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1726                libc_cv_cxx_thread_local, [
1727 old_CXXFLAGS="$CXXFLAGS"
1728 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1729 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1730 #include <thread>
1731
1732 // Compiler support.
1733 struct S
1734 {
1735   S ();
1736   ~S ();
1737 };
1738 thread_local S s;
1739 S * get () { return &s; }
1740
1741 // libstdc++ support.
1742 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1743 #error __cxa_thread_atexit_impl not supported
1744 #endif
1745 ])],
1746                [libc_cv_cxx_thread_local=yes],
1747                [libc_cv_cxx_thread_local=no])
1748 CXXFLAGS="$old_CXXFLAGS"
1749 ])
1750 AC_SUBST(libc_cv_cxx_thread_local)
1751
1752 AC_LANG_POP([C++])
1753 dnl End of C++ feature tests.
1754
1755 ### End of automated tests.
1756 ### Now run sysdeps configure fragments.
1757
1758 # They also can set these variables.
1759 use_ldconfig=no
1760 ldd_rewrite_script=no
1761 libc_cv_sysconfdir=$sysconfdir
1762 libc_cv_localstatedir=$localstatedir
1763 libc_cv_gcc_unwind_find_fde=no
1764 libc_cv_idn=no
1765 pthread_in_libc=yes
1766
1767 # Iterate over all the sysdep directories we will use, running their
1768 # configure fragments.
1769 for dir in $sysnames; do
1770   case $dir in
1771     /*) dest=$dir ;;
1772     *)  dest=$srcdir/$dir ;;
1773   esac
1774   if test -r $dest/configure; then
1775     AC_MSG_RESULT(running configure fragment for $dir)
1776     . $dest/configure
1777   fi
1778 done
1779
1780 if test x"$build_mathvec" = xnotset; then
1781   build_mathvec=no
1782 fi
1783 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1784
1785 AC_SUBST(libc_extra_cflags)
1786 AC_SUBST(libc_extra_cppflags)
1787
1788 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1789   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1790 fi
1791 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1792
1793 # A sysdeps configure fragment can reset this if IFUNC is not actually
1794 # usable even though the assembler knows how to generate the symbol type.
1795 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1796   AC_DEFINE(HAVE_IFUNC)
1797 fi
1798 LIBC_CONFIG_VAR([have-ifunc], [$libc_cv_ld_gnu_indirect_function])
1799
1800 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1801   AC_DEFINE(HAVE_GCC_IFUNC)
1802 fi
1803 LIBC_CONFIG_VAR([have-gcc-ifunc], [$libc_cv_gcc_indirect_function])
1804
1805 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1806 # configure fragment can override the value to prevent this AC_DEFINE.
1807 AC_SUBST(use_nscd)
1808 if test "x$use_nscd" != xno; then
1809   AC_DEFINE([USE_NSCD])
1810 fi
1811 if test "x$build_nscd" = xdefault; then
1812   build_nscd=$use_nscd
1813 fi
1814
1815 AC_SUBST(libc_cv_slibdir)
1816 AC_SUBST(libc_cv_rtlddir)
1817 AC_SUBST(libc_cv_complocaledir)
1818 AC_SUBST(libc_cv_sysconfdir)
1819 AC_SUBST(libc_cv_localstatedir)
1820 AC_SUBST(libc_cv_rootsbindir)
1821
1822 if test x$use_ldconfig = xyes; then
1823   AC_DEFINE(USE_LDCONFIG)
1824 fi
1825 AC_SUBST(use_ldconfig)
1826 AC_SUBST(ldd_rewrite_script)
1827
1828 AC_SUBST(static)
1829 AC_SUBST(shared)
1830
1831 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1832 [libc_cv_pic_default=yes
1833 cat > conftest.c <<EOF
1834 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1835 # error PIC is default.
1836 #endif
1837 EOF
1838 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1839   libc_cv_pic_default=no
1840 fi
1841 rm -f conftest.*])
1842 AC_SUBST(libc_cv_pic_default)
1843
1844 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1845 [libc_cv_cc_pie_default=yes
1846 cat > conftest.c <<EOF
1847 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1848 # error PIE is default.
1849 #endif
1850 EOF
1851 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1852   libc_cv_cc_pie_default=no
1853 fi
1854 rm -f conftest.*])
1855 libc_cv_pie_default=$libc_cv_cc_pie_default
1856 AC_SUBST(libc_cv_cc_pie_default)
1857 AC_SUBST(libc_cv_pie_default)
1858
1859 # Set the `multidir' variable by grabbing the variable from the compiler.
1860 # We do it once and save the result in a generated makefile.
1861 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1862 AC_SUBST(libc_cv_multidir)
1863
1864 if test "$static_pie" = yes; then
1865   # Check target support for static PIE
1866   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#ifndef SUPPORT_STATIC_PIE
1867 # error static PIE is not supported
1868 #endif]])], , AC_MSG_ERROR([the architecture does not support static PIE]))
1869   # The linker must support --no-dynamic-linker.
1870   if test "$libc_cv_no_dynamic_linker" != yes; then
1871     AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1872   fi
1873   # Default to PIE.
1874   libc_cv_pie_default=yes
1875   AC_DEFINE(ENABLE_STATIC_PIE)
1876 fi
1877 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1878
1879 AC_SUBST(profile)
1880 AC_SUBST(static_nss)
1881
1882 AC_SUBST(DEFINES)
1883
1884 dnl See sysdeps/mach/configure.ac for this variable.
1885 AC_SUBST(mach_interface_list)
1886
1887 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1888 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1889 AC_SUBST(VERSION)
1890 AC_SUBST(RELEASE)
1891
1892 if test "$pthread_in_libc" = yes; then
1893   AC_DEFINE(PTHREAD_IN_LIBC)
1894 fi
1895 AC_SUBST(pthread_in_libc)
1896
1897 AC_CONFIG_FILES([config.make Makefile])
1898 AC_CONFIG_COMMANDS([default],[[
1899 case $CONFIG_FILES in *config.make*)
1900 echo "$config_vars" >> config.make;;
1901 esac
1902 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1903 AC_OUTPUT