configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.53)dnl              dnl Minimum Autoconf version required.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 # Glibc should not depend on any header files
   9 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  10   [m4_divert_text([DEFAULTS],
  11     [ac_includes_default='/* none */'])])
  12
  13 dnl This is here so we can set $subdirs directly based on configure fragments.
  14 AC_CONFIG_SUBDIRS()
  15
  16 AC_CANONICAL_HOST
  17
  18 AC_PROG_CC
  19 if test $host != $build; then
  20   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  21 fi
  22 AC_SUBST(cross_compiling)
  23 AC_PROG_CPP
  24 # We need the C++ compiler only for testing.
  25 AC_PROG_CXX
  26
  27 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  28   AC_MSG_ERROR([you must configure in a separate build directory])
  29 fi
  30
  31 # This will get text that should go into config.make.
  32 config_vars=
  33
  34 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  35 AC_ARG_WITH([gd],
  36             AC_HELP_STRING([--with-gd=DIR],
  37                            [find libgd include dir and library with prefix DIR]),
  38             [dnl
  39 case "$with_gd" in
  40 yes|''|no) ;;
  41 *) libgd_include="-I$withval/include"
  42    libgd_ldflags="-L$withval/lib" ;;
  43 esac
  44 ])
  45 AC_ARG_WITH([gd-include],
  46             AC_HELP_STRING([--with-gd-include=DIR],
  47                            [find libgd include files in DIR]),
  48             [dnl
  49 case "$with_gd_include" in
  50 ''|no) ;;
  51 *) libgd_include="-I$withval" ;;
  52 esac
  53 ])
  54 AC_ARG_WITH([gd-lib],
  55             AC_HELP_STRING([--with-gd-lib=DIR],
  56                            [find libgd library files in DIR]),
  57             [dnl
  58 case "$with_gd_lib" in
  59 ''|no) ;;
  60 *) libgd_ldflags="-L$withval" ;;
  61 esac
  62 ])
  63
  64 if test -n "$libgd_include"; then
  65   config_vars="$config_vars
  66 CFLAGS-memusagestat.c = $libgd_include"
  67 fi
  68 if test -n "$libgd_ldflags"; then
  69   config_vars="$config_vars
  70 libgd-LDFLAGS = $libgd_ldflags"
  71 fi
  72
  73 dnl Arguments to specify presence of other packages/features.
  74 AC_ARG_WITH([fp],
  75             AC_HELP_STRING([--with-fp],
  76                            [if using floating-point hardware @<:@default=yes@:>@]),
  77             [with_fp=$withval],
  78             [with_fp=yes])
  79 AC_SUBST(with_fp)
  80 AC_ARG_WITH([binutils],
  81             AC_HELP_STRING([--with-binutils=PATH],
  82                            [specify location of binutils (as and ld)]),
  83             [path_binutils=$withval],
  84             [path_binutils=''])
  85 AC_ARG_WITH([selinux],
  86             AC_HELP_STRING([--with-selinux],
  87                            [if building with SELinux support]),
  88             [with_selinux=$withval],
  89             [with_selinux=auto])
  90
  91 AC_ARG_WITH([headers],
  92             AC_HELP_STRING([--with-headers=PATH],
  93                            [location of system headers to use
  94                             (for example /usr/src/linux/include)
  95                             @<:@default=compiler default@:>@]),
  96             [sysheaders=$withval],
  97             [sysheaders=''])
  98 AC_SUBST(sysheaders)
  99
 100 AC_SUBST(use_default_link)
 101 AC_ARG_WITH([default-link],
 102             AC_HELP_STRING([--with-default-link],
 103                            [do not use explicit linker scripts]),
 104             [use_default_link=$withval],
 105             [use_default_link=default])
 106
 107 AC_ARG_ENABLE([sanity-checks],
 108               AC_HELP_STRING([--disable-sanity-checks],
 109                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 110               [enable_sanity=$enableval],
 111               [enable_sanity=yes])
 112
 113 AC_ARG_ENABLE([shared],
 114               AC_HELP_STRING([--enable-shared],
 115                              [build shared library @<:@default=yes if GNU ld@:>@]),
 116               [shared=$enableval],
 117               [shared=yes])
 118 AC_ARG_ENABLE([profile],
 119               AC_HELP_STRING([--enable-profile],
 120                              [build profiled library @<:@default=no@:>@]),
 121               [profile=$enableval],
 122               [profile=no])
 123 AC_ARG_ENABLE([versioning],
 124               AC_HELP_STRING([--disable-versioning],
 125                              [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
 126               [enable_versioning=$enableval],
 127               [enable_versioning=yes])
 128
 129 AC_ARG_ENABLE([oldest-abi],
 130               AC_HELP_STRING([--enable-oldest-abi=ABI],
 131                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 132               [oldest_abi=$enableval],
 133               [oldest_abi=no])
 134 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 135   oldest_abi=default
 136 else
 137   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 138 fi
 139 AC_SUBST(oldest_abi)
 140
 141 AC_ARG_ENABLE([stackguard-randomization],
 142               AC_HELP_STRING([--enable-stackguard-randomization],
 143                              [initialize __stack_chk_guard canary with a random number at program start]),
 144               [enable_stackguard_randomize=$enableval],
 145               [enable_stackguard_randomize=no])
 146 if test "$enable_stackguard_randomize" = yes; then
 147   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 148 fi
 149
 150 dnl Generic infrastructure for drop-in additions to libc.
 151 AC_ARG_ENABLE([add-ons],
 152               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 153                              [configure and build add-ons in DIR1,DIR2,...
 154                               search for add-ons if no parameter given]),
 155                              , [enable_add_ons=yes])
 156
 157 AC_ARG_ENABLE([hidden-plt],
 158               AC_HELP_STRING([--disable-hidden-plt],
 159                              [do not hide internal function calls to avoid PLT]),
 160               [hidden=$enableval],
 161               [hidden=yes])
 162 if test "x$hidden" = xno; then
 163   AC_DEFINE(NO_HIDDEN)
 164 fi
 165
 166 AC_ARG_ENABLE([bind-now],
 167               AC_HELP_STRING([--enable-bind-now],
 168                              [disable lazy relocations in DSOs]),
 169               [bindnow=$enableval],
 170               [bindnow=no])
 171 AC_SUBST(bindnow)
 172
 173 dnl On some platforms we cannot use dynamic loading.  We must provide
 174 dnl static NSS modules.
 175 AC_ARG_ENABLE([static-nss],
 176               AC_HELP_STRING([--enable-static-nss],
 177                              [build static NSS modules @<:@default=no@:>@]),
 178               [static_nss=$enableval],
 179               [static_nss=no])
 180 dnl Enable static NSS also if we build no shared objects.
 181 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 182   static_nss=yes
 183   AC_DEFINE(DO_STATIC_NSS)
 184 fi
 185
 186 AC_ARG_ENABLE([force-install],
 187               AC_HELP_STRING([--disable-force-install],
 188                              [don't force installation of files from this package, even if they are older than the installed files]),
 189               [force_install=$enableval],
 190               [force_install=yes])
 191 AC_SUBST(force_install)
 192
 193 dnl On some platforms we allow dropping compatibility with all kernel
 194 dnl versions.
 195 AC_ARG_ENABLE([kernel],
 196               AC_HELP_STRING([--enable-kernel=VERSION],
 197                              [compile for compatibility with kernel not older than VERSION]),
 198               [minimum_kernel=$enableval],
 199               [])
 200 dnl Prevent unreasonable values.
 201 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 202   # Better nothing than this.
 203   minimum_kernel=""
 204 else
 205   if test "$minimum_kernel" = current; then
 206     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 207   fi
 208 fi
 209
 210 dnl For the development we sometimes want gcc to issue even more warnings.
 211 dnl This is not the default since many of the extra warnings are not
 212 dnl appropriate.
 213 AC_ARG_ENABLE([all-warnings],
 214               AC_HELP_STRING([--enable-all-warnings],
 215                              [enable all useful warnings gcc can issue]),
 216               [all_warnings=$enableval],
 217               [])
 218 AC_SUBST(all_warnings)
 219
 220 AC_ARG_ENABLE([multi-arch],
 221               AC_HELP_STRING([--enable-multi-arch],
 222                              [enable single DSO with optimizations for multiple architectures]),
 223               [multi_arch=$enableval],
 224               [multi_arch=default])
 225
 226 AC_ARG_ENABLE([nss-crypt],
 227               AC_HELP_STRING([--enable-nss-crypt],
 228                              [enable libcrypt to use nss]),
 229               [nss_crypt=$enableval],
 230               [nss_crypt=no])
 231 if test x$nss_crypt = xyes; then
 232   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 233   if test $? -ne 0; then
 234     AC_MSG_ERROR([cannot find include directory with nss-config])
 235   fi
 236   old_CFLAGS="$CFLAGS"
 237   CFLAGS="$CFLAGS $nss_includes"
 238   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 239 #include <hasht.h>
 240 #include <nsslowhash.h>
 241 void f (void) { NSSLOW_Init (); }])],
 242              libc_cv_nss_crypt=yes,
 243              AC_MSG_ERROR([
 244 cannot find NSS headers with lowlevel hash function interfaces]))
 245   old_LIBS="$LIBS"
 246   LIBS="$LIBS -lfreebl3"
 247   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 248 #include <hasht.h>
 249 #include <nsslowhash.h>],
 250                                   [NSSLOW_Init();])],
 251                  libc_cv_nss_crypt=yes,
 252                  AC_MSG_ERROR([
 253 cannot link program using lowlevel NSS hash functions]))
 254   CFLAGS="$old_CFLAGS"
 255   LIBS="$old_LIBS"
 256 else
 257   libc_cv_nss_crypt=no
 258 fi
 259 AC_SUBST(libc_cv_nss_crypt)
 260
 261
 262 AC_ARG_ENABLE([obsolete-rpc],
 263               AC_HELP_STRING([--enable-obsolete-rpc],
 264                              [build and install the obsolete RPC code for link-time usage]),
 265               [link_obsolete_rpc=$enableval],
 266               [link_obsolete_rpc=no])
 267 AC_SUBST(link_obsolete_rpc)
 268
 269 if test "$link_obsolete_rpc" = yes; then
 270   AC_DEFINE(LINK_OBSOLETE_RPC)
 271 fi
 272
 273 AC_ARG_ENABLE([systemtap],
 274               [AS_HELP_STRING([--enable-systemtap],
 275                [enable systemtap static probe points @<:@default=no@:>@])],
 276               [systemtap=$enableval],
 277               [systemtap=no])
 278 if test "x$systemtap" != xno; then
 279   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 280   old_CFLAGS="$CFLAGS"
 281   CFLAGS="-std=gnu99 $CFLAGS"
 282   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 283 void foo (int i, void *p)
 284 {
 285   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 286        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 287 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 288   CFLAGS="$old_CFLAGS"])
 289   if test $libc_cv_sdt = yes; then
 290     AC_DEFINE([USE_STAP_PROBE])
 291   elif test "x$systemtap" != xauto; then
 292     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 293   fi
 294 fi
 295
 296 # Note the use of $use_nscd is near the bottom of the file.
 297 AC_ARG_ENABLE([nscd],
 298               [AS_HELP_STRING([--disable-nscd],
 299                [library functions will not contact the nscd daemon])],
 300               [use_nscd=$enableval],
 301               [use_nscd=yes])
 302
 303 # The way shlib-versions is used to generate soversions.mk uses a
 304 # fairly simplistic model for name recognition that can't distinguish
 305 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 306 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 307 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 308 case "$host_os" in
 309 linux*)
 310   ;;
 311 gnu*)
 312   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 313   ;;
 314 esac
 315
 316 # We keep the original values in `$config_*' and never modify them, so we
 317 # can write them unchanged into config.make.  Everything else uses
 318 # $machine, $vendor, and $os, and changes them whenever convenient.
 319 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 320
 321 # Don't allow vendor == "unknown"
 322 test "$config_vendor" = unknown && config_vendor=
 323 config_os="`echo $config_os | sed 's/^unknown-//'`"
 324
 325 # Some configurations imply other options.
 326 elf=yes
 327
 328 # The configure fragment of an add-on port can modify these to supplement
 329 # or override the table in the case statement below.  No fragment should
 330 # ever change the config_* variables, however.
 331 machine=$config_machine
 332 vendor=$config_vendor
 333 os=$config_os
 334 base_os=''
 335
 336 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 337 # Unify this here.
 338 if test "$machine" = rs6000; then
 339   machine="powerpc"
 340 fi
 341
 342 # Braindead PowerPC box with absolutely no FPU.
 343 case "$machine-$host_os" in
 344   powerpc*-*soft)
 345     with_fp=no
 346     ;;
 347 esac
 348
 349 submachine=
 350 AC_ARG_WITH([cpu],
 351             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 352             [dnl
 353   case "$withval" in
 354   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 355   no) ;;
 356   *) submachine="$withval" ;;
 357   esac
 358 ])
 359
 360 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 361 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 362
 363 # An add-on can set this when it wants to disable the sanity check below.
 364 libc_config_ok=no
 365
 366 dnl Having this here, though empty, makes sure that if add-ons' fragments
 367 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 368 dnl our AC_OUTPUT will actually use it.
 369 AC_CONFIG_SUBDIRS()
 370
 371 case "$enable_add_ons" in
 372 ''|no) add_ons= ;;
 373 yes|'*')
 374  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 375           sed 's@/[[^/]]*$@@' | sort | uniq`
 376          add_ons_automatic=yes
 377          ;;
 378 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 379        add_ons_automatic=no ;;
 380 esac
 381
 382 configured_add_ons=
 383 add_ons_sfx=
 384 add_ons_pfx=
 385 if test x"$add_ons" != x; then
 386   for f in $add_ons; do
 387     # Some sanity checks
 388     case "$f" in
 389     crypt)
 390       AC_MSG_ERROR([
 391 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 392 *** part of glibc and using the old add-on will not work with this
 393 *** release.  Start again with fresh sources and without the old
 394 *** \`crypt' add-on.])
 395     ;;
 396     localedata)
 397       AC_MSG_ERROR([
 398 *** It seems that you're using an old \`localedata' add-on.  localedata
 399 *** is now part of glibc and using the old add-on will not work with
 400 *** this release.  Start again with fresh sources and without the old
 401 *** \`localedata' add-on.])
 402     ;;
 403     esac
 404   done
 405
 406   # Now source each add-on's configure fragment.
 407   # The fragments can use $srcdir/$libc_add_on to find themselves,
 408   # and test $add_ons_automatic to see if they were explicitly requested.
 409   # A fragment can clear (or even change) $libc_add_on to affect
 410   # whether it goes into the list to be actually used in the build.
 411   use_add_ons=
 412   for libc_add_on in $add_ons; do
 413     # Test whether such a directory really exists.
 414     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 415     case "$libc_add_on" in
 416     /*)
 417       libc_add_on_srcdir=$libc_add_on
 418       ;;
 419     *)
 420       test -d "$srcdir/$libc_add_on" || {
 421         if test -d "$libc_add_on"; then
 422           libc_add_on="`pwd`/$libc_add_on"
 423         else
 424           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 425         fi
 426       }
 427       libc_add_on_srcdir=$srcdir/$libc_add_on
 428       ;;
 429     esac
 430
 431     libc_add_on_frag=$libc_add_on_srcdir/configure
 432     libc_add_on_canonical=
 433     libc_add_on_config_subdirs=
 434     if test -r "$libc_add_on_frag"; then
 435       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 436       libc_add_on_canonical=unknown
 437       libc_add_on_subdirs=
 438       . "$libc_add_on_frag"
 439       test -z "$libc_add_on" || {
 440         configured_add_ons="$configured_add_ons $libc_add_on"
 441         if test "x$libc_add_on_canonical" = xunknown; then
 442           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 443         fi
 444         for d in $libc_add_on_subdirs; do
 445           case "$libc_add_on" in
 446           /*) subdir_srcdir="$libc_add_on" ;;
 447           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 448           esac
 449           case "$d" in
 450           .)
 451             d="${libc_add_on_canonical:-$libc_add_on}"
 452             ;;
 453           /*)
 454             subdir_srcdir="$d"
 455             ;;
 456           *)
 457             subdir_srcdir="$subdir_srcdir/$d"
 458             ;;
 459           esac
 460           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 461           add_on_subdirs="$add_on_subdirs $d"
 462           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 463 $d-srcdir = $subdir_srcdir"
 464         done
 465         for d in $libc_add_on_config_subdirs; do
 466           case "$d" in
 467           /*) AC_MSG_ERROR(dnl
 468 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 469           esac
 470           if test ! -d "$libc_add_on_srcdir/$d"; then
 471             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 472           fi
 473           case "$libc_add_on" in
 474           /*) AC_MSG_ERROR(dnl
 475 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 476           esac
 477           subdirs="$subdirs $libc_add_on/$d"
 478         done
 479       }
 480     fi
 481     if test -n "$libc_add_on"; then
 482       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 483       use_add_ons="$use_add_ons $libc_add_on"
 484       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 485       test -z "$libc_add_on_canonical" ||
 486       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 487     fi
 488   done
 489   # Use echo to strip excess whitespace.
 490   add_ons="`echo $use_add_ons`"
 491 fi
 492 AC_SUBST(add_ons)
 493 AC_SUBST(add_on_subdirs)
 494
 495
 496 ###
 497 ### I put this here to prevent those annoying emails from people who cannot
 498 ### read and try to compile glibc on unsupported platforms.  --drepper
 499 ###
 500 ### By using the undocumented --enable-hacker-mode option for configure
 501 ### one can skip this test to make the configuration not fail for unsupported
 502 ### platforms.
 503 ###
 504 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 505   case "$machine-$host_os" in
 506   *-linux* | *-gnu*)
 507     ;;
 508   *)
 509     echo "*** The GNU C library is currently not available for this platform."
 510     echo "*** So far nobody cared to port it and if there is no volunteer it"
 511     echo "*** might never happen.  So, if you have interest to see glibc on"
 512     echo "*** this platform visit"
 513     echo "***   http://www.gnu.org/software/libc/porting.html"
 514     echo "*** and join the group of porters"
 515     exit 1
 516     ;;
 517   esac
 518 fi
 519
 520 dnl We need to use [ and ] for other purposes for a while now.
 521 changequote(,)dnl
 522 # Expand the configuration machine name into a subdirectory by architecture
 523 # type and particular chip.  If an add-on configure fragment already set
 524 # base_machine, we don't change it.
 525 test -n "$base_machine" || case "$machine" in
 526 i[34567]86)     base_machine=i386 machine=i386/$machine ;;
 527 powerpc)        base_machine=powerpc machine=powerpc/powerpc32 ;;
 528 powerpc64)      base_machine=powerpc machine=powerpc/powerpc64 ;;
 529 s390)           base_machine=s390 machine=s390/s390-32 ;;
 530 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 531 sh3*)           base_machine=sh machine=sh/sh3 ;;
 532 sh4*)           base_machine=sh machine=sh/sh4 ;;
 533 sparc | sparcv[67])
 534                 base_machine=sparc machine=sparc/sparc32 ;;
 535 sparcv8 | supersparc | hypersparc)
 536                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 537 sparcv8plus | sparcv8plusa | sparcv9)
 538                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 539 sparcv8plusb | sparcv9b)
 540                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
 541 sparcv9v)
 542                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
 543 sparcv9v2)
 544                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
 545 sparc64)
 546                 base_machine=sparc machine=sparc/sparc64 ;;
 547 sparc64b)
 548                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 549 sparc64v)
 550                 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
 551 sparc64v2)
 552                 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
 553 *)              base_machine=$machine ;;
 554 esac
 555 changequote([,])dnl
 556 AC_SUBST(base_machine)
 557
 558 if test "$base_machine" = "i386"; then
 559   AC_DEFINE(USE_REGPARMS)
 560 fi
 561
 562 # For the multi-arch option we need support in the assembler.
 563 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
 564                libc_cv_asm_gnu_indirect_function, [dnl
 565 cat > conftest.s <<EOF
 566 .type foo,%gnu_indirect_function
 567 EOF
 568 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
 569 then
 570   libc_cv_asm_gnu_indirect_function=yes
 571 else
 572   libc_cv_asm_gnu_indirect_function=no
 573 fi
 574 rm -f conftest*])
 575
 576 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 577 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 578 cat > conftest.s <<EOF
 579 .text
 580 EOF
 581 libc_cv_dot_text=
 582 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 583   libc_cv_dot_text=.text
 584 fi
 585 rm -f conftest*])
 586 if test -z "$libc_cv_dot_text"; then
 587   AC_MSG_RESULT(no)
 588 else
 589   AC_MSG_RESULT(yes)
 590 fi
 591
 592 if test x"$libc_cv_asm_gnu_indirect_function" != xyes; then
 593   if test x"$multi_arch" = xyes; then
 594     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 595   else
 596     multi_arch=no
 597   fi
 598 fi
 599 if test x"$multi_arch" != xno; then
 600   multi_arch_d=/multiarch
 601 fi
 602
 603 # Compute the list of sysdep directories for this configuration.
 604 # This can take a while to compute.
 605 sysdep_dir=$srcdir/sysdeps
 606 AC_MSG_CHECKING(sysdep dirs)
 607 dnl We need to use [ and ] for other purposes for a while now.
 608 changequote(,)dnl
 609 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 610 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 611
 612 test "x$base_os" != x || case "$os" in
 613 gnu*)
 614   base_os=mach/hurd ;;
 615 linux*)
 616   base_os=unix/sysv ;;
 617 esac
 618
 619 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 620 tail=$os
 621 ostry=$os
 622 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 623   ostry="$ostry /$o"
 624   tail=$o
 625 done
 626 o=`echo $tail | sed 's/[0-9]*$//'`
 627 if test $o != $tail; then
 628   ostry="$ostry /$o"
 629 fi
 630 # For linux-gnu, try linux-gnu, then linux.
 631 o=`echo $tail | sed 's/-.*$//'`
 632 if test $o != $tail; then
 633   ostry="$ostry /$o"
 634 fi
 635
 636 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 637 base=
 638 tail=$base_os
 639 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 640   set $b
 641   base="$base /$1"
 642   tail="$2"
 643 done
 644
 645 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 646 mach=
 647 tail=$machine${submachine:+/$submachine}
 648 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 649   set $m
 650   # Prepend the machine's FPU directory unless --without-fp.
 651   if test "$with_fp" = yes; then
 652     mach="$mach /$1/fpu"
 653   else
 654     mach="$mach /$1/nofpu"
 655   fi
 656   mach="$mach /$1"
 657   tail="$2"
 658 done
 659
 660 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 661 changequote([,])dnl
 662
 663 # Find what sysdep directories exist.
 664 sysnames_add_ons=
 665 sysnames=
 666 for b in $base ''; do
 667   for m0 in $mach ''; do
 668     for v in /$vendor ''; do
 669       test "$v" = / && continue
 670       for o in /$ostry ''; do
 671         test "$o" = / && continue
 672         for m in $multi_arch_d $mach ''; do
 673           for d in $add_ons_pfx ''; do
 674             for a in $add_ons_sfx ''; do
 675               if test -n "$m0$m0sub$b$v$o$m$msub"; then
 676                 try_srcdir="${srcdir}/"
 677                 case "$d" in
 678                 /*) try_srcdir= ;;
 679                 esac
 680                 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
 681                 test -n "$enable_debug_configure" &&
 682                 echo "$0 [DEBUG]: try $try" >&2
 683                 if test -d "$try_srcdir$try"; then
 684                   sysnames="$sysnames $try"
 685                   { test -n "$o" || test -n "$b"; } && os_used=t
 686                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 687                   case x${m0:-$m} in
 688                   x*/$submachine) submachine_used=t ;;
 689                   esac
 690                   if test -n "$d"; then
 691                     case "$sysnames_add_ons" in
 692                     *" $d "*) ;;
 693                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 694                     esac
 695                   fi
 696                 fi
 697               fi
 698             done
 699           done
 700         done
 701       done
 702     done
 703   done
 704 done
 705
 706 # If the assembler supports gnu_indirect_function symbol type and the
 707 # architecture supports multi-arch, we enable multi-arch by default.
 708 case $sysnames_add_ons$sysnames in
 709 *"$multi_arch_d"*)
 710   ;;
 711 *)
 712   test x"$multi_arch" = xdefault && multi_arch=no
 713   ;;
 714 esac
 715 if test x"$multi_arch" != xno; then
 716   AC_DEFINE(USE_MULTIARCH)
 717 fi
 718 AC_SUBST(multi_arch)
 719
 720 if test -z "$os_used" && test "$os" != none; then
 721   AC_MSG_ERROR(Operating system $os is not supported.)
 722 fi
 723 if test -z "$machine_used" && test "$machine" != none; then
 724   AC_MSG_ERROR(The $machine is not supported.)
 725 fi
 726 if test -z "$submachine_used" && test -n "$submachine"; then
 727   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 728 fi
 729 AC_SUBST(submachine)
 730
 731 # We have now validated the configuration.
 732
 733 # Expand the list of system names into a full list of directories
 734 # from each element's parent name and Implies file (if present).
 735 set $sysnames
 736 names=
 737 while test $# -gt 0; do
 738   name=$1
 739   shift
 740
 741   case " $names " in *" $name "*)
 742     # Already in the list.
 743     continue
 744   esac
 745
 746   # Report each name as we discover it, so there is no long pause in output.
 747   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 748
 749   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 750
 751   case $name in
 752     /*) xsrcdir= ;;
 753     *)  xsrcdir=$srcdir/ ;;
 754   esac
 755   test -n "$enable_debug_configure" &&
 756   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 757
 758   for implies_file in Implies Implies-before Implies-after; do
 759     implies_type=`echo $implies_file | sed s/-/_/`
 760     eval ${implies_type}=
 761     if test -f $xsrcdir$name/$implies_file; then
 762       # Collect more names from the `Implies' file (removing comments).
 763       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 764       for x in $implied_candidate; do
 765         found=no
 766         if test -d $xsrcdir$name_base/$x; then
 767           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 768           found=yes
 769         fi
 770         for d in $add_ons_pfx ''; do
 771           try="${d}sysdeps/$x"
 772           case $d in
 773            /*) try_srcdir= ;;
 774            *) try_srcdir=$srcdir/ ;;
 775           esac
 776           test -n "$enable_debug_configure" &&
 777            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 778           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 779           then
 780             eval "${implies_type}=\"\$${implies_type} \$try\""
 781             found=yes
 782             case "$sysnames_add_ons" in
 783             *" $d "*) ;;
 784             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 785             esac
 786           fi
 787         done
 788         if test $found = no; then
 789           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 790         fi
 791       done
 792     fi
 793   done
 794
 795   # Add NAME to the list of names.
 796   names="$names $name"
 797
 798   # Find the parent of NAME, using the empty string if it has none.
 799 changequote(,)dnl
 800   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 801 changequote([,])dnl
 802
 803   test -n "$enable_debug_configure" &&
 804     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 805 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 806
 807   # Add the names implied by NAME, and NAME's parent (if it has one), to
 808   # the list of names to be processed (the argument list).  We prepend the
 809   # implied names to the list and append the parent.  We want implied
 810   # directories to come before further directories inferred from the
 811   # configuration components; this ensures that for sysv4, unix/common
 812   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 813   # after sysv4).
 814   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 815   test -n "$sysnames" && set $sysnames
 816 done
 817
 818 # Add the default directories.
 819 default_sysnames="sysdeps/generic"
 820 sysnames="$names $default_sysnames"
 821 AC_SUBST(sysnames)
 822 # The other names were emitted during the scan.
 823 AC_MSG_RESULT($default_sysnames)
 824
 825 # Collect the list of add-ons that supply partial sysdeps trees.
 826 sysdeps_add_ons=
 827 for add_on in $add_ons; do
 828   case "$add_on" in
 829   /*) xsrcdir= ;;
 830   *) xsrcdir="$srcdir/" ;;
 831   esac
 832
 833   test -d "$xsrcdir$add_on/sysdeps" || {
 834     case "$configured_add_ons " in
 835     *" $add_on "*) ;;
 836     *|'')
 837       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 838       ;;
 839     esac
 840     continue
 841   }
 842
 843   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 844   case "$sysnames_add_ons" in
 845   *" $add_on/ "*) ;;
 846   *|'')
 847     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 848     continue ;;
 849   esac
 850
 851   found=no
 852   for d in $sysnames; do
 853     case "$d" in
 854     $add_on/sysdeps/*) ;;
 855     *) continue ;;
 856     esac
 857     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 858        case "$f" in
 859        sys|bits)
 860          for ff in $f/*.h; do
 861            test -d "$ff" || { test -e "$ff" && exit 88; }
 862          done
 863          ;;
 864        *)
 865          test -d "$f" || { test -e "$f" && exit 88; }
 866          ;;
 867        esac
 868      done)
 869     if test $? -eq 88; then
 870       found=yes
 871       break
 872     fi
 873   done
 874   if test $found = no; then
 875     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 876   fi
 877 done
 878 AC_SUBST(sysdeps_add_ons)
 879
 880
 881 ### Locate tools.
 882
 883 AC_PROG_INSTALL
 884 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 885   # The makefiles need to use a different form to find it in $srcdir.
 886   INSTALL='\$(..)./scripts/install-sh -c'
 887 fi
 888 AC_PROG_LN_S
 889
 890 LIBC_PROG_BINUTILS
 891 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
 892
 893 # Accept binutils 2.20 or newer.
 894 AC_CHECK_PROG_VER(AS, $AS, --version,
 895                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 896                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
 897 AC_CHECK_PROG_VER(LD, $LD, --version,
 898                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 899                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
 900
 901 # These programs are version sensitive.
 902 AC_CHECK_TOOL_PREFIX
 903 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 904   [version \([egcygnustpi-]*[0-9.]*\)], [4.[3-9].* | 4.[1-9][0-9].* | [5-9].* ],
 905   critic_missing="$critic_missing gcc")
 906 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 907   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 908   [3.79* | 3.[89]*], critic_missing="$critic_missing make")
 909
 910 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 911   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 912   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 913   MSGFMT=: aux_missing="$aux_missing msgfmt")
 914 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 915   [GNU texinfo.* \([0-9][0-9.]*\)],
 916   [4.[5-9]*|4.[1-9][0-9]*|[5-9].*],
 917   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 918 AC_CHECK_PROG_VER(SED, sed, --version,
 919   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 920   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 921   SED=: aux_missing="$aux_missing sed")
 922
 923 AC_CHECK_TOOL(READELF, readelf, false)
 924 AC_CHECK_TOOL(NM, nm, false)
 925
 926 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 927 case "x$AUTOCONF" in
 928 xno|x|x:) AUTOCONF=no ;;
 929 *)
 930   AC_CACHE_CHECK(dnl
 931 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 932   if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
 933     libc_cv_autoconf_works=yes
 934   else
 935     libc_cv_autoconf_works=no
 936   fi])
 937   test $libc_cv_autoconf_works = yes || AUTOCONF=no
 938   ;;
 939 esac
 940 if test "x$AUTOCONF" = xno; then
 941   aux_missing="$aux_missing autoconf"
 942 fi
 943
 944 test -n "$critic_missing" && AC_MSG_ERROR([
 945 *** These critical programs are missing or too old:$critic_missing
 946 *** Check the INSTALL file for required versions.])
 947
 948 test -n "$aux_missing" && AC_MSG_WARN([
 949 *** These auxiliary programs are missing or incompatible versions:$aux_missing
 950 *** some features will be disabled.
 951 *** Check the INSTALL file for required versions.])
 952
 953 # if using special system headers, find out the compiler's sekrit
 954 # header directory and add that to the list.  NOTE: Only does the right
 955 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 956 if test -n "$sysheaders"; then
 957   SYSINCLUDES=-nostdinc
 958   for d in include include-fixed; do
 959     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
 960     SYSINCLUDES="$SYSINCLUDES -isystem $i"
 961   done
 962   SYSINCLUDES="$SYSINCLUDES \
 963 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
 964   if test -n "$CXX"; then
 965     CXX_SYSINCLUDES=
 966     cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
 967     cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
 968     for d in include "$cxxmachine/include"; do
 969       i=../../../../$d/c++/$cxxversion
 970       cxxheaders=`$CXX -print-file-name="$i"` &&
 971       test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
 972       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
 973 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
 974     done
 975   fi
 976 fi
 977 AC_SUBST(SYSINCLUDES)
 978 AC_SUBST(CXX_SYSINCLUDES)
 979
 980 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 981 # since this would lead to problems installing/building glibc.
 982 # LD_LIBRARY_PATH contains the current directory if one of the following
 983 # is true:
 984 # - one of the terminals (":" and ";") is the first or last sign
 985 # - two terminals occur directly after each other
 986 # - the path contains an element with a dot in it
 987 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 988 changequote(,)dnl
 989 case ${LD_LIBRARY_PATH} in
 990   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 991     ld_library_path_setting="contains current directory"
 992     ;;
 993   *)
 994     ld_library_path_setting="ok"
 995     ;;
 996 esac
 997 changequote([,])dnl
 998 AC_MSG_RESULT($ld_library_path_setting)
 999 if test "$ld_library_path_setting" != "ok"; then
1000 AC_MSG_ERROR([
1001 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1002 *** building glibc. Please change the environment variable
1003 *** and run configure again.])
1004 fi
1005
1006 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1007 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1008   libc_cv_gcc_static_libgcc=
1009 else
1010   libc_cv_gcc_static_libgcc=-static-libgcc
1011 fi])
1012 AC_SUBST(libc_cv_gcc_static_libgcc)
1013
1014 AC_PATH_PROG(BASH_SHELL, bash, no)
1015 if test "$BASH_SHELL" != no &&
1016    $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1017              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1018   libc_cv_have_bash2=yes
1019 else
1020   libc_cv_have_bash2=no
1021 fi
1022 AC_SUBST(libc_cv_have_bash2)
1023
1024 dnl We need a ksh compatible shell for tzselect.
1025 if test "$BASH_SHELL" = no; then
1026   AC_PATH_PROG(KSH, ksh, no)
1027   if test "$KSH" = no; then
1028     libc_cv_have_ksh=no
1029   else
1030     libc_cv_have_ksh=yes
1031   fi
1032 else
1033   KSH="$BASH_SHELL"
1034   AC_SUBST(KSH)
1035   libc_cv_have_ksh=yes
1036 fi
1037 AC_SUBST(libc_cv_have_ksh)
1038
1039 AC_PROG_AWK
1040 AC_PATH_PROG(PERL, perl, no)
1041 if test "$PERL" != no &&
1042    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1043   PERL=no
1044 fi
1045 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1046              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1047 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1048
1049 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1050 AC_TRY_COMPILE(dnl
1051 [#define __need_size_t
1052 #define __need_wchar_t
1053 #include <stddef.h>
1054 #define __need_NULL
1055 #include <stddef.h>], [size_t size; wchar_t wchar;
1056 #ifdef offsetof
1057 #error stddef.h ignored __need_*
1058 #endif
1059 if (&size == NULL || &wchar == NULL) abort ();],
1060                libc_cv_friendly_stddef=yes,
1061                libc_cv_friendly_stddef=no)])
1062 if test $libc_cv_friendly_stddef = yes; then
1063   config_vars="$config_vars
1064 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1065 fi
1066
1067 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1068                libc_cv_need_minus_P, [dnl
1069 cat > conftest.S <<EOF
1070 #include "confdefs.h"
1071 /* Nothing whatsoever.  */
1072 EOF
1073 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1074   libc_cv_need_minus_P=no
1075 else
1076   libc_cv_need_minus_P=yes
1077 fi
1078 rm -f conftest*])
1079 if test $libc_cv_need_minus_P = yes; then
1080   config_vars="$config_vars
1081 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1082 fi
1083
1084 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1085 cat > conftest.s <<EOF
1086 ${libc_cv_dot_text}
1087 foo:
1088 .set glibc_conftest_frobozz,foo
1089 .globl glibc_conftest_frobozz
1090 EOF
1091 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1092 # (but it doesn't work), so we must do a linking check to be sure.
1093 cat > conftest1.c <<\EOF
1094 extern int glibc_conftest_frobozz;
1095 void _start() { glibc_conftest_frobozz = 1; }
1096 EOF
1097 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1098             -nostartfiles -nostdlib \
1099             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1100   libc_cv_asm_set_directive=yes
1101 else
1102   libc_cv_asm_set_directive=no
1103 fi
1104 rm -f conftest*])
1105 if test $libc_cv_asm_set_directive = yes; then
1106   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1107 fi
1108
1109 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1110                libc_cv_asm_unique_object, [dnl
1111 cat > conftest.s <<EOF
1112 ${libc_cv_dot_text}
1113 _sym:
1114 .type _sym, %gnu_unique_object
1115 EOF
1116 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1117   libc_cv_asm_unique_object=yes
1118 else
1119   libc_cv_asm_unique_object=no
1120 fi
1121 rm -f conftest*])
1122 if test $libc_cv_asm_unique_object = yes; then
1123   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1124 fi
1125
1126 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1127 [cat > conftest.s <<EOF
1128 ${libc_cv_dot_text}
1129 _sym:
1130 .symver _sym,sym@VERS
1131 EOF
1132 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1133   libc_cv_asm_symver_directive=yes
1134 else
1135   libc_cv_asm_symver_directive=no
1136 fi
1137 rm -f conftest*])
1138 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1139 if test $libc_cv_asm_symver_directive = yes; then
1140   cat > conftest.s <<EOF
1141 ${libc_cv_dot_text}
1142 _sym:
1143 .symver _sym,sym@VERS
1144 EOF
1145   cat > conftest.map <<EOF
1146 VERS_1 {
1147         global: sym;
1148 };
1149
1150 VERS_2 {
1151         global: sym;
1152 } VERS_1;
1153 EOF
1154   if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1155     if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1156                                 -o conftest.so conftest.o
1157                                 -nostartfiles -nostdlib
1158                                 -Wl,--version-script,conftest.map
1159                        1>&AS_MESSAGE_LOG_FD]);
1160     then
1161       libc_cv_ld_version_script_option=yes
1162     else
1163       libc_cv_ld_version_script_option=no
1164     fi
1165   else
1166     libc_cv_ld_version_script_option=no
1167   fi
1168 else
1169   libc_cv_ld_version_script_option=no
1170 fi
1171 rm -f conftest*])
1172 if test $shared != no &&
1173    test $libc_cv_asm_symver_directive = yes &&
1174    test $libc_cv_ld_version_script_option = yes &&
1175    test $enable_versioning = yes; then
1176   VERSIONING=yes
1177   AC_DEFINE(DO_VERSIONING)
1178 else
1179   VERSIONING=no
1180 fi
1181 AC_SUBST(VERSIONING)
1182
1183 if test $shared != no && test $VERSIONING = no; then
1184   echo "\
1185 *** WARNING: You should not compile GNU libc without versioning. Not using
1186 *** versioning will introduce incompatibilities so that old binaries
1187 *** will not run anymore.
1188 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1189 fi
1190 AC_CACHE_CHECK(for .previous assembler directive,
1191                libc_cv_asm_previous_directive, [dnl
1192 cat > conftest.s <<EOF
1193 .section foo_section
1194 .previous
1195 EOF
1196 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1197   libc_cv_asm_previous_directive=yes
1198 else
1199   libc_cv_asm_previous_directive=no
1200 fi
1201 rm -f conftest*])
1202 if test $libc_cv_asm_previous_directive = yes; then
1203   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1204 else
1205   AC_CACHE_CHECK(for .popsection assembler directive,
1206                  libc_cv_asm_popsection_directive, [dnl
1207   cat > conftest.s <<EOF
1208 .pushsection foo_section
1209 .popsection
1210 EOF
1211   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1212     libc_cv_asm_popsection_directive=yes
1213   else
1214     libc_cv_asm_popsection_directive=no
1215   fi
1216   rm -f conftest*])
1217   if test $libc_cv_asm_popsection_directive = yes; then
1218     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1219   fi
1220 fi
1221 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1222                libc_cv_asm_protected_directive, [dnl
1223 cat > conftest.s <<EOF
1224 .protected foo
1225 foo:
1226 .hidden bar
1227 bar:
1228 EOF
1229 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1230   libc_cv_asm_protected_directive=yes
1231 else
1232   AC_MSG_ERROR(assembler support for symbol visibility is required)
1233 fi
1234 rm -f conftest*])
1235
1236 if test $libc_cv_asm_protected_directive = yes; then
1237   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1238                  libc_cv_visibility_attribute,
1239                  [cat > conftest.c <<EOF
1240                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1241                   int bar __attribute__ ((visibility ("protected"))) = 1;
1242 EOF
1243                   libc_cv_visibility_attribute=no
1244                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1245                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1246                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1247                         libc_cv_visibility_attribute=yes
1248                       fi
1249                     fi
1250                   fi
1251                   rm -f conftest.{c,s}
1252                  ])
1253   if test $libc_cv_visibility_attribute != yes; then
1254     AC_MSG_ERROR(compiler support for visibility attribute is required)
1255   fi
1256 fi
1257
1258 if test $libc_cv_visibility_attribute = yes; then
1259   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1260                  libc_cv_broken_visibility_attribute,
1261                  [cat > conftest.c <<EOF
1262                   int foo (int x);
1263                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1264                   int bar (int x) { return x; }
1265 EOF
1266                   libc_cv_broken_visibility_attribute=yes
1267                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1268 changequote(,)dnl
1269                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1270 changequote([,])dnl
1271                       libc_cv_broken_visibility_attribute=no
1272                     fi
1273                   fi
1274                   rm -f conftest.c conftest.s
1275                  ])
1276   if test $libc_cv_broken_visibility_attribute = yes; then
1277     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1278   fi
1279 fi
1280
1281 AC_CACHE_CHECK(for broken __attribute__((alias())),
1282                libc_cv_broken_alias_attribute,
1283                [cat > conftest.c <<EOF
1284                extern int foo (int x) __asm ("xyzzy");
1285                int bar (int x) { return x; }
1286                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1287                extern int dfoo;
1288                extern __typeof (dfoo) dfoo __asm ("abccb");
1289                int dfoo = 1;
1290 EOF
1291                libc_cv_broken_alias_attribute=yes
1292                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1293                  if grep 'xyzzy' conftest.s >/dev/null &&
1294                     grep 'abccb' conftest.s >/dev/null; then
1295                    libc_cv_broken_alias_attribute=no
1296                  fi
1297                fi
1298                rm -f conftest.c conftest.s
1299                ])
1300 if test $libc_cv_broken_alias_attribute = yes; then
1301   AC_MSG_ERROR(working alias attribute support required)
1302 fi
1303
1304 if test $libc_cv_visibility_attribute = yes; then
1305   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1306                  libc_cv_have_sdata_section,
1307                  [echo "int i;" > conftest.c
1308                   libc_cv_have_sdata_section=no
1309                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1310                      | grep '\.sdata' >/dev/null; then
1311                     libc_cv_have_sdata_section=yes
1312                   fi
1313                   rm -f conftest.c conftest.so
1314                  ])
1315   if test $libc_cv_have_sdata_section = yes; then
1316     AC_DEFINE(HAVE_SDATA_SECTION)
1317   fi
1318 fi
1319
1320 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1321                libc_cv_initfini_array, [dnl
1322 LIBC_TRY_LINK_STATIC([
1323 int foo (void) { return 1; }
1324 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1325 ],
1326   [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1327     libc_cv_initfini_array=yes
1328   else
1329     libc_cv_initfini_array=no
1330   fi],
1331   [libc_cv_initfini_array=no])
1332 ])
1333 if test $libc_cv_initfini_array != yes; then
1334   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1335 fi
1336
1337 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1338                libc_cv_ctors_header, [dnl
1339   libc_cv_ctors_header=yes
1340   LIBC_TRY_LINK_STATIC([
1341 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1342 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1343 ],
1344               [dnl
1345       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1346         { gsub(/\@<:@ */, "@<:@") }
1347         $2 == ".ctors" || $2 == ".dtors" {
1348           size = strtonum("0x" $6)
1349           align = strtonum("0x" $NF)
1350           seen@<:@$2@:>@ = 1
1351           stub@<:@$2@:>@ = size == align * 2
1352         }
1353         END {
1354           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1355           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1356           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1357         }
1358       '], [libc_cv_ctors_header=no])
1359     ], [dnl
1360       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1361     ])
1362 ])
1363 if test $libc_cv_ctors_header = no; then
1364   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1365 fi
1366
1367 AC_CACHE_CHECK(for libunwind-support in compiler,
1368                libc_cv_cc_with_libunwind, [
1369   cat > conftest.c <<EOF
1370 int main (void) { return 0; }
1371 EOF
1372   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1373      conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1374     libc_cv_cc_with_libunwind=yes
1375   else
1376     libc_cv_cc_with_libunwind=no
1377   fi
1378   rm -f conftest*])
1379 AC_SUBST(libc_cv_cc_with_libunwind)
1380 if test $libc_cv_cc_with_libunwind = yes; then
1381   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1382 fi
1383
1384 AC_CACHE_CHECK(for -z nodelete option,
1385                libc_cv_z_nodelete, [dnl
1386 cat > conftest.c <<EOF
1387 int _start (void) { return 42; }
1388 EOF
1389 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1390                    -fPIC -shared -o conftest.so conftest.c
1391                    -nostartfiles -nostdlib
1392                    -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1393 then
1394   libc_cv_z_nodelete=yes
1395 else
1396   AC_MSG_ERROR(linker with -z nodelete support required)
1397 fi
1398 rm -f conftest*])
1399
1400 AC_CACHE_CHECK(for -z nodlopen option,
1401                libc_cv_z_nodlopen, [dnl
1402 cat > conftest.c <<EOF
1403 int _start (void) { return 42; }
1404 EOF
1405 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1406                         -fPIC -shared -o conftest.so conftest.c
1407                         -nostartfiles -nostdlib
1408                         -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1409 then
1410   libc_cv_z_nodlopen=yes
1411 else
1412   AC_MSG_ERROR(linker with -z nodlopen support required)
1413 fi
1414 rm -f conftest*])
1415
1416 AC_CACHE_CHECK(for -z initfirst option,
1417                libc_cv_z_initfirst, [dnl
1418 cat > conftest.c <<EOF
1419 int _start (void) { return 42; }
1420 EOF
1421 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1422                         -fPIC -shared -o conftest.so conftest.c
1423                         -nostartfiles -nostdlib
1424                         -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1425 then
1426   libc_cv_z_initfirst=yes
1427 else
1428   AC_MSG_ERROR(linker with -z initfirst support required)
1429 fi
1430 rm -f conftest*])
1431
1432 # Add-on fragments can set these for other machines.
1433 libc_commonpagesize=${libc_commonpagesize:-no}
1434 libc_relro_required=${libc_relro_required:-no}
1435 case "$base_machine" in
1436   i[[34567]]86 | x86_64 | powerpc* | s390*)
1437     libc_commonpagesize=0x1000
1438     libc_relro_required=yes
1439     ;;
1440   sparc*)
1441     libc_commonpagesize=0x2000
1442     libc_relro_required=yes
1443     ;;
1444 esac
1445
1446 if test $libc_commonpagesize != no; then
1447   AC_CACHE_CHECK(for -z relro option,
1448                  libc_cv_z_relro, [dnl
1449   libc_cv_z_relro=no
1450   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1451 int _start (void) { return 42; }
1452 extern void _exit (int);
1453 /* Since these pointers are const, they should go in rodata.
1454    Since they refer to functions that have to be resolved by
1455    dynamic linking, they should instead go in RELRO data.  */
1456 const void *const relro[] = { &_start, &_exit, 0 };
1457 /* GNU ld fails to produce RELRO data when it's very small and there is no
1458    normal writable data following it, or if only uninitialized (.bss) data
1459    follows it, or only very small writable data.  */
1460 int data[0x10000] = { 1, };
1461 ]])])
1462   cat > conftest.awk <<\EOF
1463 BEGIN {
1464   result = "no"
1465   commonpagesize = strtonum(commonpagesize)
1466 }
1467 { print "LINE:", $0 > "/dev/stderr" }
1468 $1 == "GNU_RELRO" {
1469   vaddr = strtonum($3)
1470   memsz = strtonum($6)
1471   end = vaddr + memsz
1472   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1473     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1474   result = (end % commonpagesize == 0) ? "yes" : "broken"
1475 }
1476 END { print result }
1477 EOF
1478   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1479                     -fPIC -shared -o conftest.so conftest.c
1480                     -nostartfiles -nostdlib
1481                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1482   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1483   AC_TRY_COMMAND([
1484       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1485            conftest.ph > conftest.cps
1486     ]) &&
1487   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1488   rm -f conftest*])
1489   if { test "x$libc_relro_required" = xyes &&
1490        test "x$libc_cv_z_relro" != xyes
1491      }
1492   then
1493     AC_MSG_ERROR(linker with -z relro support required)
1494   fi
1495 else
1496   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1497 fi
1498
1499 AC_CACHE_CHECK(for -Bgroup option,
1500                libc_cv_Bgroup, [dnl
1501 cat > conftest.c <<EOF
1502 int _start (void) { return 42; }
1503 EOF
1504 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1505                             -fPIC -shared -o conftest.so conftest.c
1506                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1507 then
1508   libc_cv_Bgroup=yes
1509 else
1510   libc_cv_Bgroup=no
1511 fi
1512 rm -f conftest*])
1513 AC_SUBST(libc_cv_Bgroup)
1514
1515 ASFLAGS_config=
1516 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1517                libc_cv_as_noexecstack, [dnl
1518 cat > conftest.c <<EOF
1519 void foo (void) { }
1520 EOF
1521 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1522                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1523    && grep -q .note.GNU-stack conftest.s \
1524    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1525                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1526 then
1527   libc_cv_as_noexecstack=yes
1528 else
1529   libc_cv_as_noexecstack=no
1530 fi
1531 rm -f conftest*])
1532 if test $libc_cv_as_noexecstack = yes; then
1533   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1534 fi
1535 AC_SUBST(ASFLAGS_config)
1536
1537 AC_CACHE_CHECK(for -z combreloc,
1538                libc_cv_z_combreloc, [dnl
1539 cat > conftest.c <<EOF
1540 extern int bar (int);
1541 extern int mumble;
1542 int foo (void) { return bar (mumble); }
1543 EOF
1544 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1545                         -fPIC -shared -o conftest.so conftest.c
1546                         -nostdlib -nostartfiles
1547                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1548 then
1549 dnl The following test is a bit weak.  We must use a tool which can test
1550 dnl cross-platform since the gcc used can be a cross compiler.  Without
1551 dnl introducing new options this is not easily doable.  Instead use a tool
1552 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1553 dnl look for a section named .rel.dyn.
1554   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1555     libc_cv_z_combreloc=yes
1556   else
1557     libc_cv_z_combreloc=no
1558   fi
1559 else
1560   libc_cv_z_combreloc=no
1561 fi
1562 rm -f conftest*])
1563 if test "$libc_cv_z_combreloc" = yes; then
1564   AC_DEFINE(HAVE_Z_COMBRELOC)
1565 fi
1566 AC_SUBST(libc_cv_z_combreloc)
1567
1568 AC_CACHE_CHECK(for -z execstack,
1569                libc_cv_z_execstack, [dnl
1570 cat > conftest.c <<EOF
1571 int _start (void) { return 42; }
1572 EOF
1573 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1574                             -fPIC -shared -o conftest.so conftest.c
1575                             -Wl,-z,execstack -nostdlib
1576                             1>&AS_MESSAGE_LOG_FD])
1577 then
1578   libc_cv_z_execstack=yes
1579 else
1580   libc_cv_z_execstack=no
1581 fi
1582 rm -f conftest*])
1583 AC_SUBST(libc_cv_z_execstack)
1584
1585 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1586 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1587 ])
1588
1589 AC_SUBST(libc_cv_fpie)
1590
1591 AC_CACHE_CHECK(for --hash-style option,
1592                libc_cv_hashstyle, [dnl
1593 cat > conftest.c <<EOF
1594 int _start (void) { return 42; }
1595 EOF
1596 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1597                             -fPIC -shared -o conftest.so conftest.c
1598                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1599 then
1600   libc_cv_hashstyle=yes
1601 else
1602   libc_cv_hashstyle=no
1603 fi
1604 rm -f conftest*])
1605 AC_SUBST(libc_cv_hashstyle)
1606
1607 # The linker's default -shared behavior is good enough if it
1608 # does these things that our custom linker scripts ensure that
1609 # all allocated NOTE sections come first.
1610 if test "$use_default_link" = default; then
1611   AC_CACHE_CHECK([for sufficient default -shared layout],
1612                   libc_cv_use_default_link, [dnl
1613   libc_cv_use_default_link=no
1614   cat > conftest.s <<\EOF
1615           .section .note.a,"a",%note
1616           .balign 4
1617           .long 4,4,9
1618           .string "GNU"
1619           .string "foo"
1620           .section .note.b,"a",%note
1621           .balign 4
1622           .long 4,4,9
1623           .string "GNU"
1624           .string "bar"
1625 EOF
1626   if AC_TRY_COMMAND([dnl
1627   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1628        ac_try=`$READELF -S conftest.so | sed -n \
1629          ['${x;p;}
1630           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1631           t a
1632           b
1633           : a
1634           H']`
1635   then
1636     libc_seen_a=no libc_seen_b=no
1637     set -- $ac_try
1638     while test $# -ge 2 -a "$1" = NOTE; do
1639       case "$2" in
1640       .note.a) libc_seen_a=yes ;;
1641       .note.b) libc_seen_b=yes ;;
1642       esac
1643       shift 2
1644     done
1645     case "$libc_seen_a$libc_seen_b" in
1646     yesyes)
1647       libc_cv_use_default_link=yes
1648       ;;
1649     *)
1650       echo >&AS_MESSAGE_LOG_FD "\
1651 $libc_seen_a$libc_seen_b from:
1652 $ac_try"
1653       ;;
1654     esac
1655   fi
1656   rm -f conftest*])
1657   use_default_link=$libc_cv_use_default_link
1658 fi
1659
1660 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1661 if libc_cv_output_format=`
1662 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1663 then
1664   :
1665 else
1666   libc_cv_output_format=
1667 fi
1668 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1669 AC_SUBST(libc_cv_output_format)
1670
1671 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1672 cat > conftest.c <<EOF
1673 int foo;
1674 EOF
1675 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1676                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1677 then
1678   libc_cv_fno_toplevel_reorder=yes
1679 else
1680   libc_cv_fno_toplevel_reorder=no
1681 fi
1682 rm -f conftest*])
1683 if test $libc_cv_fno_toplevel_reorder = yes; then
1684   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1685 else
1686   fno_unit_at_a_time=-fno-unit-at-a-time
1687 fi
1688 AC_SUBST(fno_unit_at_a_time)
1689
1690 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1691 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1692                    [libc_cv_ssp=yes],
1693                    [libc_cv_ssp=no])
1694 ])
1695 AC_SUBST(libc_cv_ssp)
1696
1697 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1698 cat > conftest.c <<EOF
1699 int foo;
1700 #ifdef __GNUC_GNU_INLINE__
1701 main () { return 0;}
1702 #else
1703 #error
1704 #endif
1705 EOF
1706 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1707                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1708 then
1709   libc_cv_gnu89_inline=yes
1710 else
1711   libc_cv_gnu89_inline=no
1712 fi
1713 rm -f conftest*])
1714 if test $libc_cv_gnu89_inline = yes; then
1715   gnu89_inline=-fgnu89-inline
1716 else
1717   gnu89_inline=
1718 fi
1719 AC_SUBST(gnu89_inline)
1720
1721 AC_CACHE_CHECK(whether cc puts quotes around section names,
1722                libc_cv_have_section_quotes,
1723                [cat > conftest.c <<EOF
1724                 static const int foo
1725                 __attribute__ ((section ("bar"))) = 1;
1726 EOF
1727                 if ${CC-cc} -S conftest.c -o conftest.s; then
1728                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1729                     libc_cv_have_section_quotes=yes
1730                   else
1731                     libc_cv_have_section_quotes=no
1732                   fi
1733                 else
1734                   libc_cv_have_section_quotes=unknown
1735                 fi
1736                 rm -f conftest.{c,s}
1737                 ])
1738 if test $libc_cv_have_section_quotes = yes; then
1739   AC_DEFINE(HAVE_SECTION_QUOTES)
1740 fi
1741
1742 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1743                [dnl
1744 cat > conftest.s <<EOF
1745 ${libc_cv_dot_text}
1746 .globl foo
1747 foo:
1748 .weak foo
1749 .weak bar; bar = foo
1750 EOF
1751 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1752   libc_cv_asm_weak_directive=yes
1753 else
1754   libc_cv_asm_weak_directive=no
1755 fi
1756 rm -f conftest*])
1757
1758 if test $libc_cv_asm_weak_directive = no; then
1759   AC_CACHE_CHECK(for assembler .weakext directive,
1760                  libc_cv_asm_weakext_directive,
1761                  [dnl
1762 cat > conftest.s <<EOF
1763 ${libc_cv_dot_text}
1764 .globl foo
1765 foo:
1766 .weakext bar foo
1767 .weakext baz
1768 .globl baz
1769 baz:
1770 EOF
1771   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1772     libc_cv_asm_weakext_directive=yes
1773   else
1774     libc_cv_asm_weakext_directive=no
1775   fi
1776   rm -f conftest*])
1777
1778 fi # no .weak
1779
1780 if test $libc_cv_asm_weak_directive = yes; then
1781   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1782 elif test $libc_cv_asm_weakext_directive = yes; then
1783   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1784 fi
1785
1786 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1787 case $machine in
1788   sparc/sparc64*) cfi_offset=2047;;
1789   *) cfi_offset=0;;
1790 esac
1791 cat > conftest.s <<EOF
1792         .text
1793         .type   func,%function
1794 func:
1795         .cfi_startproc
1796         .cfi_remember_state
1797         .cfi_rel_offset 1, $cfi_offset
1798         .cfi_endproc
1799 EOF
1800 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1801   libc_cv_asm_cfi_directives=yes
1802 else
1803   libc_cv_asm_cfi_directives=no
1804 fi
1805 rm -f conftest*])
1806 if test $libc_cv_asm_cfi_directives = yes; then
1807   AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1808 fi
1809
1810 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1811 cat > conftest.c <<\EOF
1812 _start () {}
1813 int __eh_pc;
1814 __throw () {}
1815 EOF
1816 dnl No \ in command here because it ends up inside ''.
1817 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1818                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1819                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1820   libc_cv_ld_no_whole_archive=yes
1821 else
1822   libc_cv_ld_no_whole_archive=no
1823 fi
1824 rm -f conftest*])
1825 if test $libc_cv_ld_no_whole_archive = no; then
1826   AC_MSG_ERROR([support for --no-whole-archive is needed])
1827 fi
1828
1829 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1830 cat > conftest.c <<\EOF
1831 _start () {}
1832 int __eh_pc;
1833 __throw () {}
1834 EOF
1835 dnl No \ in command here because it ends up inside ''.
1836 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1837                             -nostdlib -nostartfiles -fexceptions
1838                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1839   libc_cv_gcc_exceptions=yes
1840 else
1841   libc_cv_gcc_exceptions=no
1842 fi
1843 rm -f conftest*])
1844 if test $libc_cv_gcc_exceptions = yes; then
1845   exceptions=-fexceptions
1846 fi
1847 AC_SUBST(exceptions)dnl
1848
1849 if test "$host_cpu" = powerpc ; then
1850 # Check for a bug present in at least versions 2.8.x of GCC
1851 # and versions 1.0.x of EGCS.
1852 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1853 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1854                libc_cv_c_asmcr0_bug='no',
1855                libc_cv_c_asmcr0_bug='yes')])
1856 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1857   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1858 fi
1859 fi
1860
1861 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1862 cat > conftest.c <<\EOF
1863 void zero (void *x)
1864 {
1865   __builtin_memset (x, 0, 1000);
1866 }
1867 EOF
1868 dnl
1869 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1870 then
1871   libc_cv_gcc_builtin_memset=no
1872 else
1873   libc_cv_gcc_builtin_memset=yes
1874 fi
1875 rm -f conftest* ])
1876 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1877   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1878 fi
1879
1880 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1881 cat > conftest.c <<\EOF
1882 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1883 char *foo (const char *a, const char *b)
1884 {
1885   return __builtin_strstr (a, b);
1886 }
1887 EOF
1888 dnl
1889 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1890 then
1891   libc_cv_gcc_builtin_redirection=yes
1892 else
1893   libc_cv_gcc_builtin_redirection=no
1894 fi
1895 rm -f conftest* ])
1896 if test "$libc_cv_gcc_builtin_redirection" = no; then
1897   AC_MSG_ERROR([support for the symbol redirection needed])
1898 fi
1899
1900 dnl Check whether the compiler supports the __thread keyword.
1901 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1902 [cat > conftest.c <<\EOF
1903 __thread int a = 42;
1904 EOF
1905 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1906   libc_cv_gcc___thread=yes
1907 else
1908   libc_cv_gcc___thread=no
1909 fi
1910 rm -f conftest*])
1911 if test "$libc_cv_gcc___thread" = no; then
1912   AC_MSG_ERROR([support for the __thread keyword is required])
1913 fi
1914
1915 dnl Check whether the compiler supports the tls_model attribute.
1916 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1917 cat > conftest.c <<\EOF
1918 extern __thread int a __attribute__((tls_model ("initial-exec")));
1919 EOF
1920 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1921   libc_cv_gcc_tls_model_attr=yes
1922 else
1923   libc_cv_gcc_tls_model_attr=no
1924 fi
1925 rm -f conftest*])
1926 if test "$libc_cv_gcc_tls_model_attr" = no; then
1927   AC_MSG_ERROR([support for the tls_model attribute is required])
1928 fi
1929
1930 dnl Determine how to disable generation of FMA instructions.
1931 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1932                libc_cv_cc_nofma, [dnl
1933 libc_cv_cc_nofma=
1934 for opt in -ffp-contract=off -mno-fused-madd; do
1935   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1936 done])
1937
1938 if test -n "$submachine"; then
1939   AC_CACHE_CHECK([for compiler option for CPU variant],
1940                  libc_cv_cc_submachine, [dnl
1941   libc_cv_cc_submachine=no
1942   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1943     LIBC_TRY_CC_OPTION([$opt], [
1944       libc_cv_cc_submachine="$opt"
1945       break], [])
1946   done])
1947   if test "x$libc_cv_cc_submachine" = xno; then
1948     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1949   fi
1950 fi
1951 AC_SUBST(libc_cv_cc_submachine)
1952
1953 dnl Check whether we have the gd library available.
1954 AC_MSG_CHECKING(for libgd)
1955 if test "$with_gd" != "no"; then
1956   old_CFLAGS="$CFLAGS"
1957   CFLAGS="$CFLAGS $libgd_include"
1958   old_LDFLAGS="$LDFLAGS"
1959   LDFLAGS="$LDFLAGS $libgd_ldflags"
1960   old_LIBS="$LIBS"
1961   LIBS="$LIBS -lgd -lpng -lz -lm"
1962   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1963   CFLAGS="$old_CFLAGS"
1964   LDFLAGS="$old_LDFLAGS"
1965   LIBS="$old_LIBS"
1966 else
1967   LIBGD=no
1968 fi
1969 AC_MSG_RESULT($LIBGD)
1970 AC_SUBST(LIBGD)
1971
1972 # SELinux detection
1973 if test x$with_selinux = xno ; then
1974   have_selinux=no;
1975 else
1976   # See if we have the SELinux library
1977   AC_CHECK_LIB(selinux, is_selinux_enabled,
1978                have_selinux=yes, have_selinux=no)
1979   # See if we have the SELinux header with the NSCD permissions in it.
1980   if test x$have_selinux = xyes ; then
1981     AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
1982     AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
1983                     [#ifdef NSCD__SHMEMHOST
1984                      return 0;
1985                      #else
1986                      #error NSCD__SHMEMHOST not defined
1987                      #endif],
1988                     have_selinux=yes, have_selinux=no)
1989     AC_MSG_RESULT($have_selinux)
1990   fi
1991
1992   if test x$with_selinux = xyes ; then
1993     if test x$have_selinux = xno ; then
1994       AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
1995     fi
1996   fi
1997 fi
1998 # Check if we're building with SELinux support.
1999 if test "x$have_selinux" = xyes; then
2000   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2001
2002   # See if we have the libaudit library
2003   AC_CHECK_LIB(audit, audit_log_user_avc_message,
2004                have_libaudit=yes, have_libaudit=no)
2005   if test "x$have_libaudit" = xyes; then
2006     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2007   fi
2008   AC_SUBST(have_libaudit)
2009
2010   # See if we have the libcap library
2011   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2012   if test "x$have_libcap" = xyes; then
2013     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2014   fi
2015   AC_SUBST(have_libcap)
2016 fi
2017 AC_SUBST(have_selinux)
2018
2019 dnl check for the size of 'long double'.
2020 AC_CHECK_SIZEOF(long double, 0)
2021 sizeof_long_double=$ac_cv_sizeof_long_double
2022 AC_SUBST(sizeof_long_double)
2023
2024 CPPUNDEFS=
2025 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
2026 dnl Since we are building the implementations of the fortified functions here,
2027 dnl having the macro defined interacts very badly.
2028 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
2029 [AC_TRY_COMPILE([], [
2030 #ifdef _FORTIFY_SOURCE
2031 # error bogon
2032 #endif],
2033                 [libc_cv_predef_fortify_source=no],
2034                 [libc_cv_predef_fortify_source=yes])])
2035 if test $libc_cv_predef_fortify_source = yes; then
2036   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
2037 fi
2038 AC_SUBST(CPPUNDEFS)
2039
2040 dnl Check for silly hacked compilers inserting -fstack-protector.
2041 dnl This breaks badly for the early startup code we compile, since
2042 dnl the compiled code can refer to a magic machine-dependent location
2043 dnl for the canary value before we have sufficient setup for that to
2044 dnl work.  It's also questionable to build all of libc with this flag
2045 dnl even when you're doing that for most applications you build, since
2046 dnl libc's code is so heavily-used and performance-sensitive.  If we
2047 dnl ever really want to make that work, it should be enabled explicitly
2048 dnl in the libc build, not inherited from implicit compiler settings.
2049 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
2050                libc_cv_predef_stack_protector, [
2051 AC_TRY_COMPILE([extern void foobar (char *);],
2052                [char large_array[2048]; foobar (large_array);], [
2053 libc_undefs=`$NM -u conftest.o |
2054   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
2055     2>&AS_MESSAGE_LOG_FD` || {
2056   AC_MSG_ERROR([confusing output from $NM -u])
2057 }
2058 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
2059 # On some architectures, there are architecture-specific undefined
2060 # symbols (resolved by the linker), so filter out unknown symbols.
2061 # This will fail to produce the correct result if the compiler
2062 # defaults to -fstack-protector but this produces an undefined symbol
2063 # other than __stack_chk_fail.  However, compilers like that have not
2064 # been encountered in practice.
2065 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
2066 case "$libc_undefs" in
2067 foobar) libc_cv_predef_stack_protector=no ;;
2068 '__stack_chk_fail
2069 foobar') libc_cv_predef_stack_protector=yes ;;
2070 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
2071 esac],
2072                [AC_MSG_ERROR([test compilation failed])])
2073 ])
2074 libc_extra_cflags=
2075 if test $libc_cv_predef_stack_protector = yes; then
2076   libc_extra_cflags=-fno-stack-protector
2077 fi
2078 AC_SUBST(libc_extra_cflags)
2079
2080 ### End of automated tests.
2081 ### Now run sysdeps configure fragments.
2082
2083 # They also can set these variables.
2084 use_ldconfig=no
2085 ldd_rewrite_script=no
2086 libc_cv_sysconfdir=$sysconfdir
2087 libc_cv_localstatedir=$localstatedir
2088 libc_cv_gcc_unwind_find_fde=no
2089 libc_cv_idn=no
2090
2091 # Iterate over all the sysdep directories we will use, running their
2092 # configure fragments.
2093 for dir in $sysnames; do
2094   case $dir in
2095     /*) dest=$dir ;;
2096     *)  dest=$srcdir/$dir ;;
2097   esac
2098   if test -r $dest/configure; then
2099     AC_MSG_RESULT(running configure fragment for $dir)
2100     . $dest/configure
2101   fi
2102 done
2103
2104 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2105   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2106 fi
2107 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2108
2109 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
2110 # configure fragment can override the value to prevent this AC_DEFINE.
2111 AC_SUBST(use_nscd)
2112 if test "x$use_nscd" != xno; then
2113   AC_DEFINE([USE_NSCD])
2114 fi
2115
2116 # Test for old glibc 2.0.x headers so that they can be removed properly
2117 # Search only in includedir.
2118 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2119 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2120 then
2121   old_glibc_headers=yes
2122 else
2123   old_glibc_headers=no
2124 fi
2125 AC_MSG_RESULT($old_glibc_headers)
2126 if test ${old_glibc_headers} = yes; then
2127   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2128   AC_MSG_WARN(*** be removed.)
2129 fi
2130 AC_SUBST(old_glibc_headers)
2131
2132 AC_SUBST(libc_cv_slibdir)
2133 AC_SUBST(libc_cv_localedir)
2134 AC_SUBST(libc_cv_sysconfdir)
2135 AC_SUBST(libc_cv_localstatedir)
2136 AC_SUBST(libc_cv_rootsbindir)
2137 AC_SUBST(libc_cv_forced_unwind)
2138
2139 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2140 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2141 AC_SUBST(libc_cv_cc_sse4)
2142 AC_SUBST(libc_cv_cc_avx)
2143 AC_SUBST(libc_cv_cc_sse2avx)
2144 AC_SUBST(libc_cv_cc_novzeroupper)
2145 AC_SUBST(libc_cv_cc_fma4)
2146 AC_SUBST(libc_cv_cc_nofma)
2147 AC_SUBST(libc_cv_as_i686)
2148 AC_SUBST(libc_cv_sparc_as_vis3)
2149
2150 AC_SUBST(use_ldconfig)
2151 AC_SUBST(ldd_rewrite_script)
2152
2153 AC_SUBST(static)
2154 AC_SUBST(shared)
2155
2156 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2157 [libc_cv_pic_default=yes
2158 cat > conftest.c <<EOF
2159 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2160 # error PIC is default.
2161 #endif
2162 EOF
2163 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2164   libc_cv_pic_default=no
2165 fi
2166 rm -f conftest.*])
2167 AC_SUBST(libc_cv_pic_default)
2168
2169 AC_SUBST(profile)
2170 AC_SUBST(static_nss)
2171
2172 AC_SUBST(DEFINES)
2173
2174 dnl See sysdeps/mach/configure.in for this variable.
2175 AC_SUBST(mach_interface_list)
2176
2177 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2178   config_makefile=
2179 else
2180   config_makefile=Makefile
2181 fi
2182
2183 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2184 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2185 AC_SUBST(VERSION)
2186 AC_SUBST(RELEASE)
2187
2188 AC_CONFIG_FILES([config.make ${config_makefile}])
2189 AC_CONFIG_COMMANDS([default],[[
2190 case $CONFIG_FILES in *config.make*)
2191 echo "$config_vars" >> config.make;;
2192 esac
2193 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2194 AC_OUTPUT