sysdeps/sparc/rshift.S

   1 ! sparc __mpn_rshift --
   2
   3 ! Copyright (C) 1995 Free Software Foundation, Inc.
   4
   5 ! This file is part of the GNU MP Library.
   6
   7 ! The GNU MP Library is free software; you can redistribute it and/or modify
   8 ! it under the terms of the GNU Library General Public License as published by
   9 ! the Free Software Foundation; either version 2 of the License, or (at your
  10 ! option) any later version.
  11
  12 ! The GNU MP Library is distributed in the hope that it will be useful, but
  13 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  15 ! License for more details.
  16
  17 ! You should have received a copy of the GNU Library General Public License
  18 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19 ! the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  20
  21
  22 ! INPUT PARAMETERS
  23 ! res_ptr       %o0
  24 ! src_ptr       %o1
  25 ! size          %o2
  26 ! cnt           %o3
  27
  28 #include "sysdep.h"
  29
  30         .text
  31         .align  4
  32         .global C_SYMBOL_NAME(__mpn_rshift)
  33 C_SYMBOL_NAME(__mpn_rshift):
  34         ld      [%o1],%g2       ! load first limb
  35         sub     %g0,%o3,%o5     ! negate shift count
  36         add     %o2,-1,%o2
  37         andcc   %o2,4-1,%g4     ! number of limbs in first loop
  38         sll     %g2,%o5,%g1     ! compute function result
  39         beq     L0              ! if multiple of 4 limbs, skip first loop
  40         st      %g1,[%sp+80]
  41
  42         sub     %o2,%g4,%o2     ! adjust count for main loop
  43
  44 Loop0:  ld      [%o1+4],%g3
  45         add     %o0,4,%o0
  46         add     %o1,4,%o1
  47         addcc   %g4,-1,%g4
  48         srl     %g2,%o3,%o4
  49         sll     %g3,%o5,%g1
  50         mov     %g3,%g2
  51         or      %o4,%g1,%o4
  52         bne     Loop0
  53          st     %o4,[%o0-4]
  54
  55 L0:     tst     %o2
  56         beq     Lend
  57          nop
  58
  59 Loop:   ld      [%o1+4],%g3
  60         add     %o0,16,%o0
  61         addcc   %o2,-4,%o2
  62         srl     %g2,%o3,%o4
  63         sll     %g3,%o5,%g1
  64
  65         ld      [%o1+8],%g2
  66         srl     %g3,%o3,%g4
  67         or      %o4,%g1,%o4
  68         st      %o4,[%o0-16]
  69         sll     %g2,%o5,%g1
  70
  71         ld      [%o1+12],%g3
  72         srl     %g2,%o3,%o4
  73         or      %g4,%g1,%g4
  74         st      %g4,[%o0-12]
  75         sll     %g3,%o5,%g1
  76
  77         ld      [%o1+16],%g2
  78         srl     %g3,%o3,%g4
  79         or      %o4,%g1,%o4
  80         st      %o4,[%o0-8]
  81         sll     %g2,%o5,%g1
  82
  83         add     %o1,16,%o1
  84         or      %g4,%g1,%g4
  85         bne     Loop
  86          st     %g4,[%o0-4]
  87
  88 Lend:   srl     %g2,%o3,%g2
  89         st      %g2,[%o0-0]
  90         retl
  91         ld      [%sp+80],%o0