nptl/sysdeps/unix/sysv/linux/i386/i486/pthread_cond_broadcast.S

   1 /* Copyright (C) 2002, 2003, 2004, 2006 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <shlib-compat.h>
  22 #include <lowlevelcond.h>
  23 #include <kernel-features.h>
  24 #include <pthread-pi-defines.h>
  25
  26 #ifdef UP
  27 # define LOCK
  28 #else
  29 # define LOCK lock
  30 #endif
  31
  32 #define SYS_futex               240
  33 #define FUTEX_WAIT              0
  34 #define FUTEX_WAKE              1
  35 #define FUTEX_REQUEUE           3
  36 #define FUTEX_CMP_REQUEUE       4
  37
  38 #define EINVAL                  22
  39
  40
  41         .text
  42
  43         /* int pthread_cond_broadcast (pthread_cond_t *cond) */
  44         .globl  __pthread_cond_broadcast
  45         .type   __pthread_cond_broadcast, @function
  46         .align  16
  47 __pthread_cond_broadcast:
  48
  49         pushl   %ebx
  50         pushl   %esi
  51         pushl   %edi
  52         pushl   %ebp
  53
  54         movl    20(%esp), %ebx
  55
  56         /* Get internal lock.  */
  57         movl    $1, %edx
  58         xorl    %eax, %eax
  59         LOCK
  60 #if cond_lock == 0
  61         cmpxchgl %edx, (%ebx)
  62 #else
  63         cmpxchgl %edx, cond_lock(%ebx)
  64 #endif
  65         jnz     1f
  66
  67 2:      addl    $cond_futex, %ebx
  68         movl    total_seq+4-cond_futex(%ebx), %eax
  69         movl    total_seq-cond_futex(%ebx), %ebp
  70         cmpl    wakeup_seq+4-cond_futex(%ebx), %eax
  71         ja      3f
  72         jb      4f
  73         cmpl    wakeup_seq-cond_futex(%ebx), %ebp
  74         jna     4f
  75
  76         /* Cause all currently waiting threads to recognize they are
  77            woken up.  */
  78 3:      movl    %ebp, wakeup_seq-cond_futex(%ebx)
  79         movl    %eax, wakeup_seq-cond_futex+4(%ebx)
  80         movl    %ebp, woken_seq-cond_futex(%ebx)
  81         movl    %eax, woken_seq-cond_futex+4(%ebx)
  82         addl    %ebp, %ebp
  83         addl    $1, broadcast_seq-cond_futex(%ebx)
  84         movl    %ebp, (%ebx)
  85
  86         /* Get the address of the mutex used.  */
  87         movl    dep_mutex-cond_futex(%ebx), %edi
  88
  89         /* Unlock.  */
  90         LOCK
  91         subl    $1, cond_lock-cond_futex(%ebx)
  92         jne     7f
  93
  94         /* Don't use requeue for pshared condvars.  */
  95 8:      cmpl    $-1, %edi
  96         je      9f
  97
  98         /* XXX: The kernel so far doesn't support requeue to PI futex.  */
  99         testl   $PI_BIT, MUTEX_KIND(%edi)
 100         jne     9f
 101
 102         /* Wake up all threads.  */
 103         movl    $FUTEX_CMP_REQUEUE, %ecx
 104         movl    $SYS_futex, %eax
 105         movl    $0x7fffffff, %esi
 106         movl    $1, %edx
 107         /* Get the address of the futex involved.  */
 108 # if MUTEX_FUTEX != 0
 109         addl    $MUTEX_FUTEX, %edi
 110 # endif
 111 /* FIXME: Until Ingo fixes 4G/4G vDSO, 6 arg syscalls are broken for sysenter.
 112         ENTER_KERNEL  */
 113         int     $0x80
 114
 115         /* For any kind of error, which mainly is EAGAIN, we try again
 116            with WAKE.  The general test also covers running on old
 117            kernels.  */
 118         cmpl    $0xfffff001, %eax
 119         jae     9f
 120
 121 10:     xorl    %eax, %eax
 122         popl    %ebp
 123         popl    %edi
 124         popl    %esi
 125         popl    %ebx
 126         ret
 127
 128         .align  16
 129         /* Unlock.  */
 130 4:      LOCK
 131         subl    $1, cond_lock-cond_futex(%ebx)
 132         jne     5f
 133
 134 6:      xorl    %eax, %eax
 135         popl    %ebp
 136         popl    %edi
 137         popl    %esi
 138         popl    %ebx
 139         ret
 140
 141         /* Initial locking failed.  */
 142 1:
 143 #if cond_lock == 0
 144         movl    %ebx, %ecx
 145 #else
 146         leal    cond_lock(%ebx), %ecx
 147 #endif
 148         call    __lll_mutex_lock_wait
 149         jmp     2b
 150
 151         /* Unlock in loop requires waekup.  */
 152 5:      leal    cond_lock-cond_futex(%ebx), %eax
 153         call    __lll_mutex_unlock_wake
 154         jmp     6b
 155
 156         /* Unlock in loop requires waekup.  */
 157 7:      leal    cond_lock-cond_futex(%ebx), %eax
 158         call    __lll_mutex_unlock_wake
 159         jmp     8b
 160
 161 9:      /* The futex requeue functionality is not available.  */
 162         movl    $0x7fffffff, %edx
 163         movl    $FUTEX_WAKE, %ecx
 164         movl    $SYS_futex, %eax
 165         ENTER_KERNEL
 166         jmp     10b
 167         .size   __pthread_cond_broadcast, .-__pthread_cond_broadcast
 168 versioned_symbol (libpthread, __pthread_cond_broadcast, pthread_cond_broadcast,
 169                   GLIBC_2_3_2)