sysdeps/powerpc/powerpc32/lshift.S

   1 /* Shift a limb left, low level routine.
   2    Copyright (C) 1996, 1997, 1999, 2000, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <bp-sym.h>
  21 #include <bp-asm.h>
  22
  23 /* mp_limb_t mpn_lshift (mp_ptr wp, mp_srcptr up, mp_size_t usize,
  24                          unsigned int cnt)  */
  25
  26 EALIGN (BP_SYM (__mpn_lshift), 3, 0)
  27
  28 #if __BOUNDED_POINTERS__
  29         slwi r10,r5,2           /* convert limbs to bytes */
  30         CHECK_BOUNDS_BOTH_WIDE (r3, r8, r9, r10)
  31         CHECK_BOUNDS_BOTH_WIDE (r4, r8, r9, r10)
  32 #endif
  33         mtctr   r5              # copy size into CTR
  34         cmplwi  cr0,r5,16       # is size < 16
  35         slwi    r0,r5,2
  36         add     r7,r3,r0        # make r7 point at end of res
  37         add     r4,r4,r0        # make r4 point at end of s1
  38         lwzu    r11,-4(r4)      # load first s1 limb
  39         subfic  r8,r6,32
  40         srw     r3,r11,r8       # compute function return value
  41         bge     cr0,L(big)      # branch if size >= 16
  42
  43         bdz     L(end1)
  44
  45 L(0):   lwzu    r10,-4(r4)
  46         slw     r9,r11,r6
  47         srw     r12,r10,r8
  48         or      r9,r9,r12
  49         stwu    r9,-4(r7)
  50         bdz     L(end2)
  51         lwzu    r11,-4(r4)
  52         slw     r9,r10,r6
  53         srw     r12,r11,r8
  54         or      r9,r9,r12
  55         stwu    r9,-4(r7)
  56         bdnz    L(0)
  57
  58 L(end1):slw     r0,r11,r6
  59         stw     r0,-4(r7)
  60         blr
  61
  62
  63 /* Guaranteed not to succeed.  */
  64 L(boom): tweq    r0,r0
  65
  66 /* We imitate a case statement, by using (yuk!) fixed-length code chunks,
  67    of size 4*12 bytes.  We have to do this (or something) to make this PIC.  */
  68 L(big): mflr    r9
  69         cfi_register(lr,r9)
  70         bltl-   cr0,L(boom)     # Never taken, only used to set LR.
  71         slwi    r10,r6,4
  72         mflr    r12
  73         add     r10,r12,r10
  74         slwi    r8,r6,5
  75         add     r10,r8,r10
  76         mtctr   r10
  77         addi    r5,r5,-1
  78         mtlr    r9
  79         cfi_same_value (lr)
  80         bctr
  81
  82 L(end2):slw     r0,r10,r6
  83         stw     r0,-4(r7)
  84         blr
  85
  86 #define DO_LSHIFT(n) \
  87         mtctr   r5;                                                     \
  88 L(n):   lwzu    r10,-4(r4);                                             \
  89         slwi    r9,r11,n;                                               \
  90         inslwi  r9,r10,n,32-n;                                  \
  91         stwu    r9,-4(r7);                                              \
  92         bdz-    L(end2);                                                \
  93         lwzu    r11,-4(r4);                                             \
  94         slwi    r9,r10,n;                                               \
  95         inslwi  r9,r11,n,32-n;                                  \
  96         stwu    r9,-4(r7);                                              \
  97         bdnz    L(n);                                                   \
  98         b       L(end1)
  99
 100         DO_LSHIFT(1)
 101         DO_LSHIFT(2)
 102         DO_LSHIFT(3)
 103         DO_LSHIFT(4)
 104         DO_LSHIFT(5)
 105         DO_LSHIFT(6)
 106         DO_LSHIFT(7)
 107         DO_LSHIFT(8)
 108         DO_LSHIFT(9)
 109         DO_LSHIFT(10)
 110         DO_LSHIFT(11)
 111         DO_LSHIFT(12)
 112         DO_LSHIFT(13)
 113         DO_LSHIFT(14)
 114         DO_LSHIFT(15)
 115         DO_LSHIFT(16)
 116         DO_LSHIFT(17)
 117         DO_LSHIFT(18)
 118         DO_LSHIFT(19)
 119         DO_LSHIFT(20)
 120         DO_LSHIFT(21)
 121         DO_LSHIFT(22)
 122         DO_LSHIFT(23)
 123         DO_LSHIFT(24)
 124         DO_LSHIFT(25)
 125         DO_LSHIFT(26)
 126         DO_LSHIFT(27)
 127         DO_LSHIFT(28)
 128         DO_LSHIFT(29)
 129         DO_LSHIFT(30)
 130         DO_LSHIFT(31)
 131
 132 END (BP_SYM (__mpn_lshift))