sysdeps/unix/sysv/linux/m68k/clone.S

   1 /* Copyright (C) 1996,97,98,2002,2010 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Andreas Schwab (schwab@issan.informatik.uni-dortmund.de)
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 /* clone() is even more special than fork() as it mucks with stacks
  21    and invokes a function in the right context after its all over.  */
  22
  23 #include <sysdep.h>
  24 #define _ERRNO_H        1
  25 #include <bits/errno.h>
  26 #ifdef RESET_PID
  27 #include <tls.h>
  28 #endif
  29
  30 #define CLONE_VM      0x00000100
  31 #define CLONE_THREAD  0x00010000
  32
  33 /* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
  34              void *parent_tidptr, void *tls, void *child_tidptr) */
  35
  36         .text
  37 ENTRY (__clone)
  38
  39         /* Sanity check arguments.  */
  40         movel   #-EINVAL, %d0
  41         movel   4(%sp), %a0             /* no NULL function pointers */
  42         tstl    %a0
  43         jeq     SYSCALL_ERROR_LABEL
  44         movel   8(%sp), %a1             /* no NULL stack pointers */
  45         tstl    %a1
  46         jeq     SYSCALL_ERROR_LABEL
  47
  48         /* Allocate space and copy the argument onto the new stack.  */
  49         movel   16(%sp), -(%a1)
  50
  51         /* Do the system call */
  52         movel   12+0(%sp), %d1          /* get flags */
  53         movel   %d3, -(%a1)             /* save %d3 and get parent_tidptr */
  54         movel   %d3, -(%sp)
  55         movel   20+4(%sp), %d3
  56         movel   %d4, -(%a1)             /* save %d4 and get child_tidptr */
  57         movel   %d4, -(%sp)
  58         movel   28+8(%sp), %d4
  59         movel   %d5, -(%a1)             /* save %d5 and get tls */
  60         movel   %d5, -(%sp)
  61         movel   24+12(%sp), %d5
  62         /* save %d2 and get stack pointer */
  63 #ifdef __mcoldfire__
  64         movel   %d2, -(%a1)
  65         movel   %d2, -(%sp)
  66         movel   %a1, %d2
  67 #else
  68         exg     %d2, %a1                /* save %d2 and get stack pointer */
  69 #endif
  70         movel   #SYS_ify (clone), %d0
  71         trap    #0
  72 #ifdef __mcoldfire__
  73         movel   (%sp)+, %d2
  74 #else
  75         exg     %d2, %a1                /* restore %d2 */
  76 #endif
  77         movel   (%sp)+, %d5             /* restore %d5, %d4 and %d3 */
  78         movel   (%sp)+, %d4
  79         movel   (%sp)+, %d3
  80
  81         tstl    %d0
  82         jmi     SYSCALL_ERROR_LABEL
  83         jeq     thread_start
  84
  85         rts
  86
  87 thread_start:
  88         cfi_startproc
  89         cfi_undefined (pc)      /* Mark end of stack */
  90         subl    %fp, %fp        /* terminate the stack frame */
  91 #ifdef RESET_PID
  92         /* Check and see if we need to reset the PID.  */
  93         movel   %d1, %a1
  94         andl    #CLONE_THREAD, %d1
  95         jne     donepid
  96         movel   %a1, %d1
  97         movel   #-1, %d0
  98         andl    #CLONE_VM, %d1
  99         jne     gotpid
 100         movel   #SYS_ify (getpid), %d0
 101         trap    #0
 102 gotpid:
 103         movel   %a0, -(%sp)
 104         movel   %d0, -(%sp)
 105         bsrl    __m68k_read_tp@PLTPC
 106         movel   (%sp)+, %d0
 107         movel   %d0, PID_OFFSET(%a0)
 108         movel   %d0, TID_OFFSET(%a0)
 109         movel   (%sp)+, %a0
 110 donepid:
 111 #endif
 112         jsr     (%a0)
 113         movel   %d0, %d1
 114         movel   #SYS_ify (exit), %d0
 115         trap    #0
 116         cfi_endproc
 117
 118 PSEUDO_END (__clone)
 119
 120 weak_alias (__clone, clone)