sysdeps/ia64/fpu/s_truncl.S

   1 .file "truncl.s"
   2
   3
   4 // Copyright (c) 2000 - 2003, Intel Corporation
   5 // All rights reserved.
   6 //
   7 //
   8 // Redistribution and use in source and binary forms, with or without
   9 // modification, are permitted provided that the following conditions are
  10 // met:
  11 //
  12 // * Redistributions of source code must retain the above copyright
  13 // notice, this list of conditions and the following disclaimer.
  14 //
  15 // * Redistributions in binary form must reproduce the above copyright
  16 // notice, this list of conditions and the following disclaimer in the
  17 // documentation and/or other materials provided with the distribution.
  18 //
  19 // * The name of Intel Corporation may not be used to endorse or promote
  20 // products derived from this software without specific prior written
  21 // permission.
  22
  23 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  24 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  25 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  26 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  27 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  28 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  29 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  30 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  31 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  32 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  33 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  34 //
  35 // Intel Corporation is the author of this code, and requests that all
  36 // problem reports or change requests be submitted to it directly at
  37 // http://www.intel.com/software/products/opensource/libraries/num.htm.
  38 //
  39 // History
  40 //==============================================================
  41 // 07/07/00 Created
  42 // 05/20/02 Cleaned up namespace and sf0 syntax
  43 // 01/20/03 Improved performance and reduced code size
  44 //==============================================================
  45
  46 // API
  47 //==============================================================
  48 // long double truncl(long double x)
  49 //==============================================================
  50
  51 // general input registers:
  52 // r14 - r18
  53
  54 rExpBias   = r14
  55 rSignexp   = r15
  56 rExp       = r16
  57 rExpMask   = r17
  58 rBigexp    = r18
  59
  60 // floating-point registers:
  61 // f8 - f10
  62
  63 fXtruncInt = f9
  64 fNormX     = f10
  65
  66 // predicate registers used:
  67 // p6, p7
  68
  69 // Overview of operation
  70 //==============================================================
  71 // long double truncl(long double x)
  72 // Return an integer value (represented as a long double) less than or
  73 // equal to x in magnitude.
  74 // This is x rounded toward zero to an integral value.
  75 //==============================================================
  76
  77 // double_extended
  78 // if the exponent is > 1003e => 3F(true) = 63(decimal)
  79 // we have a significand of 64 bits 1.63-bits.
  80 // If we multiply by 2^63, we no longer have a fractional part
  81 // So input is an integer value already.
  82
  83 // double
  84 // if the exponent is >= 10033 => 34(true) = 52(decimal)
  85 // 34 + 3ff = 433
  86 // we have a significand of 53 bits 1.52-bits. (implicit 1)
  87 // If we multiply by 2^52, we no longer have a fractional part
  88 // So input is an integer value already.
  89
  90 // single
  91 // if the exponent is > 10016 => 17(true) = 23(decimal)
  92 // we have a significand of 24 bits 1.23-bits. (implicit 1)
  93 // If we multiply by 2^23, we no longer have a fractional part
  94 // So input is an integer value already.
  95
  96 .section .text
  97 GLOBAL_LIBM_ENTRY(truncl)
  98
  99 { .mfi
 100       getf.exp         rSignexp  = f8        // Get signexp, recompute if unorm
 101       fcvt.fx.trunc.s1 fXtruncInt  = f8      // Convert to int in significand
 102       addl             rBigexp = 0x1003e, r0 // Set exponent at which is integer
 103 }
 104 { .mfi
 105       mov              rExpBias    = 0x0FFFF // Form exponent bias
 106       fnorm.s1         fNormX  = f8          // Normalize input
 107       mov              rExpMask    = 0x1FFFF // Form exponent mask
 108 }
 109 ;;
 110
 111 { .mfi
 112       nop.m            0
 113       fclass.m         p7,p0 = f8, 0x0b      // Test x unorm
 114       nop.i            0
 115 }
 116 ;;
 117
 118 { .mfb
 119       nop.m            0
 120       fclass.m         p6,p0 = f8, 0x1e3     // Test x natval, nan, inf
 121 (p7)  br.cond.spnt     TRUNC_UNORM           // Branch if x unorm
 122 }
 123 ;;
 124
 125 TRUNC_COMMON:
 126 // Return here from TRUNC_UNORM
 127 { .mfb
 128       and              rExp = rSignexp, rExpMask // Get biased exponent
 129 (p6)  fma.s0           f8 = f8, f1, f0       // Result if x natval, nan, inf
 130 (p6)  br.ret.spnt      b0                    // Exit if x natval, nan, inf
 131 }
 132 ;;
 133
 134 { .mfi
 135       cmp.lt           p6,p0 = rExp, rExpBias // Is |x| < 1?
 136       fcvt.xf          f8 = fXtruncInt        // Result, assume 1 <= |x| < 2^63
 137       cmp.ge           p7,p0 = rExp, rBigexp  // Is |x| >= 2^63?
 138 }
 139 ;;
 140
 141 // We must correct result if |x| < 1, or |x| >= 2^63
 142 .pred.rel "mutex",p6,p7
 143 { .mfi
 144       nop.m            0
 145 (p6)  fmerge.s         f8 = fNormX, f0        // If |x| < 1, result sgn(x)*0
 146       nop.i            0
 147 }
 148 { .mfb
 149       nop.m            0
 150 (p7)  fma.s0           f8 = fNormX, f1, f0    // If |x| >= 2^63, result x
 151       br.ret.sptk      b0                     // Exit main path
 152 }
 153 ;;
 154
 155
 156 TRUNC_UNORM:
 157 // Here if x unorm
 158 { .mfb
 159       getf.exp         rSignexp  = fNormX     // Get signexp, recompute if unorm
 160       fcmp.eq.s0       p7,p0 = f8, f0         // Dummy op to set denormal flag
 161       br.cond.sptk     TRUNC_COMMON           // Return to main path
 162 }
 163 ;;
 164
 165 GLOBAL_LIBM_END(truncl)
 166 libm_alias_ldouble_other (trunc, trunc)