configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.53)dnl              dnl Minimum Autoconf version required.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 # Glibc should not depend on any header files
   9 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  10   [m4_divert_text([DEFAULTS],
  11     [ac_includes_default='/* none */'])])
  12
  13 dnl This is here so we can set $subdirs directly based on configure fragments.
  14 AC_CONFIG_SUBDIRS()
  15
  16 AC_CANONICAL_HOST
  17
  18 AC_PROG_CC
  19 if test $host != $build; then
  20   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  21 fi
  22 AC_SUBST(cross_compiling)
  23 AC_PROG_CPP
  24 # We need the C++ compiler only for testing.
  25 AC_PROG_CXX
  26
  27 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  28   AC_MSG_ERROR([you must configure in a separate build directory])
  29 fi
  30
  31 # This will get text that should go into config.make.
  32 config_vars=
  33
  34 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  35 AC_ARG_WITH([gd],
  36             AC_HELP_STRING([--with-gd=DIR],
  37                            [find libgd include dir and library with prefix DIR]),
  38             [dnl
  39 case "$with_gd" in
  40 yes|''|no) ;;
  41 *) libgd_include="-I$withval/include"
  42    libgd_ldflags="-L$withval/lib" ;;
  43 esac
  44 ])
  45 AC_ARG_WITH([gd-include],
  46             AC_HELP_STRING([--with-gd-include=DIR],
  47                            [find libgd include files in DIR]),
  48             [dnl
  49 case "$with_gd_include" in
  50 ''|no) ;;
  51 *) libgd_include="-I$withval" ;;
  52 esac
  53 ])
  54 AC_ARG_WITH([gd-lib],
  55             AC_HELP_STRING([--with-gd-lib=DIR],
  56                            [find libgd library files in DIR]),
  57             [dnl
  58 case "$with_gd_lib" in
  59 ''|no) ;;
  60 *) libgd_ldflags="-L$withval" ;;
  61 esac
  62 ])
  63
  64 if test -n "$libgd_include"; then
  65   config_vars="$config_vars
  66 CFLAGS-memusagestat.c = $libgd_include"
  67 fi
  68 if test -n "$libgd_ldflags"; then
  69   config_vars="$config_vars
  70 libgd-LDFLAGS = $libgd_ldflags"
  71 fi
  72
  73 dnl Arguments to specify presence of other packages/features.
  74 AC_ARG_WITH([fp],
  75             AC_HELP_STRING([--with-fp],
  76                            [if using floating-point hardware @<:@default=yes@:>@]),
  77             [with_fp=$withval],
  78             [with_fp=yes])
  79 AC_SUBST(with_fp)
  80 AC_ARG_WITH([binutils],
  81             AC_HELP_STRING([--with-binutils=PATH],
  82                            [specify location of binutils (as and ld)]),
  83             [path_binutils=$withval],
  84             [path_binutils=''])
  85 AC_ARG_WITH([selinux],
  86             AC_HELP_STRING([--with-selinux],
  87                            [if building with SELinux support]),
  88             [with_selinux=$withval],
  89             [with_selinux=auto])
  90
  91 AC_ARG_WITH([headers],
  92             AC_HELP_STRING([--with-headers=PATH],
  93                            [location of system headers to use
  94                             (for example /usr/src/linux/include)
  95                             @<:@default=compiler default@:>@]),
  96             [sysheaders=$withval],
  97             [sysheaders=''])
  98
  99 AC_SUBST(use_default_link)
 100 AC_ARG_WITH([default-link],
 101             AC_HELP_STRING([--with-default-link],
 102                            [do not use explicit linker scripts]),
 103             [use_default_link=$withval],
 104             [use_default_link=default])
 105
 106 AC_ARG_ENABLE([sanity-checks],
 107               AC_HELP_STRING([--disable-sanity-checks],
 108                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 109               [enable_sanity=$enableval],
 110               [enable_sanity=yes])
 111
 112 AC_ARG_ENABLE([shared],
 113               AC_HELP_STRING([--enable-shared],
 114                              [build shared library @<:@default=yes if GNU ld@:>@]),
 115               [shared=$enableval],
 116               [shared=yes])
 117 AC_ARG_ENABLE([profile],
 118               AC_HELP_STRING([--enable-profile],
 119                              [build profiled library @<:@default=no@:>@]),
 120               [profile=$enableval],
 121               [profile=no])
 122 AC_ARG_ENABLE([versioning],
 123               AC_HELP_STRING([--disable-versioning],
 124                              [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
 125               [enable_versioning=$enableval],
 126               [enable_versioning=yes])
 127
 128 AC_ARG_ENABLE([oldest-abi],
 129               AC_HELP_STRING([--enable-oldest-abi=ABI],
 130                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 131               [oldest_abi=$enableval],
 132               [oldest_abi=no])
 133 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 134   oldest_abi=default
 135 else
 136   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 137 fi
 138 AC_SUBST(oldest_abi)
 139
 140 AC_ARG_ENABLE([stackguard-randomization],
 141               AC_HELP_STRING([--enable-stackguard-randomization],
 142                              [initialize __stack_chk_guard canary with a random number at program start]),
 143               [enable_stackguard_randomize=$enableval],
 144               [enable_stackguard_randomize=no])
 145 if test "$enable_stackguard_randomize" = yes; then
 146   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 147 fi
 148
 149 dnl Generic infrastructure for drop-in additions to libc.
 150 AC_ARG_ENABLE([add-ons],
 151               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 152                              [configure and build add-ons in DIR1,DIR2,...
 153                               search for add-ons if no parameter given]),
 154                              , [enable_add_ons=yes])
 155
 156 AC_ARG_ENABLE([hidden-plt],
 157               AC_HELP_STRING([--disable-hidden-plt],
 158                              [do not hide internal function calls to avoid PLT]),
 159               [hidden=$enableval],
 160               [hidden=yes])
 161 if test "x$hidden" = xno; then
 162   AC_DEFINE(NO_HIDDEN)
 163 fi
 164
 165 AC_ARG_ENABLE([bind-now],
 166               AC_HELP_STRING([--enable-bind-now],
 167                              [disable lazy relocations in DSOs]),
 168               [bindnow=$enableval],
 169               [bindnow=no])
 170 AC_SUBST(bindnow)
 171
 172 dnl On some platforms we cannot use dynamic loading.  We must provide
 173 dnl static NSS modules.
 174 AC_ARG_ENABLE([static-nss],
 175               AC_HELP_STRING([--enable-static-nss],
 176                              [build static NSS modules @<:@default=no@:>@]),
 177               [static_nss=$enableval],
 178               [static_nss=no])
 179 dnl Enable static NSS also if we build no shared objects.
 180 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 181   static_nss=yes
 182   AC_DEFINE(DO_STATIC_NSS)
 183 fi
 184
 185 AC_ARG_ENABLE([force-install],
 186               AC_HELP_STRING([--disable-force-install],
 187                              [don't force installation of files from this package, even if they are older than the installed files]),
 188               [force_install=$enableval],
 189               [force_install=yes])
 190 AC_SUBST(force_install)
 191
 192 dnl On some platforms we allow dropping compatibility with all kernel
 193 dnl versions.
 194 AC_ARG_ENABLE([kernel],
 195               AC_HELP_STRING([--enable-kernel=VERSION],
 196                              [compile for compatibility with kernel not older than VERSION]),
 197               [minimum_kernel=$enableval],
 198               [])
 199 dnl Prevent unreasonable values.
 200 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 201   # Better nothing than this.
 202   minimum_kernel=""
 203 else
 204   if test "$minimum_kernel" = current; then
 205     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 206   fi
 207 fi
 208
 209 dnl For the development we sometimes want gcc to issue even more warnings.
 210 dnl This is not the default since many of the extra warnings are not
 211 dnl appropriate.
 212 AC_ARG_ENABLE([all-warnings],
 213               AC_HELP_STRING([--enable-all-warnings],
 214                              [enable all useful warnings gcc can issue]),
 215               [all_warnings=$enableval],
 216               [])
 217 AC_SUBST(all_warnings)
 218
 219 AC_ARG_ENABLE([multi-arch],
 220               AC_HELP_STRING([--enable-multi-arch],
 221                              [enable single DSO with optimizations for multiple architectures]),
 222               [multi_arch=$enableval],
 223               [multi_arch=default])
 224
 225 AC_ARG_ENABLE([nss-crypt],
 226               AC_HELP_STRING([--enable-nss-crypt],
 227                              [enable libcrypt to use nss]),
 228               [nss_crypt=$enableval],
 229               [nss_crypt=no])
 230 if test x$nss_crypt = xyes; then
 231   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 232   if test $? -ne 0; then
 233     AC_MSG_ERROR([cannot find include directory with nss-config])
 234   fi
 235   old_CFLAGS="$CFLAGS"
 236   CFLAGS="$CFLAGS $nss_includes"
 237   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 238 #include <hasht.h>
 239 #include <nsslowhash.h>
 240 void f (void) { NSSLOW_Init (); }])],
 241              libc_cv_nss_crypt=yes,
 242              AC_MSG_ERROR([
 243 cannot find NSS headers with lowlevel hash function interfaces]))
 244   old_LIBS="$LIBS"
 245   LIBS="$LIBS -lfreebl3"
 246   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 247 #include <hasht.h>
 248 #include <nsslowhash.h>],
 249                                   [NSSLOW_Init();])],
 250                  libc_cv_nss_crypt=yes,
 251                  AC_MSG_ERROR([
 252 cannot link program using lowlevel NSS hash functions]))
 253   CFLAGS="$old_CFLAGS"
 254   LIBS="$old_LIBS"
 255 else
 256   libc_cv_nss_crypt=no
 257 fi
 258 AC_SUBST(libc_cv_nss_crypt)
 259
 260
 261 AC_ARG_ENABLE([obsolete-rpc],
 262               AC_HELP_STRING([--enable-obsolete-rpc],
 263                              [build and install the obsolete RPC code for link-time usage]),
 264               [link_obsolete_rpc=$enableval],
 265               [link_obsolete_rpc=no])
 266 AC_SUBST(link_obsolete_rpc)
 267
 268 if test "$link_obsolete_rpc" = yes; then
 269   AC_DEFINE(LINK_OBSOLETE_RPC)
 270 fi
 271
 272 AC_ARG_ENABLE([systemtap],
 273               [AS_HELP_STRING([--enable-systemtap],
 274                [enable systemtap static probe points @<:@default=no@:>@])],
 275               [systemtap=$enableval],
 276               [systemtap=no])
 277 if test "x$systemtap" != xno; then
 278   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 279   old_CFLAGS="$CFLAGS"
 280   CFLAGS="-std=gnu99 $CFLAGS"
 281   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 282 void foo (int i, void *p)
 283 {
 284   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 285        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 286 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 287   CFLAGS="$old_CFLAGS"])
 288   if test $libc_cv_sdt = yes; then
 289     AC_DEFINE([USE_STAP_PROBE])
 290   elif test "x$systemtap" != xauto; then
 291     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 292   fi
 293 fi
 294
 295 # The way shlib-versions is used to generate soversions.mk uses a
 296 # fairly simplistic model for name recognition that can't distinguish
 297 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 298 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 299 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 300 case "$host_os" in
 301 linux*)
 302   ;;
 303 gnu*)
 304   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 305   ;;
 306 esac
 307
 308 # We keep the original values in `$config_*' and never modify them, so we
 309 # can write them unchanged into config.make.  Everything else uses
 310 # $machine, $vendor, and $os, and changes them whenever convenient.
 311 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 312
 313 # Don't allow vendor == "unknown"
 314 test "$config_vendor" = unknown && config_vendor=
 315 config_os="`echo $config_os | sed 's/^unknown-//'`"
 316
 317 # Some configurations imply other options.
 318 elf=yes
 319
 320 # The configure fragment of an add-on port can modify these to supplement
 321 # or override the table in the case statement below.  No fragment should
 322 # ever change the config_* variables, however.
 323 machine=$config_machine
 324 vendor=$config_vendor
 325 os=$config_os
 326 base_os=''
 327
 328 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 329 # Unify this here.
 330 if test "$machine" = rs6000; then
 331   machine="powerpc"
 332 fi
 333
 334 # Braindead PowerPC box with absolutely no FPU.
 335 case "$machine-$host_os" in
 336   powerpc*-*soft)
 337     with_fp=no
 338     ;;
 339 esac
 340
 341 submachine=
 342 AC_ARG_WITH([cpu],
 343             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 344             [dnl
 345   case "$withval" in
 346   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 347   no) ;;
 348   *) submachine="$withval" ;;
 349   esac
 350 ])
 351
 352 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 353 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 354
 355 # An add-on can set this when it wants to disable the sanity check below.
 356 libc_config_ok=no
 357
 358 dnl Having this here, though empty, makes sure that if add-ons' fragments
 359 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 360 dnl our AC_OUTPUT will actually use it.
 361 AC_CONFIG_SUBDIRS()
 362
 363 case "$enable_add_ons" in
 364 ''|no) add_ons= ;;
 365 yes|'*')
 366  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 367           sed 's@/[[^/]]*$@@' | sort | uniq`
 368          add_ons_automatic=yes
 369          ;;
 370 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 371        add_ons_automatic=no ;;
 372 esac
 373
 374 configured_add_ons=
 375 add_ons_sfx=
 376 add_ons_pfx=
 377 if test x"$add_ons" != x; then
 378   for f in $add_ons; do
 379     # Some sanity checks
 380     case "$f" in
 381     crypt)
 382       AC_MSG_ERROR([
 383 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 384 *** part of glibc and using the old add-on will not work with this
 385 *** release.  Start again with fresh sources and without the old
 386 *** \`crypt' add-on.])
 387     ;;
 388     localedata)
 389       AC_MSG_ERROR([
 390 *** It seems that you're using an old \`localedata' add-on.  localedata
 391 *** is now part of glibc and using the old add-on will not work with
 392 *** this release.  Start again with fresh sources and without the old
 393 *** \`localedata' add-on.])
 394     ;;
 395     esac
 396   done
 397
 398   # Now source each add-on's configure fragment.
 399   # The fragments can use $srcdir/$libc_add_on to find themselves,
 400   # and test $add_ons_automatic to see if they were explicitly requested.
 401   # A fragment can clear (or even change) $libc_add_on to affect
 402   # whether it goes into the list to be actually used in the build.
 403   use_add_ons=
 404   for libc_add_on in $add_ons; do
 405     # Test whether such a directory really exists.
 406     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 407     case "$libc_add_on" in
 408     /*)
 409       libc_add_on_srcdir=$libc_add_on
 410       ;;
 411     *)
 412       test -d "$srcdir/$libc_add_on" || {
 413         if test -d "$libc_add_on"; then
 414           libc_add_on="`pwd`/$libc_add_on"
 415         else
 416           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 417         fi
 418       }
 419       libc_add_on_srcdir=$srcdir/$libc_add_on
 420       ;;
 421     esac
 422
 423     libc_add_on_frag=$libc_add_on_srcdir/configure
 424     libc_add_on_canonical=
 425     libc_add_on_config_subdirs=
 426     if test -r "$libc_add_on_frag"; then
 427       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 428       libc_add_on_canonical=unknown
 429       libc_add_on_subdirs=
 430       . "$libc_add_on_frag"
 431       test -z "$libc_add_on" || {
 432         configured_add_ons="$configured_add_ons $libc_add_on"
 433         if test "x$libc_add_on_canonical" = xunknown; then
 434           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 435         fi
 436         for d in $libc_add_on_subdirs; do
 437           case "$libc_add_on" in
 438           /*) subdir_srcdir="$libc_add_on" ;;
 439           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 440           esac
 441           case "$d" in
 442           .)
 443             d="${libc_add_on_canonical:-$libc_add_on}"
 444             ;;
 445           /*)
 446             subdir_srcdir="$d"
 447             ;;
 448           *)
 449             subdir_srcdir="$subdir_srcdir/$d"
 450             ;;
 451           esac
 452           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 453           add_on_subdirs="$add_on_subdirs $d"
 454           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 455 $d-srcdir = $subdir_srcdir"
 456         done
 457         for d in $libc_add_on_config_subdirs; do
 458           case "$d" in
 459           /*) AC_MSG_ERROR(dnl
 460 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 461           esac
 462           if test ! -d "$libc_add_on_srcdir/$d"; then
 463             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 464           fi
 465           case "$libc_add_on" in
 466           /*) AC_MSG_ERROR(dnl
 467 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 468           esac
 469           subdirs="$subdirs $libc_add_on/$d"
 470         done
 471       }
 472     fi
 473     if test -n "$libc_add_on"; then
 474       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 475       use_add_ons="$use_add_ons $libc_add_on"
 476       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 477       test -z "$libc_add_on_canonical" ||
 478       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 479     fi
 480   done
 481   # Use echo to strip excess whitespace.
 482   add_ons="`echo $use_add_ons`"
 483 fi
 484 AC_SUBST(add_ons)
 485 AC_SUBST(add_on_subdirs)
 486
 487
 488 ###
 489 ### I put this here to prevent those annoying emails from people who cannot
 490 ### read and try to compile glibc on unsupported platforms.  --drepper
 491 ###
 492 ### By using the undocumented --enable-hacker-mode option for configure
 493 ### one can skip this test to make the configuration not fail for unsupported
 494 ### platforms.
 495 ###
 496 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 497   case "$machine-$host_os" in
 498   *-linux* | *-gnu*)
 499     ;;
 500   *)
 501     echo "*** The GNU C library is currently not available for this platform."
 502     echo "*** So far nobody cared to port it and if there is no volunteer it"
 503     echo "*** might never happen.  So, if you have interest to see glibc on"
 504     echo "*** this platform visit"
 505     echo "***   http://www.gnu.org/software/libc/porting.html"
 506     echo "*** and join the group of porters"
 507     exit 1
 508     ;;
 509   esac
 510 fi
 511
 512 dnl We need to use [ and ] for other purposes for a while now.
 513 changequote(,)dnl
 514 # Expand the configuration machine name into a subdirectory by architecture
 515 # type and particular chip.  If an add-on configure fragment already set
 516 # base_machine, we don't change it.
 517 test -n "$base_machine" || case "$machine" in
 518 i[34567]86)     base_machine=i386 machine=i386/$machine ;;
 519 powerpc)        base_machine=powerpc machine=powerpc/powerpc32 ;;
 520 powerpc64)      base_machine=powerpc machine=powerpc/powerpc64 ;;
 521 s390)           base_machine=s390 machine=s390/s390-32 ;;
 522 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 523 sh3*)           base_machine=sh machine=sh/sh3 ;;
 524 sh4*)           base_machine=sh machine=sh/sh4 ;;
 525 sparc | sparcv[67])
 526                 base_machine=sparc machine=sparc/sparc32 ;;
 527 sparcv8 | supersparc | hypersparc)
 528                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 529 sparcv8plus | sparcv8plusa | sparcv9)
 530                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 531 sparcv8plusb | sparcv9b)
 532                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
 533 sparcv9v)
 534                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
 535 sparcv9v2)
 536                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
 537 sparc64)
 538                 base_machine=sparc machine=sparc/sparc64 ;;
 539 sparc64b)
 540                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 541 sparc64v)
 542                 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
 543 sparc64v2)
 544                 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
 545 *)              base_machine=$machine ;;
 546 esac
 547 changequote([,])dnl
 548 AC_SUBST(base_machine)
 549
 550 if test "$base_machine" = "i386"; then
 551   AC_DEFINE(USE_REGPARMS)
 552 fi
 553
 554 # For the multi-arch option we need support in the assembler.
 555 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
 556                libc_cv_asm_gnu_indirect_function, [dnl
 557 cat > conftest.s <<EOF
 558 .type foo,%gnu_indirect_function
 559 EOF
 560 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
 561 then
 562   libc_cv_asm_gnu_indirect_function=yes
 563 else
 564   libc_cv_asm_gnu_indirect_function=no
 565 fi
 566 rm -f conftest*])
 567
 568 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 569 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 570 cat > conftest.s <<EOF
 571 .text
 572 EOF
 573 libc_cv_dot_text=
 574 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 575   libc_cv_dot_text=.text
 576 fi
 577 rm -f conftest*])
 578 if test -z "$libc_cv_dot_text"; then
 579   AC_MSG_RESULT(no)
 580 else
 581   AC_MSG_RESULT(yes)
 582 fi
 583
 584 AC_CACHE_CHECK(for assembler .type directive prefix,
 585                libc_cv_asm_type_prefix, [dnl
 586 libc_cv_asm_type_prefix=no
 587 for ac_try_prefix in '@' '%' '#'; do
 588   cat > conftest.s <<EOF
 589         ${libc_cv_dot_text}
 590         .globl foo
 591         .type foo, ${ac_try_prefix}object
 592         .size foo, 1
 593 foo:
 594         .byte 1
 595 EOF
 596   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 597     libc_cv_asm_type_prefix=${ac_try_prefix}
 598   fi
 599   rm -f conftest*
 600   test "x$libc_cv_asm_type_prefix" != xno && break
 601 done])
 602 if test "x$libc_cv_asm_type_prefix" != xno; then
 603   AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
 604 fi
 605
 606 if test x"$libc_cv_asm_gnu_indirect_function" != xyes -o x"$libc_cv_asm_type_prefix" = xno; then
 607   if test x"$multi_arch" = xyes; then
 608     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 609   else
 610     multi_arch=no
 611   fi
 612 fi
 613 if test x"$multi_arch" != xno; then
 614   multi_arch_d=/multiarch
 615 fi
 616
 617 # Compute the list of sysdep directories for this configuration.
 618 # This can take a while to compute.
 619 sysdep_dir=$srcdir/sysdeps
 620 AC_MSG_CHECKING(sysdep dirs)
 621 dnl We need to use [ and ] for other purposes for a while now.
 622 changequote(,)dnl
 623 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 624 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 625
 626 test "x$base_os" != x || case "$os" in
 627 gnu*)
 628   base_os=mach/hurd ;;
 629 linux*)
 630   base_os=unix/sysv ;;
 631 esac
 632
 633 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 634 tail=$os
 635 ostry=$os
 636 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 637   ostry="$ostry /$o"
 638   tail=$o
 639 done
 640 o=`echo $tail | sed 's/[0-9]*$//'`
 641 if test $o != $tail; then
 642   ostry="$ostry /$o"
 643 fi
 644 # For linux-gnu, try linux-gnu, then linux.
 645 o=`echo $tail | sed 's/-.*$//'`
 646 if test $o != $tail; then
 647   ostry="$ostry /$o"
 648 fi
 649
 650 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 651 base=
 652 tail=$base_os
 653 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 654   set $b
 655   base="$base /$1"
 656   tail="$2"
 657 done
 658
 659 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 660 mach=
 661 tail=$machine${submachine:+/$submachine}
 662 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 663   set $m
 664   # Prepend the machine's FPU directory unless --without-fp.
 665   if test "$with_fp" = yes; then
 666     mach="$mach /$1/fpu"
 667   else
 668     mach="$mach /$1/nofpu"
 669   fi
 670   mach="$mach /$1"
 671   tail="$2"
 672 done
 673
 674 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 675 changequote([,])dnl
 676
 677 # Find what sysdep directories exist.
 678 sysnames_add_ons=
 679 sysnames=
 680 for b in $base ''; do
 681   for m0 in $mach ''; do
 682     for v in /$vendor ''; do
 683       test "$v" = / && continue
 684       for o in /$ostry ''; do
 685         test "$o" = / && continue
 686         for m in $multi_arch_d $mach ''; do
 687           for d in $add_ons_pfx ''; do
 688             for a in $add_ons_sfx ''; do
 689               if test -n "$m0$m0sub$b$v$o$m$msub"; then
 690                 try_srcdir="${srcdir}/"
 691                 case "$d" in
 692                 /*) try_srcdir= ;;
 693                 esac
 694                 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
 695                 test -n "$enable_debug_configure" &&
 696                 echo "$0 [DEBUG]: try $try" >&2
 697                 if test -d "$try_srcdir$try"; then
 698                   sysnames="$sysnames $try"
 699                   { test -n "$o" || test -n "$b"; } && os_used=t
 700                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 701                   case x${m0:-$m} in
 702                   x*/$submachine) submachine_used=t ;;
 703                   esac
 704                   if test -n "$d"; then
 705                     case "$sysnames_add_ons" in
 706                     *" $d "*) ;;
 707                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 708                     esac
 709                   fi
 710                 fi
 711               fi
 712             done
 713           done
 714         done
 715       done
 716     done
 717   done
 718 done
 719
 720 # If the assembler supports gnu_indirect_function symbol type and the
 721 # architecture supports multi-arch, we enable multi-arch by default.
 722 case $sysnames_add_ons$sysnames in
 723 *"$multi_arch_d"*)
 724   ;;
 725 *)
 726   test x"$multi_arch" = xdefault && multi_arch=no
 727   ;;
 728 esac
 729 if test x"$multi_arch" != xno; then
 730   AC_DEFINE(USE_MULTIARCH)
 731 fi
 732 AC_SUBST(multi_arch)
 733
 734 if test -z "$os_used" && test "$os" != none; then
 735   AC_MSG_ERROR(Operating system $os is not supported.)
 736 fi
 737 if test -z "$machine_used" && test "$machine" != none; then
 738   AC_MSG_ERROR(The $machine is not supported.)
 739 fi
 740 if test -z "$submachine_used" && test -n "$submachine"; then
 741   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 742 fi
 743 AC_SUBST(submachine)
 744
 745 # We have now validated the configuration.
 746
 747 # Expand the list of system names into a full list of directories
 748 # from each element's parent name and Implies file (if present).
 749 set $sysnames
 750 names=
 751 while test $# -gt 0; do
 752   name=$1
 753   shift
 754
 755   case " $names " in *" $name "*)
 756     # Already in the list.
 757     continue
 758   esac
 759
 760   # Report each name as we discover it, so there is no long pause in output.
 761   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 762
 763   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 764
 765   case $name in
 766     /*) xsrcdir= ;;
 767     *)  xsrcdir=$srcdir/ ;;
 768   esac
 769   test -n "$enable_debug_configure" &&
 770   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 771
 772   for implies_file in Implies Implies-before Implies-after; do
 773     implies_type=`echo $implies_file | sed s/-/_/`
 774     eval ${implies_type}=
 775     if test -f $xsrcdir$name/$implies_file; then
 776       # Collect more names from the `Implies' file (removing comments).
 777       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 778       for x in $implied_candidate; do
 779         found=no
 780         if test -d $xsrcdir$name_base/$x; then
 781           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 782           found=yes
 783         fi
 784         for d in $add_ons_pfx ''; do
 785           try="${d}sysdeps/$x"
 786           case $d in
 787            /*) try_srcdir= ;;
 788            *) try_srcdir=$srcdir/ ;;
 789           esac
 790           test -n "$enable_debug_configure" &&
 791            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 792           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 793           then
 794             eval "${implies_type}=\"\$${implies_type} \$try\""
 795             found=yes
 796             case "$sysnames_add_ons" in
 797             *" $d "*) ;;
 798             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 799             esac
 800           fi
 801         done
 802         if test $found = no; then
 803           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 804         fi
 805       done
 806     fi
 807   done
 808
 809   # Add NAME to the list of names.
 810   names="$names $name"
 811
 812   # Find the parent of NAME, using the empty string if it has none.
 813 changequote(,)dnl
 814   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 815 changequote([,])dnl
 816
 817   test -n "$enable_debug_configure" &&
 818     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 819 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 820
 821   # Add the names implied by NAME, and NAME's parent (if it has one), to
 822   # the list of names to be processed (the argument list).  We prepend the
 823   # implied names to the list and append the parent.  We want implied
 824   # directories to come before further directories inferred from the
 825   # configuration components; this ensures that for sysv4, unix/common
 826   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 827   # after sysv4).
 828   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 829   test -n "$sysnames" && set $sysnames
 830 done
 831
 832 # Add the default directories.
 833 default_sysnames="sysdeps/generic"
 834 sysnames="$names $default_sysnames"
 835 AC_SUBST(sysnames)
 836 # The other names were emitted during the scan.
 837 AC_MSG_RESULT($default_sysnames)
 838
 839 # Collect the list of add-ons that supply partial sysdeps trees.
 840 sysdeps_add_ons=
 841 for add_on in $add_ons; do
 842   case "$add_on" in
 843   /*) xsrcdir= ;;
 844   *) xsrcdir="$srcdir/" ;;
 845   esac
 846
 847   test -d "$xsrcdir$add_on/sysdeps" || {
 848     case "$configured_add_ons " in
 849     *" $add_on "*) ;;
 850     *|'')
 851       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 852       ;;
 853     esac
 854     continue
 855   }
 856
 857   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 858   case "$sysnames_add_ons" in
 859   *" $add_on/ "*) ;;
 860   *|'')
 861     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 862     continue ;;
 863   esac
 864
 865   found=no
 866   for d in $sysnames; do
 867     case "$d" in
 868     $add_on/sysdeps/*) ;;
 869     *) continue ;;
 870     esac
 871     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 872        case "$f" in
 873        sys|bits)
 874          for ff in $f/*.h; do
 875            test -d "$ff" || { test -e "$ff" && exit 88; }
 876          done
 877          ;;
 878        *)
 879          test -d "$f" || { test -e "$f" && exit 88; }
 880          ;;
 881        esac
 882      done)
 883     if test $? -eq 88; then
 884       found=yes
 885       break
 886     fi
 887   done
 888   if test $found = no; then
 889     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 890   fi
 891 done
 892 AC_SUBST(sysdeps_add_ons)
 893
 894
 895 ### Locate tools.
 896
 897 AC_PROG_INSTALL
 898 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 899   # The makefiles need to use a different form to find it in $srcdir.
 900   INSTALL='\$(..)./scripts/install-sh -c'
 901 fi
 902 AC_PROG_LN_S
 903
 904 LIBC_PROG_BINUTILS
 905 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
 906
 907 # Accept binutils 2.20 or newer.
 908 AC_CHECK_PROG_VER(AS, $AS, --version,
 909                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 910                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
 911 AC_CHECK_PROG_VER(LD, $LD, --version,
 912                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 913                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
 914
 915 # These programs are version sensitive.
 916 AC_CHECK_TOOL_PREFIX
 917 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 918   [version \([egcygnustpi-]*[0-9.]*\)], [4.[3-9].* | 4.[1-9][0-9].* | [5-9].* ],
 919   critic_missing="$critic_missing gcc")
 920 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 921   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 922   [3.79* | 3.[89]*], critic_missing="$critic_missing make")
 923
 924 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 925   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 926   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 927   MSGFMT=: aux_missing="$aux_missing msgfmt")
 928 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 929   [GNU texinfo.* \([0-9][0-9.]*\)],
 930   [4.[5-9]*|4.[1-9][0-9]*|[5-9].*],
 931   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 932 AC_CHECK_PROG_VER(SED, sed, --version,
 933   [GNU sed version \([0-9]*\.[0-9.]*\)],
 934   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 935   SED=: aux_missing="$aux_missing sed")
 936
 937 AC_CHECK_TOOL(READELF, readelf, false)
 938 AC_CHECK_TOOL(NM, nm, false)
 939
 940 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 941 case "x$AUTOCONF" in
 942 xno|x|x:) AUTOCONF=no ;;
 943 *)
 944   AC_CACHE_CHECK(dnl
 945 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 946   if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
 947     libc_cv_autoconf_works=yes
 948   else
 949     libc_cv_autoconf_works=no
 950   fi])
 951   test $libc_cv_autoconf_works = yes || AUTOCONF=no
 952   ;;
 953 esac
 954 if test "x$AUTOCONF" = xno; then
 955   aux_missing="$aux_missing autoconf"
 956 fi
 957
 958 test -n "$critic_missing" && AC_MSG_ERROR([
 959 *** These critical programs are missing or too old:$critic_missing
 960 *** Check the INSTALL file for required versions.])
 961
 962 test -n "$aux_missing" && AC_MSG_WARN([
 963 *** These auxiliary programs are missing or incompatible versions:$aux_missing
 964 *** some features will be disabled.
 965 *** Check the INSTALL file for required versions.])
 966
 967 # if using special system headers, find out the compiler's sekrit
 968 # header directory and add that to the list.  NOTE: Only does the right
 969 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 970 if test -n "$sysheaders"; then
 971   SYSINCLUDES=-nostdinc
 972   for d in include include-fixed; do
 973     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
 974     SYSINCLUDES="$SYSINCLUDES -isystem $i"
 975   done
 976   SYSINCLUDES="$SYSINCLUDES \
 977 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
 978   if test -n "$CXX"; then
 979     CXX_SYSINCLUDES=
 980     cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
 981     cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
 982     for d in include "$cxxmachine/include"; do
 983       i=../../../../$d/c++/$cxxversion
 984       cxxheaders=`$CXX -print-file-name="$i"` &&
 985       test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
 986       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
 987 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
 988     done
 989   fi
 990 fi
 991 AC_SUBST(SYSINCLUDES)
 992 AC_SUBST(CXX_SYSINCLUDES)
 993
 994 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 995 # since this would lead to problems installing/building glibc.
 996 # LD_LIBRARY_PATH contains the current directory if one of the following
 997 # is true:
 998 # - one of the terminals (":" and ";") is the first or last sign
 999 # - two terminals occur directly after each other
1000 # - the path contains an element with a dot in it
1001 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1002 changequote(,)dnl
1003 case ${LD_LIBRARY_PATH} in
1004   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1005     ld_library_path_setting="contains current directory"
1006     ;;
1007   *)
1008     ld_library_path_setting="ok"
1009     ;;
1010 esac
1011 changequote([,])dnl
1012 AC_MSG_RESULT($ld_library_path_setting)
1013 if test "$ld_library_path_setting" != "ok"; then
1014 AC_MSG_ERROR([
1015 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1016 *** building glibc. Please change the environment variable
1017 *** and run configure again.])
1018 fi
1019
1020 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1021 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1022   libc_cv_gcc_static_libgcc=
1023 else
1024   libc_cv_gcc_static_libgcc=-static-libgcc
1025 fi])
1026 AC_SUBST(libc_cv_gcc_static_libgcc)
1027
1028 AC_PATH_PROG(BASH_SHELL, bash, no)
1029 if test "$BASH_SHELL" != no &&
1030    $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1031              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1032   libc_cv_have_bash2=yes
1033 else
1034   libc_cv_have_bash2=no
1035 fi
1036 AC_SUBST(libc_cv_have_bash2)
1037
1038 dnl We need a ksh compatible shell for tzselect.
1039 if test "$BASH_SHELL" = no; then
1040   AC_PATH_PROG(KSH, ksh, no)
1041   if test "$KSH" = no; then
1042     libc_cv_have_ksh=no
1043   else
1044     libc_cv_have_ksh=yes
1045   fi
1046 else
1047   KSH="$BASH_SHELL"
1048   AC_SUBST(KSH)
1049   libc_cv_have_ksh=yes
1050 fi
1051 AC_SUBST(libc_cv_have_ksh)
1052
1053 AC_PROG_AWK
1054 AC_PATH_PROG(PERL, perl, no)
1055 if test "$PERL" != no &&
1056    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1057   PERL=no
1058 fi
1059 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1060              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1061 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1062
1063 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1064 AC_TRY_COMPILE(dnl
1065 [#define __need_size_t
1066 #define __need_wchar_t
1067 #include <stddef.h>
1068 #define __need_NULL
1069 #include <stddef.h>], [size_t size; wchar_t wchar;
1070 #ifdef offsetof
1071 #error stddef.h ignored __need_*
1072 #endif
1073 if (&size == NULL || &wchar == NULL) abort ();],
1074                libc_cv_friendly_stddef=yes,
1075                libc_cv_friendly_stddef=no)])
1076 if test $libc_cv_friendly_stddef = yes; then
1077   config_vars="$config_vars
1078 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1079 fi
1080
1081 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1082                libc_cv_need_minus_P, [dnl
1083 cat > conftest.S <<EOF
1084 #include "confdefs.h"
1085 /* Nothing whatsoever.  */
1086 EOF
1087 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1088   libc_cv_need_minus_P=no
1089 else
1090   libc_cv_need_minus_P=yes
1091 fi
1092 rm -f conftest*])
1093 if test $libc_cv_need_minus_P = yes; then
1094   config_vars="$config_vars
1095 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1096 fi
1097
1098 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1099 cat > conftest.s <<EOF
1100 ${libc_cv_dot_text}
1101 foo:
1102 .set glibc_conftest_frobozz,foo
1103 .globl glibc_conftest_frobozz
1104 EOF
1105 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1106 # (but it doesn't work), so we must do a linking check to be sure.
1107 cat > conftest1.c <<\EOF
1108 extern int glibc_conftest_frobozz;
1109 void _start() { glibc_conftest_frobozz = 1; }
1110 EOF
1111 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1112             -nostartfiles -nostdlib \
1113             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1114   libc_cv_asm_set_directive=yes
1115 else
1116   libc_cv_asm_set_directive=no
1117 fi
1118 rm -f conftest*])
1119 if test $libc_cv_asm_set_directive = yes; then
1120   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1121 fi
1122
1123 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1124                libc_cv_asm_unique_object, [dnl
1125 cat > conftest.s <<EOF
1126 ${libc_cv_dot_text}
1127 _sym:
1128 .type _sym, ${libc_cv_asm_type_prefix}gnu_unique_object
1129 EOF
1130 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1131   libc_cv_asm_unique_object=yes
1132 else
1133   libc_cv_asm_unique_object=no
1134 fi
1135 rm -f conftest*])
1136 if test $libc_cv_asm_unique_object = yes; then
1137   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1138 fi
1139
1140 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1141 [cat > conftest.s <<EOF
1142 ${libc_cv_dot_text}
1143 _sym:
1144 .symver _sym,sym@VERS
1145 EOF
1146 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1147   libc_cv_asm_symver_directive=yes
1148 else
1149   libc_cv_asm_symver_directive=no
1150 fi
1151 rm -f conftest*])
1152 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1153 if test $libc_cv_asm_symver_directive = yes; then
1154   cat > conftest.s <<EOF
1155 ${libc_cv_dot_text}
1156 _sym:
1157 .symver _sym,sym@VERS
1158 EOF
1159   cat > conftest.map <<EOF
1160 VERS_1 {
1161         global: sym;
1162 };
1163
1164 VERS_2 {
1165         global: sym;
1166 } VERS_1;
1167 EOF
1168   if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1169     if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1170                                 -o conftest.so conftest.o
1171                                 -nostartfiles -nostdlib
1172                                 -Wl,--version-script,conftest.map
1173                        1>&AS_MESSAGE_LOG_FD]);
1174     then
1175       libc_cv_ld_version_script_option=yes
1176     else
1177       libc_cv_ld_version_script_option=no
1178     fi
1179   else
1180     libc_cv_ld_version_script_option=no
1181   fi
1182 else
1183   libc_cv_ld_version_script_option=no
1184 fi
1185 rm -f conftest*])
1186 if test $shared != no &&
1187    test $libc_cv_asm_symver_directive = yes &&
1188    test $libc_cv_ld_version_script_option = yes &&
1189    test $enable_versioning = yes; then
1190   VERSIONING=yes
1191   AC_DEFINE(DO_VERSIONING)
1192 else
1193   VERSIONING=no
1194 fi
1195 AC_SUBST(VERSIONING)
1196
1197 if test $shared != no && test $VERSIONING = no; then
1198   echo "\
1199 *** WARNING: You should not compile GNU libc without versioning. Not using
1200 *** versioning will introduce incompatibilities so that old binaries
1201 *** will not run anymore.
1202 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1203 fi
1204 AC_CACHE_CHECK(for .previous assembler directive,
1205                libc_cv_asm_previous_directive, [dnl
1206 cat > conftest.s <<EOF
1207 .section foo_section
1208 .previous
1209 EOF
1210 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1211   libc_cv_asm_previous_directive=yes
1212 else
1213   libc_cv_asm_previous_directive=no
1214 fi
1215 rm -f conftest*])
1216 if test $libc_cv_asm_previous_directive = yes; then
1217   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1218 else
1219   AC_CACHE_CHECK(for .popsection assembler directive,
1220                  libc_cv_asm_popsection_directive, [dnl
1221   cat > conftest.s <<EOF
1222 .pushsection foo_section
1223 .popsection
1224 EOF
1225   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1226     libc_cv_asm_popsection_directive=yes
1227   else
1228     libc_cv_asm_popsection_directive=no
1229   fi
1230   rm -f conftest*])
1231   if test $libc_cv_asm_popsection_directive = yes; then
1232     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1233   fi
1234 fi
1235 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1236                libc_cv_asm_protected_directive, [dnl
1237 cat > conftest.s <<EOF
1238 .protected foo
1239 foo:
1240 .hidden bar
1241 bar:
1242 EOF
1243 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1244   libc_cv_asm_protected_directive=yes
1245 else
1246   AC_MSG_ERROR(assembler support for symbol visibility is required)
1247 fi
1248 rm -f conftest*])
1249
1250 if test $libc_cv_asm_protected_directive = yes; then
1251   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1252                  libc_cv_visibility_attribute,
1253                  [cat > conftest.c <<EOF
1254                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1255                   int bar __attribute__ ((visibility ("protected"))) = 1;
1256 EOF
1257                   libc_cv_visibility_attribute=no
1258                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1259                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1260                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1261                         libc_cv_visibility_attribute=yes
1262                       fi
1263                     fi
1264                   fi
1265                   rm -f conftest.{c,s}
1266                  ])
1267   if test $libc_cv_visibility_attribute != yes; then
1268     AC_MSG_ERROR(compiler support for visibility attribute is required)
1269   fi
1270 fi
1271
1272 if test $libc_cv_visibility_attribute = yes; then
1273   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1274                  libc_cv_broken_visibility_attribute,
1275                  [cat > conftest.c <<EOF
1276                   int foo (int x);
1277                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1278                   int bar (int x) { return x; }
1279 EOF
1280                   libc_cv_broken_visibility_attribute=yes
1281                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1282 changequote(,)dnl
1283                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1284 changequote([,])dnl
1285                       libc_cv_broken_visibility_attribute=no
1286                     fi
1287                   fi
1288                   rm -f conftest.c conftest.s
1289                  ])
1290   if test $libc_cv_broken_visibility_attribute = yes; then
1291     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1292   fi
1293 fi
1294
1295 AC_CACHE_CHECK(for broken __attribute__((alias())),
1296                libc_cv_broken_alias_attribute,
1297                [cat > conftest.c <<EOF
1298                extern int foo (int x) __asm ("xyzzy");
1299                int bar (int x) { return x; }
1300                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1301                extern int dfoo;
1302                extern __typeof (dfoo) dfoo __asm ("abccb");
1303                int dfoo = 1;
1304 EOF
1305                libc_cv_broken_alias_attribute=yes
1306                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1307                  if grep 'xyzzy' conftest.s >/dev/null &&
1308                     grep 'abccb' conftest.s >/dev/null; then
1309                    libc_cv_broken_alias_attribute=no
1310                  fi
1311                fi
1312                rm -f conftest.c conftest.s
1313                ])
1314 if test $libc_cv_broken_alias_attribute = yes; then
1315   AC_MSG_ERROR(working alias attribute support required)
1316 fi
1317
1318 if test $libc_cv_visibility_attribute = yes; then
1319   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1320                  libc_cv_have_sdata_section,
1321                  [echo "int i;" > conftest.c
1322                   libc_cv_have_sdata_section=no
1323                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1324                      | grep '\.sdata' >/dev/null; then
1325                     libc_cv_have_sdata_section=yes
1326                   fi
1327                   rm -f conftest.c conftest.so
1328                  ])
1329   if test $libc_cv_have_sdata_section = yes; then
1330     AC_DEFINE(HAVE_SDATA_SECTION)
1331   fi
1332 fi
1333
1334 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1335                libc_cv_initfini_array, [dnl
1336 LIBC_TRY_LINK_STATIC([
1337 int foo (void) { return 1; }
1338 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1339 ],
1340   [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1341     libc_cv_initfini_array=yes
1342   else
1343     libc_cv_initfini_array=no
1344   fi],
1345   [libc_cv_initfini_array=no])
1346 ])
1347 if test $libc_cv_initfini_array != yes; then
1348   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1349 fi
1350
1351 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1352                libc_cv_ctors_header, [dnl
1353   libc_cv_ctors_header=yes
1354   LIBC_TRY_LINK_STATIC([
1355 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1356 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1357 ],
1358               [dnl
1359       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1360         { gsub(/\@<:@ */, "@<:@") }
1361         $2 == ".ctors" || $2 == ".dtors" {
1362           size = strtonum("0x" $6)
1363           align = strtonum("0x" $NF)
1364           seen@<:@$2@:>@ = 1
1365           stub@<:@$2@:>@ = size == align * 2
1366         }
1367         END {
1368           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1369           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1370           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1371         }
1372       '], [libc_cv_ctors_header=no])
1373     ], [dnl
1374       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1375     ])
1376 ])
1377 if test $libc_cv_ctors_header = no; then
1378   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1379 fi
1380
1381 AC_CACHE_CHECK(for libunwind-support in compiler,
1382                libc_cv_cc_with_libunwind, [
1383   cat > conftest.c <<EOF
1384 int main (void) { return 0; }
1385 EOF
1386   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1387      conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1388     libc_cv_cc_with_libunwind=yes
1389   else
1390     libc_cv_cc_with_libunwind=no
1391   fi
1392   rm -f conftest*])
1393 AC_SUBST(libc_cv_cc_with_libunwind)
1394 if test $libc_cv_cc_with_libunwind = yes; then
1395   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1396 fi
1397
1398 AC_CACHE_CHECK(for -z nodelete option,
1399                libc_cv_z_nodelete, [dnl
1400 cat > conftest.c <<EOF
1401 int _start (void) { return 42; }
1402 EOF
1403 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1404                    -fPIC -shared -o conftest.so conftest.c
1405                    -nostartfiles -nostdlib
1406                    -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1407 then
1408   libc_cv_z_nodelete=yes
1409 else
1410   AC_MSG_ERROR(linker with -z nodelete support required)
1411 fi
1412 rm -f conftest*])
1413
1414 AC_CACHE_CHECK(for -z nodlopen option,
1415                libc_cv_z_nodlopen, [dnl
1416 cat > conftest.c <<EOF
1417 int _start (void) { return 42; }
1418 EOF
1419 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1420                         -fPIC -shared -o conftest.so conftest.c
1421                         -nostartfiles -nostdlib
1422                         -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1423 then
1424   libc_cv_z_nodlopen=yes
1425 else
1426   AC_MSG_ERROR(linker with -z nodlopen support required)
1427 fi
1428 rm -f conftest*])
1429
1430 AC_CACHE_CHECK(for -z initfirst option,
1431                libc_cv_z_initfirst, [dnl
1432 cat > conftest.c <<EOF
1433 int _start (void) { return 42; }
1434 EOF
1435 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1436                         -fPIC -shared -o conftest.so conftest.c
1437                         -nostartfiles -nostdlib
1438                         -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1439 then
1440   libc_cv_z_initfirst=yes
1441 else
1442   AC_MSG_ERROR(linker with -z initfirst support required)
1443 fi
1444 rm -f conftest*])
1445
1446 # Add-on fragments can set these for other machines.
1447 libc_commonpagesize=${libc_commonpagesize:-no}
1448 libc_relro_required=${libc_relro_required:-no}
1449 case "$base_machine" in
1450   i[[34567]]86 | x86_64 | powerpc* | s390*)
1451     libc_commonpagesize=0x1000
1452     libc_relro_required=yes
1453     ;;
1454   sparc*)
1455     libc_commonpagesize=0x2000
1456     libc_relro_required=yes
1457     ;;
1458 esac
1459
1460 if test $libc_commonpagesize != no; then
1461   AC_CACHE_CHECK(for -z relro option,
1462                  libc_cv_z_relro, [dnl
1463   libc_cv_z_relro=no
1464   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1465 int _start (void) { return 42; }
1466 extern void _exit (int);
1467 /* Since these pointers are const, they should go in rodata.
1468    Since they refer to functions that have to be resolved by
1469    dynamic linking, they should instead go in RELRO data.  */
1470 const void *const relro[] = { &_start, &_exit, 0 };
1471 /* GNU ld fails to produce RELRO data when it's very small and there is no
1472    normal writable data following it, or if only uninitialized (.bss) data
1473    follows it, or only very small writable data.  */
1474 int data[0x10000] = { 1, };
1475 ]])])
1476   cat > conftest.awk <<\EOF
1477 BEGIN {
1478   result = "no"
1479   commonpagesize = strtonum(commonpagesize)
1480 }
1481 { print "LINE:", $0 > "/dev/stderr" }
1482 $1 == "GNU_RELRO" {
1483   vaddr = strtonum($3)
1484   memsz = strtonum($6)
1485   end = vaddr + memsz
1486   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1487     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1488   result = (end % commonpagesize == 0) ? "yes" : "broken"
1489 }
1490 END { print result }
1491 EOF
1492   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1493                     -fPIC -shared -o conftest.so conftest.c
1494                     -nostartfiles -nostdlib
1495                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1496   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1497   AC_TRY_COMMAND([
1498       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1499            conftest.ph > conftest.cps
1500     ]) &&
1501   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1502   rm -f conftest*])
1503   if { test "x$libc_relro_required" = xyes &&
1504        test "x$libc_cv_z_relro" != xyes
1505      }
1506   then
1507     AC_MSG_ERROR(linker with -z relro support required)
1508   fi
1509 else
1510   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1511 fi
1512
1513 AC_CACHE_CHECK(for -Bgroup option,
1514                libc_cv_Bgroup, [dnl
1515 cat > conftest.c <<EOF
1516 int _start (void) { return 42; }
1517 EOF
1518 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1519                             -fPIC -shared -o conftest.so conftest.c
1520                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1521 then
1522   libc_cv_Bgroup=yes
1523 else
1524   libc_cv_Bgroup=no
1525 fi
1526 rm -f conftest*])
1527 AC_SUBST(libc_cv_Bgroup)
1528
1529 ASFLAGS_config=
1530 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1531                libc_cv_as_noexecstack, [dnl
1532 cat > conftest.c <<EOF
1533 void foo (void) { }
1534 EOF
1535 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1536                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1537    && grep -q .note.GNU-stack conftest.s \
1538    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1539                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1540 then
1541   libc_cv_as_noexecstack=yes
1542 else
1543   libc_cv_as_noexecstack=no
1544 fi
1545 rm -f conftest*])
1546 if test $libc_cv_as_noexecstack = yes; then
1547   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1548 fi
1549 AC_SUBST(ASFLAGS_config)
1550
1551 AC_CACHE_CHECK(for -z combreloc,
1552                libc_cv_z_combreloc, [dnl
1553 cat > conftest.c <<EOF
1554 extern int bar (int);
1555 extern int mumble;
1556 int foo (void) { return bar (mumble); }
1557 EOF
1558 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1559                         -fPIC -shared -o conftest.so conftest.c
1560                         -nostdlib -nostartfiles
1561                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1562 then
1563 dnl The following test is a bit weak.  We must use a tool which can test
1564 dnl cross-platform since the gcc used can be a cross compiler.  Without
1565 dnl introducing new options this is not easily doable.  Instead use a tool
1566 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1567 dnl look for a section named .rel.dyn.
1568   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1569     libc_cv_z_combreloc=yes
1570   else
1571     libc_cv_z_combreloc=no
1572   fi
1573 else
1574   libc_cv_z_combreloc=no
1575 fi
1576 rm -f conftest*])
1577 if test "$libc_cv_z_combreloc" = yes; then
1578   AC_DEFINE(HAVE_Z_COMBRELOC)
1579 fi
1580 AC_SUBST(libc_cv_z_combreloc)
1581
1582 AC_CACHE_CHECK(for -z execstack,
1583                libc_cv_z_execstack, [dnl
1584 cat > conftest.c <<EOF
1585 int _start (void) { return 42; }
1586 EOF
1587 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1588                             -fPIC -shared -o conftest.so conftest.c
1589                             -Wl,-z,execstack -nostdlib
1590                             1>&AS_MESSAGE_LOG_FD])
1591 then
1592   libc_cv_z_execstack=yes
1593 else
1594   libc_cv_z_execstack=no
1595 fi
1596 rm -f conftest*])
1597 AC_SUBST(libc_cv_z_execstack)
1598
1599 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1600 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1601 ])
1602
1603 AC_SUBST(libc_cv_fpie)
1604
1605 AC_CACHE_CHECK(for --hash-style option,
1606                libc_cv_hashstyle, [dnl
1607 cat > conftest.c <<EOF
1608 int _start (void) { return 42; }
1609 EOF
1610 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1611                             -fPIC -shared -o conftest.so conftest.c
1612                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1613 then
1614   libc_cv_hashstyle=yes
1615 else
1616   libc_cv_hashstyle=no
1617 fi
1618 rm -f conftest*])
1619 AC_SUBST(libc_cv_hashstyle)
1620
1621 # The linker's default -shared behavior is good enough if it
1622 # does these things that our custom linker scripts ensure that
1623 # all allocated NOTE sections come first.
1624 if test "$use_default_link" = default; then
1625   AC_CACHE_CHECK([for sufficient default -shared layout],
1626                   libc_cv_use_default_link, [dnl
1627   libc_cv_use_default_link=no
1628   cat > conftest.s <<\EOF
1629           .section .note.a,"a",%note
1630           .balign 4
1631           .long 4,4,9
1632           .string "GNU"
1633           .string "foo"
1634           .section .note.b,"a",%note
1635           .balign 4
1636           .long 4,4,9
1637           .string "GNU"
1638           .string "bar"
1639 EOF
1640   if AC_TRY_COMMAND([dnl
1641   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1642        ac_try=`$READELF -S conftest.so | sed -n \
1643          ['${x;p;}
1644           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1645           t a
1646           b
1647           : a
1648           H']`
1649   then
1650     libc_seen_a=no libc_seen_b=no
1651     set -- $ac_try
1652     while test $# -ge 2 -a "$1" = NOTE; do
1653       case "$2" in
1654       .note.a) libc_seen_a=yes ;;
1655       .note.b) libc_seen_b=yes ;;
1656       esac
1657       shift 2
1658     done
1659     case "$libc_seen_a$libc_seen_b" in
1660     yesyes)
1661       libc_cv_use_default_link=yes
1662       ;;
1663     *)
1664       echo >&AS_MESSAGE_LOG_FD "\
1665 $libc_seen_a$libc_seen_b from:
1666 $ac_try"
1667       ;;
1668     esac
1669   fi
1670   rm -f conftest*])
1671   use_default_link=$libc_cv_use_default_link
1672 fi
1673
1674 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1675 if libc_cv_output_format=`
1676 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1677 then
1678   :
1679 else
1680   libc_cv_output_format=
1681 fi
1682 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1683 AC_SUBST(libc_cv_output_format)
1684
1685 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1686 cat > conftest.c <<EOF
1687 int foo;
1688 EOF
1689 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1690                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1691 then
1692   libc_cv_fno_toplevel_reorder=yes
1693 else
1694   libc_cv_fno_toplevel_reorder=no
1695 fi
1696 rm -f conftest*])
1697 if test $libc_cv_fno_toplevel_reorder = yes; then
1698   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1699 else
1700   fno_unit_at_a_time=-fno-unit-at-a-time
1701 fi
1702 AC_SUBST(fno_unit_at_a_time)
1703
1704 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1705 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1706                    [libc_cv_ssp=yes],
1707                    [libc_cv_ssp=no])
1708 ])
1709 AC_SUBST(libc_cv_ssp)
1710
1711 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1712 cat > conftest.c <<EOF
1713 int foo;
1714 #ifdef __GNUC_GNU_INLINE__
1715 main () { return 0;}
1716 #else
1717 #error
1718 #endif
1719 EOF
1720 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1721                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1722 then
1723   libc_cv_gnu89_inline=yes
1724 else
1725   libc_cv_gnu89_inline=no
1726 fi
1727 rm -f conftest*])
1728 if test $libc_cv_gnu89_inline = yes; then
1729   gnu89_inline=-fgnu89-inline
1730 else
1731   gnu89_inline=
1732 fi
1733 AC_SUBST(gnu89_inline)
1734
1735 AC_CACHE_CHECK(whether cc puts quotes around section names,
1736                libc_cv_have_section_quotes,
1737                [cat > conftest.c <<EOF
1738                 static const int foo
1739                 __attribute__ ((section ("bar"))) = 1;
1740 EOF
1741                 if ${CC-cc} -S conftest.c -o conftest.s; then
1742                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1743                     libc_cv_have_section_quotes=yes
1744                   else
1745                     libc_cv_have_section_quotes=no
1746                   fi
1747                 else
1748                   libc_cv_have_section_quotes=unknown
1749                 fi
1750                 rm -f conftest.{c,s}
1751                 ])
1752 if test $libc_cv_have_section_quotes = yes; then
1753   AC_DEFINE(HAVE_SECTION_QUOTES)
1754 fi
1755
1756 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1757                [dnl
1758 cat > conftest.s <<EOF
1759 ${libc_cv_dot_text}
1760 .globl foo
1761 foo:
1762 .weak foo
1763 .weak bar; bar = foo
1764 EOF
1765 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1766   libc_cv_asm_weak_directive=yes
1767 else
1768   libc_cv_asm_weak_directive=no
1769 fi
1770 rm -f conftest*])
1771
1772 if test $libc_cv_asm_weak_directive = no; then
1773   AC_CACHE_CHECK(for assembler .weakext directive,
1774                  libc_cv_asm_weakext_directive,
1775                  [dnl
1776 cat > conftest.s <<EOF
1777 ${libc_cv_dot_text}
1778 .globl foo
1779 foo:
1780 .weakext bar foo
1781 .weakext baz
1782 .globl baz
1783 baz:
1784 EOF
1785   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1786     libc_cv_asm_weakext_directive=yes
1787   else
1788     libc_cv_asm_weakext_directive=no
1789   fi
1790   rm -f conftest*])
1791
1792 fi # no .weak
1793
1794 if test $libc_cv_asm_weak_directive = yes; then
1795   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1796 elif test $libc_cv_asm_weakext_directive = yes; then
1797   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1798 fi
1799
1800 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1801 case $machine in
1802   sparc/sparc64*) cfi_offset=2047;;
1803   *) cfi_offset=0;;
1804 esac
1805 cat > conftest.s <<EOF
1806         .text
1807         .type   func,%function
1808 func:
1809         .cfi_startproc
1810         .cfi_remember_state
1811         .cfi_rel_offset 1, $cfi_offset
1812         .cfi_endproc
1813 EOF
1814 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1815   libc_cv_asm_cfi_directives=yes
1816 else
1817   libc_cv_asm_cfi_directives=no
1818 fi
1819 rm -f conftest*])
1820 if test $libc_cv_asm_cfi_directives = yes; then
1821   AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1822 fi
1823
1824 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1825 cat > conftest.c <<\EOF
1826 _start () {}
1827 int __eh_pc;
1828 __throw () {}
1829 EOF
1830 dnl No \ in command here because it ends up inside ''.
1831 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1832                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1833                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1834   libc_cv_ld_no_whole_archive=yes
1835 else
1836   libc_cv_ld_no_whole_archive=no
1837 fi
1838 rm -f conftest*])
1839 if test $libc_cv_ld_no_whole_archive = no; then
1840   AC_MSG_ERROR([support for --no-whole-archive is needed])
1841 fi
1842
1843 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1844 cat > conftest.c <<\EOF
1845 _start () {}
1846 int __eh_pc;
1847 __throw () {}
1848 EOF
1849 dnl No \ in command here because it ends up inside ''.
1850 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1851                             -nostdlib -nostartfiles -fexceptions
1852                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1853   libc_cv_gcc_exceptions=yes
1854 else
1855   libc_cv_gcc_exceptions=no
1856 fi
1857 rm -f conftest*])
1858 if test $libc_cv_gcc_exceptions = yes; then
1859   exceptions=-fexceptions
1860 fi
1861 AC_SUBST(exceptions)dnl
1862
1863 if test "$host_cpu" = powerpc ; then
1864 # Check for a bug present in at least versions 2.8.x of GCC
1865 # and versions 1.0.x of EGCS.
1866 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1867 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1868                libc_cv_c_asmcr0_bug='no',
1869                libc_cv_c_asmcr0_bug='yes')])
1870 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1871   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1872 fi
1873 fi
1874
1875 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1876 cat > conftest.c <<\EOF
1877 void zero (void *x)
1878 {
1879   __builtin_memset (x, 0, 1000);
1880 }
1881 EOF
1882 dnl
1883 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1884 then
1885   libc_cv_gcc_builtin_memset=no
1886 else
1887   libc_cv_gcc_builtin_memset=yes
1888 fi
1889 rm -f conftest* ])
1890 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1891   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1892 fi
1893
1894 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1895 cat > conftest.c <<\EOF
1896 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1897 char *foo (const char *a, const char *b)
1898 {
1899   return __builtin_strstr (a, b);
1900 }
1901 EOF
1902 dnl
1903 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1904 then
1905   libc_cv_gcc_builtin_redirection=yes
1906 else
1907   libc_cv_gcc_builtin_redirection=no
1908 fi
1909 rm -f conftest* ])
1910 if test "$libc_cv_gcc_builtin_redirection" = no; then
1911   AC_MSG_ERROR([support for the symbol redirection needed])
1912 fi
1913
1914 dnl Check whether the compiler supports the __thread keyword.
1915 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1916 [cat > conftest.c <<\EOF
1917 __thread int a = 42;
1918 EOF
1919 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1920   libc_cv_gcc___thread=yes
1921 else
1922   libc_cv_gcc___thread=no
1923 fi
1924 rm -f conftest*])
1925 if test "$libc_cv_gcc___thread" = no; then
1926   AC_MSG_ERROR([support for the __thread keyword is required])
1927 fi
1928
1929 dnl Check whether the compiler supports the tls_model attribute.
1930 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1931 cat > conftest.c <<\EOF
1932 extern __thread int a __attribute__((tls_model ("initial-exec")));
1933 EOF
1934 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1935   libc_cv_gcc_tls_model_attr=yes
1936 else
1937   libc_cv_gcc_tls_model_attr=no
1938 fi
1939 rm -f conftest*])
1940 if test "$libc_cv_gcc_tls_model_attr" = no; then
1941   AC_MSG_ERROR([support for the tls_model attribute is required])
1942 fi
1943
1944 dnl Determine how to disable generation of FMA instructions.
1945 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1946                libc_cv_cc_nofma, [dnl
1947 libc_cv_cc_nofma=
1948 for opt in -ffp-contract=off -mno-fused-madd; do
1949   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1950 done])
1951
1952 if test -n "$submachine"; then
1953   AC_CACHE_CHECK([for compiler option for CPU variant],
1954                  libc_cv_cc_submachine, [dnl
1955   libc_cv_cc_submachine=no
1956   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1957     LIBC_TRY_CC_OPTION([$opt], [
1958       libc_cv_cc_submachine="$opt"
1959       break], [])
1960   done])
1961   if test "x$libc_cv_cc_submachine" = xno; then
1962     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1963   fi
1964 fi
1965 AC_SUBST(libc_cv_cc_submachine)
1966
1967 dnl Check whether we have the gd library available.
1968 AC_MSG_CHECKING(for libgd)
1969 if test "$with_gd" != "no"; then
1970   old_CFLAGS="$CFLAGS"
1971   CFLAGS="$CFLAGS $libgd_include"
1972   old_LDFLAGS="$LDFLAGS"
1973   LDFLAGS="$LDFLAGS $libgd_ldflags"
1974   old_LIBS="$LIBS"
1975   LIBS="$LIBS -lgd -lpng -lz -lm"
1976   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1977   CFLAGS="$old_CFLAGS"
1978   LDFLAGS="$old_LDFLAGS"
1979   LIBS="$old_LIBS"
1980 else
1981   LIBGD=no
1982 fi
1983 AC_MSG_RESULT($LIBGD)
1984 AC_SUBST(LIBGD)
1985
1986 # SELinux detection
1987 if test x$with_selinux = xno ; then
1988   have_selinux=no;
1989 else
1990   # See if we have the SELinux library
1991   AC_CHECK_LIB(selinux, is_selinux_enabled,
1992                have_selinux=yes, have_selinux=no)
1993   # See if we have the SELinux header with the NSCD permissions in it.
1994   if test x$have_selinux = xyes ; then
1995     AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
1996     AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
1997                     [#ifdef NSCD__SHMEMHOST
1998                      return 0;
1999                      #else
2000                      #error NSCD__SHMEMHOST not defined
2001                      #endif],
2002                     have_selinux=yes, have_selinux=no)
2003     AC_MSG_RESULT($have_selinux)
2004   fi
2005
2006   if test x$with_selinux = xyes ; then
2007     if test x$have_selinux = xno ; then
2008       AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2009     fi
2010   fi
2011 fi
2012 # Check if we're building with SELinux support.
2013 if test "x$have_selinux" = xyes; then
2014   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2015
2016   # See if we have the libaudit library
2017   AC_CHECK_LIB(audit, audit_log_user_avc_message,
2018                have_libaudit=yes, have_libaudit=no)
2019   if test "x$have_libaudit" = xyes; then
2020     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2021   fi
2022   AC_SUBST(have_libaudit)
2023
2024   # See if we have the libcap library
2025   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2026   if test "x$have_libcap" = xyes; then
2027     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2028   fi
2029   AC_SUBST(have_libcap)
2030 fi
2031 AC_SUBST(have_selinux)
2032
2033 dnl check for the size of 'long double'.
2034 AC_CHECK_SIZEOF(long double, 0)
2035 sizeof_long_double=$ac_cv_sizeof_long_double
2036 AC_SUBST(sizeof_long_double)
2037
2038 CPPUNDEFS=
2039 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
2040 dnl Since we are building the implementations of the fortified functions here,
2041 dnl having the macro defined interacts very badly.
2042 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
2043 [AC_TRY_COMPILE([], [
2044 #ifdef _FORTIFY_SOURCE
2045 # error bogon
2046 #endif],
2047                 [libc_cv_predef_fortify_source=no],
2048                 [libc_cv_predef_fortify_source=yes])])
2049 if test $libc_cv_predef_fortify_source = yes; then
2050   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
2051 fi
2052 AC_SUBST(CPPUNDEFS)
2053
2054 dnl Check for silly hacked compilers inserting -fstack-protector.
2055 dnl This breaks badly for the early startup code we compile, since
2056 dnl the compiled code can refer to a magic machine-dependent location
2057 dnl for the canary value before we have sufficient setup for that to
2058 dnl work.  It's also questionable to build all of libc with this flag
2059 dnl even when you're doing that for most applications you build, since
2060 dnl libc's code is so heavily-used and performance-sensitive.  If we
2061 dnl ever really want to make that work, it should be enabled explicitly
2062 dnl in the libc build, not inherited from implicit compiler settings.
2063 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
2064                libc_cv_predef_stack_protector, [
2065 AC_TRY_COMPILE([extern void foobar (char *);],
2066                [char large_array[2048]; foobar (large_array);], [
2067 libc_undefs=`$NM -u conftest.o |
2068   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
2069     2>&AS_MESSAGE_LOG_FD` || {
2070   AC_MSG_ERROR([confusing output from $NM -u])
2071 }
2072 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
2073 # On some architectures, there are architecture-specific undefined
2074 # symbols (resolved by the linker), so filter out unknown symbols.
2075 # This will fail to produce the correct result if the compiler
2076 # defaults to -fstack-protector but this produces an undefined symbol
2077 # other than __stack_chk_fail.  However, compilers like that have not
2078 # been encountered in practice.
2079 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
2080 case "$libc_undefs" in
2081 foobar) libc_cv_predef_stack_protector=no ;;
2082 '__stack_chk_fail
2083 foobar') libc_cv_predef_stack_protector=yes ;;
2084 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
2085 esac],
2086                [AC_MSG_ERROR([test compilation failed])])
2087 ])
2088 libc_extra_cflags=
2089 if test $libc_cv_predef_stack_protector = yes; then
2090   libc_extra_cflags=-fno-stack-protector
2091 fi
2092 AC_SUBST(libc_extra_cflags)
2093
2094 ### End of automated tests.
2095 ### Now run sysdeps configure fragments.
2096
2097 # They also can set these variables.
2098 use_ldconfig=no
2099 ldd_rewrite_script=no
2100 libc_cv_sysconfdir=$sysconfdir
2101 libc_cv_localstatedir=$localstatedir
2102 libc_cv_gcc_unwind_find_fde=no
2103 libc_cv_idn=no
2104
2105 # Iterate over all the sysdep directories we will use, running their
2106 # configure fragments.
2107 for dir in $sysnames; do
2108   case $dir in
2109     /*) dest=$dir ;;
2110     *)  dest=$srcdir/$dir ;;
2111   esac
2112   if test -r $dest/configure; then
2113     AC_MSG_RESULT(running configure fragment for $dir)
2114     . $dest/configure
2115   fi
2116 done
2117
2118 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2119   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2120 fi
2121 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2122
2123 # Test for old glibc 2.0.x headers so that they can be removed properly
2124 # Search only in includedir.
2125 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2126 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2127 then
2128   old_glibc_headers=yes
2129 else
2130   old_glibc_headers=no
2131 fi
2132 AC_MSG_RESULT($old_glibc_headers)
2133 if test ${old_glibc_headers} = yes; then
2134   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2135   AC_MSG_WARN(*** be removed.)
2136 fi
2137 AC_SUBST(old_glibc_headers)
2138
2139 AC_SUBST(libc_cv_slibdir)
2140 AC_SUBST(libc_cv_localedir)
2141 AC_SUBST(libc_cv_sysconfdir)
2142 AC_SUBST(libc_cv_localstatedir)
2143 AC_SUBST(libc_cv_rootsbindir)
2144 AC_SUBST(libc_cv_forced_unwind)
2145
2146 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2147 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2148 AC_SUBST(libc_cv_cc_sse4)
2149 AC_SUBST(libc_cv_cc_avx)
2150 AC_SUBST(libc_cv_cc_sse2avx)
2151 AC_SUBST(libc_cv_cc_novzeroupper)
2152 AC_SUBST(libc_cv_cc_fma4)
2153 AC_SUBST(libc_cv_cc_nofma)
2154 AC_SUBST(libc_cv_as_i686)
2155 AC_SUBST(libc_cv_sparc_as_vis3)
2156
2157 AC_SUBST(use_ldconfig)
2158 AC_SUBST(ldd_rewrite_script)
2159
2160 AC_SUBST(static)
2161 AC_SUBST(shared)
2162
2163 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2164 [libc_cv_pic_default=yes
2165 cat > conftest.c <<EOF
2166 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2167 # error PIC is default.
2168 #endif
2169 EOF
2170 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2171   libc_cv_pic_default=no
2172 fi
2173 rm -f conftest.*])
2174 AC_SUBST(libc_cv_pic_default)
2175
2176 AC_SUBST(profile)
2177 AC_SUBST(static_nss)
2178
2179 AC_SUBST(DEFINES)
2180
2181 dnl See sysdeps/mach/configure.in for this variable.
2182 AC_SUBST(mach_interface_list)
2183
2184 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2185   config_makefile=
2186 else
2187   config_makefile=Makefile
2188 fi
2189
2190 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2191 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2192 AC_SUBST(VERSION)
2193 AC_SUBST(RELEASE)
2194
2195 AC_CONFIG_FILES([config.make ${config_makefile}])
2196 AC_CONFIG_COMMANDS([default],[[
2197 case $CONFIG_FILES in *config.make*)
2198 echo "$config_vars" >> config.make;;
2199 esac
2200 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2201 AC_OUTPUT