sysdeps/powerpc/powerpc32/add_n.S

   1 /* Add two limb vectors of equal, non-zero length for PowerPC.
   2    Copyright (C) 1997, 1999, 2000 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <bp-sym.h>
  21 #include <bp-asm.h>
  22
  23 /* mp_limb_t mpn_add_n (mp_ptr res_ptr, mp_srcptr s1_ptr, mp_srcptr s2_ptr,
  24                         mp_size_t size)
  25    Calculate s1+s2 and put result in res_ptr; return carry, 0 or 1.  */
  26
  27 /* Note on optimisation: This code is optimal for the 601.  Almost every other
  28    possible 2-unrolled inner loop will not be.  Also, watch out for the
  29    alignment...  */
  30
  31 EALIGN (BP_SYM (__mpn_add_n), 3, 0)
  32
  33 #if __BOUNDED_POINTERS__
  34         slwi r10,r6,2           /* convert limbs to bytes */
  35         CHECK_BOUNDS_BOTH_WIDE (r3, r8, r9, r10)
  36         CHECK_BOUNDS_BOTH_WIDE (r4, r8, r9, r10)
  37         CHECK_BOUNDS_BOTH_WIDE (r5, r8, r9, r10)
  38 #endif
  39 /* Set up for loop below.  */
  40         mtcrf 0x01,r6
  41         srwi. r7,r6,1
  42         li    r10,0
  43         mtctr r7
  44         bt    31,L(2)
  45
  46 /* Clear the carry.  */
  47         addic r0,r0,0
  48 /* Adjust pointers for loop.  */
  49         addi  r3,r3,-4
  50         addi  r4,r4,-4
  51         addi  r5,r5,-4
  52         b     L(0)
  53
  54 L(2):   lwz  r7,0(r5)
  55         lwz  r6,0(r4)
  56         addc r6,r6,r7
  57         stw  r6,0(r3)
  58         beq  L(1)
  59
  60 /* The loop.  */
  61
  62 /* Align start of loop to an odd word boundary to guarantee that the
  63    last two words can be fetched in one access (for 601).  */
  64 L(0):   lwz  r9,4(r4)
  65         lwz  r8,4(r5)
  66         lwzu r6,8(r4)
  67         lwzu r7,8(r5)
  68         adde r8,r9,r8
  69         stw  r8,4(r3)
  70         adde r6,r6,r7
  71         stwu r6,8(r3)
  72         bdnz L(0)
  73 /* Return the carry.  */
  74 L(1):   addze r3,r10
  75         blr
  76 END (BP_SYM (__mpn_add_n))