sysdeps/i386/start.S

   1 /* Startup code compliant to the ELF i386 ABI.
   2    Copyright (C) 1995-2022 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library; if not, see
  34    <https://www.gnu.org/licenses/>.  */
  35
  36 /* This is the canonical entry point, usually the first thing in the text
  37    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
  38    point runs, most registers' values are unspecified, except for:
  39
  40    %edx         Contains a function pointer to be registered with `atexit'.
  41                 This is how the dynamic linker arranges to have DT_FINI
  42                 functions called for shared libraries that have been loaded
  43                 before this code runs.
  44
  45    %esp         The stack contains the arguments and environment:
  46                 0(%esp)                 argc
  47                 4(%esp)                 argv[0]
  48                 ...
  49                 (4*argc)(%esp)          NULL
  50                 (4*(argc+1))(%esp)      envp[0]
  51                 ...
  52                                         NULL
  53 */
  54
  55 #include <sysdep.h>
  56
  57 ENTRY (_start)
  58         /* Clearing frame pointer is insufficient, use CFI.  */
  59         cfi_undefined (eip)
  60         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  61            the outermost frame obviously.  */
  62         xorl %ebp, %ebp
  63
  64         /* Extract the arguments as encoded on the stack and set up
  65            the arguments for `main': argc, argv.  envp will be determined
  66            later in __libc_start_main.  */
  67         popl %esi               /* Pop the argument count.  */
  68         movl %esp, %ecx         /* argv starts just at the current stack top.*/
  69
  70         /* Before pushing the arguments align the stack to a 16-byte
  71         (SSE needs 16-byte alignment) boundary to avoid penalties from
  72         misaligned accesses.  Thanks to Edward Seidl <seidl@janed.com>
  73         for pointing this out.  */
  74         andl $0xfffffff0, %esp
  75         pushl %eax              /* Push garbage because we allocate
  76                                    28 more bytes.  */
  77
  78         /* Provide the highest stack address to the user code (for stacks
  79            which grow downwards).  */
  80         pushl %esp
  81
  82         pushl %edx              /* Push address of the shared library
  83                                    termination function.  */
  84
  85 #ifdef PIC
  86         /* Load PIC register.  */
  87         call 1f
  88         addl $_GLOBAL_OFFSET_TABLE_, %ebx
  89
  90         /* This used to be the addresses of .fini and .init.  */
  91         pushl $0
  92         pushl $0
  93
  94         pushl %ecx              /* Push second argument: argv.  */
  95         pushl %esi              /* Push first argument: argc.  */
  96
  97 # ifdef SHARED
  98         pushl main@GOT(%ebx)
  99 # else
 100         /* Avoid relocation in static PIE since _start is called before
 101            it is relocated.  This also avoid rely on linker optimization to
 102            transform 'movl main@GOT(%ebx), %eax' to 'leal main@GOTOFF(%ebx)'
 103            if main is defined locally.  */
 104         leal __wrap_main@GOTOFF(%ebx), %eax
 105         pushl %eax
 106 # endif
 107
 108         /* Call the user's main function, and exit with its value.
 109            But let the libc call main.    */
 110         call __libc_start_main@PLT
 111 #else
 112         /* This used to be the addresses of .fini and .init.  */
 113         pushl $0
 114         pushl $0
 115
 116         pushl %ecx              /* Push second argument: argv.  */
 117         pushl %esi              /* Push first argument: argc.  */
 118
 119         pushl $main
 120
 121         /* Call the user's main function, and exit with its value.
 122            But let the libc call main.    */
 123         call __libc_start_main
 124 #endif
 125
 126         hlt                     /* Crash if somehow `exit' does return.  */
 127
 128 #ifdef PIC
 129 1:      movl    (%esp), %ebx
 130         ret
 131 #endif
 132
 133 #if defined PIC && !defined SHARED
 134 __wrap_main:
 135         _CET_ENDBR
 136         jmp     main@PLT
 137 #endif
 138 END (_start)
 139
 140 /* To fulfill the System V/i386 ABI we need this symbol.  Yuck, it's so
 141    meaningless since we don't support machines < 80386.  */
 142         .section .rodata
 143         .globl _fp_hw
 144 _fp_hw: .long 3
 145         .size _fp_hw, 4
 146         .type _fp_hw,@object
 147
 148 /* Define a symbol for the first piece of initialized data.  */
 149         .data
 150         .globl __data_start
 151 __data_start:
 152         .long 0
 153         .weak data_start
 154         data_start = __data_start