sysdeps/i386/add_n.S

   1 /* Add two limb vectors of the same length > 0 and store sum in a third
   2    limb vector.
   3    Copyright (C) 1992, 94, 95, 97, 98, 2000 Free Software Foundation, Inc.
   4    This file is part of the GNU MP Library.
   5
   6    The GNU MP Library is free software; you can redistribute it and/or modify
   7    it under the terms of the GNU Library General Public License as published by
   8    the Free Software Foundation; either version 2 of the License, or (at your
   9    option) any later version.
  10
  11    The GNU MP Library is distributed in the hope that it will be useful, but
  12    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  13    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  14    License for more details.
  15
  16    You should have received a copy of the GNU Library General Public License
  17    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  18    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  19    MA 02111-1307, USA. */
  20
  21 #include "sysdep.h"
  22 #include "asm-syntax.h"
  23 #include "bp-asm.h"
  24
  25 #define PARMS   LINKAGE+8       /* space for 2 saved regs */
  26 #define RES     PARMS
  27 #define S1      RES+PTR_SIZE
  28 #define S2      S1+PTR_SIZE
  29 #define SIZE    S2+PTR_SIZE
  30
  31         .text
  32 ENTRY(__mpn_add_n)
  33         ENTER
  34
  35         pushl %edi
  36         pushl %esi
  37
  38         movl RES(%esp),%edi
  39         movl S1(%esp),%esi
  40         movl S2(%esp),%edx
  41         movl SIZE(%esp),%ecx
  42
  43         movl    %ecx,%eax
  44         shrl    $3,%ecx                 /* compute count for unrolled loop */
  45         negl    %eax
  46         andl    $7,%eax                 /* get index where to start loop */
  47         jz      L(oop)                  /* necessary special case for 0 */
  48         incl    %ecx                    /* adjust loop count */
  49         shll    $2,%eax                 /* adjustment for pointers... */
  50         subl    %eax,%edi               /* ... since they are offset ... */
  51         subl    %eax,%esi               /* ... by a constant when we ... */
  52         subl    %eax,%edx               /* ... enter the loop */
  53         shrl    $2,%eax                 /* restore previous value */
  54 #ifdef PIC
  55 /* Calculate start address in loop for PIC.  Due to limitations in some
  56    assemblers, Loop-L0-3 cannot be put into the leal */
  57         call    L(0)
  58 L(0):   leal    (%eax,%eax,8),%eax
  59         addl    (%esp),%eax
  60         addl    $(L(oop)-L(0)-3),%eax
  61         addl    $4,%esp
  62 #else
  63 /* Calculate start address in loop for non-PIC.  */
  64         leal    (L(oop) - 3)(%eax,%eax,8),%eax
  65 #endif
  66         jmp     *%eax                   /* jump into loop */
  67         ALIGN (3)
  68 L(oop): movl    (%esi),%eax
  69         adcl    (%edx),%eax
  70         movl    %eax,(%edi)
  71         movl    4(%esi),%eax
  72         adcl    4(%edx),%eax
  73         movl    %eax,4(%edi)
  74         movl    8(%esi),%eax
  75         adcl    8(%edx),%eax
  76         movl    %eax,8(%edi)
  77         movl    12(%esi),%eax
  78         adcl    12(%edx),%eax
  79         movl    %eax,12(%edi)
  80         movl    16(%esi),%eax
  81         adcl    16(%edx),%eax
  82         movl    %eax,16(%edi)
  83         movl    20(%esi),%eax
  84         adcl    20(%edx),%eax
  85         movl    %eax,20(%edi)
  86         movl    24(%esi),%eax
  87         adcl    24(%edx),%eax
  88         movl    %eax,24(%edi)
  89         movl    28(%esi),%eax
  90         adcl    28(%edx),%eax
  91         movl    %eax,28(%edi)
  92         leal    32(%edi),%edi
  93         leal    32(%esi),%esi
  94         leal    32(%edx),%edx
  95         decl    %ecx
  96         jnz     L(oop)
  97
  98         sbbl    %eax,%eax
  99         negl    %eax
 100
 101         popl %esi
 102         popl %edi
 103
 104         LEAVE
 105         ret
 106 END(__mpn_add_n)