sysdeps/powerpc/powerpc64/strncmp.S

   1 /* Optimized strcmp implementation for PowerPC64.
   2    Copyright (C) 2003, 2011 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <bp-sym.h>
  21 #include <bp-asm.h>
  22
  23 /* See strlen.s for comments on how the end-of-string testing works.  */
  24
  25 /* int [r3] strncmp (const char *s1 [r3], const char *s2 [r4], size_t size [r5])  */
  26
  27 EALIGN (BP_SYM(strncmp), 4, 0)
  28         CALL_MCOUNT 3
  29
  30 #define rTMP    r0
  31 #define rRTN    r3
  32 #define rSTR1   r3      /* first string arg */
  33 #define rSTR2   r4      /* second string arg */
  34 #define rN      r5      /* max string length */
  35 /* Note:  The Bounded pointer support in this code is broken.  This code
  36    was inherited from PPC32 and that support was never completed.
  37    Current PPC gcc does not support -fbounds-check or -fbounded-pointers.  */
  38 #define rWORD1  r6      /* current word in s1 */
  39 #define rWORD2  r7      /* current word in s2 */
  40 #define rFEFE   r8      /* constant 0xfefefefefefefeff (-0x0101010101010101) */
  41 #define r7F7F   r9      /* constant 0x7f7f7f7f7f7f7f7f */
  42 #define rNEG    r10     /* ~(word in s1 | 0x7f7f7f7f7f7f7f7f) */
  43 #define rBITDIF r11     /* bits that differ in s1 & s2 words */
  44
  45         dcbt    0,rSTR1
  46         or      rTMP, rSTR2, rSTR1
  47         lis     r7F7F, 0x7f7f
  48         dcbt    0,rSTR2
  49         clrldi. rTMP, rTMP, 61
  50         cmpldi  cr1, rN, 0
  51         lis     rFEFE, -0x101
  52         bne     L(unaligned)
  53 /* We are doubleword alligned so set up for two loops.  first a double word
  54    loop, then fall into the byte loop if any residual.  */
  55         srdi.   rTMP, rN, 3
  56         clrldi  rN, rN, 61
  57         addi    rFEFE, rFEFE, -0x101
  58         addi    r7F7F, r7F7F, 0x7f7f
  59         cmpldi  cr1, rN, 0
  60         beq     L(unaligned)
  61
  62         mtctr   rTMP    /* Power4 wants mtctr 1st in dispatch group.  */
  63         ld      rWORD1, 0(rSTR1)
  64         ld      rWORD2, 0(rSTR2)
  65         sldi    rTMP, rFEFE, 32
  66         insrdi  r7F7F, r7F7F, 32, 0
  67         add     rFEFE, rFEFE, rTMP
  68         b       L(g1)
  69
  70 L(g0):
  71         ldu     rWORD1, 8(rSTR1)
  72         bne-    cr1, L(different)
  73         ldu     rWORD2, 8(rSTR2)
  74 L(g1):  add     rTMP, rFEFE, rWORD1
  75         nor     rNEG, r7F7F, rWORD1
  76         bdz     L(tail)
  77         and.    rTMP, rTMP, rNEG
  78         cmpd    cr1, rWORD1, rWORD2
  79         beq+    L(g0)
  80
  81 /* OK. We've hit the end of the string. We need to be careful that
  82    we don't compare two strings as different because of gunk beyond
  83    the end of the strings...  */
  84
  85 L(endstring):
  86         and     rTMP, r7F7F, rWORD1
  87         beq     cr1, L(equal)
  88         add     rTMP, rTMP, r7F7F
  89         xor.    rBITDIF, rWORD1, rWORD2
  90
  91         andc    rNEG, rNEG, rTMP
  92         blt-    L(highbit)
  93         cntlzd  rBITDIF, rBITDIF
  94         cntlzd  rNEG, rNEG
  95         addi    rNEG, rNEG, 7
  96         cmpd    cr1, rNEG, rBITDIF
  97         sub     rRTN, rWORD1, rWORD2
  98         blt-    cr1, L(equal)
  99         sradi   rRTN, rRTN, 63
 100         ori     rRTN, rRTN, 1
 101         blr
 102 L(equal):
 103         li      rRTN, 0
 104         blr
 105
 106 L(different):
 107         ldu     rWORD1, -8(rSTR1)
 108         xor.    rBITDIF, rWORD1, rWORD2
 109         sub     rRTN, rWORD1, rWORD2
 110         blt-    L(highbit)
 111         sradi   rRTN, rRTN, 63
 112         ori     rRTN, rRTN, 1
 113         blr
 114 L(highbit):
 115         srdi    rWORD2, rWORD2, 56
 116         srdi    rWORD1, rWORD1, 56
 117         sub     rRTN, rWORD1, rWORD2
 118         blr
 119
 120
 121 /* Oh well.  In this case, we just do a byte-by-byte comparison.  */
 122         .align 4
 123 L(tail):
 124         and.    rTMP, rTMP, rNEG
 125         cmpd    cr1, rWORD1, rWORD2
 126         bne-    L(endstring)
 127         addi    rSTR1, rSTR1, 8
 128         bne-    cr1, L(different)
 129         addi    rSTR2, rSTR2, 8
 130         cmpldi  cr1, rN, 0
 131 L(unaligned):
 132         mtctr   rN      /* Power4 wants mtctr 1st in dispatch group */
 133         bgt     cr1, L(uz)
 134 L(ux):
 135         li      rRTN, 0
 136         blr
 137         .align 4
 138 L(uz):
 139         lbz     rWORD1, 0(rSTR1)
 140         lbz     rWORD2, 0(rSTR2)
 141         nop
 142         b       L(u1)
 143 L(u0):
 144         lbzu    rWORD2, 1(rSTR2)
 145 L(u1):
 146         bdz     L(u3)
 147         cmpdi   cr1, rWORD1, 0
 148         cmpd    rWORD1, rWORD2
 149         beq-    cr1, L(u3)
 150         lbzu    rWORD1, 1(rSTR1)
 151         bne-    L(u2)
 152         lbzu    rWORD2, 1(rSTR2)
 153         bdz     L(u3)
 154         cmpdi   cr1, rWORD1, 0
 155         cmpd    rWORD1, rWORD2
 156         bne-    L(u3)
 157         lbzu    rWORD1, 1(rSTR1)
 158         bne+    cr1, L(u0)
 159
 160 L(u2):  lbzu    rWORD1, -1(rSTR1)
 161 L(u3):  sub     rRTN, rWORD1, rWORD2
 162         blr
 163 END (BP_SYM (strncmp))
 164 libc_hidden_builtin_def (strncmp)