sysdeps/unix/sysv/linux/arm/vfork.S

   1 /* Copyright (C) 1999-2016 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Philip Blundell <philb@gnu.org>.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H        1
  21 #include <bits/errno.h>
  22 #include <tcb-offsets.h>
  23
  24
  25 /* Clone the calling process, but without copying the whole address space.
  26    The calling process is suspended until the new process exits or is
  27    replaced by a call to `execve'.  Return -1 for errors, 0 to the new process,
  28    and the process ID of the new process to the old process.  */
  29
  30 ENTRY (__vfork)
  31         /* Save the PID value.  */
  32         GET_TLS (r2)
  33         NEGOFF_ADJ_BASE2 (r2, r0, PID_OFFSET) /* Save the TLS addr in r2.  */
  34         ldr     r3, NEGOFF_OFF1 (r2, PID_OFFSET) /* Load the saved PID.  */
  35         rsbs    r0, r3, #0              /* Negate it, and test for zero.  */
  36         /* Use 0x80000000 if it was 0.  See raise.c for how this is used.  */
  37         it      eq
  38         moveq   r0, #0x80000000
  39         str     r0, NEGOFF_OFF1 (r2, PID_OFFSET) /* Store the temp PID.  */
  40
  41         /* The DO_CALL macro saves r7 on the stack, to enable generation
  42            of ARM unwind info.  Since the stack is initially shared between
  43            parent and child of vfork, that saved value could be corrupted.
  44            To avoid this problem, we save r7 into ip as well, and restore
  45            from there.  */
  46         mov     ip, r7
  47         cfi_register (r7, ip)
  48         .fnstart
  49         push    { r7 }
  50         cfi_adjust_cfa_offset (4)
  51         .save { r7 }
  52         ldr     r7, =SYS_ify (vfork)
  53         swi     0x0
  54         .fnend
  55         add     sp, sp, #4
  56         cfi_adjust_cfa_offset (-4)
  57         mov     r7, ip
  58         cfi_restore (r7)
  59
  60         /* Restore the old PID value in the parent.  */
  61         cmp     r0, #0          /* If we are the parent... */
  62         it      ne
  63         strne   r3, NEGOFF_OFF1 (r2, PID_OFFSET) /* restore the saved PID.  */
  64
  65         cmn     a1, #4096
  66         it      cc
  67         RETINSTR(cc, lr)
  68
  69         b       PLTJMP(SYSCALL_ERROR)
  70 PSEUDO_END (__vfork)
  71 libc_hidden_def (__vfork)
  72
  73 weak_alias (__vfork, vfork)
  74 strong_alias (__vfork, __libc_vfork)