sysdeps/unix/sysv/linux/i386/vfork.S

   1 /* Copyright (C) 1999-2023 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, see
  16    <https://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep.h>
  19 #define _ERRNO_H        1
  20 #include <bits/errno.h>
  21 #include <tcb-offsets.h>
  22
  23 /* Clone the calling process, but without copying the whole address space.
  24    The calling process is suspended until the new process exits or is
  25    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  26    and the process ID of the new process to the old process.  */
  27
  28 ENTRY (__vfork)
  29
  30         /* Pop the return PC value into ECX.  */
  31         popl    %ecx
  32         cfi_adjust_cfa_offset (-4)
  33         cfi_register (%eip, %ecx)
  34
  35         /* Stuff the syscall number in EAX and enter into the kernel.  */
  36         movl    $SYS_ify (vfork), %eax
  37         int     $0x80
  38
  39         /* Jump to the return PC.  Don't jump directly since this
  40            disturbs the branch target cache.  Instead push the return
  41            address back on the stack.  */
  42         pushl   %ecx
  43         cfi_adjust_cfa_offset (4)
  44
  45         cmpl    $-4095, %eax
  46         /* Branch forward if it failed.  */
  47         jae     SYSCALL_ERROR_LABEL
  48
  49 #if SHSTK_ENABLED
  50         /* Check if shadow stack is in use.  */
  51         xorl    %edx, %edx
  52         rdsspd  %edx
  53         testl   %edx, %edx
  54         /* Normal return if shadow stack isn't in use.  */
  55         je      L(no_shstk)
  56
  57         testl   %eax, %eax
  58         /* In parent, normal return.  */
  59         jnz     L(no_shstk)
  60
  61         /* NB: In child, jump back to caller via indirect branch without
  62            popping shadow stack which is shared with parent.  Keep shadow
  63            stack mismatched so that child returns in the vfork-calling
  64            function will trigger SIGSEGV.  */
  65         popl    %ecx
  66         cfi_adjust_cfa_offset (-4)
  67         jmp     *%ecx
  68
  69 L(no_shstk):
  70 #endif
  71
  72         ret
  73
  74 PSEUDO_END (__vfork)
  75 libc_hidden_def (__vfork)
  76
  77 weak_alias (__vfork, vfork)
  78 strong_alias (__vfork, __libc_vfork)