configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  36 AC_ARG_WITH(gd, dnl
  37   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  38             [dnl
  39 case "$with_gd" in
  40 yes|''|no) ;;
  41 *) libgd_include="-I$withval/include"
  42    libgd_ldflags="-L$withval/lib" ;;
  43 esac
  44 ])
  45 AC_ARG_WITH(gd-include, dnl
  46   --with-gd-include=DIR   find libgd include files in DIR,
  47             [dnl
  48 case "$with_gd_include" in
  49 ''|no) ;;
  50 *) libgd_include="-I$withval" ;;
  51 esac
  52 ])
  53 AC_ARG_WITH(gd-lib, dnl
  54   --with-gd-lib=DIR       find libgd library files in DIR,
  55             [dnl
  56 case "$with_gd_lib" in
  57 ''|no) ;;
  58 *) libgd_ldflags="-L$withval" ;;
  59 esac
  60 ])
  61
  62 if test -n "$libgd_include"; then
  63   config_vars="$config_vars
  64 CFLAGS-memprofstat.c = $libgd_include"
  65 fi
  66 if test -n "$libgd_ldflags"; then
  67   config_vars="$config_vars
  68 libgd-LDFLAGS = $libgd_ldflags"
  69 fi
  70
  71 dnl Arguments to specify presence of other packages/features.
  72 AC_ARG_WITH(fp, dnl
  73 [  --with-fp              if using floating-point hardware [default=yes]],
  74             with_fp=$withval, with_fp=yes)
  75 AC_ARG_WITH(binutils, dnl
  76   --with-binutils=PATH    specify location of binutils (as and ld),
  77             path_binutils=$withval, path_binutils='')
  78 AC_ARG_WITH(elf, dnl
  79   --with-elf              if using the ELF object format,
  80             elf=$withval, elf=no)
  81 AC_ARG_WITH(cvs, dnl
  82 [  --without-cvs          if CVS should not be used],
  83             with_cvs=$withval, with_cvs=yes)
  84 AC_SUBST(with_cvs)
  85
  86 AC_ARG_WITH(headers, dnl
  87 [  --with-headers=PATH     location of system headers to use
  88                           [e.g. /usr/src/linux/include]
  89                           [default=compiler default]],
  90             sysheaders=$withval, sysheaders='')
  91
  92 AC_ARG_ENABLE(libio, dnl
  93 [  --enable-libio          build in GNU libio instead of GNU stdio],
  94               [if test $enableval = yes; then
  95                  stdio=libio
  96                else
  97                  stdio=stdio
  98                fi],
  99               stdio=default)
 100
 101 AC_ARG_ENABLE(sanity-checks, dnl
 102 [  --disable-sanity-checks really do not use threads (should not be used
 103                           except in special situations) [default=yes]],
 104               enable_sanity=$enableval, enable_sanity=yes)
 105
 106 dnl Arguments to enable or disable building the static, shared, profiled,
 107 dnl and -fomit-frame-pointer libraries.
 108 dnl I've disabled this for now since we cannot build glibc without static
 109 dnl libraries built in the moment.
 110 dnl AC_ARG_ENABLE(static, dnl
 111 dnl [  --enable-static         build static library [default=yes]],
 112 dnl           static=$enableval, static=yes)
 113 static=yes
 114 AC_ARG_ENABLE(shared, dnl
 115 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 116               shared=$enableval, shared=default)
 117 AC_ARG_ENABLE(profile, dnl
 118 [  --enable-profile        build profiled library [default=yes]],
 119               profile=$enableval, profile=yes)
 120 AC_ARG_ENABLE(omitfp, dnl
 121 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 122               omitfp=$enableval, omitfp=no)
 123 AC_ARG_ENABLE(bounded, dnl
 124 [  --enable-bounded        build with runtime bounds checking [default=no]],
 125               bounded=$enableval, bounded=no)
 126 AC_ARG_ENABLE(versioning, dnl
 127 [  --disable-versioning    do not include versioning information in the
 128                           library objects [default=yes if supported]],
 129              enable_versioning=$enableval, enable_versioning=yes)
 130
 131 dnl Generic infrastructure for drop-in additions to libc.
 132 AC_ARG_ENABLE(add-ons, dnl
 133 [  --enable-add-ons[=DIR1,DIR2]...
 134                           configure and build add-ons in DIR1,DIR2,...
 135                           search for add-ons if no parameter given],
 136   [case "$enableval" in
 137     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 138          test "$add_ons" = "*" && add_ons= ;;
 139     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 140    esac],
 141   [add_ons=])
 142
 143 AC_CONFIG_SUBDIRS($add_ons)
 144 add_ons_pfx=
 145 if test x"$add_ons" != x; then
 146   for f in $add_ons; do
 147     # Test whether such a subdir really exists.
 148     if test -d $srcdir/$f; then
 149       add_ons_pfx="$add_ons_pfx $f/"
 150     else
 151       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 152     fi
 153   done
 154 fi
 155
 156 dnl On some platforms we cannot use dynamic loading.  We must provide
 157 dnl static NSS modules.
 158 AC_ARG_ENABLE(static-nss, dnl
 159 [  --enable-static-nss     build static NSS modules [default=no]],
 160               static_nss=$enableval, static_nss=no)
 161 if test x"$static_nss" = xyes; then
 162   AC_DEFINE(DO_STATIC_NSS)
 163 fi
 164
 165 AC_ARG_ENABLE(force-install,
 166 [  --disable-force-install don't force installation of files from this package,
 167                           even if they are older than the installed files],
 168               force_install=$enableval, force_install=yes)
 169 AC_SUBST(force_install)
 170
 171 dnl On some platforms we allow dropping compatibility with all kernel
 172 dnl versions.
 173 AC_ARG_ENABLE(kernel,
 174 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 175                            than VERSION],
 176               minimum_kernel=$enableval)
 177 dnl Prevent unreasonable values.
 178 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 179   # Better nothing than this.
 180   minimum_kernel=""
 181 else
 182   if test "$minimum_kernel" = current; then
 183     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 184   fi
 185 fi
 186
 187 AC_CANONICAL_HOST
 188
 189 # The way shlib-versions is used to generate soversions.mk uses a
 190 # fairly simplistic model for name recognition that can't distinguish
 191 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 192 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 193 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 194 case "$host_os" in
 195 linux*)
 196   ;;
 197 gnu*)
 198   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 199   ;;
 200 esac
 201
 202 # We keep the original values in `$config_*' and never modify them, so we
 203 # can write them unchanged into config.make.  Everything else uses
 204 # $machine, $vendor, and $os, and changes them whenever convenient.
 205 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 206
 207 # Some configurations imply other options.
 208 case "$host_os" in
 209 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 210   # These systems always use GNU tools.
 211   gnu_ld=yes gnu_as=yes ;;
 212 esac
 213 case "$host_os" in
 214 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 215 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 216   ;;
 217 gnu* | linux* | sysv4* | solaris2* | irix6*)
 218   # These systems (almost) always use the ELF format.
 219   elf=yes
 220   ;;
 221 esac
 222
 223 machine=$config_machine
 224 vendor=$config_vendor
 225 os=$config_os
 226
 227 ###
 228 ### I put this here to prevent those annoying emails from people who cannot
 229 ### read and try to compile glibc on unsupported platforms.  --drepper
 230 ###
 231 ### By using the undocumented --enable-hacker-mode option for configure
 232 ### one can skip this test to make the configuration not fail for unsupported
 233 ### platforms.
 234 ###
 235 if test -z "$enable_hacker_mode"; then
 236   case "$machine-$host_os" in
 237   *-linux* | *-gnu* | arm*-none*)
 238     ;;
 239   *)
 240     echo "*** The GNU C library is currently not available for this platform."
 241     echo "*** So far nobody cared to port it and if there is no volunteer it"
 242     echo "*** might never happen.  So, if you have interest to see glibc on"
 243     echo "*** this platform visit"
 244     echo "***   http://www.gnu.org/software/libc/porting.html"
 245     echo "*** and join the group of porters"
 246     exit 1
 247     ;;
 248   esac
 249 fi
 250
 251 dnl We need to use [ and ] for other purposes for a while now.
 252 changequote(,)dnl
 253 # Expand the configuration machine name into a subdirectory by architecture
 254 # type and particular chip.
 255 case "$machine" in
 256 a29k | am29000) base_machine=a29k machine=a29k ;;
 257 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 258 arm*)           base_machine=arm machine=arm/$machine ;;
 259 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 260 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 261 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 262 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 263 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 264 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 265 m88???)         base_machine=m88k machine=m88k/$machine ;;
 266 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 267 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 268 mips*)          base_machine=mips
 269                 case "`uname -m`" in
 270                 IP22) machine=mips/mips3 ;;
 271                 *)    machine=mips/$machine ;;
 272                 esac ;;
 273 sparc | sparcv[67])
 274                 base_machine=sparc machine=sparc/sparc32 ;;
 275 sparcv8 | supersparc | hypersparc)
 276                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 277 sparcv8plus | sparcv8plusa | sparcv9)
 278                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 279 sparc64 | ultrasparc)
 280                 base_machine=sparc machine=sparc/sparc64 ;;
 281 esac
 282 changequote([,])dnl
 283 AC_SUBST(base_machine)
 284
 285 if test "$base_machine" = "i386"; then
 286   AC_DEFINE(USE_REGPARMS)
 287 fi
 288
 289 # Compute the list of sysdep directories for this configuration.
 290 # This can take a while to compute.
 291 sysdep_dir=$srcdir/sysdeps
 292 AC_MSG_CHECKING(sysdep dirs)
 293 dnl We need to use [ and ] for other purposes for a while now.
 294 changequote(,)dnl
 295 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 296 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 297
 298 case "$os" in
 299 gnu*)
 300   base_os=mach/hurd ;;
 301 netbsd* | 386bsd* | freebsd* | bsdi*)
 302   base_os=unix/bsd/bsd4.4 ;;
 303 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 304   base_os=unix/bsd ;;
 305 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 306   base_os=unix/sysv ;;
 307 irix6*)
 308   base_os=unix/sysv/irix6/$os ;;
 309 solaris[2-9]*)
 310   base_os=unix/sysv/sysv4 ;;
 311 hpux*)
 312   base_os=unix/sysv/hpux/$os ;;
 313 none)
 314   base_os=standalone ;;
 315 *)
 316   base_os='' ;;
 317 esac
 318
 319 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 320 tail=$os
 321 ostry=$os
 322 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 323   ostry="$ostry /$o"
 324   tail=$o
 325 done
 326 o=`echo $tail | sed 's/[0-9]*$//'`
 327 if test $o != $tail; then
 328   ostry="$ostry /$o"
 329 fi
 330 # For linux-gnu, try linux-gnu, then linux.
 331 o=`echo $tail | sed 's/-.*$//'`
 332 if test $o != $tail; then
 333   ostry="$ostry /$o"
 334 fi
 335
 336 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 337 base=
 338 tail=$base_os
 339 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 340   set $b
 341   base="$base /$1"
 342   tail="$2"
 343 done
 344
 345 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 346 mach=
 347 tail=$machine
 348 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 349   set $m
 350   # Prepend the machine's FPU directory unless --without-fp.
 351   if test "$with_fp" = yes; then
 352     mach="$mach /$1/fpu"
 353   fi
 354   mach="$mach /$1"
 355   tail="$2"
 356 done
 357
 358 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 359 changequote([,])dnl
 360
 361 # Find what sysdep directories exist.
 362 sysnames=
 363 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 364 for d in $add_ons_pfx ''; do
 365   for b in $base ''; do
 366     for m0 in $mach ''; do
 367       for v in /$vendor ''; do
 368         test "$v" = / && continue
 369         for o in /$ostry ''; do
 370           test "$o" = / && continue
 371           for m in $mach ''; do
 372             if test "$m0$b$v$o$m"; then
 373               try="${d}sysdeps$m0$b$v$o$m"
 374               test -n "$enable_debug_configure" &&
 375               echo "$0 [DEBUG]: try $try" >&2
 376               if test -d $srcdir/$try; then
 377                 sysnames="$sysnames $try"
 378                 { test -n "$o" || test -n "$b"; } && os_used=t
 379                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 380               fi
 381             fi
 382           done
 383         done
 384       done
 385     done
 386   done
 387 done
 388 IFS="$ac_save_ifs"
 389
 390 if test -z "$os_used" && test "$os" != none; then
 391   AC_MSG_ERROR(Operating system $os is not supported.)
 392 fi
 393 if test -z "$machine_used" && test "$machine" != none; then
 394   AC_MSG_ERROR(The $machine is not supported.)
 395 fi
 396
 397 # We have now validated the configuration.
 398
 399
 400 # If using ELF, look for an `elf' subdirectory of each machine directory.
 401 # We prepend these rather than inserting them whereever the machine appears
 402 # because things specified by the machine's ELF ABI should override
 403 # OS-specific things, and should always be the same for any OS on the
 404 # machine (otherwise what's the point of an ABI?).
 405 if test "$elf" = yes; then
 406   elf_dirs=
 407   for d in $add_ons_pfx ''; do
 408     for m in $mach; do
 409       if test -d $srcdir/${d}sysdeps$m/elf; then
 410         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 411       fi
 412     done
 413   done
 414   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 415 fi
 416
 417
 418 # Expand the list of system names into a full list of directories
 419 # from each element's parent name and Implies file (if present).
 420 set $sysnames
 421 names=
 422 while test $# -gt 0; do
 423   name=$1
 424   shift
 425
 426   case " $names " in *" $name "*)
 427     # Already in the list.
 428     continue
 429   esac
 430
 431   # Report each name as we discover it, so there is no long pause in output.
 432   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 433
 434   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 435
 436   case $name in
 437     /*) xsrcdir= ;;
 438     *)  xsrcdir=$srcdir/ ;;
 439   esac
 440   test -n "$enable_debug_configure" &&
 441   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 442
 443   if test -f $xsrcdir$name/Implies; then
 444     # Collect more names from the `Implies' file (removing comments).
 445     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 446     implied=
 447     for x in $implied_candidate; do
 448       if test -d $xsrcdir$name_base/$x; then
 449         implied="$implied $name_base/$x";
 450       else
 451         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 452       fi
 453     done
 454   else
 455     implied=
 456   fi
 457
 458   # Add NAME to the list of names.
 459   names="$names $name"
 460
 461   # Find the parent of NAME, using the empty string if it has none.
 462 changequote(,)dnl
 463   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 464 changequote([,])dnl
 465
 466   # Add the names implied by NAME, and NAME's parent (if it has one), to
 467   # the list of names to be processed (the argument list).  We prepend the
 468   # implied names to the list and append the parent.  We want implied
 469   # directories to come before further directories inferred from the
 470   # configuration components; this ensures that for sysv4, unix/common
 471   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 472   # after sysv4).
 473   sysnames="`echo $implied $* $parent`"
 474   test -n "$sysnames" && set $sysnames
 475 done
 476
 477 # Add the default directories.
 478 default_sysnames=sysdeps/generic
 479 if test "$elf" = yes; then
 480   default_sysnames="sysdeps/generic/elf $default_sysnames"
 481 fi
 482 sysnames="$names $default_sysnames"
 483 AC_SUBST(sysnames)
 484 # The other names were emitted during the scan.
 485 AC_MSG_RESULT($default_sysnames)
 486
 487
 488 ### Locate tools.
 489
 490 AC_PROG_INSTALL
 491 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 492   # The makefiles need to use a different form to find it in $srcdir.
 493   INSTALL='\$(..)./scripts/install-sh -c'
 494 fi
 495 AC_PROG_LN_S
 496
 497 # These programs are version sensitive.
 498 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 499 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 500   [version \([egcygnustp-]*[0-9.]*\)],
 501   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]],
 502   critic_missing=t)
 503 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 504   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 505   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 506
 507 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 508   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 509   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 510 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 511   [GNU texinfo.* \([0-9][0-9.]*\)],
 512   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 513
 514 if test -n "$critic_missing"; then
 515 AC_MSG_ERROR([
 516 *** Some critical program is missing or too old.
 517 *** Check the INSTALL file for required versions.])
 518 fi
 519
 520 test -n "$aux_missing" && AC_MSG_WARN([
 521 *** An auxiliary program is missing or too old;
 522 *** some features will be disabled.
 523 *** Check the INSTALL file for required versions.])
 524
 525 # glibcbug.in wants to know the compiler version.
 526 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 527 AC_SUBST(CCVERSION)
 528
 529 AC_PROG_CC_LOCAL
 530 AC_CANONICAL_BUILD
 531 if test $host != $build; then
 532   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 533 fi
 534 AC_SUBST(cross_compiling)
 535 AC_PROG_CPP
 536 LIBC_PROG_BINUTILS
 537 AC_CHECK_TOOL(MIG, mig)
 538
 539 # if using special system headers, find out the compiler's sekrit
 540 # header directory and add that to the list.  NOTE: Only does the right
 541 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 542 if test -n "$sysheaders"; then
 543   ccheaders=`$CC -print-file-name=include`
 544   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 545 fi
 546 AC_SUBST(SYSINCLUDES)
 547
 548 # check if ranlib is necessary
 549 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 550 cat > conftest.c <<EOF
 551 int a;
 552 char b;
 553 void c(void) {}
 554 EOF
 555 $CC $CFLAGS -c conftest.c
 556 $AR cr conftest.a conftest.c
 557 cp conftest.a conftest2.a
 558 $RANLIB conftest.a
 559 if cmp -s conftest.a conftest2.a; then
 560   libc_cv_ranlib_necessary=no
 561 else
 562   libc_cv_ranlib_necessary=yes
 563 fi
 564 rm -rf conftest*])
 565 if test "$libc_cv_ranlib_necessary" = no; then
 566  RANLIB=:
 567 fi
 568
 569 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 570 # since this would lead to problems installing/building glibc.
 571 # LD_LIBRARY_PATH contains the current directory if one of the following
 572 # is true:
 573 # - one of the terminals (":" and ";") is the first or last sign
 574 # - two terminals occur directly after each other
 575 # - the path contains an element with a dot in it
 576 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 577 changequote(,)dnl
 578 case ${LD_LIBRARY_PATH} in
 579   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 580     ld_library_path_setting="contains current directory"
 581     ;;
 582   *)
 583     ld_library_path_setting="ok"
 584     ;;
 585 esac
 586 changequote([,])dnl
 587 AC_MSG_RESULT($ld_library_path_setting)
 588 if test "$ld_library_path_setting" != "ok"; then
 589 AC_MSG_ERROR([
 590 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 591 *** building glibc. Please change the environment variable
 592 *** and run configure again.])
 593 fi
 594
 595 AC_PATH_PROG(BASH, bash, no)
 596 if test "$BASH" != no &&
 597    $BASH -c 'test "$BASH_VERSINFO" \
 598              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 599   libc_cv_have_bash2=yes
 600 else
 601   libc_cv_have_bash2=no
 602 fi
 603 AC_SUBST(libc_cv_have_bash2)
 604
 605 dnl We need a ksh compatible shell for tzselect.
 606 if test "$BASH" = no; then
 607   AC_PATH_PROG(KSH, ksh, no)
 608   if test "$KSH" = no; then
 609     libc_cv_have_ksh=no
 610   else
 611     libc_cv_have_ksh=yes
 612   fi
 613 else
 614   KSH="$BASH"
 615   AC_SUBST(KSH)
 616   libc_cv_have_ksh=yes
 617 fi
 618 AC_SUBST(libc_cv_have_ksh)
 619
 620 AC_PROG_AWK
 621 AC_PATH_PROG(PERL, perl, no)
 622 AC_SUBST(PERL)
 623 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 624              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 625 AC_SUBST(INSTALL_INFO)
 626 if test "$INSTALL_INFO" != "no"; then
 627 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 628  [mkdir conftest.d
 629   # There is a hard ^_ on the next line.  I am open to better ideas.
 630   (echo '\x1f'
 631   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 632   echo '* Menu:') >conftest.d/dir
 633   (echo 'INFO-DIR-SECTION i-d-s works'
 634   echo 'START-INFO-DIR-ENTRY'
 635   echo '* Prog: (prog).   Program.'
 636   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 637   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 638   then
 639     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 640     then libc_cv_old_debian_install_info=no
 641     else libc_cv_old_debian_install_info=yes
 642     fi
 643   else libc_cv_old_debian_install_info=no testfailed=t
 644   fi
 645   rm -fr conftest.d])
 646 if test -n "$testfailed"
 647 then AC_MSG_WARN([install-info errored out, check config.log])
 648 fi
 649 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 650 fi
 651 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 652
 653 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 654 echo '#include <stddef.h>
 655 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 656 if eval "$ac_cpp conftest.c 2>/dev/null" \
 657 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 658   libc_cv_signed_size_t=no
 659 else
 660   libc_cv_signed_size_t=yes
 661 fi
 662 rm -f conftest*])
 663 if test $libc_cv_signed_size_t = yes; then
 664   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 665   cat >> confdefs.h <<\EOF
 666 #undef __SIZE_TYPE__
 667 #define __SIZE_TYPE__ unsigned
 668 EOF
 669 fi
 670
 671 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 672 AC_TRY_COMPILE(dnl
 673 [#define __need_size_t
 674 #define __need_wchar_t
 675 #include <stddef.h>
 676 #define __need_NULL
 677 #include <stddef.h>], [size_t size; wchar_t wchar;
 678 #ifdef offsetof
 679 #error stddef.h ignored __need_*
 680 #endif
 681 if (&size == NULL || &wchar == NULL) abort ();],
 682                libc_cv_friendly_stddef=yes,
 683                libc_cv_friendly_stddef=no)])
 684 if test $libc_cv_friendly_stddef = yes; then
 685   config_vars="$config_vars
 686 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 687 fi
 688
 689 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 690                libc_cv_need_minus_P, [dnl
 691 cat > conftest.S <<EOF
 692 #include "confdefs.h"
 693 /* Nothing whatsoever.  */
 694 EOF
 695 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 696   libc_cv_need_minus_P=no
 697 else
 698   libc_cv_need_minus_P=yes
 699 fi
 700 rm -f conftest*])
 701 if test $libc_cv_need_minus_P = yes; then
 702   config_vars="$config_vars
 703 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 704 fi
 705
 706 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 707 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 708 cat > conftest.s <<EOF
 709 .text
 710 EOF
 711 libc_cv_dot_text=
 712 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 713   libc_cv_dot_text=.text
 714 fi
 715 rm -f conftest*])
 716 if test -z "$libc_cv_dot_text"; then
 717   AC_MSG_RESULT(no)
 718 else
 719   AC_MSG_RESULT(yes)
 720 fi
 721
 722 AC_CACHE_CHECK(for assembler global-symbol directive,
 723                libc_cv_asm_global_directive, [dnl
 724 libc_cv_asm_global_directive=UNKNOWN
 725 for ac_globl in .globl .global .EXPORT; do
 726   cat > conftest.s <<EOF
 727         ${libc_cv_dot_text}
 728         ${ac_globl} foo
 729 foo:
 730 EOF
 731   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 732     libc_cv_asm_global_directive=${ac_globl}
 733   fi
 734   rm -f conftest*
 735   test $libc_cv_asm_global_directive != UNKNOWN && break
 736 done])
 737 if test $libc_cv_asm_global_directive = UNKNOWN; then
 738   AC_MSG_ERROR(cannot determine asm global directive)
 739 else
 740   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 741 fi
 742
 743 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 744 cat > conftest.s <<EOF
 745 ${libc_cv_dot_text}
 746 foo:
 747 .set glibc_conftest_frobozz,foo
 748 $libc_cv_asm_global_directive glibc_conftest_frobozz
 749 EOF
 750 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 751 # (but it doesn't work), so we must do a linking check to be sure.
 752 cat > conftest1.c <<\EOF
 753 extern int glibc_conftest_frobozz;
 754 main () { printf ("%d\n", glibc_conftest_frobozz); }
 755 EOF
 756 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 757             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 758   libc_cv_asm_set_directive=yes
 759 else
 760   libc_cv_asm_set_directive=no
 761 fi
 762 rm -f conftest*])
 763 if test $libc_cv_asm_set_directive = yes; then
 764   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 765 fi
 766
 767 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 768 [cat > conftest.s <<EOF
 769 ${libc_cv_dot_text}
 770 _sym:
 771 .symver _sym,sym@VERS
 772 EOF
 773 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 774   libc_cv_asm_symver_directive=yes
 775 else
 776   libc_cv_asm_symver_directive=no
 777 fi
 778 rm -f conftest*])
 779 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 780 if test $libc_cv_asm_symver_directive = yes; then
 781   cat > conftest.s <<EOF
 782 ${libc_cv_dot_text}
 783 _sym:
 784 .symver _sym,sym@VERS
 785 EOF
 786   cat > conftest.map <<EOF
 787 VERS_1 {
 788         global: sym;
 789 };
 790
 791 VERS_2 {
 792         global: sym;
 793 } VERS_1;
 794 EOF
 795   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 796     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 797                                         -nostartfiles -nostdlib
 798                                         -Wl,--version-script,conftest.map
 799                        1>&AC_FD_CC]);
 800     then
 801       libc_cv_ld_version_script_option=yes
 802     else
 803       libc_cv_ld_version_script_option=no
 804     fi
 805   else
 806     libc_cv_ld_version_script_option=no
 807   fi
 808 else
 809   libc_cv_ld_version_script_option=no
 810 fi
 811 rm -f conftest*])
 812 if test $libc_cv_asm_symver_directive = yes &&
 813    test $libc_cv_ld_version_script_option = yes &&
 814    test $enable_versioning = yes; then
 815   VERSIONING=yes
 816   AC_DEFINE(DO_VERSIONING)
 817 else
 818   VERSIONING=no
 819 fi
 820 AC_SUBST(VERSIONING)
 821
 822 if test $VERSIONING = no; then
 823   echo "\
 824 *** WARNING: You should not compile GNU libc without versioning. Not using
 825 *** versioning will introduce incompatibilities so that old binaries
 826 *** will not run anymore.
 827 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 828 fi
 829 if test $elf = yes; then
 830   AC_CACHE_CHECK(for .previous assembler directive,
 831                  libc_cv_asm_previous_directive, [dnl
 832   cat > conftest.s <<EOF
 833 .section foo_section
 834 .previous
 835 EOF
 836   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 837     libc_cv_asm_previous_directive=yes
 838   else
 839     libc_cv_asm_previous_directive=no
 840   fi
 841   rm -f conftest*])
 842   if test $libc_cv_asm_previous_directive = yes; then
 843     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 844   else
 845     AC_CACHE_CHECK(for .popsection assembler directive,
 846                    libc_cv_asm_popsection_directive, [dnl
 847     cat > conftest.s <<EOF
 848 .pushsection foo_section
 849 .popsection
 850 EOF
 851     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 852       libc_cv_asm_popsection_directive=yes
 853     else
 854       libc_cv_asm_popsection_directive=no
 855     fi
 856     rm -f conftest*])
 857     if test $libc_cv_asm_popsection_directive = yes; then
 858       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 859     fi
 860   fi
 861 fi
 862
 863 if test $elf != yes; then
 864   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 865                  [AC_TRY_COMPILE(, [asm (".section .init");
 866                                     asm (".section .fini");
 867                                     asm ("${libc_cv_dot_text}");],
 868                                  libc_cv_have_initfini=yes,
 869                                  libc_cv_have_initfini=no)])
 870   AC_SUBST(libc_cv_have_initfini)dnl
 871   if test $libc_cv_have_initfini = yes; then
 872     AC_DEFINE(HAVE_INITFINI)
 873   fi
 874 fi
 875
 876 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 877 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 878 [cat > conftest.$ac_ext <<EOF
 879 dnl This sometimes fails to find confdefs.h, for some reason.
 880 dnl [#]line __oline__ "[$]0"
 881 [#]line __oline__ "configure"
 882 #include "confdefs.h"
 883 void underscore_test(void) {
 884 return; }
 885 EOF
 886 if AC_TRY_EVAL(ac_compile); then
 887   if grep _underscore_test conftest* >/dev/null; then
 888     ifelse([$1], , :, [rm -f conftest*
 889     $1])
 890   else
 891     ifelse([$2], , , [rm -f conftest*
 892     $2])
 893   fi
 894 else
 895   echo "configure: failed program was:" >&AC_FD_CC
 896   cat conftest.$ac_ext >&AC_FD_CC
 897   ifelse([$2], , , [rm -f conftest*
 898   $2])
 899 fi
 900 rm -f conftest*])
 901
 902 if test $elf = yes; then
 903   libc_cv_asm_underscores=no
 904 else
 905   if test $ac_cv_prog_cc_works = yes; then
 906     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 907                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 908                                 libc_cv_asm_underscores=yes,
 909                                 libc_cv_asm_underscores=no)])
 910   else
 911     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 912                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 913                                             libc_cv_asm_underscores=no)])
 914   fi
 915 fi
 916 if test $libc_cv_asm_underscores = no; then
 917   AC_DEFINE(NO_UNDERSCORES)
 918 fi
 919
 920 if test $elf = yes; then
 921   libc_cv_weak_symbols=yes
 922 fi
 923
 924 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 925                  [dnl
 926 cat > conftest.s <<EOF
 927 ${libc_cv_dot_text}
 928 ${libc_cv_asm_global_directive} foo
 929 foo:
 930 .weak foo
 931 .weak bar; bar = foo
 932 EOF
 933 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 934   libc_cv_asm_weak_directive=yes
 935 else
 936   libc_cv_asm_weak_directive=no
 937 fi
 938 rm -f conftest*])
 939
 940 if test $libc_cv_asm_weak_directive = no; then
 941   AC_CACHE_CHECK(for assembler .weakext directive,
 942                  libc_cv_asm_weakext_directive,
 943                  [dnl
 944 cat > conftest.s <<EOF
 945 ${libc_cv_dot_text}
 946 ${libc_cv_asm_global_directive} foo
 947 foo:
 948 .weakext bar foo
 949 .weakext baz
 950 ${libc_cv_asm_global_directive} baz
 951 baz:
 952 EOF
 953   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 954     libc_cv_asm_weakext_directive=yes
 955   else
 956     libc_cv_asm_weakext_directive=no
 957   fi
 958   rm -f conftest*])
 959
 960 fi # no .weak
 961
 962 if test $libc_cv_asm_weak_directive = yes; then
 963   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 964 elif test $libc_cv_asm_weakext_directive = yes; then
 965   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 966 fi
 967
 968 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 969 cat > conftest.c <<\EOF
 970 _start () {}
 971 int __eh_pc;
 972 __throw () {}
 973 EOF
 974 dnl No \ in command here because it ends up inside ''.
 975 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 976                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 977                             -o conftest conftest.c 1>&AC_FD_CC]); then
 978   libc_cv_ld_no_whole_archive=yes
 979 else
 980   libc_cv_ld_no_whole_archive=no
 981 fi
 982 rm -f conftest*])
 983 if test $libc_cv_ld_no_whole_archive = yes; then
 984   no_whole_archive=-Wl,--no-whole-archive
 985 fi
 986 AC_SUBST(no_whole_archive)dnl
 987
 988 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
 989 cat > conftest.c <<\EOF
 990 _start () {}
 991 int __eh_pc;
 992 __throw () {}
 993 EOF
 994 dnl No \ in command here because it ends up inside ''.
 995 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 996                             -nostdlib -nostartfiles -fexceptions
 997                             -o conftest conftest.c 1>&AC_FD_CC]); then
 998   libc_cv_gcc_exceptions=yes
 999 else
