ports/sysdeps/arm/memset.S

   1 /* Copyright (C) 1998-2013 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Philip Blundell <philb@gnu.org>
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* Thumb requires excessive IT insns here.  */
  20 #define NO_THUMB
  21 #include <sysdep.h>
  22
  23         .text
  24         .syntax unified
  25
  26 /* void *memset (dstpp, c, len) */
  27
  28 ENTRY(memset)
  29         mov     r3, r0
  30         cmp     r2, #8
  31         bcc     2f              @ less than 8 bytes to move
  32
  33 1:
  34         tst     r3, #3          @ aligned yet?
  35         strbne  r1, [r3], #1
  36         subne   r2, r2, #1
  37         bne     1b
  38
  39         and     r1, r1, #255    @ clear any sign bits
  40         orr     r1, r1, r1, lsl $8
  41         orr     r1, r1, r1, lsl $16
  42         mov     ip, r1
  43
  44 1:
  45         subs    r2, r2, #8
  46         stmiacs r3!, {r1, ip}   @ store up to 32 bytes per loop iteration
  47         subscs  r2, r2, #8
  48         stmiacs r3!, {r1, ip}
  49         subscs  r2, r2, #8
  50         stmiacs r3!, {r1, ip}
  51         subscs  r2, r2, #8
  52         stmiacs r3!, {r1, ip}
  53         bcs     1b
  54
  55         and     r2, r2, #7
  56 2:
  57         subs    r2, r2, #1      @ store up to 4 bytes per loop iteration
  58         strbcs  r1, [r3], #1
  59         subscs  r2, r2, #1
  60         strbcs  r1, [r3], #1
  61         subscs  r2, r2, #1
  62         strbcs  r1, [r3], #1
  63         subscs  r2, r2, #1
  64         strbcs  r1, [r3], #1
  65         bcs     2b
  66
  67         DO_RET(lr)
  68 END(memset)
  69 libc_hidden_builtin_def (memset)