sysdeps/i386/setjmp.S

   1 /* setjmp for i386.
   2 Copyright (C) 1995 Free Software Foundation, Inc.
   3 This file is part of the GNU C Library.
   4
   5 The GNU C Library is free software; you can redistribute it and/or
   6 modify it under the terms of the GNU Library General Public License as
   7 published by the Free Software Foundation; either version 2 of the
   8 License, or (at your option) any later version.
   9
  10 The GNU C Library is distributed in the hope that it will be useful,
  11 but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 Library General Public License for more details.
  14
  15 You should have received a copy of the GNU Library General Public
  16 License along with the GNU C Library; see the file COPYING.LIB.  If
  17 not, write to the Free Software Foundation, Inc., 675 Mass Ave,
  18 Cambridge, MA 02139, USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #include <jmp_buf.h>
  23
  24 ENTRY (__sigsetjmp)
  25         movl 4(%esp), %eax      /* User's jmp_buf in %eax.  */
  26         /* Save registers.  */
  27         movl %ebx, (JB_BX*4)(%eax)
  28         movl %esi, (JB_SI*4)(%eax)
  29         movl %edi, (JB_DI*4)(%eax)
  30         movl %ebp, (JB_BP*4)(%eax)
  31         leal 4(%esp), %ecx      /* Save SP as it will be after we return.  */
  32         movl %ecx, (JB_SP*4)(%eax)
  33         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  34         movl %ecx, (JB_PC*4)(%eax)
  35
  36         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  37 #ifdef  PIC
  38         /* We cannot use the PLT, because it requires that %ebx be set, but
  39            we can't save and restore our caller's value.  Instead, we do an
  40            indirect jump through the GOT, using for the temporary register
  41            %ecx, which is call-clobbered.  */
  42         call here
  43 here:   popl %ecx
  44         addl $_GLOBAL_OFFSET_TABLE_+[.-here], %ecx
  45         movl C_SYMBOL_NAME(__sigjmp_save@GOT)(%ecx), %ecx
  46         jmp *%ecx
  47 #else
  48         jmp __sigjmp_save
  49 #endif