sysdeps/i386/rshift.S

   1 /* i80386 __mpn_rshift --
   2    Copyright (C) 1992, 1994, 1997, 1998 Free Software Foundation, Inc.
   3    This file is part of the GNU MP Library.
   4
   5    The GNU MP Library is free software; you can redistribute it and/or modify
   6    it under the terms of the GNU Library General Public License as published by
   7    the Free Software Foundation; either version 2 of the License, or (at your
   8    option) any later version.
   9
  10    The GNU MP Library is distributed in the hope that it will be useful, but
  11    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  12    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  13    License for more details.
  14
  15    You should have received a copy of the GNU Library General Public License
  16    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  17    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  18    MA 02111-1307, USA. */
  19
  20 /*
  21   INPUT PARAMETERS
  22   res_ptr       (sp + 4)
  23   s_ptr         (sp + 8)
  24   size          (sp + 12)
  25   cnt           (sp + 16)
  26 */
  27
  28 #include "sysdep.h"
  29 #include "asm-syntax.h"
  30
  31         .text
  32 ENTRY(__mpn_rshift)
  33         pushl   %edi
  34         pushl   %esi
  35         pushl   %ebx
  36
  37         movl    16(%esp),%edi           /* res_ptr */
  38         movl    20(%esp),%esi           /* s_ptr */
  39         movl    24(%esp),%edx           /* size */
  40         movl    28(%esp),%ecx           /* cnt */
  41
  42         leal    -4(%edi,%edx,4),%edi
  43         leal    (%esi,%edx,4),%esi
  44         negl    %edx
  45
  46         movl    (%esi,%edx,4),%ebx      /* read least significant limb */
  47         xorl    %eax,%eax
  48         shrdl   %cl,%ebx,%eax           /* compute carry limb */
  49         incl    %edx
  50         jz      L(end)
  51         pushl   %eax                    /* push carry limb onto stack */
  52         testb   $1,%edx
  53         jnz     L(1)                    /* enter loop in the middle */
  54         movl    %ebx,%eax
  55
  56         ALIGN (3)
  57 L(oop): movl    (%esi,%edx,4),%ebx      /* load next higher limb */
  58         shrdl   %cl,%ebx,%eax           /* compute result limb */
  59         movl    %eax,(%edi,%edx,4)      /* store it */
  60         incl    %edx
  61 L(1):   movl    (%esi,%edx,4),%eax
  62         shrdl   %cl,%eax,%ebx
  63         movl    %ebx,(%edi,%edx,4)
  64         incl    %edx
  65         jnz     L(oop)
  66
  67         shrl    %cl,%eax                /* compute most significant limb */
  68         movl    %eax,(%edi)             /* store it */
  69
  70         popl    %eax                    /* pop carry limb */
  71
  72         popl    %ebx
  73         popl    %esi
  74         popl    %edi
  75         ret
  76
  77 L(end): shrl    %cl,%ebx                /* compute most significant limb */
  78         movl    %ebx,(%edi)             /* store it */
  79
  80         popl    %ebx
  81         popl    %esi
  82         popl    %edi
  83         ret
  84 END(__mpn_rshift)