sysdeps/x86_64/fpu/e_logl.S

   1 /*
   2  * Written by J.T. Conklin <jtc@netbsd.org>.
   3  * Public domain.
   4  *
   5  * Adapted for `long double' by Ulrich Drepper <drepper@cygnus.com>.
   6  * Adapted for x86-64 by Andreas Jaeger <aj@suse.de>.
   7  */
   8
   9 #include <machine/asm.h>
  10
  11
  12         .section .rodata.cst8,"aM",@progbits,8
  13
  14         .p2align 3
  15         .type one,@object
  16 one:    .double 1.0
  17         ASM_SIZE_DIRECTIVE(one)
  18         /* It is not important that this constant is precise.  It is only
  19            a value which is known to be on the safe side for using the
  20            fyl2xp1 instruction.  */
  21         .type limit,@object
  22 limit:  .double 0.29
  23         ASM_SIZE_DIRECTIVE(limit)
  24
  25
  26 #ifdef PIC
  27 # define MO(op) op##(%rip)
  28 #else
  29 # define MO(op) op
  30 #endif
  31
  32         .text
  33 ENTRY(__ieee754_logl)
  34         fldln2                  // log(2)
  35         fldt    8(%rsp)         // x : log(2)
  36         fxam
  37         fnstsw
  38         fld     %st             // x : x : log(2)
  39         testb   $1, %ah
  40         jnz     3f              // in case x is NaN or +-Inf
  41 4:      fsubl   MO(one)         // x-1 : x : log(2)
  42         fld     %st             // x-1 : x-1 : x : log(2)
  43         fabs                    // |x-1| : x-1 : x : log(2)
  44         fcompl  MO(limit)       // x-1 : x : log(2)
  45         fnstsw                  // x-1 : x : log(2)
  46         andb    $0x45, %ah
  47         jz      2f
  48         fstp    %st(1)          // x-1 : log(2)
  49         fyl2xp1                 // log(x)
  50         ret
  51
  52 2:      fstp    %st(0)          // x : log(2)
  53         fyl2x                   // log(x)
  54         ret
  55
  56 3:      testb   $4, %ah
  57         jnz     4b              // in case x is +-Inf
  58         fstp    %st(1)
  59         fstp    %st(1)
  60         ret
  61 END (__ieee754_logl)
  62
  63
  64 ENTRY(__logl_finite)
  65         fldln2                  // log(2)
  66         fldt    8(%rsp)         // x : log(2)
  67         fld     %st             // x : x : log(2)
  68         fsubl   MO(one)         // x-1 : x : log(2)
  69         fld     %st             // x-1 : x-1 : x : log(2)
  70         fabs                    // |x-1| : x-1 : x : log(2)
  71         fcompl  MO(limit)       // x-1 : x : log(2)
  72         fnstsw                  // x-1 : x : log(2)
  73         andb    $0x45, %ah
  74         jz      2b
  75         fstp    %st(1)          // x-1 : log(2)
  76         fyl2xp1                 // log(x)
  77         ret
  78 END (__logl_finite)