sysdeps/mach/hurd/configure.ac

   1 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
   2
   3 dnl We need this setting because of the need for PLT calls in ld.so.
   4 dnl See Roland's comment in
   5 dnl https://sourceware.org/bugzilla/show_bug.cgi?id=15605
   6 AC_DEFINE([NO_RTLD_HIDDEN])
   7
   8 if test -n "$sysheaders"; then
   9   OLD_CPPFLAGS=$CPPFLAGS
  10   CPPFLAGS="$CPPFLAGS $SYSINCLUDES"
  11 fi
  12
  13 AC_CACHE_CHECK(Hurd header version, libc_cv_hurd_version, [dnl
  14 AC_PREPROC_IFELSE([AC_LANG_PROGRAM(dnl
  15 [[#include <hurd/version.h>]], [[
  16 #define NEED_VERSION 20020609
  17 #if HURD_INTERFACE_VERSION < NEED_VERSION
  18 # error Hurd version too old: HURD_INTERFACE_VERSION < NEED_VERSION
  19 #endif]])],
  20                [libc_cv_hurd_version=ok],
  21                [libc_cv_hurd_version=bad])])
  22 if test "x$libc_cv_hurd_version" != xok; then
  23   AC_MSG_ERROR(Hurd headers not installed or too old)
  24 fi
  25
  26 dnl
  27 dnl hurd_RPC_CHECK(interface.defs, rpc_method, define)
  28 dnl
  29 dnl Check if rpc_method RPC is defined by interface.defs
  30 dnl and define `define`.
  31 dnl
  32 AC_DEFUN([hurd_RPC_CHECK], [dnl
  33 AC_CACHE_CHECK(for $2 in $1, libc_cv_hurd_rpc_$2, [dnl
  34 AC_EGREP_HEADER($2, hurd/$1,
  35                 libc_cv_hurd_rpc_$2=yes,
  36                 libc_cv_hurd_rpc_$2=no)])
  37 if test $libc_cv_hurd_rpc_$2 = yes; then
  38   AC_DEFINE([$3])
  39 fi
  40 ])
  41
  42 hurd_RPC_CHECK(process.defs, proc_getchildren_rusage,
  43                HAVE_HURD_PROC_GETCHILDREN_RUSAGE)
  44
  45 if test -n "$sysheaders"; then
  46   CPPFLAGS=$OLD_CPPFLAGS
  47 fi
  48
  49 # Hurd has libpthread as a separate library.
  50 pthread_in_libc=no