1000   libc_cv_gcc_exceptions=no
1001 fi
1002 rm -f conftest*])
1003 if test $libc_cv_gcc_exceptions = yes; then
1004   exceptions=-fexceptions
1005 fi
1006 AC_SUBST(exceptions)dnl
1007
1008 if test "$base_machine" = alpha ; then
1009 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1010 cat > conftest.c <<\EOF
1011 foo () { }
1012 EOF
1013 dnl
1014 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1015 then
1016   libc_cv_gcc_alpha_ng_prefix=yes
1017 else
1018   libc_cv_gcc_alpha_ng_prefix=no
1019 fi
1020 rm -f conftest* ])
1021 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1022   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1023 else
1024   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1025 fi
1026 fi
1027
1028 if test "$host_cpu" = powerpc ; then
1029 # Check for a bug present in at least versions 2.8.x of GCC
1030 # and versions 1.0.x of EGCS.
1031 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1032 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1033                libc_cv_c_asmcr0_bug='no',
1034                libc_cv_c_asmcr0_bug='yes')])
1035 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1036   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1037 fi
1038 fi
1039
1040 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1041 [cat > conftest.c <<EOF
1042 #line __oline__ "configure"
1043 static char __EH_FRAME_BEGIN__[];
1044 _start ()
1045 {
1046 #ifdef CHECK__register_frame
1047   __register_frame (__EH_FRAME_BEGIN__);
1048   __deregister_frame (__EH_FRAME_BEGIN__);
1049 #endif
1050 #ifdef CHECK__register_frame_info
1051   __register_frame_info (__EH_FRAME_BEGIN__);
1052   __deregister_frame_info (__EH_FRAME_BEGIN__);
1053 #endif
1054 }
1055 int __eh_pc;
1056 __throw () {}
1057 /* FIXME: this is fragile.  */
1058 malloc () {}
1059 strcmp () {}
1060 strlen () {}
1061 memcpy () {}
1062 memset () {}
1063 free () {}
1064 abort () {}
1065 __bzero () {}
1066 EOF
1067 dnl No \ in command here because it ends up inside ''.
1068 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1069                             -nostdlib -nostartfiles
1070                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1071   libc_cv_gcc_dwarf2_unwind_info=static
1072 else
1073   libc_cv_gcc_dwarf2_unwind_info=no
1074 fi
1075 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1076   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1077                               -nostdlib -nostartfiles
1078                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1079     libc_cv_gcc_dwarf2_unwind_info=yes
1080   else
1081     libc_cv_gcc_dwarf2_unwind_info=no
1082   fi
1083 fi
1084 rm -f conftest*])
1085 case $libc_cv_gcc_dwarf2_unwind_info in
1086 yes)
1087   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1088   ;;
1089 static)
1090   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1091   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1092   ;;
1093 esac
1094
1095 dnl Check whether compiler understands __builtin_expect.
1096 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1097 [cat > conftest.c <<EOF
1098 #line __oline__ "configure"
1099 int foo (int a)
1100 {
1101   a = __builtin_expect (a, 10);
1102   return a == 10 ? 0 : 1;
1103 }
1104 EOF
1105 dnl No \ in command here because it ends up inside ''.
1106 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1107                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1108   libc_cv_gcc_builtin_expect=yes
1109 else
1110   libc_cv_gcc_builtin_expect=no
1111 fi
1112 rm -f conftest*])
1113 if test "$libc_cv_gcc_builtin_expect" = yes; then
1114   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1115 fi
1116
1117 dnl Check whether the compiler supports subtraction of local labels.
1118 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1119 [cat > conftest.c <<EOF
1120 changequote(,)dnl
1121 #line __oline__ "configure"
1122 int foo (int a)
1123 {
1124   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1125   void *p = &&l1 + ar[a];
1126   goto *p;
1127  l1:
1128   return 1;
1129  l2:
1130   return 2;
1131 }
1132 changequote([,])dnl
1133 EOF
1134 dnl No \ in command here because it ends up inside ''.
1135 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1136                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1137   libc_cv_gcc_subtract_local_labels=yes
1138 else
1139   libc_cv_gcc_subtract_local_labels=no
1140 fi
1141 rm -f conftest*])
1142 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1143   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1144 fi
1145
1146 dnl Check whether we have the gd library available.
1147 AC_MSG_CHECKING(for libgd)
1148 old_CFLAGS="$CFLAGS"
1149 CFLAGS="$CFLAGS $libgd_include"
1150 old_LDFLAGS="$LDFLAGS"
1151 LDFLAGS="$LDFLAGS $libgd_ldflags"
1152 old_LIBS="$LIBS"
1153 LIBS="$LIBS -lgd -lpng -lz"
1154 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1155 CFLAGS="$old_CFLAGS"
1156 LDFLAGS="$old_LDFLAGS"
1157 LIBS="$old_LIBS"
1158 AC_MSG_RESULT($LIBGD)
1159 AC_SUBST(LIBGD)
1160
1161 ### End of automated tests.
1162 ### Now run sysdeps configure fragments.
1163
1164 # sysdeps configure fragments may set these with files to be linked below.
1165 libc_link_dests=
1166 libc_link_sources=
1167
1168 # They also can set these variables.
1169 ldd_rewrite_script=no
1170
1171 # Iterate over all the sysdep directories we will use, running their
1172 # configure fragments, and looking for a uname implementation.
1173 uname=
1174 for dir in $sysnames; do
1175   case $dir in
1176     /*) dest=$dir ;;
1177     *)  dest=$srcdir/$dir ;;
1178   esac
1179   if test -r $dest/configure; then
1180     AC_MSG_RESULT(running configure fragment for $dest)
1181     . $dest/configure
1182   fi
1183 [
1184   if test -z "$uname"; then
1185     if test -r $dest/uname.c ||
1186        test -r $dest/uname.S ||
1187        { test -r $dest/syscalls.list &&
1188          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1189       uname=$dir
1190     fi
1191   fi
1192 ]dnl
1193 done
1194
1195 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1196
1197 # If we will use the generic uname implementation, we must figure out what
1198 # it will say by examining the system, and write the results in config-name.h.
1199 if test "$uname" = "sysdeps/generic"; then
1200
1201 changequote(,)dnl
1202   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1203 changequote([,])dnl
1204   if test $uname_sysname != $config_os; then
1205     config_release=`echo $config_os | sed s/$uname_sysname//`
1206   fi
1207 dnl
1208 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1209     if test -r /vmunix; then
1210       kernel_id=`strings /vmunix | grep UNIX`
1211     elif test -r /dynix; then
1212       kernel_id=`strings /dynix | grep DYNIX`
1213     else
1214       kernel_id=
1215     fi
1216 ])dnl
1217
1218   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1219 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1220 changequote(,)dnl
1221   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1222 changequote([,])dnl
1223   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1224          != x$config_release; then
1225     # The configuration release is a substring of the kernel release.
1226     libc_cv_uname_release=$kernel_release
1227   elif test x$config_release != x; then
1228     libc_cv_uname_release=$config_release
1229   elif test x$kernel_release != x; then
1230     libc_cv_uname_release=$kernel_release
1231   else
1232     libc_cv_uname_release=unknown
1233   fi])
1234   uname_release="$libc_cv_uname_release"
1235
1236   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1237 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1238 changequote(,)dnl
1239   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1240 changequote([,])dnl
1241   if test -n "$kernel_version"; then
1242     libc_cv_uname_version="$kernel_version"
1243   else
1244     libc_cv_uname_version=unknown
1245   fi])
1246   uname_version="$libc_cv_uname_version"
1247
1248 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1249   config_uname=config-name.h:config-name.in
1250 else
1251   # For non-generic uname, we don't need to create config-name.h at all.
1252   config_uname=
1253 fi
1254
1255 AC_MSG_CHECKING(stdio selection)
1256 AC_SUBST(stdio)
1257 case $stdio in
1258 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1259 default) stdio=stdio ;;
1260 esac
1261 AC_MSG_RESULT($stdio)
1262
1263 # Test for old glibc 2.0.x headers so that they can be removed properly
1264 # Search only in includedir.
1265 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1266 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1267 then
1268   old_glibc_headers=yes
1269 else
1270   old_glibc_headers=no
1271 fi
1272 AC_MSG_RESULT($old_glibc_headers)
1273 if test ${old_glibc_headers} = yes; then
1274   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1275   AC_MSG_WARN(*** be removed.)
1276 fi
1277 AC_SUBST(old_glibc_headers)
1278
1279 AC_SUBST(libc_cv_slibdir)
1280 AC_SUBST(libc_cv_sysconfdir)
1281 AC_SUBST(libc_cv_rootsbindir)
1282
1283 AC_SUBST(has_ldconfig)
1284 AC_SUBST(ldd_rewrite_script)
1285
1286 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1287 if test $gnu_ld = yes; then
1288   AC_DEFINE(HAVE_GNU_LD)
1289 fi
1290 if test $gnu_as = yes; then
1291   AC_DEFINE(HAVE_GNU_AS)
1292 fi
1293 if test $elf = yes; then
1294   AC_DEFINE(HAVE_ELF)
1295 fi
1296
1297 AC_SUBST(static)
1298 AC_SUBST(shared)
1299 if test $shared = default; then
1300   if test $gnu_ld = yes; then
1301     shared=$elf
1302   else
1303     # For now we do not assume shared libs are available.  In future more
1304     # tests might become available.
1305     shared=no
1306   fi
1307 fi
1308
1309 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1310 [pic_default=yes
1311 cat > conftest.c <<EOF
1312 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1313 # error PIC is default.
1314 #endif
1315 EOF
1316 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1317   pic_default=no
1318 fi
1319 rm -f conftest.*])
1320 AC_SUBST(pic_default)
1321
1322 AC_SUBST(profile)
1323 AC_SUBST(omitfp)
1324 AC_SUBST(bounded)
1325 AC_SUBST(static_nss)
1326 AC_SUBST(nopic_initfini)
1327
1328 AC_SUBST(DEFINES)
1329
1330 case "$add_ons" in
1331   *door*) linux_doors=yes ;;
1332   *) linux_doors=no ;;
1333 esac
1334 AC_SUBST(linux_doors)
1335
1336 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1337   config_makefile=
1338 else
1339   config_makefile=Makefile
1340 fi
1341
1342 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1343 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1344 AC_SUBST(VERSION)
1345 AC_SUBST(RELEASE)
1346
1347 echo '*** Do NOT install this release on any production system!'
1348 echo '*** It is known to be broken and will be so for quite some time.'
1349 echo '*** Use the latest released version instead.'
1350
1351 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1352 case $CONFIG_FILES in *config.make*)
1353 echo "$config_vars" >> config.make;;
1354 esac
1355 test -d bits || mkdir bits], [config_vars='$config_vars'])