sysdeps/i386/sub_n.S

   1 /* i80386 __mpn_sub_n -- Add two limb vectors of the same length > 0 and store
   2    sum in a third limb vector.
   3
   4 Copyright (C) 1992, 1994, 1995 Free Software Foundation, Inc.
   5
   6 This file is part of the GNU MP Library.
   7
   8 The GNU MP Library is free software; you can redistribute it and/or modify
   9 it under the terms of the GNU Library General Public License as published by
  10 the Free Software Foundation; either version 2 of the License, or (at your
  11 option) any later version.
  12
  13 The GNU MP Library is distributed in the hope that it will be useful, but
  14 WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  16 License for more details.
  17
  18 You should have received a copy of the GNU Library General Public License
  19 along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA. */
  21
  22 /*
  23   INPUT PARAMETERS
  24   res_ptr       (sp + 4)
  25   s1_ptr        (sp + 8)
  26   s2_ptr        (sp + 12)
  27   size          (sp + 16)
  28 */
  29
  30 #include "sysdep.h"
  31 #include "asm-syntax.h"
  32
  33 .text
  34         ALIGN (3)
  35         .globl C_SYMBOL_NAME(__mpn_sub_n)
  36 C_SYMBOL_NAME(__mpn_sub_n:)
  37         pushl %edi
  38         pushl %esi
  39
  40         movl 12(%esp),%edi              /* res_ptr */
  41         movl 16(%esp),%esi              /* s1_ptr */
  42         movl 20(%esp),%edx              /* s2_ptr */
  43         movl 24(%esp),%ecx              /* size */
  44
  45         movl    %ecx,%eax
  46         shrl    $3,%ecx                 /* compute count for unrolled loop */
  47         negl    %eax
  48         andl    $7,%eax                 /* get index where to start loop */
  49         jz      Loop                    /* necessary special case for 0 */
  50         incl    %ecx                    /* adjust loop count */
  51         shll    $2,%eax                 /* adjustment for pointers... */
  52         subl    %eax,%edi               /* ... since they are offset ... */
  53         subl    %eax,%esi               /* ... by a constant when we ... */
  54         subl    %eax,%edx               /* ... enter the loop */
  55         shrl    $2,%eax                 /* restore previous value */
  56 #ifdef PIC
  57 /* Calculate start address in loop for PIC.  Due to limitations in some
  58    assemblers, Loop-L0-3 cannot be put into the leal */
  59         call    L0
  60 L0:     leal    (%eax,%eax,8),%eax
  61         addl    (%esp),%eax
  62         addl    $(Loop-L0-3),%eax
  63         addl    $4,%esp
  64 #else
  65 /* Calculate start address in loop for non-PIC.  */
  66         leal    (Loop - 3)(%eax,%eax,8),%eax
  67 #endif
  68         jmp     *%eax                   /* jump into loop */
  69         ALIGN (3)
  70 Loop:   movl    (%esi),%eax
  71         sbbl    (%edx),%eax
  72         movl    %eax,(%edi)
  73         movl    4(%esi),%eax
  74         sbbl    4(%edx),%eax
  75         movl    %eax,4(%edi)
  76         movl    8(%esi),%eax
  77         sbbl    8(%edx),%eax
  78         movl    %eax,8(%edi)
  79         movl    12(%esi),%eax
  80         sbbl    12(%edx),%eax
  81         movl    %eax,12(%edi)
  82         movl    16(%esi),%eax
  83         sbbl    16(%edx),%eax
  84         movl    %eax,16(%edi)
  85         movl    20(%esi),%eax
  86         sbbl    20(%edx),%eax
  87         movl    %eax,20(%edi)
  88         movl    24(%esi),%eax
  89         sbbl    24(%edx),%eax
  90         movl    %eax,24(%edi)
  91         movl    28(%esi),%eax
  92         sbbl    28(%edx),%eax
  93         movl    %eax,28(%edi)
  94         leal    32(%edi),%edi
  95         leal    32(%esi),%esi
  96         leal    32(%edx),%edx
  97         decl    %ecx
  98         jnz     Loop
  99
 100         sbbl    %eax,%eax
 101         negl    %eax
 102
 103         popl %esi
 104         popl %edi
 105         ret