sysdeps/riscv/configure.ac

   1 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
   2 # Local configure fragment for sysdeps/riscv/elf.
   3
   4 # Check if static linker supports R_RISCV_ALIGN
   5 AC_CACHE_CHECK([for R_RISCV_ALIGN linker relaxation support], [libc_cv_riscv_r_align],[dnl
   6   cat > conftest.S <<EOF
   7 .align 3
   8 foo:
   9   li a0,42
  10   ret
  11 EOF
  12   libc_cv_riscv_r_align=no
  13   if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostdlib -nostartfiles $no_ssp -shared -fPIC -o contests.o conftest.S])
  14   then
  15     libc_cv_riscv_r_align=yes
  16   fi
  17   rm -rf conftest.*])
  18 LIBC_CONFIG_VAR([riscv-r-align], [$libc_cv_riscv_r_align])
  19
  20 dnl Test if the toolchain is new enough for static PIE.
  21 AC_CACHE_CHECK([if the toolchain is sufficient to build static PIE on RISC-V],
  22 libc_cv_static_pie_on_riscv, [
  23   cat > conftest1.S <<\EOF
  24     .globl _start
  25     .type   _start, @function
  26 _start:
  27     nop
  28
  29     .data
  30     /* This should produce an R_RISCV_RELATIVE in the static PIE.  */
  31     .dword      _start
  32 EOF
  33
  34   libc_cv_static_pie_on_riscv=no
  35   if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static-pie -nostdlib -fPIE -o conftest1 conftest1.S]) \
  36      && AC_TRY_COMMAND([LC_ALL=C $READELF -Wr conftest1 | grep -q R_RISCV_RELATIVE]) \
  37      && ! AC_TRY_COMMAND([LC_ALL=C $READELF -Wl conftest1 | grep -q INTERP])
  38   then
  39     libc_cv_static_pie_on_riscv=yes
  40   fi
  41   rm -rf conftest* ])
  42
  43 if test "$libc_cv_static_pie_on_riscv" = yes; then
  44   AC_DEFINE(SUPPORT_STATIC_PIE)
  45 fi