| blob | 678c7399ad885ef3d9a649a219cdf42e4a849c85 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Note we do not use AC_PREREQ here! See aclocal.m4 for what we use instead.
3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
4 AC_CONFIG_SRCDIR([include/features.h])
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([scripts])
8 ACX_PKGVERSION([GNU libc])
9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
11 [Package description])
12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
13 [Bug reporting address])
15 # Glibc should not depend on any header files
16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
17 [m4_divert_text([DEFAULTS],
18 [ac_includes_default='/* none */'])])
20 # We require GCC, and by default use its preprocessor. Override AC_PROG_CPP
21 # here to work around the Autoconf issue discussed in
22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
23 AC_DEFUN([AC_PROG_CPP],
24 [AC_REQUIRE([AC_PROG_CC])dnl
25 AC_ARG_VAR([CPP], [C preprocessor])dnl
26 _AC_ARG_VAR_CPPFLAGS()dnl
27 # On Suns, sometimes $CPP names a directory.
28 if test -n "$CPP" && test -d "$CPP"; then
29 CPP=
30 fi
31 if test -z "$CPP"; then
32 CPP="$CC -E"
33 fi
34 AC_SUBST(CPP)dnl
35 ])# AC_PROG_CPP
37 # We require GCC. Override _AC_PROG_CC_C89 here to work around the Autoconf
38 # issue discussed in
39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
42 dnl This is here so we can set $subdirs directly based on configure fragments.
43 AC_CONFIG_SUBDIRS()
45 AC_CANONICAL_HOST
47 AC_PROG_CC
48 if test $host != $build; then
49 AC_CHECK_PROGS(BUILD_CC, gcc cc)
50 fi
51 AC_SUBST(cross_compiling)
52 AC_PROG_CPP
53 AC_CHECK_TOOL(READELF, readelf, false)
55 # We need the C++ compiler only for testing.
56 AC_PROG_CXX
57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
59 AC_LANG_PUSH([C++])
60 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
61 [libc_cv_cxx_link_ok=yes],
62 [libc_cv_cxx_link_ok=no])
63 AC_LANG_POP([C++])])
64 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
66 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
67 AC_MSG_ERROR([you must configure in a separate build directory])
68 fi
70 # This will get text that should go into config.make.
71 config_vars=
73 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
74 AC_ARG_WITH([gd],
75 AC_HELP_STRING([--with-gd=DIR],
76 [find libgd include dir and library with prefix DIR]),
77 [dnl
78 case "$with_gd" in
79 yes|''|no) ;;
80 *) libgd_include="-I$withval/include"
81 libgd_ldflags="-L$withval/lib" ;;
82 esac
83 ])
84 AC_ARG_WITH([gd-include],
85 AC_HELP_STRING([--with-gd-include=DIR],
86 [find libgd include files in DIR]),
87 [dnl
88 case "$with_gd_include" in
89 ''|no) ;;
90 *) libgd_include="-I$withval" ;;
91 esac
92 ])
93 AC_ARG_WITH([gd-lib],
94 AC_HELP_STRING([--with-gd-lib=DIR],
95 [find libgd library files in DIR]),
96 [dnl
97 case "$with_gd_lib" in
98 ''|no) ;;
99 *) libgd_ldflags="-L$withval" ;;
100 esac
101 ])
103 if test -n "$libgd_include"; then
104 config_vars="$config_vars
105 CFLAGS-memusagestat.c = $libgd_include"
106 fi
107 if test -n "$libgd_ldflags"; then
108 config_vars="$config_vars
109 libgd-LDFLAGS = $libgd_ldflags"
110 fi
112 dnl Arguments to specify presence of other packages/features.
113 AC_ARG_WITH([fp],
114 AC_HELP_STRING([--with-fp],
115 [if using floating-point hardware @<:@default=yes@:>@]),
116 [with_fp=$withval],
117 [with_fp=yes])
118 AC_SUBST(with_fp)
119 AC_ARG_WITH([binutils],
120 AC_HELP_STRING([--with-binutils=PATH],
121 [specify location of binutils (as and ld)]),
122 [path_binutils=$withval],
123 [path_binutils=''])
124 AC_ARG_WITH([selinux],
125 AC_HELP_STRING([--with-selinux],
126 [if building with SELinux support]),
127 [with_selinux=$withval],
128 [with_selinux=auto])
130 AC_ARG_WITH([headers],
131 AC_HELP_STRING([--with-headers=PATH],
132 [location of system headers to use
133 (for example /usr/src/linux/include)
134 @<:@default=compiler default@:>@]),
135 [sysheaders=$withval],
136 [sysheaders=''])
137 AC_SUBST(sysheaders)
139 AC_SUBST(use_default_link)
140 AC_ARG_WITH([default-link],
141 AC_HELP_STRING([--with-default-link],
142 [do not use explicit linker scripts]),
143 [use_default_link=$withval],
144 [use_default_link=default])
146 AC_ARG_ENABLE([sanity-checks],
147 AC_HELP_STRING([--disable-sanity-checks],
148 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
149 [enable_sanity=$enableval],
150 [enable_sanity=yes])
152 AC_ARG_ENABLE([shared],
153 AC_HELP_STRING([--enable-shared],
154 [build shared library @<:@default=yes if GNU ld@:>@]),
155 [shared=$enableval],
156 [shared=yes])
157 AC_ARG_ENABLE([profile],
158 AC_HELP_STRING([--enable-profile],
159 [build profiled library @<:@default=no@:>@]),
160 [profile=$enableval],
161 [profile=no])
163 AC_ARG_ENABLE([hardcoded-path-in-tests],
164 AC_HELP_STRING([--enable-hardcoded-path-in-tests],
165 [hardcode newly built glibc path in tests @<:@default=no@:>@]),
166 [hardcoded_path_in_tests=$enableval],
167 [hardcoded_path_in_tests=no])
168 AC_SUBST(hardcoded_path_in_tests)
170 AC_ARG_ENABLE([stackguard-randomization],
171 AC_HELP_STRING([--enable-stackguard-randomization],
172 [initialize __stack_chk_guard canary with a random number at program start]),
173 [enable_stackguard_randomize=$enableval],
174 [enable_stackguard_randomize=no])
175 if test "$enable_stackguard_randomize" = yes; then
176 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
177 fi
179 AC_ARG_ENABLE([lock-elision],
180 AC_HELP_STRING([--enable-lock-elision[=yes/no]],
181 [Enable lock elision for pthread mutexes by default]),
182 [enable_lock_elision=$enableval],
183 [enable_lock_elision=no])
184 AC_SUBST(enable_lock_elision)
185 if test "$enable_lock_elision" = yes ; then
186 AC_DEFINE(ENABLE_LOCK_ELISION)
187 fi
189 dnl Generic infrastructure for drop-in additions to libc.
190 AC_ARG_ENABLE([add-ons],
191 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
192 [configure and build add-ons in DIR1,DIR2,...
193 search for add-ons if no parameter given]),
194 , [enable_add_ons=yes])
196 AC_ARG_ENABLE([hidden-plt],
197 AC_HELP_STRING([--disable-hidden-plt],
198 [do not hide internal function calls to avoid PLT]),
199 [hidden=$enableval],
200 [hidden=yes])
201 if test "x$hidden" = xno; then
202 AC_DEFINE(NO_HIDDEN)
203 fi
205 AC_ARG_ENABLE([bind-now],
206 AC_HELP_STRING([--enable-bind-now],
207 [disable lazy relocations in DSOs]),
208 [bindnow=$enableval],
209 [bindnow=no])
210 AC_SUBST(bindnow)
212 dnl On some platforms we cannot use dynamic loading. We must provide
213 dnl static NSS modules.
214 AC_ARG_ENABLE([static-nss],
215 AC_HELP_STRING([--enable-static-nss],
216 [build static NSS modules @<:@default=no@:>@]),
217 [static_nss=$enableval],
218 [static_nss=no])
219 dnl Enable static NSS also if we build no shared objects.
220 if test x"$static_nss" = xyes || test x"$shared" = xno; then
221 static_nss=yes
222 AC_DEFINE(DO_STATIC_NSS)
223 fi
225 AC_ARG_ENABLE([force-install],
226 AC_HELP_STRING([--disable-force-install],
227 [don't force installation of files from this package, even if they are older than the installed files]),
228 [force_install=$enableval],
229 [force_install=yes])
230 AC_SUBST(force_install)
232 AC_ARG_ENABLE([maintainer-mode],
233 AC_HELP_STRING([--enable-maintainer-mode],
234 [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
235 [maintainer=$enableval],
236 [maintainer=no])
238 dnl On some platforms we allow dropping compatibility with all kernel
239 dnl versions.
240 AC_ARG_ENABLE([kernel],
241 AC_HELP_STRING([--enable-kernel=VERSION],
242 [compile for compatibility with kernel not older than VERSION]),
243 [minimum_kernel=$enableval],
244 [])
245 dnl Prevent unreasonable values.
246 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
247 # Better nothing than this.
248 minimum_kernel=""
249 else
250 if test "$minimum_kernel" = current; then
251 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
252 fi
253 fi
255 dnl For the development we sometimes want gcc to issue even more warnings.
256 dnl This is not the default since many of the extra warnings are not
257 dnl appropriate.
258 AC_ARG_ENABLE([all-warnings],
259 AC_HELP_STRING([--enable-all-warnings],
260 [enable all useful warnings gcc can issue]),
261 [all_warnings=$enableval],
262 [])
263 AC_SUBST(all_warnings)
265 AC_ARG_ENABLE([werror],
266 AC_HELP_STRING([--disable-werror],
267 [do not build with -Werror]),
268 [enable_werror=$enableval],
269 [enable_werror=yes])
270 AC_SUBST(enable_werror)
272 AC_ARG_ENABLE([multi-arch],
273 AC_HELP_STRING([--enable-multi-arch],
274 [enable single DSO with optimizations for multiple architectures]),
275 [multi_arch=$enableval],
276 [multi_arch=default])
278 AC_ARG_ENABLE([nss-crypt],
279 AC_HELP_STRING([--enable-nss-crypt],
280 [enable libcrypt to use nss]),
281 [nss_crypt=$enableval],
282 [nss_crypt=no])
283 if test x$nss_crypt = xyes; then
284 nss_includes=-I$(nss-config --includedir 2>/dev/null)
285 if test $? -ne 0; then
286 AC_MSG_ERROR([cannot find include directory with nss-config])
287 fi
288 old_CFLAGS="$CFLAGS"
289 CFLAGS="$CFLAGS $nss_includes"
290 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
291 #include <hasht.h>
292 #include <nsslowhash.h>
293 void f (void) { NSSLOW_Init (); }])],
294 libc_cv_nss_crypt=yes,
295 AC_MSG_ERROR([
296 cannot find NSS headers with lowlevel hash function interfaces]))
297 old_LIBS="$LIBS"
298 LIBS="$LIBS -lfreebl3"
299 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
300 #include <hasht.h>
301 #include <nsslowhash.h>],
302 [NSSLOW_Init();])],
303 libc_cv_nss_crypt=yes,
304 AC_MSG_ERROR([
305 cannot link program using lowlevel NSS hash functions]))
306 CFLAGS="$old_CFLAGS"
307 LIBS="$old_LIBS"
308 else
309 libc_cv_nss_crypt=no
310 fi
311 AC_SUBST(libc_cv_nss_crypt)
314 AC_ARG_ENABLE([obsolete-rpc],
315 AC_HELP_STRING([--enable-obsolete-rpc],
316 [build and install the obsolete RPC code for link-time usage]),
317 [link_obsolete_rpc=$enableval],
318 [link_obsolete_rpc=no])
319 AC_SUBST(link_obsolete_rpc)
321 if test "$link_obsolete_rpc" = yes; then
322 AC_DEFINE(LINK_OBSOLETE_RPC)
323 fi
325 AC_ARG_ENABLE([systemtap],
326 [AS_HELP_STRING([--enable-systemtap],
327 [enable systemtap static probe points @<:@default=no@:>@])],
328 [systemtap=$enableval],
329 [systemtap=no])
330 if test "x$systemtap" != xno; then
331 AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
332 old_CFLAGS="$CFLAGS"
333 CFLAGS="-std=gnu99 $CFLAGS"
334 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
335 void foo (int i, void *p)
336 {
337 asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
338 :: STAP_PROBE_ASM_OPERANDS (2, i, p));
339 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
340 CFLAGS="$old_CFLAGS"])
341 if test $libc_cv_sdt = yes; then
342 AC_DEFINE([USE_STAP_PROBE])
343 elif test "x$systemtap" != xauto; then
344 AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
345 fi
346 fi
348 AC_ARG_ENABLE([build-nscd],
349 [AS_HELP_STRING([--disable-build-nscd],
350 [disable building and installing the nscd daemon])],
351 [build_nscd=$enableval],
352 [build_nscd=default])
353 AC_SUBST(build_nscd)
355 # Note the use of $use_nscd is near the bottom of the file.
356 AC_ARG_ENABLE([nscd],
357 [AS_HELP_STRING([--disable-nscd],
358 [library functions will not contact the nscd daemon])],
359 [use_nscd=$enableval],
360 [use_nscd=yes])
362 AC_ARG_ENABLE([pt_chown],
363 [AS_HELP_STRING([--enable-pt_chown],
364 [Enable building and installing pt_chown])],
365 [build_pt_chown=$enableval],
366 [build_pt_chown=no])
367 AC_SUBST(build_pt_chown)
368 if test "$build_pt_chown" = yes; then
369 AC_DEFINE(HAVE_PT_CHOWN)
370 fi
372 # The abi-tags file uses a fairly simplistic model for name recognition that
373 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a
374 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
375 # This doesn't get used much beyond that, so it's fairly safe.
376 case "$host_os" in
377 linux*)
378 ;;
379 gnu*)
380 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
381 ;;
382 esac
384 # We keep the original values in `$config_*' and never modify them, so we
385 # can write them unchanged into config.make. Everything else uses
386 # $machine, $vendor, and $os, and changes them whenever convenient.
387 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
389 # Don't allow vendor == "unknown"
390 test "$config_vendor" = unknown && config_vendor=
391 config_os="`echo $config_os | sed 's/^unknown-//'`"
393 # Some configurations imply other options.
394 elf=yes
396 # The configure fragment of an add-on port can modify these to supplement
397 # or override the table in the case statement below. No fragment should
398 # ever change the config_* variables, however.
399 machine=$config_machine
400 vendor=$config_vendor
401 os=$config_os
402 base_os=''
404 submachine=
405 AC_ARG_WITH([cpu],
406 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
407 [dnl
408 case "$withval" in
409 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
410 no) ;;
411 *) submachine="$withval" ;;
412 esac
413 ])
415 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
416 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
418 # An add-on can set this when it wants to disable the sanity check below.
419 libc_config_ok=no
421 dnl Having this here, though empty, makes sure that if add-ons' fragments
422 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
423 dnl our AC_OUTPUT will actually use it.
424 AC_CONFIG_SUBDIRS()
426 case "$enable_add_ons" in
427 ''|no) add_ons= ;;
428 yes|'*')
429 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
430 sed 's@/[[^/]]*$@@' | sort | uniq`
431 add_ons_automatic=yes
432 ;;
433 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
434 add_ons_automatic=no ;;
435 esac
437 configured_add_ons=
438 add_ons_sfx=
439 add_ons_pfx=
440 if test x"$add_ons" != x; then
441 for f in $add_ons; do
442 # Some sanity checks
443 case "$f" in
444 crypt)
445 AC_MSG_ERROR([
446 *** It seems that you're using an old \`crypt' add-on. crypt is now
447 *** part of glibc and using the old add-on will not work with this
448 *** release. Start again with fresh sources and without the old
449 *** \`crypt' add-on.])
450 ;;
451 localedata)
452 AC_MSG_ERROR([
453 *** It seems that you're using an old \`localedata' add-on. localedata
454 *** is now part of glibc and using the old add-on will not work with
455 *** this release. Start again with fresh sources and without the old
456 *** \`localedata' add-on.])
457 ;;
458 esac
459 done
461 # Now source each add-on's configure fragment.
462 # The fragments can use $srcdir/$libc_add_on to find themselves,
463 # and test $add_ons_automatic to see if they were explicitly requested.
464 # A fragment can clear (or even change) $libc_add_on to affect
465 # whether it goes into the list to be actually used in the build.
466 use_add_ons=
467 for libc_add_on in $add_ons; do
468 # Test whether such a directory really exists.
469 # It can be absolute, or relative to $srcdir, or relative to the build dir.
470 case "$libc_add_on" in
471 /*)
472 libc_add_on_srcdir=$libc_add_on
473 ;;
474 *)
475 test -d "$srcdir/$libc_add_on" || {
476 if test -d "$libc_add_on"; then
477 libc_add_on="`pwd`/$libc_add_on"
478 else
479 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
480 fi
481 }
482 libc_add_on_srcdir=$srcdir/$libc_add_on
483 ;;
484 esac
486 libc_add_on_frag=$libc_add_on_srcdir/configure
487 libc_add_on_canonical=
488 libc_add_on_config_subdirs=
489 if test -r "$libc_add_on_frag"; then
490 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
491 libc_add_on_canonical=unknown
492 libc_add_on_subdirs=
493 . "$libc_add_on_frag"
494 test -z "$libc_add_on" || {
495 configured_add_ons="$configured_add_ons $libc_add_on"
496 if test "x$libc_add_on_canonical" = xunknown; then
497 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
498 fi
499 for d in $libc_add_on_subdirs; do
500 case "$libc_add_on" in
501 /*) subdir_srcdir="$libc_add_on" ;;
502 *) subdir_srcdir="\$(..)$libc_add_on" ;;
503 esac
504 case "$d" in
505 .)
506 d="${libc_add_on_canonical:-$libc_add_on}"
507 ;;
508 /*)
509 subdir_srcdir="$d"
510 ;;
511 *)
512 subdir_srcdir="$subdir_srcdir/$d"
513 ;;
514 esac
515 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
516 add_on_subdirs="$add_on_subdirs $d"
517 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
518 $d-srcdir = $subdir_srcdir"
519 done
520 for d in $libc_add_on_config_subdirs; do
521 case "$d" in
522 /*) AC_MSG_ERROR(dnl
523 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
524 esac
525 if test ! -d "$libc_add_on_srcdir/$d"; then
526 AC_MSG_ERROR(fragment wants to configure missing directory $d)
527 fi
528 case "$libc_add_on" in
529 /*) AC_MSG_ERROR(dnl
530 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
531 esac
532 subdirs="$subdirs $libc_add_on/$d"
533 done
534 }
535 fi
536 if test -n "$libc_add_on"; then
537 LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
538 use_add_ons="$use_add_ons $libc_add_on"
539 add_ons_pfx="$add_ons_pfx $libc_add_on/"
540 test -z "$libc_add_on_canonical" ||
541 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
542 fi
543 done
544 # Use echo to strip excess whitespace.
545 add_ons="`echo $use_add_ons`"
546 fi
547 AC_SUBST(add_ons)
548 AC_SUBST(add_on_subdirs)
551 ###
552 ### I put this here to prevent those annoying emails from people who cannot
553 ### read and try to compile glibc on unsupported platforms. --drepper
554 ###
555 ### By using the undocumented --enable-hacker-mode option for configure
556 ### one can skip this test to make the configuration not fail for unsupported
557 ### platforms.
558 ###
559 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
560 case "$machine-$host_os" in
561 *-linux* | *-gnu*)
562 ;;
563 *)
564 echo "*** The GNU C library is currently not available for this platform."
565 echo "*** So far nobody cared to port it and if there is no volunteer it"
566 echo "*** might never happen. So, if you have interest to see glibc on"
567 echo "*** this platform visit"
568 echo "*** http://www.gnu.org/software/libc/porting.html"
569 echo "*** and join the group of porters"
570 exit 1
571 ;;
572 esac
573 fi
575 # Set base_machine if not set by a preconfigure fragment.
576 test -n "$base_machine" || base_machine=$machine
577 AC_SUBST(base_machine)
579 # For the multi-arch option we need support in the assembler & linker.
580 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
581 libc_cv_ld_gnu_indirect_function, [dnl
582 cat > conftest.S <<EOF
583 .type foo,%gnu_indirect_function
584 foo:
585 .globl _start
586 _start:
587 .globl __start
588 __start:
589 .data
590 #ifdef _LP64
591 .quad foo
592 #else
593 .long foo
594 #endif
595 EOF
596 libc_cv_ld_gnu_indirect_function=no
597 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
598 -nostartfiles -nostdlib \
599 -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
600 # Do a link to see if the backend supports IFUNC relocs.
601 $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
602 LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
603 libc_cv_ld_gnu_indirect_function=yes
604 }
605 fi
606 rm -f conftest*])
608 AC_MSG_CHECKING(whether .text pseudo-op must be used)
609 AC_CACHE_VAL(libc_cv_dot_text, [dnl
610 cat > conftest.s <<EOF
611 .text
612 EOF
613 libc_cv_dot_text=
614 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
615 libc_cv_dot_text=.text
616 fi
617 rm -f conftest*])
618 if test -z "$libc_cv_dot_text"; then
619 AC_MSG_RESULT(no)
620 else
621 AC_MSG_RESULT(yes)
622 fi
624 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
625 if test x"$multi_arch" = xyes; then
626 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
627 else
628 multi_arch=no
629 fi
630 fi
631 multi_arch_d=
632 if test x"$multi_arch" != xno; then
633 multi_arch_d=/multiarch
634 fi
636 # Compute the list of sysdep directories for this configuration.
637 # This can take a while to compute.
638 sysdep_dir=$srcdir/sysdeps
639 AC_MSG_CHECKING(sysdep dirs)
640 dnl We need to use [ and ] for other purposes for a while now.
641 changequote(,)dnl
642 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
643 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
645 test "x$base_os" != x || case "$os" in
646 gnu*)
647 base_os=mach/hurd ;;
648 linux*)
649 base_os=unix/sysv ;;
650 esac
652 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
653 tail=$os
654 ostry=$os
655 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
656 ostry="$ostry /$o"
657 tail=$o
658 done
659 o=`echo $tail | sed 's/[0-9]*$//'`
660 if test $o != $tail; then
661 ostry="$ostry /$o"
662 fi
663 # For linux-gnu, try linux-gnu, then linux.
664 o=`echo $tail | sed 's/-.*$//'`
665 if test $o != $tail; then
666 ostry="$ostry /$o"
667 fi
669 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
670 base=
671 tail=$base_os
672 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
673 set $b
674 base="$base /$1"
675 tail="$2"
676 done
678 # For sparc/sparc32, try sparc/sparc32 and then sparc.
679 mach=
680 tail=$machine${submachine:+/$submachine}
681 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
682 set $m
683 # Prepend the machine's FPU directory unless --without-fp.
684 if test "$with_fp" = yes; then
685 maybe_fpu=/fpu
686 else
687 maybe_fpu=/nofpu
688 fi
689 # For each machine term, try it with and then without /multiarch.
690 for try_fpu in $maybe_fpu ''; do
691 for try_multi in $multi_arch_d ''; do
692 mach="$mach /$1$try_fpu$try_multi"
693 done
694 done
695 tail="$2"
696 done
698 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
699 changequote([,])dnl
701 # Find what sysdep directories exist.
702 sysnames_add_ons=
703 sysnames=
704 for b in $base ''; do
705 for m0 in $mach ''; do
706 for v in /$vendor ''; do
707 test "$v" = / && continue
708 for o in /$ostry ''; do
709 test "$o" = / && continue
710 for m in $mach ''; do
711 for d in $add_ons_pfx ''; do
712 for a in $add_ons_sfx ''; do
713 try_suffix="$m0$b$v$o$m"
714 if test -n "$try_suffix"; then
715 try_srcdir="${srcdir}/"
716 case "$d" in
717 /*) try_srcdir= ;;
718 esac
719 try="${d}sysdeps$try_suffix$a"
720 test -n "$enable_debug_configure" &&
721 echo "$0 [DEBUG]: try $try" >&2
722 if test -d "$try_srcdir$try"; then
723 sysnames="$sysnames $try"
724 { test -n "$o" || test -n "$b"; } && os_used=t
725 { test -n "$m" || test -n "$m0"; } && machine_used=t
726 case x${m0:-$m} in
727 x*/$submachine) submachine_used=t ;;
728 esac
729 if test -n "$d"; then
730 case "$sysnames_add_ons" in
731 *" $d "*) ;;
732 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
733 esac
734 fi
735 fi
736 fi
737 done
738 done
739 done
740 done
741 done
742 done
743 done
745 # If the assembler supports gnu_indirect_function symbol type and the
746 # architecture supports multi-arch, we enable multi-arch by default.
747 case $sysnames_add_ons$sysnames in
748 *"$multi_arch_d"*)
749 ;;
750 *)
751 test x"$multi_arch" = xdefault && multi_arch=no
752 ;;
753 esac
754 if test x"$multi_arch" != xno; then
755 AC_DEFINE(USE_MULTIARCH)
756 fi
757 AC_SUBST(multi_arch)
759 if test -z "$os_used" && test "$os" != none; then
760 AC_MSG_ERROR(Operating system $os is not supported.)
761 fi
762 if test -z "$machine_used" && test "$machine" != none; then
763 AC_MSG_ERROR(The $machine is not supported.)
764 fi
765 if test -z "$submachine_used" && test -n "$submachine"; then
766 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
767 fi
768 AC_SUBST(submachine)
770 # We have now validated the configuration.
772 # Expand the list of system names into a full list of directories
773 # from each element's parent name and Implies file (if present).
774 set $sysnames
775 names=
776 while test $# -gt 0; do
777 name=$1
778 shift
780 case " $names " in *" $name "*)
781 # Already in the list.
782 continue
783 esac
785 # Report each name as we discover it, so there is no long pause in output.
786 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
788 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
790 case $name in
791 /*) xsrcdir= ;;
792 *) xsrcdir=$srcdir/ ;;
793 esac
794 test -n "$enable_debug_configure" &&
795 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
797 for implies_file in Implies Implies-before Implies-after; do
798 implies_type=`echo $implies_file | sed s/-/_/`
799 eval ${implies_type}=
800 if test -f $xsrcdir$name/$implies_file; then
801 # Collect more names from the `Implies' file (removing comments).
802 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
803 for x in $implied_candidate; do
804 found=no
805 if test -d $xsrcdir$name_base/$x; then
806 eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
807 found=yes
808 fi
809 for d in $add_ons_pfx ''; do
810 try="${d}sysdeps/$x"
811 case $d in
812 /*) try_srcdir= ;;
813 *) try_srcdir=$srcdir/ ;;
814 esac
815 test -n "$enable_debug_configure" &&
816 echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
817 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
818 then
819 eval "${implies_type}=\"\$${implies_type} \$try\""
820 found=yes
821 case "$sysnames_add_ons" in
822 *" $d "*) ;;
823 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
824 esac
825 fi
826 done
827 if test $found = no; then
828 AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
829 fi
830 done
831 fi
832 done
834 # Add NAME to the list of names.
835 names="$names $name"
837 # Find the parent of NAME, using the empty string if it has none.
838 changequote(,)dnl
839 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
840 changequote([,])dnl
842 test -n "$enable_debug_configure" &&
843 echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
844 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
846 # Add the names implied by NAME, and NAME's parent (if it has one), to
847 # the list of names to be processed (the argument list). We prepend the
848 # implied names to the list and append the parent. We want implied
849 # directories to come before further directories inferred from the
850 # configuration components; this ensures that for sysv4, unix/common
851 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
852 # after sysv4).
853 sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
854 test -n "$sysnames" && set $sysnames
855 done
857 # Add the default directories.
858 default_sysnames="sysdeps/generic"
859 sysnames="$names $default_sysnames"
860 AC_SUBST(sysnames)
861 # The other names were emitted during the scan.
862 AC_MSG_RESULT($default_sysnames)
864 # Collect the list of add-ons that supply partial sysdeps trees.
865 sysdeps_add_ons=
866 for add_on in $add_ons; do
867 case "$add_on" in
868 /*) xsrcdir= ;;
869 *) xsrcdir="$srcdir/" ;;
870 esac
872 test -d "$xsrcdir$add_on/sysdeps" || {
873 case "$configured_add_ons " in
874 *" $add_on "*) ;;
875 *|'')
876 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
877 ;;
878 esac
879 continue
880 }
882 sysdeps_add_ons="$sysdeps_add_ons $add_on"
883 case "$sysnames_add_ons" in
884 *" $add_on/ "*) ;;
885 *|'')
886 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
887 continue ;;
888 esac
890 found=no
891 for d in $sysnames; do
892 case "$d" in
893 $add_on/sysdeps/*) ;;
894 *) continue ;;
895 esac
896 (cd "$xsrcdir$d" && for f in *[[!~]]; do
897 case "$f" in
898 sys|bits)
899 for ff in $f/*.h; do
900 test -d "$ff" || { test -e "$ff" && exit 88; }
901 done
902 ;;
903 *)
904 test -d "$f" || { test -e "$f" && exit 88; }
905 ;;
906 esac
907 done)
908 if test $? -eq 88; then
909 found=yes
910 break
911 fi
912 done
913 if test $found = no; then
914 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
915 fi
916 done
917 AC_SUBST(sysdeps_add_ons)
920 ### Locate tools.
922 AC_PROG_INSTALL
923 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
924 # The makefiles need to use a different form to find it in $srcdir.
925 INSTALL='\$(..)./scripts/install-sh -c'
926 fi
927 AC_PROG_LN_S
929 LIBC_PROG_BINUTILS
931 # Accept binutils 2.22 or newer.
932 AC_CHECK_PROG_VER(AS, $AS, --version,
933 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
934 [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
935 AS=: critic_missing="$critic_missing as")
936 AC_CHECK_PROG_VER(LD, $LD, --version,
937 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
938 [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
939 LD=: critic_missing="$critic_missing ld")
941 # These programs are version sensitive.
942 AC_CHECK_TOOL_PREFIX
943 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
944 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
945 [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
947 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
948 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
949 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
950 MSGFMT=: aux_missing="$aux_missing msgfmt")
951 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
952 [GNU texinfo.* \([0-9][0-9.]*\)],
953 [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
954 MAKEINFO=: aux_missing="$aux_missing makeinfo")
955 AC_CHECK_PROG_VER(SED, sed, --version,
956 [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
957 [3.0[2-9]*|3.[1-9]*|[4-9]*],
958 SED=: aux_missing="$aux_missing sed")
959 AC_CHECK_PROG_VER(AWK, gawk, --version,
960 [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
961 [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
963 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
964 AC_TRY_COMPILE([], [
965 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6)
966 #error insufficient compiler
967 #endif],
968 [libc_cv_compiler_ok=yes],
969 [libc_cv_compiler_ok=no])])
970 AS_IF([test $libc_cv_compiler_ok != yes],
971 [critic_missing="$critic_missing compiler"])
973 AC_CHECK_TOOL(NM, nm, false)
975 if test "x$maintainer" = "xyes"; then
976 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
977 case "x$AUTOCONF" in
978 xno|x|x:) AUTOCONF=no ;;
979 *)
980 AC_CACHE_CHECK(dnl
981 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
982 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
983 libc_cv_autoconf_works=yes
984 else
985 libc_cv_autoconf_works=no
986 fi])
987 test $libc_cv_autoconf_works = yes || AUTOCONF=no
988 ;;
989 esac
990 if test "x$AUTOCONF" = xno; then
991 aux_missing="$aux_missing autoconf"
992 fi
993 else
994 AUTOCONF=no
995 fi
997 test -n "$critic_missing" && AC_MSG_ERROR([
998 *** These critical programs are missing or too old:$critic_missing
999 *** Check the INSTALL file for required versions.])
1001 test -n "$aux_missing" && AC_MSG_WARN([
1002 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1003 *** some features will be disabled.
1004 *** Check the INSTALL file for required versions.])
1006 # if using special system headers, find out the compiler's sekrit
1007 # header directory and add that to the list. NOTE: Only does the right
1008 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
1009 if test -n "$sysheaders"; then
1010 SYSINCLUDES=-nostdinc
1011 for d in include include-fixed; do
1012 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1013 SYSINCLUDES="$SYSINCLUDES -isystem $i"
1014 done
1015 SYSINCLUDES="$SYSINCLUDES \
1016 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1017 if test -n "$CXX"; then
1018 CXX_SYSINCLUDES=
1019 for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1020 | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1021 test "x$cxxheaders" != x &&
1022 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1023 done
1024 fi
1025 fi
1026 AC_SUBST(SYSINCLUDES)
1027 AC_SUBST(CXX_SYSINCLUDES)
1029 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1030 # since this would lead to problems installing/building glibc.
1031 # LD_LIBRARY_PATH contains the current directory if one of the following
1032 # is true:
1033 # - one of the terminals (":" and ";") is the first or last sign
1034 # - two terminals occur directly after each other
1035 # - the path contains an element with a dot in it
1036 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1037 changequote(,)dnl
1038 case ${LD_LIBRARY_PATH} in
1039 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1040 ld_library_path_setting="contains current directory"
1041 ;;
1042 *)
1043 ld_library_path_setting="ok"
1044 ;;
1045 esac
1046 changequote([,])dnl
1047 AC_MSG_RESULT($ld_library_path_setting)
1048 if test "$ld_library_path_setting" != "ok"; then
1049 AC_MSG_ERROR([
1050 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1051 *** building glibc. Please change the environment variable
1052 *** and run configure again.])
1053 fi
1055 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1056 if $CC -v -static-libgcc 2>&1 | grep 'unrecognized option.*static-libgcc' >/dev/null; then
1057 libc_cv_gcc_static_libgcc=
1058 else
1059 libc_cv_gcc_static_libgcc=-static-libgcc
1060 fi])
1061 AC_SUBST(libc_cv_gcc_static_libgcc)
1063 AC_PATH_PROG(BASH_SHELL, bash, no)
1065 AC_PATH_PROG(PERL, perl, no)
1066 if test "$PERL" != no &&
1067 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1068 PERL=no
1069 fi
1070 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1071 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1072 AC_CHECK_PROG_VER(BISON, bison, --version,
1073 [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1074 [2.7*|[3-9].*|[1-9][0-9]*],
1075 BISON=no)
1077 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1078 AC_TRY_COMPILE(dnl
1079 [#define __need_size_t
1080 #define __need_wchar_t
1081 #include <stddef.h>
1082 #define __need_NULL
1083 #include <stddef.h>], [size_t size; wchar_t wchar;
1084 #ifdef offsetof
1085 #error stddef.h ignored __need_*
1086 #endif
1087 if (&size == NULL || &wchar == NULL) abort ();],
1088 libc_cv_friendly_stddef=yes,
1089 libc_cv_friendly_stddef=no)])
1090 if test $libc_cv_friendly_stddef = yes; then
1091 config_vars="$config_vars
1092 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1093 fi
1095 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1096 libc_cv_need_minus_P, [dnl
1097 cat > conftest.S <<EOF
1098 #include "confdefs.h"
1099 /* Nothing whatsoever. */
1100 EOF
1101 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1102 libc_cv_need_minus_P=no
1103 else
1104 libc_cv_need_minus_P=yes
1105 fi
1106 rm -f conftest*])
1107 if test $libc_cv_need_minus_P = yes; then
1108 config_vars="$config_vars
1109 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1110 fi
1112 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1113 cat > conftest.s <<EOF
1114 ${libc_cv_dot_text}
1115 foo:
1116 .set glibc_conftest_frobozz,foo
1117 .globl glibc_conftest_frobozz
1118 EOF
1119 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1120 # (but it doesn't work), so we must do a linking check to be sure.
1121 cat > conftest1.c <<\EOF
1122 extern int glibc_conftest_frobozz;
1123 void _start() { glibc_conftest_frobozz = 1; }
1124 EOF
1125 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1126 -nostartfiles -nostdlib \
1127 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1128 libc_cv_asm_set_directive=yes
1129 else
1130 libc_cv_asm_set_directive=no
1131 fi
1132 rm -f conftest*])
1133 if test $libc_cv_asm_set_directive = yes; then
1134 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1135 fi
1137 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1138 libc_cv_asm_unique_object, [dnl
1139 cat > conftest.s <<EOF
1140 ${libc_cv_dot_text}
1141 _sym:
1142 .type _sym, %gnu_unique_object
1143 EOF
1144 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1145 libc_cv_asm_unique_object=yes
1146 else
1147 libc_cv_asm_unique_object=no
1148 fi
1149 rm -f conftest*])
1150 if test $libc_cv_asm_unique_object = yes; then
1151 AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1152 fi
1154 AC_CACHE_CHECK(for .previous assembler directive,
1155 libc_cv_asm_previous_directive, [dnl
1156 cat > conftest.s <<EOF
1157 .section foo_section
1158 .previous
1159 EOF
1160 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1161 libc_cv_asm_previous_directive=yes
1162 else
1163 libc_cv_asm_previous_directive=no
1164 fi
1165 rm -f conftest*])
1166 if test $libc_cv_asm_previous_directive = yes; then
1167 AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1168 else
1169 AC_CACHE_CHECK(for .popsection assembler directive,
1170 libc_cv_asm_popsection_directive, [dnl
1171 cat > conftest.s <<EOF
1172 .pushsection foo_section
1173 .popsection
1174 EOF
1175 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1176 libc_cv_asm_popsection_directive=yes
1177 else
1178 libc_cv_asm_popsection_directive=no
1179 fi
1180 rm -f conftest*])
1181 if test $libc_cv_asm_popsection_directive = yes; then
1182 AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1183 fi
1184 fi
1185 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1186 libc_cv_asm_protected_directive, [dnl
1187 cat > conftest.s <<EOF
1188 .protected foo
1189 foo:
1190 .hidden bar
1191 bar:
1192 EOF
1193 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1194 libc_cv_asm_protected_directive=yes
1195 else
1196 AC_MSG_ERROR(assembler support for symbol visibility is required)
1197 fi
1198 rm -f conftest*])
1200 if test $libc_cv_asm_protected_directive = yes; then
1201 AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1202 libc_cv_visibility_attribute,
1203 [cat > conftest.c <<EOF
1204 int foo __attribute__ ((visibility ("hidden"))) = 1;
1205 int bar __attribute__ ((visibility ("protected"))) = 1;
1206 EOF
1207 libc_cv_visibility_attribute=no
1208 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1209 if grep '\.hidden.*foo' conftest.s >/dev/null; then
1210 if grep '\.protected.*bar' conftest.s >/dev/null; then
1211 libc_cv_visibility_attribute=yes
1212 fi
1213 fi
1214 fi
1215 rm -f conftest.{c,s}
1216 ])
1217 if test $libc_cv_visibility_attribute != yes; then
1218 AC_MSG_ERROR(compiler support for visibility attribute is required)
1219 fi
1220 fi
1222 if test $libc_cv_visibility_attribute = yes; then
1223 AC_CACHE_CHECK(for broken __attribute__((visibility())),
1224 libc_cv_broken_visibility_attribute,
1225 [cat > conftest.c <<EOF
1226 int foo (int x);
1227 int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1228 int bar (int x) { return x; }
1229 EOF
1230 libc_cv_broken_visibility_attribute=yes
1231 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1232 changequote(,)dnl
1233 if grep '\.hidden[ _]foo' conftest.s >/dev/null; then
1234 changequote([,])dnl
1235 libc_cv_broken_visibility_attribute=no
1236 fi
1237 fi
1238 rm -f conftest.c conftest.s
1239 ])
1240 if test $libc_cv_broken_visibility_attribute = yes; then
1241 AC_MSG_ERROR(working compiler support for visibility attribute is required)
1242 fi
1243 fi
1245 AC_CACHE_CHECK(for broken __attribute__((alias())),
1246 libc_cv_broken_alias_attribute,
1247 [cat > conftest.c <<EOF
1248 extern int foo (int x) __asm ("xyzzy");
1249 int bar (int x) { return x; }
1250 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1251 extern int dfoo;
1252 extern __typeof (dfoo) dfoo __asm ("abccb");
1253 int dfoo = 1;
1254 EOF
1255 libc_cv_broken_alias_attribute=yes
1256 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1257 if grep 'xyzzy' conftest.s >/dev/null &&
1258 grep 'abccb' conftest.s >/dev/null; then
1259 libc_cv_broken_alias_attribute=no
1260 fi
1261 fi
1262 rm -f conftest.c conftest.s
1263 ])
1264 if test $libc_cv_broken_alias_attribute = yes; then
1265 AC_MSG_ERROR(working alias attribute support required)
1266 fi
1268 if test $libc_cv_visibility_attribute = yes; then
1269 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1270 libc_cv_have_sdata_section,
1271 [echo "int i;" > conftest.c
1272 libc_cv_have_sdata_section=no
1273 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1274 | grep '\.sdata' >/dev/null; then
1275 libc_cv_have_sdata_section=yes
1276 fi
1277 rm -f conftest.c conftest.so
1278 ])
1279 if test $libc_cv_have_sdata_section = yes; then
1280 AC_DEFINE(HAVE_SDATA_SECTION)
1281 fi
1282 fi
1284 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1285 libc_cv_initfini_array, [dnl
1286 LIBC_TRY_LINK_STATIC([
1287 int foo (void) { return 1; }
1288 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1289 ],
1290 [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1291 libc_cv_initfini_array=yes
1292 else
1293 libc_cv_initfini_array=no
1294 fi],
1295 [libc_cv_initfini_array=no])
1296 ])
1297 if test $libc_cv_initfini_array != yes; then
1298 AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1299 fi
1301 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1302 libc_cv_ctors_header, [dnl
1303 libc_cv_ctors_header=yes
1304 LIBC_TRY_LINK_STATIC([
1305 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1306 __attribute__ ((destructor)) void dtor (void) { asm (""); }
1307 ],
1308 [dnl
1309 AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1310 { gsub(/\@<:@ */, "@<:@") }
1311 $2 == ".ctors" || $2 == ".dtors" {
1312 size = strtonum("0x" $6)
1313 align = strtonum("0x" $NF)
1314 seen@<:@$2@:>@ = 1
1315 stub@<:@$2@:>@ = size == align * 2
1316 }
1317 END {
1318 ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1319 dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1320 exit ((ctors_ok && dtors_ok) ? 0 : 1)
1321 }
1322 '], [libc_cv_ctors_header=no])
1323 ], [dnl
1324 AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1325 ])
1326 ])
1327 if test $libc_cv_ctors_header = no; then
1328 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1329 fi
1331 AC_CACHE_CHECK(for libunwind-support in compiler,
1332 libc_cv_cc_with_libunwind, [
1333 cat > conftest.c <<EOF
1334 int main (void) { return 0; }
1335 EOF
1336 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1337 conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1338 libc_cv_cc_with_libunwind=yes
1339 else
1340 libc_cv_cc_with_libunwind=no
1341 fi
1342 rm -f conftest*])
1343 AC_SUBST(libc_cv_cc_with_libunwind)
1344 if test $libc_cv_cc_with_libunwind = yes; then
1345 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1346 fi
1348 LIBC_LINKER_FEATURE([-z nodelete], [-Wl,--enable-new-dtags,-z,nodelete],
1349 [libc_cv_z_nodelete=yes],
1350 [AC_MSG_ERROR(linker with -z nodelete support required)])
1352 LIBC_LINKER_FEATURE([-z nodlopen], [-Wl,--enable-new-dtags,-z,nodlopen],
1353 [libc_cv_z_nodlopen=yes],
1354 [AC_MSG_ERROR(linker with -z nodlopen support required)])
1356 LIBC_LINKER_FEATURE([-z initfirst], [-Wl,--enable-new-dtags,-z,initfirst],
1357 [libc_cv_z_initfirst=yes],
1358 [AC_MSG_ERROR(linker with -z initfirst support required)])
1360 AC_CACHE_CHECK(for -Bgroup option,
1361 libc_cv_Bgroup, [dnl
1362 cat > conftest.c <<EOF
1363 int _start (void) { return 42; }
1364 EOF
1365 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1366 -fPIC -shared -o conftest.so conftest.c
1367 -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1368 then
1369 libc_cv_Bgroup=yes
1370 else
1371 libc_cv_Bgroup=no
1372 fi
1373 rm -f conftest*])
1374 AC_SUBST(libc_cv_Bgroup)
1376 ASFLAGS_config=
1377 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1378 libc_cv_as_noexecstack, [dnl
1379 cat > conftest.c <<EOF
1380 void foo (void) { }
1381 EOF
1382 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1383 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1384 && grep .note.GNU-stack conftest.s >/dev/null \
1385 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1386 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1387 then
1388 libc_cv_as_noexecstack=yes
1389 else
1390 libc_cv_as_noexecstack=no
1391 fi
1392 rm -f conftest*])
1393 if test $libc_cv_as_noexecstack = yes; then
1394 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1395 fi
1396 AC_SUBST(ASFLAGS_config)
1398 AC_CACHE_CHECK(for -z combreloc,
1399 libc_cv_z_combreloc, [dnl
1400 cat > conftest.c <<EOF
1401 extern int bar (int);
1402 extern int mumble;
1403 int foo (void) { return bar (mumble); }
1404 EOF
1405 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1406 -fPIC -shared -o conftest.so conftest.c
1407 -nostdlib -nostartfiles
1408 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1409 then
1410 dnl The following test is a bit weak. We must use a tool which can test
1411 dnl cross-platform since the gcc used can be a cross compiler. Without
1412 dnl introducing new options this is not easily doable. Instead use a tool
1413 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1414 dnl look for a section named .rel.dyn.
1415 if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1416 libc_cv_z_combreloc=yes
1417 else
1418 libc_cv_z_combreloc=no
1419 fi
1420 else
1421 libc_cv_z_combreloc=no
1422 fi
1423 rm -f conftest*])
1424 if test "$libc_cv_z_combreloc" = yes; then
1425 AC_DEFINE(HAVE_Z_COMBRELOC)
1426 fi
1427 AC_SUBST(libc_cv_z_combreloc)
1429 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1430 [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1431 AC_SUBST(libc_cv_z_execstack)
1433 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1434 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1435 ])
1437 AC_SUBST(libc_cv_fpie)
1439 AC_CACHE_CHECK(for --hash-style option,
1440 libc_cv_hashstyle, [dnl
1441 cat > conftest.c <<EOF
1442 int _start (void) { return 42; }
1443 EOF
1444 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1445 -fPIC -shared -o conftest.so conftest.c
1446 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1447 then
1448 libc_cv_hashstyle=yes
1449 else
1450 libc_cv_hashstyle=no
1451 fi
1452 rm -f conftest*])
1453 AC_SUBST(libc_cv_hashstyle)
1455 # The linker's default -shared behavior is good enough if it
1456 # does these things that our custom linker scripts ensure that
1457 # all allocated NOTE sections come first.
1458 if test "$use_default_link" = default; then
1459 AC_CACHE_CHECK([for sufficient default -shared layout],
1460 libc_cv_use_default_link, [dnl
1461 libc_cv_use_default_link=no
1462 cat > conftest.s <<\EOF
1463 .section .note.a,"a",%note
1464 .balign 4
1465 .long 4,4,9
1466 .string "GNU"
1467 .string "foo"
1468 .section .note.b,"a",%note
1469 .balign 4
1470 .long 4,4,9
1471 .string "GNU"
1472 .string "bar"
1473 EOF
1474 if AC_TRY_COMMAND([dnl
1475 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1476 ac_try=`$READELF -S conftest.so | sed -n \
1477 ['${x;p;}
1478 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1479 t a
1480 b
1481 : a
1482 H']`
1483 then
1484 libc_seen_a=no libc_seen_b=no
1485 set -- $ac_try
1486 while test $# -ge 2 -a "$1" = NOTE; do
1487 case "$2" in
1488 .note.a) libc_seen_a=yes ;;
1489 .note.b) libc_seen_b=yes ;;
1490 esac
1491 shift 2
1492 done
1493 case "$libc_seen_a$libc_seen_b" in
1494 yesyes)
1495 libc_cv_use_default_link=yes
1496 ;;
1497 *)
1498 echo >&AS_MESSAGE_LOG_FD "\
1499 $libc_seen_a$libc_seen_b from:
1500 $ac_try"
1501 ;;
1502 esac
1503 fi
1504 rm -f conftest*])
1505 use_default_link=$libc_cv_use_default_link
1506 fi
1508 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1509 if libc_cv_output_format=`
1510 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1511 then
1512 :
1513 else
1514 libc_cv_output_format=
1515 fi
1516 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1517 AC_SUBST(libc_cv_output_format)
1519 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1520 cat > conftest.c <<EOF
1521 int foo;
1522 EOF
1523 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1524 conftest.c 1>&AS_MESSAGE_LOG_FD])
1525 then
1526 libc_cv_fno_toplevel_reorder=yes
1527 else
1528 libc_cv_fno_toplevel_reorder=no
1529 fi
1530 rm -f conftest*])
1531 if test $libc_cv_fno_toplevel_reorder = yes; then
1532 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1533 else
1534 fno_unit_at_a_time=-fno-unit-at-a-time
1535 fi
1536 AC_SUBST(fno_unit_at_a_time)
1538 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1539 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1540 [libc_cv_ssp=yes],
1541 [libc_cv_ssp=no])
1542 ])
1543 AC_SUBST(libc_cv_ssp)
1545 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1546 cat > conftest.c <<EOF
1547 int foo;
1548 #ifdef __GNUC_GNU_INLINE__
1549 main () { return 0;}
1550 #else
1551 #error
1552 #endif
1553 EOF
1554 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1555 -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1556 then
1557 libc_cv_gnu89_inline=yes
1558 else
1559 libc_cv_gnu89_inline=no
1560 fi
1561 rm -f conftest*])
1562 if test $libc_cv_gnu89_inline = yes; then
1563 gnu89_inline=-fgnu89-inline
1564 else
1565 gnu89_inline=
1566 fi
1567 AC_SUBST(gnu89_inline)
1569 AC_CACHE_CHECK(whether cc puts quotes around section names,
1570 libc_cv_have_section_quotes,
1571 [cat > conftest.c <<EOF
1572 static const int foo
1573 __attribute__ ((section ("bar"))) = 1;
1574 EOF
1575 if ${CC-cc} -S conftest.c -o conftest.s; then
1576 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1577 libc_cv_have_section_quotes=yes
1578 else
1579 libc_cv_have_section_quotes=no
1580 fi
1581 else
1582 libc_cv_have_section_quotes=unknown
1583 fi
1584 rm -f conftest.{c,s}
1585 ])
1586 if test $libc_cv_have_section_quotes = yes; then
1587 AC_DEFINE(HAVE_SECTION_QUOTES)
1588 fi
1590 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1591 [dnl
1592 cat > conftest.s <<EOF
1593 ${libc_cv_dot_text}
1594 .globl foo
1595 foo:
1596 .weak foo
1597 .weak bar; bar = foo
1598 EOF
1599 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1600 libc_cv_asm_weak_directive=yes
1601 else
1602 libc_cv_asm_weak_directive=no
1603 fi
1604 rm -f conftest*])
1606 if test $libc_cv_asm_weak_directive = no; then
1607 AC_CACHE_CHECK(for assembler .weakext directive,
1608 libc_cv_asm_weakext_directive,
1609 [dnl
1610 cat > conftest.s <<EOF
1611 ${libc_cv_dot_text}
1612 .globl foo
1613 foo:
1614 .weakext bar foo
1615 .weakext baz
1616 .globl baz
1617 baz:
1618 EOF
1619 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1620 libc_cv_asm_weakext_directive=yes
1621 else
1622 libc_cv_asm_weakext_directive=no
1623 fi
1624 rm -f conftest*])
1626 fi # no .weak
1628 if test $libc_cv_asm_weak_directive = yes; then
1629 AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1630 elif test $libc_cv_asm_weakext_directive = yes; then
1631 AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1632 fi
1634 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1635 cat > conftest.c <<\EOF
1636 _start () {}
1637 int __eh_pc;
1638 __throw () {}
1639 EOF
1640 dnl No \ in command here because it ends up inside ''.
1641 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1642 -nostdlib -nostartfiles -Wl,--no-whole-archive
1643 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1644 libc_cv_ld_no_whole_archive=yes
1645 else
1646 libc_cv_ld_no_whole_archive=no
1647 fi
1648 rm -f conftest*])
1649 if test $libc_cv_ld_no_whole_archive = no; then
1650 AC_MSG_ERROR([support for --no-whole-archive is needed])
1651 fi
1653 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1654 cat > conftest.c <<\EOF
1655 _start () {}
1656 int __eh_pc;
1657 __throw () {}
1658 EOF
1659 dnl No \ in command here because it ends up inside ''.
1660 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1661 -nostdlib -nostartfiles -fexceptions
1662 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1663 libc_cv_gcc_exceptions=yes
1664 else
1665 libc_cv_gcc_exceptions=no
1666 fi
1667 rm -f conftest*])
1668 if test $libc_cv_gcc_exceptions = yes; then
1669 exceptions=-fexceptions
1670 fi
1671 AC_SUBST(exceptions)dnl
1673 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1674 cat > conftest.c <<\EOF
1675 void zero (void *x)
1676 {
1677 __builtin_memset (x, 0, 1000);
1678 }
1679 EOF
1680 dnl
1681 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1682 then
1683 libc_cv_gcc_builtin_memset=no
1684 else
1685 libc_cv_gcc_builtin_memset=yes
1686 fi
1687 rm -f conftest* ])
1688 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1689 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1690 fi
1692 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1693 cat > conftest.c <<\EOF
1694 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1695 char *foo (const char *a, const char *b)
1696 {
1697 return __builtin_strstr (a, b);
1698 }
1699 EOF
1700 dnl
1701 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1702 then
1703 libc_cv_gcc_builtin_redirection=yes
1704 else
1705 libc_cv_gcc_builtin_redirection=no
1706 fi
1707 rm -f conftest* ])
1708 if test "$libc_cv_gcc_builtin_redirection" = no; then
1709 AC_MSG_ERROR([support for the symbol redirection needed])
1710 fi
1712 dnl Check whether the compiler supports the __thread keyword.
1713 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1714 [cat > conftest.c <<\EOF
1715 __thread int a = 42;
1716 EOF
1717 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1718 libc_cv_gcc___thread=yes
1719 else
1720 libc_cv_gcc___thread=no
1721 fi
1722 rm -f conftest*])
1723 if test "$libc_cv_gcc___thread" = no; then
1724 AC_MSG_ERROR([support for the __thread keyword is required])
1725 fi
1727 dnl Check whether the compiler supports the tls_model attribute.
1728 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1729 cat > conftest.c <<\EOF
1730 extern __thread int a __attribute__((tls_model ("initial-exec")));
1731 EOF
1732 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1733 libc_cv_gcc_tls_model_attr=yes
1734 else
1735 libc_cv_gcc_tls_model_attr=no
1736 fi
1737 rm -f conftest*])
1738 if test "$libc_cv_gcc_tls_model_attr" = no; then
1739 AC_MSG_ERROR([support for the tls_model attribute is required])
1740 fi
1742 dnl Determine how to disable generation of FMA instructions.
1743 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1744 libc_cv_cc_nofma, [dnl
1745 libc_cv_cc_nofma=
1746 for opt in -ffp-contract=off -mno-fused-madd; do
1747 LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1748 done])
1749 AC_SUBST(libc_cv_cc_nofma)
1751 if test -n "$submachine"; then
1752 AC_CACHE_CHECK([for compiler option for CPU variant],
1753 libc_cv_cc_submachine, [dnl
1754 libc_cv_cc_submachine=no
1755 for opt in "-march=$submachine" "-mcpu=$submachine"; do
1756 LIBC_TRY_CC_OPTION([$opt], [
1757 libc_cv_cc_submachine="$opt"
1758 break], [])
1759 done])
1760 if test "x$libc_cv_cc_submachine" = xno; then
1761 AC_MSG_ERROR([${CC-cc} does not support $submachine])
1762 fi
1763 fi
1764 AC_SUBST(libc_cv_cc_submachine)
1766 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1767 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1768 cat > conftest.c <<EOF
1769 void
1770 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1771 foo (void) {}
1772 EOF
1773 libc_cv_cc_loop_to_function=no
1774 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1775 then
1776 libc_cv_cc_loop_to_function=yes
1777 fi
1778 rm -f conftest*])
1779 if test $libc_cv_cc_loop_to_function = yes; then
1780 AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1781 fi
1782 AC_SUBST(libc_cv_cc_loop_to_function)
1784 dnl Check whether we have the gd library available.
1785 AC_MSG_CHECKING(for libgd)
1786 if test "$with_gd" != "no"; then
1787 old_CFLAGS="$CFLAGS"
1788 CFLAGS="$CFLAGS $libgd_include"
1789 old_LDFLAGS="$LDFLAGS"
1790 LDFLAGS="$LDFLAGS $libgd_ldflags"
1791 old_LIBS="$LIBS"
1792 LIBS="$LIBS -lgd -lpng -lz -lm"
1793 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1794 CFLAGS="$old_CFLAGS"
1795 LDFLAGS="$old_LDFLAGS"
1796 LIBS="$old_LIBS"
1797 else
1798 LIBGD=no
1799 fi
1800 AC_MSG_RESULT($LIBGD)
1801 AC_SUBST(LIBGD)
1803 # SELinux detection
1804 if test x$with_selinux = xno ; then
1805 have_selinux=no;
1806 else
1807 # See if we have the SELinux library
1808 AC_CHECK_LIB(selinux, is_selinux_enabled,
1809 have_selinux=yes, have_selinux=no)
1810 if test x$with_selinux = xyes ; then
1811 if test x$have_selinux = xno ; then
1812 AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1813 fi
1814 fi
1815 fi
1816 # Check if we're building with SELinux support.
1817 if test "x$have_selinux" = xyes; then
1818 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1820 # See if we have the libaudit library
1821 AC_CHECK_LIB(audit, audit_log_user_avc_message,
1822 have_libaudit=yes, have_libaudit=no)
1823 if test "x$have_libaudit" = xyes; then
1824 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1825 fi
1826 AC_SUBST(have_libaudit)
1828 # See if we have the libcap library
1829 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1830 if test "x$have_libcap" = xyes; then
1831 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1832 fi
1833 AC_SUBST(have_libcap)
1834 fi
1835 AC_SUBST(have_selinux)
1837 dnl check for the size of 'long double'.
1838 AC_CHECK_SIZEOF(long double, 0)
1839 sizeof_long_double=$ac_cv_sizeof_long_double
1840 AC_SUBST(sizeof_long_double)
1842 CPPUNDEFS=
1843 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1844 dnl Since we are building the implementations of the fortified functions here,
1845 dnl having the macro defined interacts very badly.
1846 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1847 [AC_TRY_COMPILE([], [
1848 #ifdef _FORTIFY_SOURCE
1849 # error bogon
1850 #endif],
1851 [libc_cv_predef_fortify_source=no],
1852 [libc_cv_predef_fortify_source=yes])])
1853 if test $libc_cv_predef_fortify_source = yes; then
1854 CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1855 fi
1856 AC_SUBST(CPPUNDEFS)
1858 dnl Check for silly hacked compilers inserting -fstack-protector.
1859 dnl This breaks badly for the early startup code we compile, since
1860 dnl the compiled code can refer to a magic machine-dependent location
1861 dnl for the canary value before we have sufficient setup for that to
1862 dnl work. It's also questionable to build all of libc with this flag
1863 dnl even when you're doing that for most applications you build, since
1864 dnl libc's code is so heavily-used and performance-sensitive. If we
1865 dnl ever really want to make that work, it should be enabled explicitly
1866 dnl in the libc build, not inherited from implicit compiler settings.
1867 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
1868 libc_cv_predef_stack_protector, [
1869 AC_TRY_COMPILE([extern void foobar (char *);],
1870 [char large_array[2048]; foobar (large_array);], [
1871 libc_undefs=`$NM -u conftest.o |
1872 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1873 2>&AS_MESSAGE_LOG_FD` || {
1874 AC_MSG_ERROR([confusing output from $NM -u])
1875 }
1876 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1877 # On some architectures, there are architecture-specific undefined
1878 # symbols (resolved by the linker), so filter out unknown symbols.
1879 # This will fail to produce the correct result if the compiler
1880 # defaults to -fstack-protector but this produces an undefined symbol
1881 # other than __stack_chk_fail. However, compilers like that have not
1882 # been encountered in practice.
1883 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
1884 case "$libc_undefs" in
1885 foobar) libc_cv_predef_stack_protector=no ;;
1886 '__stack_chk_fail
1887 foobar') libc_cv_predef_stack_protector=yes ;;
1888 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
1889 esac],
1890 [AC_MSG_ERROR([test compilation failed])])
1891 ])
1892 libc_extra_cflags=
1893 if test $libc_cv_predef_stack_protector = yes; then
1894 libc_extra_cflags="$libc_extra_cflags -fno-stack-protector"
1895 fi
1896 libc_extra_cppflags=
1898 # Some linkers on some architectures support __ehdr_start but with
1899 # bugs. Make sure usage of it does not create relocations in the
1900 # output (as the linker should resolve them all for us).
1901 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1902 libc_cv_ehdr_start, [
1903 old_CFLAGS="$CFLAGS"
1904 old_LDFLAGS="$LDFLAGS"
1905 old_LIBS="$LIBS"
1906 CFLAGS="$CFLAGS -fPIC"
1907 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared"
1908 LIBS=
1909 AC_LINK_IFELSE([AC_LANG_SOURCE([
1910 typedef struct {
1911 char foo;
1912 long val;
1913 } Ehdr;
1914 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1915 long ehdr (void) { return __ehdr_start.val; }
1916 ])],
1917 [if $READELF -r conftest | fgrep __ehdr_start >/dev/null; then
1918 libc_cv_ehdr_start=broken
1919 else
1920 libc_cv_ehdr_start=yes
1921 fi], [libc_cv_ehdr_start=no])
1922 CFLAGS="$old_CFLAGS"
1923 LDFLAGS="$old_LDFLAGS"
1924 LIBS="$old_LIBS"
1925 ])
1926 if test "$libc_cv_ehdr_start" = yes; then
1927 AC_DEFINE([HAVE_EHDR_START])
1928 elif test "$libc_cv_ehdr_start" = broken; then
1929 AC_MSG_WARN([linker is broken -- you should upgrade])
1930 fi
1932 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1933 libc_cv_builtin_trap, [dnl
1934 libc_cv_builtin_trap=no
1935 AC_TRY_COMPILE([], [__builtin_trap ()], [
1936 libc_undefs=`$NM -u conftest.o |
1937 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1938 2>&AS_MESSAGE_LOG_FD` || {
1939 AC_MSG_ERROR([confusing output from $NM -u])
1940 }
1941 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1942 if test -z "$libc_undefs"; then
1943 libc_cv_builtin_trap=yes
1944 fi])])
1945 if test $libc_cv_builtin_trap = yes; then
1946 AC_DEFINE([HAVE_BUILTIN_TRAP])
1947 fi
1949 ### End of automated tests.
1950 ### Now run sysdeps configure fragments.
1952 # They also can set these variables.
1953 use_ldconfig=no
1954 ldd_rewrite_script=no
1955 libc_cv_sysconfdir=$sysconfdir
1956 libc_cv_localstatedir=$localstatedir
1957 libc_cv_gcc_unwind_find_fde=no
1958 libc_cv_idn=no
1960 # Iterate over all the sysdep directories we will use, running their
1961 # configure fragments.
1962 for dir in $sysnames; do
1963 case $dir in
1964 /*) dest=$dir ;;
1965 *) dest=$srcdir/$dir ;;
1966 esac
1967 if test -r $dest/configure; then
1968 AC_MSG_RESULT(running configure fragment for $dir)
1969 . $dest/configure
1970 fi
1971 done
1973 AC_SUBST(libc_extra_cflags)
1974 AC_SUBST(libc_extra_cppflags)
1976 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1977 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1978 fi
1979 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1981 # A sysdeps configure fragment can reset this if IFUNC is not actually
1982 # usable even though the assembler knows how to generate the symbol type.
1983 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1984 AC_DEFINE(HAVE_IFUNC)
1985 fi
1987 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1988 # configure fragment can override the value to prevent this AC_DEFINE.
1989 AC_SUBST(use_nscd)
1990 if test "x$use_nscd" != xno; then
1991 AC_DEFINE([USE_NSCD])
1992 fi
1993 if test "x$build_nscd" = xdefault; then
1994 build_nscd=$use_nscd
1995 fi
1997 # Test for old glibc 2.0.x headers so that they can be removed properly
1998 # Search only in includedir.
1999 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2000 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2001 then
2002 old_glibc_headers=yes
2003 else
2004 old_glibc_headers=no
2005 fi
2006 AC_MSG_RESULT($old_glibc_headers)
2007 if test ${old_glibc_headers} = yes; then
2008 AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2009 AC_MSG_WARN(*** be removed.)
2010 fi
2011 AC_SUBST(old_glibc_headers)
2013 AC_SUBST(libc_cv_slibdir)
2014 AC_SUBST(libc_cv_rtlddir)
2015 AC_SUBST(libc_cv_localedir)
2016 AC_SUBST(libc_cv_sysconfdir)
2017 AC_SUBST(libc_cv_localstatedir)
2018 AC_SUBST(libc_cv_rootsbindir)
2019 AC_SUBST(libc_cv_forced_unwind)
2021 if test x$use_ldconfig = xyes; then
2022 AC_DEFINE(USE_LDCONFIG)
2023 fi
2024 AC_SUBST(use_ldconfig)
2025 AC_SUBST(ldd_rewrite_script)
2027 AC_SUBST(static)
2028 AC_SUBST(shared)
2030 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2031 [libc_cv_pic_default=yes
2032 cat > conftest.c <<EOF
2033 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2034 # error PIC is default.
2035 #endif
2036 EOF
2037 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2038 libc_cv_pic_default=no
2039 fi
2040 rm -f conftest.*])
2041 AC_SUBST(libc_cv_pic_default)
2043 AC_SUBST(profile)
2044 AC_SUBST(static_nss)
2046 AC_SUBST(DEFINES)
2048 dnl See sysdeps/mach/configure.ac for this variable.
2049 AC_SUBST(mach_interface_list)
2051 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2052 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2053 AC_SUBST(VERSION)
2054 AC_SUBST(RELEASE)
2056 AC_CONFIG_FILES([config.make Makefile])
2057 AC_CONFIG_COMMANDS([default],[[
2058 case $CONFIG_FILES in *config.make*)
2059 echo "$config_vars" >> config.make;;
2060 esac
2061 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2062 AC_OUTPUT