sysdeps/powerpc/powerpc32/fpu/s_floorf.S

   1 /* float Floor function.  PowerPC32 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata.cst4,"aM",@progbits,4
  23         .align  2
  24 .LC0:   /* 2**23 */
  25         .long 0x4b000000
  26
  27         .section        ".text"
  28 ENTRY (__floorf)
  29         mffs    fp11            /* Save current FPU rounding mode.  */
  30 #ifdef SHARED
  31         mflr    r11
  32         cfi_register(lr,r11)
  33         bcl     20,31,1f
  34 1:      mflr    r9
  35         addis   r9,r9,.LC0-1b@ha
  36         lfs     fp13,.LC0-1b@l(r9)
  37         mtlr    r11
  38         cfi_same_value (lr)
  39 #else
  40         lis     r9,.LC0@ha
  41         lfs     fp13,.LC0@l(r9)
  42 #endif
  43         fabs    fp0,fp1
  44         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  45         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  46         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  47         bnllr-  cr7
  48         mtfsfi  7,3             /* Set rounding mode toward -inf.  */
  49         ble-    cr6,.L4
  50         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  51         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  52         fabs    fp1,fp1         /* if (x == 0.0)  */
  53                                 /* x = 0.0; */
  54         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  55         blr
  56 .L4:
  57         bge-    cr6,.L9         /* if (x < 0.0)  */
  58         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  59         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  60         fnabs   fp1,fp1         /* if (x == 0.0)  */
  61                                 /* x = -0.0; */
  62 .L9:
  63         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  64         blr
  65         END (__floorf)
  66
  67 weak_alias (__floorf, floorf)
  68