sysdeps/powerpc/powerpc64/fpu/s_nearbyint.S

   1 /* Round to int floating-point values.  PowerPC64 version.
   2    Copyright (C) 2011-2017 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Adhemerval Zanella <azanella@br.ibm.com>, 2011
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 /* This has been coded in assembler because GCC makes such a mess of it
  21    when it's coded in C.  */
  22
  23 #include <sysdep.h>
  24 #include <math_ldbl_opt.h>
  25 #include <libm-alias-double.h>
  26
  27
  28 /* double [fp1] nearbyint(double [fp1] x) */
  29
  30         .section        ".toc","aw"
  31 .LC0:   /* 2**52 */
  32         .tc FD_43300000_0[TC],0x4330000000000000
  33         .section        ".text"
  34
  35 ENTRY (__nearbyint, 4)
  36         CALL_MCOUNT 0
  37         fabs    fp0,fp1
  38         lfd     fp13,.LC0@toc(2)
  39         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  40         bge     cr7,.L10
  41         fsub    fp12,fp13,fp13  /* generate 0.0 */
  42         fcmpu   cr7,fp1,fp12    /* if (x > 0.0) */
  43         ble     cr7, L(lessthanzero)
  44         mffs    fp11
  45         mtfsb0  4*cr7+lt        /* Disable FE_INEXACT exception */
  46         fadd    fp1,fp1,fp13    /* x+= TWO52 */
  47         fsub    fp1,fp1,fp13    /* x-= TWO52 */
  48         fabs    fp1,fp1         /* if (x == 0.0) */
  49         mtfsf   0xff,fp11       /* Restore FE_INEXACT state.  */
  50         blr                     /* x = 0.0; */
  51 L(lessthanzero):
  52         bgelr   cr7             /* if (x < 0.0) */
  53         mffs    fp11
  54         mtfsb0  4*cr7+lt
  55         fsub    fp1,fp1,fp13    /* x -= TWO52 */
  56         fadd    fp1,fp1,fp13    /* x += TWO52 */
  57         fnabs   fp1,fp1         /* if (x == 0.0) */
  58         mtfsf   0xff,fp11       /* Restore FE_INEXACT state.  */
  59         blr                     /* x = -0.0; */
  60 .L10:
  61         /* Ensure sNaN input is converted to qNaN.  */
  62         fcmpu   cr7,fp1,fp1
  63         beqlr   cr7
  64         fadd    fp1,fp1,fp1
  65         blr
  66 END (__nearbyint)
  67
  68 libm_alias_double (__nearbyint, nearbyint)