sysdeps/alpha/strlen.S

   1 /* Copyright (C) 1996-2016 Free Software Foundation, Inc.
   2    Contributed by David Mosberger (davidm@cs.arizona.edu).
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* Finds length of a 0-terminated string.  Optimized for the Alpha
  20    architecture:
  21
  22       - memory accessed as aligned quadwords only
  23       - uses cmpbge to compare 8 bytes in parallel
  24       - does binary search to find 0 byte in last quadword (HAKMEM
  25         needed 12 instructions to do this instead of the 8 instructions
  26         that the binary search needs).
  27 */
  28
  29 #include <sysdep.h>
  30
  31         .set noreorder
  32         .set noat
  33
  34 ENTRY(strlen)
  35 #ifdef PROF
  36         ldgp    gp, 0(pv)
  37         lda     AT, _mcount
  38         jsr     AT, (AT), _mcount
  39         .prologue 1
  40 #else
  41         .prologue 0
  42 #endif
  43
  44         ldq_u   t0, 0(a0)       # load first quadword (a0 may be misaligned)
  45         lda     t1, -1(zero)
  46         insqh   t1, a0, t1
  47         andnot  a0, 7, v0
  48         or      t1, t0, t0
  49         nop                     # dual issue the next two on ev5
  50         cmpbge  zero, t0, t1    # t1 <- bitmask: bit i == 1 <==> i-th byte == 0
  51         bne     t1, $found
  52
  53 $loop:  ldq     t0, 8(v0)
  54         addq    v0, 8, v0       # addr += 8
  55         cmpbge  zero, t0, t1
  56         beq     t1, $loop
  57
  58 $found: negq    t1, t2          # clear all but least set bit
  59         and     t1, t2, t1
  60
  61         and     t1, 0xf0, t2    # binary search for that set bit
  62         and     t1, 0xcc, t3
  63         and     t1, 0xaa, t4
  64         cmovne  t2, 4, t2
  65         cmovne  t3, 2, t3
  66         cmovne  t4, 1, t4
  67         addq    t2, t3, t2
  68         addq    v0, t4, v0
  69         addq    v0, t2, v0
  70         nop                     # dual issue next two on ev4 and ev5
  71
  72         subq    v0, a0, v0
  73         ret
  74
  75         END(strlen)
  76 libc_hidden_builtin_def (strlen)