configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37 [  --with-fp              if using floating-point hardware [default=yes]],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(binutils, dnl
  40   --with-binutils=PATH    specify location of binutils (as and ld),
  41             path_binutils=$withval, path_binutils='')
  42 AC_ARG_WITH(elf, dnl
  43   --with-elf              if using the ELF object format,
  44             elf=$withval, elf=no)
  45
  46 AC_ARG_ENABLE(libio, dnl
  47 [  --enable-libio          build in GNU libio instead of GNU stdio],
  48               [if test $enableval = yes; then
  49                  stdio=libio
  50                else
  51                  stdio=stdio
  52                fi],
  53               stdio=default)
  54
  55 AC_ARG_ENABLE(sanity-checks, dnl
  56 [  --disable-sanity-checks really do not use threads (should not be used
  57                           except in special situations) [default=yes]],
  58               enable_sanity=$enableval, enable_sanity=yes)
  59
  60 dnl Arguments to enable or disable building the static, shared, profiled,
  61 dnl and -fomit-frame-pointer libraries.
  62 AC_ARG_ENABLE(static, dnl
  63 [  --enable-static         build static library [default=yes]],
  64               static=$enableval, static=yes)
  65 AC_ARG_ENABLE(shared, dnl
  66 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  67               shared=$enableval, shared=default)
  68 AC_ARG_ENABLE(profile, dnl
  69 [  --enable-profile        build profiled library [default=yes]],
  70               profile=$enableval, profile=yes)
  71 AC_ARG_ENABLE(omitfp, dnl
  72 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  73               omitfp=$enableval, omitfp=no)
  74 AC_ARG_ENABLE(bounded, dnl
  75 [  --enable-bounded        build with runtime bounds checking [default=no]],
  76               bounded=$enableval, bounded=no)
  77 AC_ARG_ENABLE(versioning, dnl
  78 [  --disable-versioning    do not include versioning information in the
  79                           library objects [default=yes if supported]],
  80              enable_versioning=$enableval, enable_versioning=yes)
  81
  82 dnl Generic infrastructure for drop-in additions to libc.
  83 AC_ARG_ENABLE(add-ons, dnl
  84 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
  85                                   search for add-ons if no parameter given],
  86   [case "$enableval" in
  87     yes) if test "$srcdir" = "."; then
  88            add_ons=`echo */configure | sed -e 's!/configure!!g'`
  89          else
  90            add_ons=`echo $srcdir/*/configure | \
  91                     sed -e "s!$srcdir/!!g" -e 's!/configure!!g'`
  92          fi;;
  93     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
  94    esac],
  95   [add_ons=])
  96
  97 AC_CONFIG_SUBDIRS($add_ons)
  98 add_ons_pfx=
  99 if test x"$add_ons" != x; then
 100   for f in $add_ons; do
 101     # Test whether such a subdir really exists.
 102     if test -d $srcdir/$f; then
 103       add_ons_pfx="$add_ons_pfx $f/"
 104     else
 105       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 106     fi
 107   done
 108 fi
 109
 110 dnl On some platforms we cannot use dynamic loading.  We must provide
 111 dnl static NSS modules.
 112 AC_ARG_ENABLE(static-nss, dnl
 113 [  --enable-static-nss     build static NSS modules [default=no]],
 114               static_nss=$enableval, static_nss=no)
 115 if test x"$static_nss" = xyes; then
 116   AC_DEFINE(DO_STATIC_NSS)
 117 fi
 118
 119 AC_CANONICAL_HOST
 120
 121 # The way shlib-versions is used to generate soversions.mk uses a
 122 # fairly simplistic model for name recognition that can't distinguish
 123 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 124 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 125 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 126 case "$host_os" in
 127 linux*)
 128   ;;
 129 gnu*)
 130   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 131   ;;
 132 esac
 133
 134 ###
 135 ### I put this here to prevent those annoying emails from people who cannot
 136 ### read and try to compile glibc on unsupported platforms.  --drepper
 137 ###
 138 ### By using the undocumented --enable-hacker-mode option for configure
 139 ### one can skip this test to make the configuration not fail for unsupported
 140 ### platforms.
 141 ###
 142 if test -z "$enable_hacker_mode"; then
 143   case "$host_os" in
 144   linux* | gnu*)
 145     ;;
 146   *)
 147     echo "*** The GNU C library is currently not available for this platform."
 148     echo "*** So far nobody cared to port it and if there is no volunteer it"
 149     echo "*** might never happen.  So, if you have interest to see glibc on"
 150     echo "*** this platform visit"
 151     echo "***   http://www.gnu.org/software/libc/porting.html"
 152     echo "*** and join the group of porters"
 153     exit 1
 154     ;;
 155   esac
 156 fi
 157
 158 # We keep the original values in `$config_*' and never modify them, so we
 159 # can write them unchanged into config.make.  Everything else uses
 160 # $machine, $vendor, and $os, and changes them whenever convenient.
 161 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 162
 163 # Some configurations imply other options.
 164 case "$host_os" in
 165 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 166   # These systems always use GNU tools.
 167   gnu_ld=yes gnu_as=yes ;;
 168 esac
 169 case "$host_os" in
 170 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 171 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 172   ;;
 173 gnu* | linux* | sysv4* | solaris2*)
 174   # These systems (almost) always use the ELF format.
 175   elf=yes
 176   ;;
 177 esac
 178
 179 machine=$config_machine
 180 vendor=$config_vendor
 181 os=$config_os
 182
 183 dnl We need to use [ and ] for other purposes for a while now.
 184 changequote(,)dnl
 185 # Expand the configuration machine name into a subdirectory by architecture
 186 # type and particular chip.
 187 case "$machine" in
 188 a29k | am29000) base_machine=a29k machine=a29k ;;
 189 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 190 arm*)           base_machine=arm machine=arm/$machine ;;
 191 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 192 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 193 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 194 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 195 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 196 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 197 m88???)         base_machine=m88k machine=m88k/$machine ;;
 198 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 199 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 200 mips*)          base_machine=mips machine=mips/$machine ;;
 201 sparc | sparcv[67])
 202                 base_machine=sparc machine=sparc/sparc32 ;;
 203 sparcv8 | supersparc | hypersparc)
 204                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 205 sparc64 | ultrasparc)
 206                 base_machine=sparc machine=sparc/sparc64 ;;
 207 esac
 208 changequote([,])dnl
 209 AC_SUBST(base_machine)
 210
 211 if test "$base_machine" = "i386"; then
 212   AC_DEFINE(USE_REGPARMS)
 213 fi
 214
 215 # Compute the list of sysdep directories for this configuration.
 216 # This can take a while to compute.
 217 sysdep_dir=$srcdir/sysdeps
 218 AC_MSG_CHECKING(sysdep dirs)
 219 dnl We need to use [ and ] for other purposes for a while now.
 220 changequote(,)dnl
 221 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 222 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 223
 224 case "$os" in
 225 gnu*)
 226   base_os=mach/hurd ;;
 227 netbsd* | 386bsd* | freebsd* | bsdi*)
 228   base_os=unix/bsd/bsd4.4 ;;
 229 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 230   base_os=unix/bsd ;;
 231 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 232   base_os=unix/sysv ;;
 233 solaris[2-9]*)
 234   base_os=unix/sysv/sysv4 ;;
 235 none)
 236   base_os=standalone ;;
 237 *)
 238   base_os='' ;;
 239 esac
 240
 241 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 242 tail=$os
 243 ostry=$os
 244 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 245   ostry="$ostry /$o"
 246   tail=$o
 247 done
 248 o=`echo $tail | sed 's/[0-9]*$//'`
 249 if test $o != $tail; then
 250   ostry="$ostry /$o"
 251 fi
 252 # For linux-gnu, try linux-gnu, then linux.
 253 o=`echo $tail | sed 's/-.*$//'`
 254 if test $o != $tail; then
 255   ostry="$ostry /$o"
 256 fi
 257
 258 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 259 base=
 260 tail=$base_os
 261 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 262   set $b
 263   base="$base /$1"
 264   tail="$2"
 265 done
 266
 267 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 268 mach=
 269 tail=$machine
 270 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 271   set $m
 272   # Prepend the machine's FPU directory unless --without-fp.
 273   if test "$with_fp" = yes; then
 274     mach="$mach /$1/fpu"
 275   fi
 276   mach="$mach /$1"
 277   tail="$2"
 278 done
 279
 280 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 281 changequote([,])dnl
 282
 283 # Find what sysdep directories exist.
 284 sysnames=
 285 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 286 for d in $add_ons_pfx ''; do
 287   for b in $base ''; do
 288     for m0 in $mach ''; do
 289       for v in /$vendor ''; do
 290         for o in /$ostry ''; do
 291           for m in $mach ''; do
 292             if test "$m0$b$v$o$m"; then
 293               try="${d}sysdeps$m0$b$v$o$m"
 294               test -n "$enable_debug_configure" &&
 295               echo "$0 [DEBUG]: try $try" >&2
 296               case $try in
 297                 /*) dest=$try ;;
 298                 *)  dest=$srcdir/$try ;;
 299               esac
 300               if test -d $dest; then
 301                 sysnames="$sysnames $try"
 302                 { test -n "$o" || test -n "$b"; } && os_used=t
 303                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 304               fi
 305             fi
 306           done
 307         done
 308       done
 309     done
 310   done
 311 done
 312 IFS="$ac_save_ifs"
 313
 314 if test -z "$os_used" && test "$os" != none; then
 315   AC_MSG_ERROR(Operating system $os is not supported.)
 316 fi
 317 if test -z "$machine_used" && test "$machine" != none; then
 318   AC_MSG_ERROR(The $machine is not supported.)
 319 fi
 320
 321 # We have now validated the configuration.
 322
 323
 324 # If using ELF, look for an `elf' subdirectory of each machine directory.
 325 # We prepend these rather than inserting them whereever the machine appears
 326 # because things specified by the machine's ELF ABI should override
 327 # OS-specific things, and should always be the same for any OS on the
 328 # machine (otherwise what's the point of an ABI?).
 329 if test "$elf" = yes; then
 330   elf_dirs=
 331   for d in $add_ons_pfx ''; do
 332     case $d in
 333       /*) xsrcdir= ;;
 334       *)  xsrcdir=$srcdir/ ;;
 335     esac
 336     for m in $mach; do
 337       if test -d $xsrcdir${d}sysdeps$m/elf; then
 338         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 339       fi
 340     done
 341   done
 342   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 343 fi
 344
 345
 346 # Expand the list of system names into a full list of directories
 347 # from each element's parent name and Implies file (if present).
 348 set $sysnames
 349 names=
 350 while test $# -gt 0; do
 351   name=$1
 352   shift
 353
 354   case " $names " in *" $name "*)
 355     # Already in the list.
 356     continue
 357   esac
 358
 359   # Report each name as we discover it, so there is no long pause in output.
 360   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 361
 362   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 363
 364   case $name in
 365     /*) xsrcdir= ;;
 366     *)  xsrcdir=$srcdir/ ;;
 367   esac
 368   test -n "$enable_debug_configure" &&
 369   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 370
 371   if test -f $xsrcdir$name/Implies; then
 372     # Collect more names from the `Implies' file (removing comments).
 373     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 374     implied=
 375     for x in $implied_candidate; do
 376       if test -d $xsrcdir$name_base/$x; then
 377         implied="$implied $name_base/$x";
 378       else
 379         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 380       fi
 381     done
 382   else
 383     implied=
 384   fi
 385
 386   # Add NAME to the list of names.
 387   names="$names $name"
 388
 389   # Find the parent of NAME, using the empty string if it has none.
 390 changequote(,)dnl
 391   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 392 changequote([,])dnl
 393
 394   # Add the names implied by NAME, and NAME's parent (if it has one), to
 395   # the list of names to be processed (the argument list).  We prepend the
 396   # implied names to the list and append the parent.  We want implied
 397   # directories to come before further directories inferred from the
 398   # configuration components; this ensures that for sysv4, unix/common
 399   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 400   # after sysv4).
 401   sysnames="`echo $implied $* $parent`"
 402   test -n "$sysnames" && set $sysnames
 403 done
 404
 405 # Add the default directories.
 406 sysnames="$names sysdeps/generic"
 407 AC_SUBST(sysnames)
 408 # The other names were emitted during the scan.
 409 AC_MSG_RESULT(sysdeps/generic)
 410
 411
 412 ### Locate tools.
 413
 414 AC_PROG_INSTALL
 415 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 416   # The makefiles need to use a different form to find it in $srcdir.
 417   INSTALL='\$(..)./install-sh -c'
 418 fi
 419 AC_PROG_LN_S
 420 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 421 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo)
 422 if test "$MAKEINFO"; then
 423 changequote(,)dnl Need [] for regexps.
 424   if $MAKEINFO --version | grep 'texinfo 3\.[1-9][1-9]' >/dev/null 2>&1
 425 changequote([,])dnl
 426   then : # Makeinfo 3.11 or greater, works.
 427   else
 428     AC_MSG_WARN([
 429 *** makeinfo is too old (need version 3.11 or better).
 430 *** You should install the needed version and re-configure since otherwise
 431 *** you won't get the info pages installed.])
 432     MAKEINFO=
 433   fi
 434 fi
 435
 436 AC_PROG_CC_LOCAL
 437 AC_CANONICAL_BUILD
 438 if test $host != $build; then
 439   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 440 fi
 441 AC_SUBST(cross_compiling)
 442 AC_PROG_CPP
 443 LIBC_PROG_BINUTILS
 444 AC_CHECK_TOOL(AR, ar)
 445 AC_CHECK_TOOL(RANLIB, ranlib, :)
 446
 447 AC_PATH_PROG(BASH, bash, no)
 448 if test "$BASH" != no &&
 449    $BASH -c 'test "$BASH_VERSINFO" \
 450              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 451   libc_cv_have_bash2=yes
 452 else
 453   libc_cv_have_bash2=no
 454 fi
 455 AC_SUBST(libc_cv_have_bash2)
 456
 457 dnl We need a ksh compatible shell for tzselect.
 458 if test "$BASH" = no; then
 459   AC_PATH_PROG(KSH, ksh, no)
 460   if test "$KSH" = no; then
 461     libc_cv_have_ksh=no
 462   else
 463     libc_cv_have_ksh=yes
 464   fi
 465 else
 466   KSH="$BASH"
 467   AC_SUBST(KSH)
 468   libc_cv_have_ksh=yes
 469 fi
 470 AC_SUBST(libc_cv_have_ksh)
 471
 472 AC_PATH_PROGS(PERL, perl, no)
 473 AC_SUBST(PERL)
 474
 475 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 476 echo '#include <stddef.h>
 477 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 478 if eval "$ac_cpp conftest.c 2>/dev/null" \
 479 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 480   libc_cv_signed_size_t=no
 481 else
 482   libc_cv_signed_size_t=yes
 483 fi
 484 rm -f conftest*])
 485 if test $libc_cv_signed_size_t = yes; then
 486   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 487   cat >> confdefs.h <<\EOF
 488 #undef __SIZE_TYPE__
 489 #define __SIZE_TYPE__ unsigned
 490 EOF
 491 fi
 492
 493 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 494 AC_TRY_COMPILE(dnl
 495 [#define __need_size_t
 496 #define __need_wchar_t
 497 #include <stddef.h>
 498 #define __need_NULL
 499 #include <stddef.h>], [size_t size; wchar_t wchar;
 500 #ifdef offsetof
 501 #error stddef.h ignored __need_*
 502 #endif
 503 if (&size == NULL || &wchar == NULL) abort ();],
 504                libc_cv_friendly_stddef=yes,
 505                libc_cv_friendly_stddef=no)])
 506 if test $libc_cv_friendly_stddef = yes; then
 507   config_vars="$config_vars
 508 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 509 fi
 510
 511 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 512                libc_cv_need_minus_P, [dnl
 513 cat > conftest.S <<EOF
 514 #include "confdefs.h"
 515 /* Nothing whatsoever.  */
 516 EOF
 517 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 518   libc_cv_need_minus_P=no
 519 else
 520   libc_cv_need_minus_P=yes
 521 fi
 522 rm -f conftest*])
 523 if test $libc_cv_need_minus_P = yes; then
 524   config_vars="$config_vars
 525 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 526 fi
 527
 528 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
 529 # be told to read stdin.  This causes the compiler to hang when fed an
 530 # .s file.
 531 if test $ac_cv_prog_gcc = yes; then
 532  case `${CC-cc} -v 2>&1` in
 533   *2.7*)
 534   # We must check this even if -pipe is not given here, because the user
 535   # might do `make CFLAGS=-pipe'.
 536   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
 537    cp /dev/null conftest.s
 538    cat >conftest1.s <<EOF
 539 .nosuchdirective
 540 EOF
 541    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
 542     libc_cv_gcc_pipe_bug=no
 543    else
 544     libc_cv_gcc_pipe_bug=yes
 545    fi
 546    rm -f conftest*])
 547   if test $libc_cv_gcc_pipe_bug = yes; then
 548    makeCC="${CC-cc} -B\$(common-objpfx)"
 549    makeCFLAGS=$CFLAGS
 550    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
 551   fi;;
 552  *) libc_cv_gcc_pipe_bug=no;;
 553  esac
 554 else
 555  libc_cv_gcc_pipe_bug=no
 556 fi
 557
 558 AC_CACHE_CHECK(for assembler global-symbol directive,
 559                libc_cv_asm_global_directive, [dnl
 560 libc_cv_asm_global_directive=UNKNOWN
 561 for ac_globl in .globl .global; do
 562   cat > conftest.s <<EOF
 563 .text
 564 ${ac_globl} foo
 565 foo:
 566 EOF
 567   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 568     libc_cv_asm_global_directive=${ac_globl}
 569   fi
 570   rm -f conftest*
 571   test $libc_cv_asm_global_directive != UNKNOWN && break
 572 done])
 573 if test $libc_cv_asm_global_directive = UNKNOWN; then
 574   AC_MSG_ERROR(cannot determine asm global directive)
 575 else
 576   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 577 fi
 578
 579 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 580 cat > conftest.s <<EOF
 581 .text
 582 foo:
 583 .set glibc_conftest_frobozz,foo
 584 $libc_cv_asm_global_directive glibc_conftest_frobozz
 585 EOF
 586 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 587 # (but it doesn't work), so we must do a linking check to be sure.
 588 cat > conftest1.c <<\EOF
 589 extern int glibc_conftest_frobozz;
 590 main () { printf ("%d\n", glibc_conftest_frobozz); }
 591 EOF
 592 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 593             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 594   libc_cv_asm_set_directive=yes
 595 else
 596   libc_cv_asm_set_directive=no
 597 fi
 598 rm -f conftest*])
 599 if test $libc_cv_asm_set_directive = yes; then
 600   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 601 fi
 602
 603 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 604 [cat > conftest.s <<EOF
 605 .text
 606 _sym:
 607 .symver _sym,sym@VERS
 608 EOF
 609 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 610   libc_cv_asm_symver_directive=yes
 611 else
 612   libc_cv_asm_symver_directive=no
 613 fi
 614 rm -f conftest*])
 615 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 616 if test $libc_cv_asm_symver_directive = yes; then
 617   cat > conftest.s <<EOF
 618 .text
 619 _sym:
 620 .symver _sym,sym@VERS
 621 EOF
 622   cat > conftest.map <<EOF
 623 VERS_1 {
 624         global: sym;
 625 };
 626
 627 VERS_2 {
 628         global: sym;
 629 } VERS_1;
 630 EOF
 631   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 632     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 633                                         -nostartfiles -nostdlib
 634                                         -Wl,--version-script,conftest.map
 635                        1>&AC_FD_CC]);
 636     then
 637       libc_cv_ld_version_script_option=yes
 638     else
 639       libc_cv_ld_version_script_option=no
 640     fi
 641   else
 642     libc_cv_ld_version_script_option=no
 643   fi
 644 else
 645   libc_cv_ld_version_script_option=no
 646 fi
 647 rm -f conftest*])
 648 if test $libc_cv_asm_symver_directive = yes &&
 649    test $libc_cv_ld_version_script_option = yes &&
 650    test $enable_versioning = yes; then
 651   VERSIONING=yes
 652   AC_DEFINE(DO_VERSIONING)
 653 else
 654   VERSIONING=no
 655 fi
 656 AC_SUBST(VERSIONING)
 657
 658 if test $VERSIONING = no; then
 659   echo "\
 660 *** WARNING: You should not compile GNU libc without versioning. Not using
 661 *** versioning will introduce incompatibilities so that old binaries
 662 *** will not run anymore.
 663 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
 664 fi
 665 if test $elf = yes; then
 666   AC_CACHE_CHECK(for .previous assembler directive,
 667                  libc_cv_asm_previous_directive, [dnl
 668   cat > conftest.s <<EOF
 669 .section foo_section
 670 .previous
 671 EOF
 672   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 673     libc_cv_asm_previous_directive=yes
 674   else
 675     libc_cv_asm_previous_directive=no
 676   fi
 677   rm -f conftest*])
 678   if test $libc_cv_asm_previous_directive = yes; then
 679     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 680   else
 681     AC_CACHE_CHECK(for .popsection assembler directive,
 682                    libc_cv_asm_popsection_directive, [dnl
 683     cat > conftest.s <<EOF
 684 .pushsection foo_section
 685 .popsection
 686 EOF
 687     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 688       libc_cv_asm_popsection_directive=yes
 689     else
 690       libc_cv_asm_popsection_directive=no
 691     fi
 692     rm -f conftest*])
 693     if test $libc_cv_asm_popsection_directive = yes; then
 694       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 695     fi
 696   fi
 697 fi
 698
 699 if test $elf != yes; then
 700   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 701                  [AC_TRY_COMPILE(, [asm (".section .init");
 702                                     asm (".section .fini");
 703                                     asm (".text");],
 704                                  libc_cv_have_initfini=yes,
 705                                  libc_cv_have_initfini=no)])
 706   AC_SUBST(libc_cv_have_initfini)dnl
 707   if test $libc_cv_have_initfini = yes; then
 708     AC_DEFINE(HAVE_INITFINI)
 709   fi
 710 fi
 711
 712 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 713 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 714 [cat > conftest.$ac_ext <<EOF
 715 dnl This sometimes fails to find confdefs.h, for some reason.
 716 dnl [#]line __oline__ "[$]0"
 717 [#]line __oline__ "configure"
 718 #include "confdefs.h"
 719 void underscore_test(void) {
 720 return; }
 721 EOF
 722 if AC_TRY_EVAL(ac_compile); then
 723   if grep _underscore_test conftest* >/dev/null; then
 724     ifelse([$1], , :, [rm -f conftest*
 725     $1])
 726   else
 727     ifelse([$2], , , [rm -f conftest*
 728     $2])
 729   fi
 730 else
 731   echo "configure: failed program was:" >&AC_FD_CC
 732   cat conftest.$ac_ext >&AC_FD_CC
 733   ifelse([$2], , , [rm -f conftest*
 734   $2])
 735 fi
 736 rm -f conftest*])
 737
 738 if test $elf = yes; then
 739   libc_cv_asm_underscores=no
 740 else
 741   if test $ac_cv_prog_cc_works = yes; then
 742     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 743                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 744                                 libc_cv_asm_underscores=yes,
 745                                 libc_cv_asm_underscores=no)])
 746   else
 747     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 748                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 749                                             libc_cv_asm_underscores=no)])
 750   fi
 751 fi
 752 if test $libc_cv_asm_underscores = no; then
 753   AC_DEFINE(NO_UNDERSCORES)
 754 fi
 755
 756 if test $elf = yes; then
 757   libc_cv_weak_symbols=yes
 758   libc_cv_asm_weak_directive=yes
 759   libc_cv_asm_weakext_directive=no
 760 else
 761   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 762                  [dnl
 763 cat > conftest.s <<EOF
 764 .text
 765 ${libc_cv_asm_global_directive} foo
 766 foo:
 767 .weak foo
 768 .weak bar; bar = foo
 769 EOF
 770   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 771     libc_cv_asm_weak_directive=yes
 772   else
 773     libc_cv_asm_weak_directive=no
 774   fi
 775   rm -f conftest*])
 776
 777 if test $libc_cv_asm_weak_directive = no; then
 778   AC_CACHE_CHECK(for assembler .weakext directive,
 779                  libc_cv_asm_weakext_directive,
 780                  [dnl
 781 cat > conftest.s <<EOF
 782 .text
 783 ${libc_cv_asm_global_directive} foo
 784 foo:
 785 .weakext foo
 786 .weakext foo, bar
 787 EOF
 788   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 789     libc_cv_asm_weakext_directive=yes
 790   else
 791     libc_cv_asm_weakext_directive=no
 792   fi
 793   rm -f conftest*])
 794
 795   fi # no .weak
 796 fi # not ELF
 797
 798 if test $libc_cv_asm_weak_directive = yes; then
 799   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 800 elif test $libc_cv_asm_weakext_directive = yes; then
 801   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 802 fi
 803
 804 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 805 cat > conftest.c <<\EOF
 806 _start () {}
 807 int __eh_pc;
 808 __throw () {}
 809 EOF
 810 dnl No \ in command here because it ends up inside ''.
 811 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 812                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 813                             -o conftest conftest.c 1>&AC_FD_CC]); then
 814   libc_cv_ld_no_whole_archive=yes
 815 else
 816   libc_cv_ld_no_whole_archive=no
 817 fi
 818 rm -f conftest*])
 819 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 820
 821 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 822 cat > conftest.c <<\EOF
 823 _start () {}
 824 int __eh_pc;
 825 __throw () {}
 826 EOF
 827 dnl No \ in command here because it ends up inside ''.
 828 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 829                             -nostdlib -nostartfiles -fno-exceptions
 830                             -o conftest conftest.c 1>&AC_FD_CC]); then
 831   libc_cv_gcc_no_exceptions=yes
 832 else
 833   libc_cv_gcc_no_exceptions=no
 834 fi
 835 rm -f conftest*])
 836 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 837
 838 if test "$base_machine" = alpha ; then
 839 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 840 cat > conftest.c <<\EOF
 841 foo () { }
 842 EOF
 843 dnl
 844 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 845 then
 846   libc_cv_gcc_alpha_ng_prefix=yes
 847 else
 848   libc_cv_gcc_alpha_ng_prefix=no
 849 fi
 850 rm -f conftest* ])
 851 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 852   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 853 else
 854   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 855 fi
 856 fi
 857
 858 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 859 [cat > conftest.c <<EOF
 860 #line __oline__ "configure"
 861 static char __EH_FRAME_BEGIN__[];
 862 _start ()
 863 {
 864 #ifdef CHECK__register_frame
 865   __register_frame (__EH_FRAME_BEGIN__);
 866   __deregister_frame (__EH_FRAME_BEGIN__);
 867 #endif
 868 #ifdef CHECK__register_frame_info
 869   __register_frame_info (__EH_FRAME_BEGIN__);
 870   __deregister_frame_info (__EH_FRAME_BEGIN__);
 871 #endif
 872 }
 873 int __eh_pc;
 874 __throw () {}
 875 /* FIXME: this is fragile.  */
 876 malloc () {}
 877 strcmp () {}
 878 strlen () {}
 879 memcpy () {}
 880 memset () {}
 881 free () {}
 882 abort () {}
 883 __bzero () {}
 884 EOF
 885 dnl No \ in command here because it ends up inside ''.
 886 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
 887                             -nostdlib -nostartfiles
 888                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 889   libc_cv_gcc_dwarf2_unwind_info=static
 890 else
 891   libc_cv_gcc_dwarf2_unwind_info=no
 892 fi
 893 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
 894   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
 895                               -nostdlib -nostartfiles
 896                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 897     libc_cv_gcc_dwarf2_unwind_info=yes
 898   else
 899     libc_cv_gcc_dwarf2_unwind_info=no
 900   fi
 901 fi
 902 rm -f conftest*])
 903 case $libc_cv_gcc_dwarf2_unwind_info in
 904 yes)
 905   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
 906   ;;
 907 static)
 908   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
 909   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
 910   ;;
 911 esac
 912
 913 ### End of automated tests.
 914 ### Now run sysdeps configure fragments.
 915
 916 # sysdeps configure fragments may set these with files to be linked below.
 917 libc_link_dests=
 918 libc_link_sources=
 919
 920 # Iterate over all the sysdep directories we will use, running their
 921 # configure fragments, and looking for a uname implementation.
 922 uname=
 923 for dir in $sysnames; do
 924   case $dir in
 925     /*) dest=$dir ;;
 926     *)  dest=$srcdir/$dir ;;
 927   esac
 928   if test -r $dest/configure; then
 929     AC_MSG_RESULT(running configure fragment for $dest)
 930     . $dest/configure
 931   fi
 932 [
 933   if test -z "$uname"; then
 934     if test -r $dest/uname.c ||
 935        test -r $dest/uname.S ||
 936        { test -r $dest/syscalls.list &&
 937          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
 938       uname=$dir
 939     fi
 940   fi
 941 ]dnl
 942 done
 943
 944 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 945
 946 # If we will use the generic uname implementation, we must figure out what
 947 # it will say by examining the system, and write the results in config-name.h.
 948 if test "$uname" = "sysdeps/generic"; then
 949
 950 changequote(,)dnl
 951   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 952 changequote([,])dnl
 953   if test $uname_sysname != $config_os; then
 954     config_release=`echo $config_os | sed s/$uname_sysname//`
 955   fi
 956 dnl
 957 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 958     if test -r /vmunix; then
 959       kernel_id=`strings /vmunix | grep UNIX`
 960     elif test -r /dynix; then
 961       kernel_id=`strings /dynix | grep DYNIX`
 962     else
 963       kernel_id=
 964     fi
 965 ])dnl
 966
 967   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 968 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 969 changequote(,)dnl
 970   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 971 changequote([,])dnl
 972   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 973          != x$config_release; then
 974     # The configuration release is a substring of the kernel release.
 975     libc_cv_uname_release=$kernel_release
 976   elif test x$config_release != x; then
 977     libc_cv_uname_release=$config_release
 978   elif test x$kernel_release != x; then
 979     libc_cv_uname_release=$kernel_release
 980   else
 981     libc_cv_uname_release=unknown
 982   fi])
 983   uname_release="$libc_cv_uname_release"
 984
 985   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 986 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 987 changequote(,)dnl
 988   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 989 changequote([,])dnl
 990   if test -n "$kernel_version"; then
 991     libc_cv_uname_version="$kernel_version"
 992   else
 993     libc_cv_uname_version=unknown
 994   fi])
 995   uname_version="$libc_cv_uname_version"
 996
 997 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 998   config_uname=config-name.h:config-name.in
 999 else
1000   # For non-generic uname, we don't need to create config-name.h at all.
1001   config_uname=
1002 fi
1003
1004 AC_MSG_CHECKING(stdio selection)
1005 AC_SUBST(stdio)
1006 case $stdio in
1007 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1008 default) stdio=stdio ;;
1009 esac
1010 AC_MSG_RESULT($stdio)
1011
1012 AC_MSG_CHECKING(ldap selection)
1013 AC_SUBST(LDAP)
1014 case $add_ons in
1015 *ldap*)
1016    ldap=yes
1017    LDAP=ldap ;;
1018 *) ldap=no
1019    LDAP= ;;
1020 esac
1021 AC_MSG_RESULT($ldap)
1022
1023 AC_SUBST(libc_cv_slibdir)
1024 AC_SUBST(libc_cv_sysconfdir)
1025 AC_SUBST(libc_cv_rootsbindir)
1026
1027 AC_SUBST(has_ldconfig)
1028
1029 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1030 if test $gnu_ld = yes; then
1031   AC_DEFINE(HAVE_GNU_LD)
1032 fi
1033 if test $gnu_as = yes; then
1034   AC_DEFINE(HAVE_GNU_AS)
1035 fi
1036 if test $elf = yes; then
1037   AC_DEFINE(HAVE_ELF)
1038 fi
1039
1040 AC_SUBST(static)
1041 AC_SUBST(shared)
1042 if test $shared = default; then
1043   if test $gnu_ld = yes; then
1044     shared=$elf
1045   else
1046     # For now we do not assume shared libs are available.  In future more
1047     # tests might become available.
1048     shared=no
1049   fi
1050 fi
1051
1052 dnl We must not allow compilation without static library on some platforms.
1053 if test $static = no && test $shared = yes; then
1054   case "$host_os" in
1055   linux* | gnu*)
1056     AC_MSG_ERROR([
1057 *** You must compile with support for the static library since the shared
1058 *** library uses it.  Restart configure without \`--disable-static'.])
1059     ;;
1060   *)
1061     ;;
1062   esac
1063 fi
1064
1065 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1066 [pic_default=yes
1067 cat > conftest.c <<EOF
1068 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1069 # error PIC is default.
1070 #endif
1071 EOF
1072 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1073   pic_default=no
1074 fi
1075 rm -f conftest.*])
1076 AC_SUBST(pic_default)
1077
1078 AC_SUBST(profile)
1079 AC_SUBST(omitfp)
1080 AC_SUBST(bounded)
1081 AC_SUBST(static_nss)
1082 AC_SUBST(nopic_initfini)
1083
1084 AC_SUBST(DEFINES)
1085
1086 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1087   config_makefile=
1088 else
1089   config_makefile=Makefile
1090 fi
1091
1092 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1093 AC_SUBST(VERSION)
1094
1095 if test $libc_cv_gcc_pipe_bug = yes; then
1096  realCC=$CC
1097  CC=$makeCC
1098  CFLAGS=$makeCFLAGS
1099 fi
1100 AC_OUTPUT_COMMANDS([
1101 if test "$realCC"; then
1102  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
1103  mv specsT specs
1104 fi], [realCC=$realCC])
1105
1106 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1107           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])