sysdeps/sparc/sparc64/multiarch/memset-niagara1.S

   1 /* Set a block of memory to some byte value.  For SUN4V Niagara.
   2    Copyright (C) 2006, 2008 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller (davem@davemloft.net)
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22 #define ASI_BLK_INIT_QUAD_LDD_P 0xe2
  23 #define ASI_P                   0x80
  24 #define ASI_PNF                 0x82
  25
  26 #ifndef XCC
  27 #define USE_BPR
  28 #define XCC xcc
  29 #endif
  30
  31 #if !defined NOT_IN_libc
  32
  33         .register       %g2,#scratch
  34
  35         .text
  36         .align          32
  37
  38 ENTRY(__memset_niagara1)
  39         /* %o0=buf, %o1=pat, %o2=len */
  40         and             %o1, 0xff, %o3
  41         mov             %o2, %o1
  42         sllx            %o3, 8, %g1
  43         or              %g1, %o3, %o2
  44         sllx            %o2, 16, %g1
  45         or              %g1, %o2, %o2
  46         sllx            %o2, 32, %g1
  47         ba,pt           %XCC, 1f
  48          or             %g1, %o2, %o2
  49 END(__memset_niagara1)
  50
  51 ENTRY(__bzero_niagara1)
  52         clr             %o2
  53 1:
  54 # ifndef USE_BRP
  55         srl             %o1, 0, %o1
  56 # endif
  57         brz,pn          %o1, 90f
  58          mov            %o0, %o3
  59
  60         wr              %g0, ASI_P, %asi
  61
  62         cmp             %o1, 15
  63         bl,pn           %icc, 70f
  64          andcc          %o0, 0x7, %g1
  65         be,pt           %XCC, 2f
  66          mov            8, %g2
  67         sub             %g2, %g1, %g1
  68         sub             %o1, %g1, %o1
  69 1:      stba            %o2, [%o0 + 0x00] %asi
  70         subcc           %g1, 1, %g1
  71         bne,pt          %XCC, 1b
  72          add            %o0, 1, %o0
  73 2:      cmp             %o1, 128
  74         bl,pn           %icc, 60f
  75          andcc          %o0, (64 - 1), %g1
  76         be,pt           %XCC, 40f
  77          mov            64, %g2
  78         sub             %g2, %g1, %g1
  79         sub             %o1, %g1, %o1
  80 1:      stxa            %o2, [%o0 + 0x00] %asi
  81         subcc           %g1, 8, %g1
  82         bne,pt          %XCC, 1b
  83          add            %o0, 8, %o0
  84
  85 40:
  86         wr              %g0, ASI_BLK_INIT_QUAD_LDD_P, %asi
  87         andn            %o1, (64 - 1), %g1
  88         sub             %o1, %g1, %o1
  89 50:
  90         stxa            %o2, [%o0 + 0x00] %asi
  91         stxa            %o2, [%o0 + 0x08] %asi
  92         stxa            %o2, [%o0 + 0x10] %asi
  93         stxa            %o2, [%o0 + 0x18] %asi
  94         stxa            %o2, [%o0 + 0x20] %asi
  95         stxa            %o2, [%o0 + 0x28] %asi
  96         stxa            %o2, [%o0 + 0x30] %asi
  97         stxa            %o2, [%o0 + 0x38] %asi
  98         subcc           %g1, 64, %g1
  99         bne,pt          %XCC, 50b
 100          add            %o0, 64, %o0
 101
 102         wr              %g0, ASI_P, %asi
 103         brz,pn          %o1, 80f
 104 60:
 105          andncc         %o1, 0x7, %g1
 106         be,pn           %XCC, 2f
 107          sub            %o1, %g1, %o1
 108 1:      stxa            %o2, [%o0 + 0x00] %asi
 109         subcc           %g1, 8, %g1
 110         bne,pt          %XCC, 1b
 111          add            %o0, 8, %o0
 112 2:      brz,pt          %o1, 80f
 113          nop
 114
 115 70:
 116 1:      stba            %o2, [%o0 + 0x00] %asi
 117         subcc           %o1, 1, %o1
 118         bne,pt          %icc, 1b
 119          add            %o0, 1, %o0
 120
 121         /* fallthrough */
 122
 123 80:
 124         wr              %g0, ASI_PNF, %asi
 125
 126 90:
 127         retl
 128          mov            %o3, %o0
 129 END(__bzero_niagara1)
 130
 131 #endif