sysdeps/s390/s390-32/memcpy.S

   1 /* memcpy - copy a block from source to destination.  S/390 version.
   2    Copyright (C) 2000, 2001, 2003 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 /* INPUT PARAMETERS
  21      %r2 = address of destination memory area
  22      %r3 = address of source memory area
  23      %r4 = number of bytes to copy.  */
  24
  25 #include "sysdep.h"
  26 #include "asm-syntax.h"
  27
  28         .text
  29 ENTRY(memcpy)
  30         ltr     %r4,%r4
  31         jz      .L3
  32         ahi     %r4,-1              # length - 1
  33         lr      %r1,%r2             # copy destination address
  34         lr      %r5,%r4
  35         srl     %r5,8
  36         ltr     %r5,%r5             # < 256 bytes to move ?
  37         jz      .L1
  38         chi     %r5,255             # > 1MB to move ?
  39         jh      .L4
  40 .L0:    mvc     0(256,%r1),0(%r3)   # move in 256 byte chunks
  41         la      %r1,256(%r1)
  42         la      %r3,256(%r3)
  43         brct    %r5,.L0
  44 .L1:    bras    %r5,.L2             # setup base pointer for execute
  45         mvc     0(1,%r1),0(%r3)     # instruction for execute
  46 .L2:    ex      %r4,0(%r5)          # execute mvc with length ((%r4)&255)+1
  47 .L3:    br      %r14
  48         # data copies > 1MB are faster with mvcle.
  49 .L4:    ahi     %r4,1               # length + 1
  50         lr      %r5,%r4             # source length
  51         lr      %r4,%r3             # source address
  52         lr      %r3,%r5             # destination length = source length
  53 .L5:    mvcle   %r2,%r4,0           # thats it, MVCLE is your friend
  54         jo      .L5
  55         lr      %r2,%r1             # return destination address
  56         br      %r14
  57 END(memcpy)
  58 libc_hidden_builtin_def (memcpy)