sysdeps/ia64/fpu/s_rint.S

   1 .file "rint.s"
   2
   3 // Copyright (c) 2000, 2001, Intel Corporation
   4 // All rights reserved.
   5 //
   6 // Contributed 2/2/2000 by John Harrison, Ted Kubaska, Bob Norin, Shane Story,
   7 // and Ping Tak Peter Tang of the Computational Software Lab, Intel Corporation.
   8 //
   9 // WARRANTY DISCLAIMER
  10 //
  11 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  12 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  13 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  14 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  15 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  16 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  17 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  18 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  19 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  20 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  21 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  22 //
  23 // Intel Corporation is the author of this code, and requests that all
  24 // problem reports or change requests be submitted to it directly at
  25 // http://developer.intel.com/opensource.
  26 //
  27 // History
  28 //==============================================================
  29 // 2/02/00: Initial version
  30 // 2/08/01  Corrected behavior for all rounding modes.
  31 //
  32 // API
  33 //==============================================================
  34 // double rint(double x)
  35
  36 #include "libm_support.h"
  37
  38 //
  39 // general registers used:
  40 //
  41 rint_GR_FFFF      = r14
  42 rint_GR_signexp   = r15
  43 rint_GR_exponent  = r16
  44 rint_GR_17ones    = r17
  45 rint_GR_10033     = r18
  46 rint_GR_fpsr      = r19
  47 rint_GR_rcs0      = r20
  48 rint_GR_rcs0_mask = r21
  49
  50
  51 // predicate registers used:
  52 // p6-11
  53
  54 // floating-point registers used:
  55
  56 RINT_NORM_f8      = f9
  57 RINT_FFFF         = f10
  58 RINT_INEXACT      = f11
  59 RINT_FLOAT_INT_f8 = f12
  60 RINT_INT_f8       = f13
  61
  62 // Overview of operation
  63 //==============================================================
  64
  65 // double rint(double x)
  66 // Return an integer value (represented as a double) that is x rounded to integer in current
  67 // rounding mode
  68 // Inexact is set if x != rint(x)
  69 // *******************************************************************************
  70
  71 // Set denormal flag for denormal input and
  72 // and take denormal fault if necessary.
  73
  74 // Is the input an integer value already?
  75
  76 // double_extended
  77 // if the exponent is >= 1003e => 3F(true) = 63(decimal)
  78 // we have a significand of 64 bits 1.63-bits.
  79 // If we multiply by 2^63, we no longer have a fractional part
  80 // So input is an integer value already.
  81
  82 // double
  83 // if the exponent is >= 10033 => 34(true) = 52(decimal)
  84 // 34 + 3ff = 433
  85 // we have a significand of 53 bits 1.52-bits. (implicit 1)
  86 // If we multiply by 2^52, we no longer have a fractional part
  87 // So input is an integer value already.
  88
  89 // single
  90 // if the exponent is >= 10016 => 17(true) = 23(decimal)
  91 // we have a significand of 53 bits 1.52-bits. (implicit 1)
  92 // If we multiply by 2^52, we no longer have a fractional part
  93 // So input is an integer value already.
  94
  95 // If x is NAN, ZERO, or INFINITY, then  return
  96
  97 // qnan snan inf norm     unorm 0 -+
  98 // 1    1    1   0        0     1 11     0xe7
  99
 100
 101 .align 32
 102 .global rint#
 103
 104 .section .text
 105 .proc  rint#
 106 .align 32
 107
 108
 109 rint:
 110 #ifdef _LIBC
 111 .global __rint
 112 .type __rint,@function
 113 __rint:
 114 #endif
 115
 116 { .mfi
 117       mov rint_GR_fpsr = ar40           // Read the fpsr--need to check rc.s0
 118       fcvt.fx.s1     RINT_INT_f8  = f8
 119       addl            rint_GR_10033 = 0x10033, r0
 120 }
 121 { .mfi
 122       mov        rint_GR_FFFF      = -1
 123       fnorm.s1        RINT_NORM_f8  = f8
 124       mov         rint_GR_17ones    = 0x1FFFF
 125 ;;
 126 }
 127
 128 { .mfi
 129       setf.sig    RINT_FFFF  = rint_GR_FFFF
 130       fclass.m.unc  p6,p0 = f8, 0xe7
 131       mov         rint_GR_rcs0_mask  = 0x0c00
 132 ;;
 133 }
 134
 135 { .mfb
 136         nop.m 999
 137 (p6)  fnorm.d f8 = f8
 138 (p6)  br.ret.spnt   b0    // Exit if x nan, inf, zero
 139 ;;
 140 }
 141
 142 { .mfi
 143         nop.m 999
 144       fcvt.xf         RINT_FLOAT_INT_f8   = RINT_INT_f8
 145         nop.i 999
 146 ;;
 147 }
 148
 149 { .mfi
 150       getf.exp rint_GR_signexp  = RINT_NORM_f8
 151       fcmp.eq.s0  p8,p0 = f8,f0      // Dummy op to set denormal
 152         nop.i 999
 153 ;;
 154 }
 155
 156
 157 { .mii
 158         nop.m 999
 159         nop.i 999
 160       and      rint_GR_exponent = rint_GR_signexp, rint_GR_17ones
 161 ;;
 162 }
 163
 164 { .mmi
 165       cmp.ge.unc      p7,p6 = rint_GR_exponent, rint_GR_10033
 166       and rint_GR_rcs0 = rint_GR_rcs0_mask, rint_GR_fpsr
 167         nop.i 999
 168 ;;
 169 }
 170
 171 // Check to see if s0 rounding mode is round to nearest.  If not then set s2
 172 // rounding mode to that of s0 and repeat conversions.
 173 L(RINT_COMMON):
 174 { .mfb
 175       cmp.ne   p11,p0 = rint_GR_rcs0, r0
 176 (p6) fclass.m.unc   p9,p10  = RINT_FLOAT_INT_f8, 0x07  // Test for result=0
 177 (p11) br.cond.spnt L(RINT_NOT_ROUND_NEAREST)  // Branch if not round to nearest
 178 ;;
 179 }
 180
 181 { .mfi
 182         nop.m 999
 183 (p6) fcmp.eq.unc.s1  p0,p8  = RINT_FLOAT_INT_f8, RINT_NORM_f8
 184         nop.i 999
 185 }
 186 { .mfi
 187         nop.m 999
 188 (p7) fnorm.d.s0   f8 = f8
 189         nop.i 999
 190 ;;
 191 }
 192
 193 // If result is zero, merge sign of input
 194 { .mfi
 195      nop.m 999
 196 (p9) fmerge.s f8 = f8, RINT_FLOAT_INT_f8
 197      nop.i 999
 198 }
 199 { .mfi
 200       nop.m 999
 201 (p10) fnorm.d f8 = RINT_FLOAT_INT_f8
 202      nop.i 999
 203 ;;
 204 }
 205
 206 { .mfb
 207      nop.m 999
 208 (p8) fmpy.s0     RINT_INEXACT = RINT_FFFF,RINT_FFFF  // Dummy to set inexact
 209      br.ret.sptk    b0
 210 ;;
 211 }
 212
 213 L(RINT_NOT_ROUND_NEAREST):
 214 // Set rounding mode of s2 to that of s0
 215 { .mfi
 216       mov rint_GR_rcs0 = r0       // Clear so we don't come back here
 217       fsetc.s2     0x7f, 0x40
 218         nop.i 999
 219 ;;
 220 }
 221
 222 { .mfi
 223         nop.m 999
 224       fcvt.fx.s2     RINT_INT_f8  = f8
 225         nop.i 999
 226 ;;
 227 }
 228
 229 { .mfb
 230         nop.m 999
 231       fcvt.xf         RINT_FLOAT_INT_f8   = RINT_INT_f8
 232       br.cond.sptk  L(RINT_COMMON)
 233 ;;
 234 }
 235
 236
 237 .endp rint
 238 ASM_SIZE_DIRECTIVE(rint)
 239 #ifdef _LIBC
 240 ASM_SIZE_DIRECTIVE(__rint)
 241 #endif