sysdeps/vax/strncat.s

   1 /*
   2  * Copyright (c) 1983 Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 4. Neither the name of the University nor the names of its contributors
  14  *    may be used to endorse or promote products derived from this software
  15  *    without specific prior written permission.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #if defined(LIBC_SCCS) && !defined(lint)
  31         .asciz "@(#)strncat.s   5.6 (Berkeley) 6/1/90"
  32 #endif /* LIBC_SCCS and not lint */
  33
  34 /*
  35  * Concatenate string s2 on the end of s1
  36  * and return the base of s1.  The parameter
  37  * n is the maximum length of string s2 to
  38  * concatenate.
  39  *
  40  * char *
  41  * strncat(s1, s2, n)
  42  *      char *s1, *s2;
  43  *      int n;
  44  */
  45 #include "DEFS.h"
  46
  47 ENTRY(strncat, R6)
  48         movl    12(ap),r6       # r6 = n
  49         bleq    done            # n <= 0
  50         movl    4(ap),r3        # r3 = s1
  51         movl    r3,r1
  52 0:
  53         locc    $0,$65535,(r1)
  54         beql    0b
  55         movl    r1,r3           # r3 = index(s1, '\0');
  56         movl    8(ap),r1        # r1 = s2
  57 1:
  58         movzwl  $65535,r2       # r2 = bytes in first chunk
  59         cmpl    r6,r2           # r2 = min(bytes in chunk, n);
  60         jgeq    2f
  61         movl    r6,r2
  62 2:
  63         subl2   r2,r6           # update n
  64         locc    $0,r2,(r1)      # '\0' found?
  65         jneq    3f
  66         subl2   r2,r1           # back up pointer updated by locc
  67         movc3   r2,(r1),(r3)    # copy in next piece
  68         tstl    r6              # run out of space?
  69         jneq    1b
  70         clrb    (r3)            # force '\0' termination
  71         jbr     done
  72 3:
  73         subl2   r0,r2           # r2 = number of bytes to move
  74         subl2   r2,r1           # back up pointer updated by locc
  75         incl    r2              # copy '\0' as well
  76         movc3   r2,(r1),(r3)    # copy in last piece
  77 done:
  78         movl    4(ap),r0        # return s1
  79         ret