sysdeps/gnu/errlist.awk

   1 # Copyright (C) 1991, 92, 93, 94, 95, 96, 97, 98 Free Software Foundation, Inc.
   2 # This file is part of the GNU C Library.
   3
   4 # The GNU C Library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Library General Public License
   6 # as published by the Free Software Foundation; either version 2 of
   7 # the License, or (at your option) any later version.
   8
   9 # The GNU C Library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Library General Public License for more details.
  13
  14 # You should have received a copy of the GNU Library General Public
  15 # License along with the GNU C Library; see the file COPYING.LIB.  If not,
  16 # write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  17 # Boston, MA 02111-1307, USA.
  18
  19 # errno.texi contains lines like:
  20 # @comment errno.h
  21 # @comment POSIX.1: Function not implemented
  22 # @deftypevr Macro int ENOSYS
  23 # @comment errno 78
  24 # Descriptive paragraph...
  25 # @end deftypevr
  26
  27 BEGIN {
  28     alias["EWOULDBLOCK"] = "EAGAIN";
  29     alias["EDEADLOCK"] = "EDEADLK";
  30
  31     print "/* This file is generated from errno.texi by errlist.awk.  */"
  32     print "";
  33     print "#include <errno.h>";
  34     print "";
  35     print "#ifndef SYS_ERRLIST";
  36     print "# define SYS_ERRLIST _sys_errlist";
  37     print "# define SYS_ERRLIST_ALIAS sys_errlist";
  38     print "#endif";
  39     print "#ifndef SYS_NERR";
  40     print "# define SYS_NERR _sys_nerr";
  41     print "# define SYS_NERR_ALIAS sys_nerr";
  42     print "#endif";
  43     print "#ifndef ERR_REMAP";
  44     print "# define ERR_REMAP(n) n";
  45     print "#endif";
  46     print "";
  47     print "const char *const SYS_ERRLIST[] =";
  48     print "  {";
  49     print "    [0] = N_(\"Success\"),"
  50   }
  51 $1 == "@comment" && $2 == "errno.h" { errnoh=1; next }
  52 errnoh == 1 && $1 == "@comment" \
  53   {
  54     ++errnoh;
  55     etext = $3;
  56     for (i = 4; i <= NF; ++i)
  57       etext = etext " " $i;
  58     next;
  59   }
  60 errnoh == 2 && $1 == "@deftypevr" && $2 == "Macro" && $3 == "int" \
  61   {
  62     e = $4; errnoh++; next;
  63   }
  64 errnoh == 3 && $1 == "@comment" && $2 == "errno" \
  65   {
  66     errno = $3 + 0;
  67     if (alias[e])
  68       printf "#if defined (%s) && %s != %s\n", e, e, alias[e];
  69     else
  70       printf "#ifdef %s\n", e;
  71     errnoh = 4;
  72     desc="";
  73     next;
  74   }
  75 errnoh == 4 && $1 == "@end" && $2 == "deftypevr" \
  76   {
  77     printf "/*%s */\n", desc;
  78     printf "    [ERR_REMAP (%s)] = N_(\"%s\"),\n", e, etext;
  79     print "#endif";
  80     errnoh = 0;
  81     next;
  82   }
  83 errnoh == 4 \
  84   {
  85     # This magic tag in C comments gets them copied into libc.pot.
  86     desc = desc "\nTRANS " $0; next
  87   }
  88 { errnoh=0 }
  89 END {
  90   print "  };";
  91   print "";
  92   print "const int SYS_NERR = sizeof SYS_ERRLIST / sizeof SYS_ERRLIST [0];";
  93   print "#ifdef SYS_ERRLIST_ALIAS";
  94   print "weak_alias (_sys_errlist, SYS_ERRLIST_ALIAS)";
  95   print "#endif";
  96   print "#ifdef SYS_NERR_ALIAS";
  97   print "weak_alias (_sys_nerr, SYS_NERR_ALIAS)";
  98   print "#endif";
  99   }