scripts/gen-as-const.awk

   1 # Script used in producing headers of assembly constants from C expressions.
   2 # The input to this script looks like:
   3 #       #cpp-directive ...
   4 #       NAME1
   5 #       NAME2 expression ...
   6 # The output of this script is C code to be run through gcc -S and then
   7 # massaged to extract the integer constant values of the given C expressions.
   8 # A line giving just a name implies an expression consisting of just that name.
   9
  10 BEGIN { started = 0 }
  11
  12 # cpp directives go straight through.
  13 /^#/ { print; next }
  14
  15 NF >= 1 && !started {
  16   if (test) {
  17     print "\n#include <inttypes.h>";
  18     print "\n#include <stdio.h>";
  19     print "\n#if __WORDSIZE__ == 64";
  20     print "\ntypedef uint64_t c_t;";
  21     print "\n#define U(n) UINT64_C (n)";
  22     print "\n#define PRI PRId64";
  23     print "\n#else";
  24     print "\ntypedef uint32_t c_t;";
  25     print "\n#define U(n) UINT32_C (n)";
  26     print "\n#define PRI PRId32";
  27     print "\n#endif";
  28     print "\nstatic int do_test (void)\n{\n  int bad = 0, good = 0;\n";
  29     print "#define TEST(name, source, expr) \\\n" \
  30       "  if (U (asconst_##name) != (c_t) (expr)) { ++bad;" \
  31       " fprintf (stderr, \"%s: %s is %\" PRI \" but %s is %\"PRI \"\\n\"," \
  32       " source, #name, U (asconst_##name), #expr, (c_t) (expr));" \
  33       " } else ++good;\n";
  34   }
  35   else
  36     print "void dummy(void) {";
  37   started = 1;
  38 }
  39
  40 # Separator.
  41 $1 == "--" { next }
  42
  43 NF == 1 { sub(/^.*$/, "& &"); }
  44
  45 NF > 1 {
  46   name = $1;
  47   sub(/^[^      ]+[     ]+/, "");
  48   if (test)
  49     print "  TEST (" name ", \"" FILENAME ":" FNR "\", " $0 ")";
  50   else
  51     printf "asm (\"@@@name@@@%s@@@value@@@%%0@@@end@@@\" : : \"i\" ((long) %s));\n",
  52       name, $0;
  53 }
  54
  55 END {
  56   if (test) {
  57     print "  printf (\"%d errors in %d tests\\n\", bad, good + bad);"
  58     print "  return bad != 0 || good == 0;\n}\n";
  59     print "#define TEST_FUNCTION do_test ()";
  60   }
  61   else if (started) print "}";
  62 }