sysdeps/i386/bsd-_setjmp.S

   1 /* BSD `_setjmp' entry point to `sigsetjmp (..., 0)'.  i386 version.
   2    Copyright (C) 1994-2014 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* This just does a tail-call to `__sigsetjmp (ARG, 0)'.
  20    We cannot do it in C because it must be a tail-call, so frame-unwinding
  21    in setjmp doesn't clobber the state restored by longjmp.  */
  22
  23 #include <sysdep.h>
  24 #include <jmpbuf-offsets.h>
  25 #include <stap-probe.h>
  26
  27 #define PARMS   4               /* no space for saved regs */
  28 #define JMPBUF  PARMS
  29 #define SIGMSK  JMPBUF+4
  30
  31 ENTRY (_setjmp)
  32
  33         xorl %eax, %eax
  34         movl JMPBUF(%esp), %edx
  35
  36         /* Save registers.  */
  37         movl %ebx, (JB_BX*4)(%edx)
  38         movl %esi, (JB_SI*4)(%edx)
  39         movl %edi, (JB_DI*4)(%edx)
  40         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  41 #ifdef PTR_MANGLE
  42         PTR_MANGLE (%ecx)
  43 #endif
  44         movl %ecx, (JB_SP*4)(%edx)
  45         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  46         LIBC_PROBE (setjmp, 3, 4@%edx, -4@$0, 4@%ecx)
  47 #ifdef PTR_MANGLE
  48         PTR_MANGLE (%ecx)
  49 #endif
  50         movl %ecx, (JB_PC*4)(%edx)
  51         movl %ebp, (JB_BP*4)(%edx) /* Save caller's frame pointer.  */
  52
  53         movl %eax, JB_SIZE(%edx) /* No signal mask set.  */
  54         ret
  55 END (_setjmp)
  56 libc_hidden_def (_setjmp)