sysdeps/powerpc/powerpc32/fpu/setjmp-common.S

   1 /* setjmp for PowerPC.
   2    Copyright (C) 1995-2000, 2003-2005, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #ifdef __NO_VMX__
  23 # include <novmxsetjmp.h>
  24 #else
  25 # include <jmpbuf-offsets.h>
  26 #endif
  27 #include <bp-sym.h>
  28 #include <bp-asm.h>
  29
  30         .machine        "altivec"
  31 ENTRY (BP_SYM (__sigsetjmp))
  32         CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
  33
  34 #ifdef PTR_MANGLE
  35         mr   r5,r1
  36         PTR_MANGLE(r5, r6)
  37         stw  r5,(JB_GPR1*4)(3)
  38 #else
  39         stw  r1,(JB_GPR1*4)(3)
  40 #endif
  41         mflr r0
  42         stw  r14,((JB_GPRS+0)*4)(3)
  43         stfd fp14,((JB_FPRS+0*2)*4)(3)
  44 #ifdef PTR_MANGLE
  45         PTR_MANGLE2 (r0, r6)
  46 #endif
  47         stw  r0,(JB_LR*4)(3)
  48         stw  r15,((JB_GPRS+1)*4)(3)
  49         stfd fp15,((JB_FPRS+1*2)*4)(3)
  50         mfcr r0
  51         stw  r16,((JB_GPRS+2)*4)(3)
  52         stfd fp16,((JB_FPRS+2*2)*4)(3)
  53         stw  r0,(JB_CR*4)(3)
  54         stw  r17,((JB_GPRS+3)*4)(3)
  55         stfd fp17,((JB_FPRS+3*2)*4)(3)
  56         stw  r18,((JB_GPRS+4)*4)(3)
  57         stfd fp18,((JB_FPRS+4*2)*4)(3)
  58         stw  r19,((JB_GPRS+5)*4)(3)
  59         stfd fp19,((JB_FPRS+5*2)*4)(3)
  60         stw  r20,((JB_GPRS+6)*4)(3)
  61         stfd fp20,((JB_FPRS+6*2)*4)(3)
  62         stw  r21,((JB_GPRS+7)*4)(3)
  63         stfd fp21,((JB_FPRS+7*2)*4)(3)
  64         stw  r22,((JB_GPRS+8)*4)(3)
  65         stfd fp22,((JB_FPRS+8*2)*4)(3)
  66         stw  r23,((JB_GPRS+9)*4)(3)
  67         stfd fp23,((JB_FPRS+9*2)*4)(3)
  68         stw  r24,((JB_GPRS+10)*4)(3)
  69         stfd fp24,((JB_FPRS+10*2)*4)(3)
  70         stw  r25,((JB_GPRS+11)*4)(3)
  71         stfd fp25,((JB_FPRS+11*2)*4)(3)
  72         stw  r26,((JB_GPRS+12)*4)(3)
  73         stfd fp26,((JB_FPRS+12*2)*4)(3)
  74         stw  r27,((JB_GPRS+13)*4)(3)
  75         stfd fp27,((JB_FPRS+13*2)*4)(3)
  76         stw  r28,((JB_GPRS+14)*4)(3)
  77         stfd fp28,((JB_FPRS+14*2)*4)(3)
  78         stw  r29,((JB_GPRS+15)*4)(3)
  79         stfd fp29,((JB_FPRS+15*2)*4)(3)
  80         stw  r30,((JB_GPRS+16)*4)(3)
  81         stfd fp30,((JB_FPRS+16*2)*4)(3)
  82         stw  r31,((JB_GPRS+17)*4)(3)
  83         stfd fp31,((JB_FPRS+17*2)*4)(3)
  84 #ifndef __NO_VMX__
  85 # ifdef PIC
  86         mflr    r6
  87         cfi_register(lr,r6)
  88         bcl     20,31,1f
  89 1:      mflr    r5
  90         addis   r5,r5,_GLOBAL_OFFSET_TABLE_-1b@ha
  91         addi    r5,r5,_GLOBAL_OFFSET_TABLE_-1b@l
  92         mtlr    r6
  93         cfi_same_value (lr)
  94 #  ifdef SHARED
  95         lwz     r5,_rtld_global_ro@got(r5)
  96         lwz     r5,RTLD_GLOBAL_RO_DL_HWCAP_OFFSET+4(r5)
  97 #  else
  98         lwz     r5,_dl_hwcap@got(r5)
  99         lwz     r5,4(r5)
 100 #  endif
 101 # else
 102         lis     r6,(_dl_hwcap+4)@ha
 103         lwz     r5,(_dl_hwcap+4)@l(r6)
 104 # endif
 105         andis.  r5,r5,(PPC_FEATURE_HAS_ALTIVEC >> 16)
 106         beq     L(no_vmx)
 107         la      r5,((JB_VRS)*4)(3)
 108         andi.   r6,r5,0xf
 109         mfspr   r0,VRSAVE
 110         stw     r0,((JB_VRSAVE)*4)(3)
 111         addi    r6,r5,16
 112         beq+    L(aligned_save_vmx)
 113         lvsr    v0,0,r5
 114         vspltisb v1,-1         /* set v1 to all 1's */
 115         vspltisb v2,0          /* set v2 to all 0's */
 116         vperm   v3,v2,v1,v0   /* v3 contains shift mask with num all 1 bytes on left = misalignment  */
 117
 118
 119         /* Special case for v20 we need to preserve what is in save area below v20 before obliterating it */
 120         lvx     v5,0,r5
 121         vperm   v20,v20,v20,v0
 122         vsel    v5,v5,v20,v3
 123         vsel    v20,v20,v2,v3
 124         stvx    v5,0,r5
 125
 126 #define save_2vmx_partial(savevr,prev_savevr,hivr,shiftvr,maskvr,savegpr,addgpr) \
 127         addi    addgpr,addgpr,32; \
 128         vperm   savevr,savevr,savevr,shiftvr; \
 129         vsel    hivr,prev_savevr,savevr,maskvr; \
 130         stvx    hivr,0,savegpr;
 131
 132         save_2vmx_partial(v21,v20,v5,v0,v3,r6,r5)
 133         save_2vmx_partial(v22,v21,v5,v0,v3,r5,r6)
 134         save_2vmx_partial(v23,v22,v5,v0,v3,r6,r5)
 135         save_2vmx_partial(v24,v23,v5,v0,v3,r5,r6)
 136         save_2vmx_partial(v25,v24,v5,v0,v3,r6,r5)
 137         save_2vmx_partial(v26,v25,v5,v0,v3,r5,r6)
 138         save_2vmx_partial(v27,v26,v5,v0,v3,r6,r5)
 139         save_2vmx_partial(v28,v27,v5,v0,v3,r5,r6)
 140         save_2vmx_partial(v29,v28,v5,v0,v3,r6,r5)
 141         save_2vmx_partial(v30,v29,v5,v0,v3,r5,r6)
 142
 143         /* Special case for r31 we need to preserve what is in save area above v31 before obliterating it */
 144         addi    r5,r5,32
 145         vperm   v31,v31,v31,v0
 146         lvx     v4,0,r5
 147         vsel    v5,v30,v31,v3
 148         stvx    v5,0,r6
 149         vsel    v4,v31,v4,v3
 150         stvx    v4,0,r5
 151         b       L(no_vmx)
 152
 153 L(aligned_save_vmx):
 154         stvx    20,0,r5
 155         addi    r5,r5,32
 156         stvx    21,0,r6
 157         addi    r6,r6,32
 158         stvx    22,0,r5
 159         addi    r5,r5,32
 160         stvx    23,0,r6
 161         addi    r6,r6,32
 162         stvx    24,0,r5
 163         addi    r5,r5,32
 164         stvx    25,0,r6
 165         addi    r6,r6,32
 166         stvx    26,0,r5
 167         addi    r5,r5,32
 168         stvx    27,0,r6
 169         addi    r6,r6,32
 170         stvx    28,0,r5
 171         addi    r5,r5,32
 172         stvx    29,0,r6
 173         addi    r6,r6,32
 174         stvx    30,0,r5
 175         stvx    31,0,r6
 176 L(no_vmx):
 177 #endif
 178         b BP_SYM (__sigjmp_save@local)
 179 END (BP_SYM (__sigsetjmp))