sysdeps/x86_64/start.S

   1 /* Startup code compliant to the ELF x86-64 ABI.
   2    Copyright (C) 2001-2023 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library; if not, see
  34    <https://www.gnu.org/licenses/>.  */
  35
  36 /* This is the canonical entry point, usually the first thing in the text
  37    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
  38    point runs, most registers' values are unspecified, except for:
  39
  40    %rdx         Contains a function pointer to be registered with `atexit'.
  41                 This is how the dynamic linker arranges to have DT_FINI
  42                 functions called for shared libraries that have been loaded
  43                 before this code runs.
  44
  45    %rsp         The stack contains the arguments and environment:
  46                 0(%rsp)                         argc
  47                 LP_SIZE(%rsp)                   argv[0]
  48                 ...
  49                 (LP_SIZE*argc)(%rsp)            NULL
  50                 (LP_SIZE*(argc+1))(%rsp)        envp[0]
  51                 ...
  52                                                 NULL
  53 */
  54
  55 #include <sysdep.h>
  56
  57 ENTRY (_start)
  58         /* Clearing frame pointer is insufficient, use CFI.  */
  59         cfi_undefined (rip)
  60         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  61            the outermost frame obviously.  */
  62         xorl %ebp, %ebp
  63
  64         /* Extract the arguments as encoded on the stack and set up
  65            the arguments for __libc_start_main (int (*main) (int, char **, char **),
  66                    int argc, char *argv,
  67                    void (*init) (void), void (*fini) (void),
  68                    void (*rtld_fini) (void), void *stack_end).
  69            The arguments are passed via registers and on the stack:
  70         main:           %rdi
  71         argc:           %rsi
  72         argv:           %rdx
  73         init:           %rcx
  74         fini:           %r8
  75         rtld_fini:      %r9
  76         stack_end:      stack.  */
  77
  78         mov %RDX_LP, %R9_LP     /* Address of the shared library termination
  79                                    function.  */
  80 #ifdef __ILP32__
  81         mov (%rsp), %esi        /* Simulate popping 4-byte argument count.  */
  82         add $4, %esp
  83 #else
  84         popq %rsi               /* Pop the argument count.  */
  85 #endif
  86         /* argv starts just at the current stack top.  */
  87         mov %RSP_LP, %RDX_LP
  88         /* Align the stack to a 16 byte boundary to follow the ABI.  */
  89         and  $~15, %RSP_LP
  90
  91         /* Push garbage because we push 8 more bytes.  */
  92         pushq %rax
  93
  94         /* Provide the highest stack address to the user code (for stacks
  95            which grow downwards).  */
  96         pushq %rsp
  97
  98         /* These used to be the addresses of .fini and .init.  */
  99         xorl %r8d, %r8d
 100         xorl %ecx, %ecx
 101
 102 #ifdef PIC
 103         mov main@GOTPCREL(%rip), %RDI_LP
 104 #else
 105         mov $main, %RDI_LP
 106 #endif
 107
 108         /* Call the user's main function, and exit with its value.
 109            But let the libc call main.  Since __libc_start_main in
 110            libc.so is called very early, lazy binding isn't relevant
 111            here.  Use indirect branch via GOT to avoid extra branch
 112            to PLT slot.  In case of static executable, ld in binutils
 113            2.26 or above can convert indirect branch into direct
 114            branch.  */
 115         call *__libc_start_main@GOTPCREL(%rip)
 116
 117         hlt                     /* Crash if somehow `exit' does return.  */
 118 END (_start)
 119
 120 /* Define a symbol for the first piece of initialized data.  */
 121         .data
 122         .globl __data_start
 123 __data_start:
 124         .long 0
 125         .weak data_start
 126         data_start = __data_start