sysdeps/libm-i387/s_frexp.S

   1 /* ix87 specific frexp implementation for double.
   2    Copyright (C) 1997 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Library General Public License as
   8    published by the Free Software Foundation; either version 2 of the
   9    License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Library General Public License for more details.
  15
  16    You should have received a copy of the GNU Library General Public
  17    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  18    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  19    Boston, MA 02111-1307, USA.  */
  20
  21 #include <machine/asm.h>
  22
  23 #ifdef __ELF__
  24         .section .rodata
  25 #else
  26         .text
  27 #endif
  28
  29         .align ALIGNARG(4)
  30         ASM_TYPE_DIRECTIVE(two54,@object)
  31 two54:  .byte 0, 0, 0, 0, 0, 0, 0x50, 0x43
  32         ASM_SIZE_DIRECTIVE(two54)
  33
  34 #ifdef PIC
  35 #define MO(op) op##@GOTOFF(%edx)
  36 #else
  37 #define MO(op) op
  38 #endif
  39
  40         .text
  41 ENTRY(__frexp)
  42         movl    4(%esp), %ecx
  43         movl    8(%esp), %eax
  44         movl    %eax, %edx
  45         andl    $0x7fffffff, %eax
  46         orl     %eax, %ecx
  47         jz      1f
  48         xorl    %ecx, %ecx
  49         cmpl    $0x7ff00000, %eax
  50         jae     1f
  51
  52         cmpl    $0x00100000, %eax
  53         jae     2f
  54
  55         fldl    4(%esp)
  56 #ifdef  PIC
  57         call    3f
  58 3:      popl    %edx
  59         addl    $_GLOBAL_OFFSET_TABLE_+[.-3b], %edx
  60 #endif
  61         fmull   MO(two54)
  62         movl    $-54, %ecx
  63         fstpl   4(%esp)
  64         movl    8(%esp), %eax
  65         movl    %eax, %edx
  66         andl    $0x7fffffff, %eax
  67
  68 2:      shrl    $20, %eax
  69         andl    $0x800fffff, %edx
  70         subl    $1022, %eax
  71         orl     $0x3fe00000, %edx
  72         addl    %eax, %ecx
  73         movl    %edx, 8(%esp)
  74
  75         /* Store %ecx in the variable pointed to by the second argument,
  76            get the factor from the stack and return.  */
  77 1:      movl    12(%esp), %eax
  78         fldl    4(%esp)
  79         movl    %ecx, (%eax)
  80         ret
  81 END(__frexp)
  82 weak_alias (__frexp, frexp)