sysdeps/tile/__longjmp.S

   1 /* Copyright (C) 2011-2015 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Chris Metcalf <cmetcalf@tilera.com>, 2011.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <jmpbuf-offsets.h>
  21 #include <asm-syntax.h>
  22 #include <arch/spr_def.h>
  23
  24 /* PL to return to via iret in longjmp */
  25 #define RETURN_PL 0
  26
  27         .text
  28 ENTRY (__longjmp)
  29         FEEDBACK_ENTER(__longjmp)
  30
  31 #define RESTORE(r) { LD r, r0 ; ADDI_PTR r0, r0, REGSIZE }
  32         FOR_EACH_CALLEE_SAVED_REG(RESTORE)
  33
  34         /* Make longjmp(buf, 0) return "1" instead.
  35            At the same time, construct our iret context; we set ICS so
  36            we can validly load EX_CONTEXT for iret without being
  37            interrupted halfway through.  */
  38         {
  39          LD r2, r0   /* retrieve ICS bit from jmp_buf */
  40          movei r3, 1
  41          CMPEQI r0, r1, 0
  42         }
  43         {
  44          mtspr INTERRUPT_CRITICAL_SECTION, r3
  45          shli r2, r2, SPR_EX_CONTEXT_0_1__ICS_SHIFT
  46         }
  47         {
  48          mtspr EX_CONTEXT_0_0, lr
  49          ori r2, r2, RETURN_PL
  50         }
  51         {
  52          or r0, r1, r0
  53          mtspr EX_CONTEXT_0_1, r2
  54         }
  55         iret
  56         jrp lr   /* Keep the backtracer happy. */
  57 END (__longjmp)