configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([fp],
 131             AC_HELP_STRING([--with-fp],
 132                            [if using floating-point hardware @<:@default=yes@:>@]),
 133             [with_fp=$withval],
 134             [with_fp=yes])
 135 AC_SUBST(with_fp)
 136 AC_ARG_WITH([binutils],
 137             AC_HELP_STRING([--with-binutils=PATH],
 138                            [specify location of binutils (as and ld)]),
 139             [path_binutils=$withval],
 140             [path_binutils=''])
 141 AC_ARG_WITH([selinux],
 142             AC_HELP_STRING([--with-selinux],
 143                            [if building with SELinux support]),
 144             [with_selinux=$withval],
 145             [with_selinux=auto])
 146
 147 AC_ARG_WITH([headers],
 148             AC_HELP_STRING([--with-headers=PATH],
 149                            [location of system headers to use
 150                             (for example /usr/src/linux/include)
 151                             @<:@default=compiler default@:>@]),
 152             [sysheaders=$withval],
 153             [sysheaders=''])
 154 AC_SUBST(sysheaders)
 155
 156 AC_SUBST(use_default_link)
 157 AC_ARG_WITH([default-link],
 158             AC_HELP_STRING([--with-default-link],
 159                            [do not use explicit linker scripts]),
 160             [use_default_link=$withval],
 161             [use_default_link=default])
 162
 163 AC_ARG_ENABLE([sanity-checks],
 164               AC_HELP_STRING([--disable-sanity-checks],
 165                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 166               [enable_sanity=$enableval],
 167               [enable_sanity=yes])
 168
 169 AC_ARG_ENABLE([shared],
 170               AC_HELP_STRING([--enable-shared],
 171                              [build shared library @<:@default=yes if GNU ld@:>@]),
 172               [shared=$enableval],
 173               [shared=yes])
 174 AC_ARG_ENABLE([profile],
 175               AC_HELP_STRING([--enable-profile],
 176                              [build profiled library @<:@default=no@:>@]),
 177               [profile=$enableval],
 178               [profile=no])
 179 AC_ARG_ENABLE([timezone-tools],
 180               AC_HELP_STRING([--disable-timezone-tools],
 181                              [do not install timezone tools @<:@default=install@:>@]),
 182               [enable_timezone_tools=$enableval],
 183               [enable_timezone_tools=yes])
 184 AC_SUBST(enable_timezone_tools)
 185
 186 AC_ARG_ENABLE([hardcoded-path-in-tests],
 187               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 188                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 189               [hardcoded_path_in_tests=$enableval],
 190               [hardcoded_path_in_tests=no])
 191 AC_SUBST(hardcoded_path_in_tests)
 192
 193 AC_ARG_ENABLE([stackguard-randomization],
 194               AC_HELP_STRING([--enable-stackguard-randomization],
 195                              [initialize __stack_chk_guard canary with a random number at program start]),
 196               [enable_stackguard_randomize=$enableval],
 197               [enable_stackguard_randomize=no])
 198 if test "$enable_stackguard_randomize" = yes; then
 199   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 200 fi
 201
 202 AC_ARG_ENABLE([lock-elision],
 203               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 204                              [Enable lock elision for pthread mutexes by default]),
 205               [enable_lock_elision=$enableval],
 206               [enable_lock_elision=no])
 207 AC_SUBST(enable_lock_elision)
 208 if test "$enable_lock_elision" = yes ; then
 209   AC_DEFINE(ENABLE_LOCK_ELISION)
 210 fi
 211
 212 dnl Generic infrastructure for drop-in additions to libc.
 213 AC_ARG_ENABLE([add-ons],
 214               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 215                              [configure and build add-ons in DIR1,DIR2,...
 216                               search for add-ons if no parameter given]),
 217                              , [enable_add_ons=yes])
 218
 219 AC_ARG_ENABLE([hidden-plt],
 220               AC_HELP_STRING([--disable-hidden-plt],
 221                              [do not hide internal function calls to avoid PLT]),
 222               [hidden=$enableval],
 223               [hidden=yes])
 224 if test "x$hidden" = xno; then
 225   AC_DEFINE(NO_HIDDEN)
 226 fi
 227
 228 AC_ARG_ENABLE([bind-now],
 229               AC_HELP_STRING([--enable-bind-now],
 230                              [disable lazy relocations in DSOs]),
 231               [bindnow=$enableval],
 232               [bindnow=no])
 233 AC_SUBST(bindnow)
 234
 235 dnl On some platforms we cannot use dynamic loading.  We must provide
 236 dnl static NSS modules.
 237 AC_ARG_ENABLE([static-nss],
 238               AC_HELP_STRING([--enable-static-nss],
 239                              [build static NSS modules @<:@default=no@:>@]),
 240               [static_nss=$enableval],
 241               [static_nss=no])
 242 dnl Enable static NSS also if we build no shared objects.
 243 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 244   static_nss=yes
 245   AC_DEFINE(DO_STATIC_NSS)
 246 fi
 247
 248 AC_ARG_ENABLE([force-install],
 249               AC_HELP_STRING([--disable-force-install],
 250                              [don't force installation of files from this package, even if they are older than the installed files]),
 251               [force_install=$enableval],
 252               [force_install=yes])
 253 AC_SUBST(force_install)
 254
 255 AC_ARG_ENABLE([maintainer-mode],
 256               AC_HELP_STRING([--enable-maintainer-mode],
 257                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 258               [maintainer=$enableval],
 259               [maintainer=no])
 260
 261 dnl On some platforms we allow dropping compatibility with all kernel
 262 dnl versions.
 263 AC_ARG_ENABLE([kernel],
 264               AC_HELP_STRING([--enable-kernel=VERSION],
 265                              [compile for compatibility with kernel not older than VERSION]),
 266               [minimum_kernel=$enableval],
 267               [])
 268 dnl Prevent unreasonable values.
 269 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 270   # Better nothing than this.
 271   minimum_kernel=""
 272 else
 273   if test "$minimum_kernel" = current; then
 274     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 275   fi
 276 fi
 277
 278 dnl For the development we sometimes want gcc to issue even more warnings.
 279 dnl This is not the default since many of the extra warnings are not
 280 dnl appropriate.
 281 AC_ARG_ENABLE([all-warnings],
 282               AC_HELP_STRING([--enable-all-warnings],
 283                              [enable all useful warnings gcc can issue]),
 284               [all_warnings=$enableval],
 285               [])
 286 AC_SUBST(all_warnings)
 287
 288 AC_ARG_ENABLE([werror],
 289               AC_HELP_STRING([--disable-werror],
 290                              [do not build with -Werror]),
 291               [enable_werror=$enableval],
 292               [enable_werror=yes])
 293 AC_SUBST(enable_werror)
 294
 295 AC_ARG_ENABLE([multi-arch],
 296               AC_HELP_STRING([--enable-multi-arch],
 297                              [enable single DSO with optimizations for multiple architectures]),
 298               [multi_arch=$enableval],
 299               [multi_arch=default])
 300
 301 AC_ARG_ENABLE([nss-crypt],
 302               AC_HELP_STRING([--enable-nss-crypt],
 303                              [enable libcrypt to use nss]),
 304               [nss_crypt=$enableval],
 305               [nss_crypt=no])
 306 if test x$nss_crypt = xyes; then
 307   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 308   if test $? -ne 0; then
 309     AC_MSG_ERROR([cannot find include directory with nss-config])
 310   fi
 311   old_CFLAGS="$CFLAGS"
 312   CFLAGS="$CFLAGS $nss_includes"
 313   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 314 #include <hasht.h>
 315 #include <nsslowhash.h>
 316 void f (void) { NSSLOW_Init (); }])],
 317              libc_cv_nss_crypt=yes,
 318              AC_MSG_ERROR([
 319 cannot find NSS headers with lowlevel hash function interfaces]))
 320   old_LIBS="$LIBS"
 321   LIBS="$LIBS -lfreebl3"
 322   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 323 #include <hasht.h>
 324 #include <nsslowhash.h>],
 325                                   [NSSLOW_Init();])],
 326                  libc_cv_nss_crypt=yes,
 327                  AC_MSG_ERROR([
 328 cannot link program using lowlevel NSS hash functions]))
 329   CFLAGS="$old_CFLAGS"
 330   LIBS="$old_LIBS"
 331 else
 332   libc_cv_nss_crypt=no
 333 fi
 334 AC_SUBST(libc_cv_nss_crypt)
 335
 336
 337 AC_ARG_ENABLE([obsolete-rpc],
 338               AC_HELP_STRING([--enable-obsolete-rpc],
 339                              [build and install the obsolete RPC code for link-time usage]),
 340               [link_obsolete_rpc=$enableval],
 341               [link_obsolete_rpc=no])
 342 AC_SUBST(link_obsolete_rpc)
 343
 344 if test "$link_obsolete_rpc" = yes; then
 345   AC_DEFINE(LINK_OBSOLETE_RPC)
 346 fi
 347
 348 AC_ARG_ENABLE([systemtap],
 349               [AS_HELP_STRING([--enable-systemtap],
 350                [enable systemtap static probe points @<:@default=no@:>@])],
 351               [systemtap=$enableval],
 352               [systemtap=no])
 353 if test "x$systemtap" != xno; then
 354   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 355   old_CFLAGS="$CFLAGS"
 356   CFLAGS="-std=gnu11 $CFLAGS"
 357   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 358 void foo (int i, void *p)
 359 {
 360   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 361        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 362 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 363   CFLAGS="$old_CFLAGS"])
 364   if test $libc_cv_sdt = yes; then
 365     AC_DEFINE([USE_STAP_PROBE])
 366   elif test "x$systemtap" != xauto; then
 367     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 368   fi
 369 fi
 370
 371 AC_ARG_ENABLE([build-nscd],
 372               [AS_HELP_STRING([--disable-build-nscd],
 373                [disable building and installing the nscd daemon])],
 374               [build_nscd=$enableval],
 375               [build_nscd=default])
 376 AC_SUBST(build_nscd)
 377
 378 # Note the use of $use_nscd is near the bottom of the file.
 379 AC_ARG_ENABLE([nscd],
 380               [AS_HELP_STRING([--disable-nscd],
 381                [library functions will not contact the nscd daemon])],
 382               [use_nscd=$enableval],
 383               [use_nscd=yes])
 384
 385 AC_ARG_ENABLE([pt_chown],
 386               [AS_HELP_STRING([--enable-pt_chown],
 387                [Enable building and installing pt_chown])],
 388               [build_pt_chown=$enableval],
 389               [build_pt_chown=no])
 390 AC_SUBST(build_pt_chown)
 391 if test "$build_pt_chown" = yes; then
 392   AC_DEFINE(HAVE_PT_CHOWN)
 393 fi
 394
 395 # The abi-tags file uses a fairly simplistic model for name recognition that
 396 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 397 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 398 # This doesn't get used much beyond that, so it's fairly safe.
 399 case "$host_os" in
 400 linux*)
 401   ;;
 402 gnu*)
 403   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 404   ;;
 405 esac
 406
 407 AC_ARG_ENABLE([mathvec],
 408               [AS_HELP_STRING([--enable-mathvec],
 409               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 410               [build_mathvec=$enableval],
 411               [build_mathvec=notset])
 412
 413 # We keep the original values in `$config_*' and never modify them, so we
 414 # can write them unchanged into config.make.  Everything else uses
 415 # $machine, $vendor, and $os, and changes them whenever convenient.
 416 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 417
 418 # Don't allow vendor == "unknown"
 419 test "$config_vendor" = unknown && config_vendor=
 420 config_os="`echo $config_os | sed 's/^unknown-//'`"
 421
 422 # Some configurations imply other options.
 423 elf=yes
 424
 425 # The configure fragment of an add-on port can modify these to supplement
 426 # or override the table in the case statement below.  No fragment should
 427 # ever change the config_* variables, however.
 428 machine=$config_machine
 429 vendor=$config_vendor
 430 os=$config_os
 431 base_os=''
 432
 433 submachine=
 434 AC_ARG_WITH([cpu],
 435             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 436             [dnl
 437   case "$withval" in
 438   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 439   no) ;;
 440   *) submachine="$withval" ;;
 441   esac
 442 ])
 443
 444 # An preconfigure script can set this when it wants to disable the sanity
 445 # check below.
 446 libc_config_ok=no
 447
 448 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 449 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 450
 451 dnl Having this here, though empty, makes sure that if add-ons' fragments
 452 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 453 dnl our AC_OUTPUT will actually use it.
 454 AC_CONFIG_SUBDIRS()
 455
 456 case "$enable_add_ons" in
 457 ''|no) add_ons= ;;
 458 yes|'*')
 459  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 460           sed 's@/[[^/]]*$@@' | sort | uniq`
 461          add_ons_automatic=yes
 462          ;;
 463 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 464        add_ons_automatic=no ;;
 465 esac
 466
 467 configured_add_ons=
 468 add_ons_sfx=
 469 add_ons_pfx=
 470 if test x"$add_ons" != x; then
 471   for f in $add_ons; do
 472     # Some sanity checks
 473     case "$f" in
 474     crypt)
 475       AC_MSG_ERROR([
 476 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 477 *** part of glibc and using the old add-on will not work with this
 478 *** release.  Start again with fresh sources and without the old
 479 *** \`crypt' add-on.])
 480     ;;
 481     localedata)
 482       AC_MSG_ERROR([
 483 *** It seems that you're using an old \`localedata' add-on.  localedata
 484 *** is now part of glibc and using the old add-on will not work with
 485 *** this release.  Start again with fresh sources and without the old
 486 *** \`localedata' add-on.])
 487     ;;
 488     esac
 489   done
 490
 491   # Now source each add-on's configure fragment.
 492   # The fragments can use $srcdir/$libc_add_on to find themselves,
 493   # and test $add_ons_automatic to see if they were explicitly requested.
 494   # A fragment can clear (or even change) $libc_add_on to affect
 495   # whether it goes into the list to be actually used in the build.
 496   use_add_ons=
 497   for libc_add_on in $add_ons; do
 498     # Test whether such a directory really exists.
 499     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 500     case "$libc_add_on" in
 501     /*)
 502       libc_add_on_srcdir=$libc_add_on
 503       ;;
 504     *)
 505       test -d "$srcdir/$libc_add_on" || {
 506         if test -d "$libc_add_on"; then
 507           libc_add_on="`pwd`/$libc_add_on"
 508         else
 509           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 510         fi
 511       }
 512       libc_add_on_srcdir=$srcdir/$libc_add_on
 513       ;;
 514     esac
 515
 516     libc_add_on_frag=$libc_add_on_srcdir/configure
 517     libc_add_on_canonical=
 518     libc_add_on_config_subdirs=
 519     if test -r "$libc_add_on_frag"; then
 520       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 521       libc_add_on_canonical=unknown
 522       libc_add_on_subdirs=
 523       . "$libc_add_on_frag"
 524       test -z "$libc_add_on" || {
 525         configured_add_ons="$configured_add_ons $libc_add_on"
 526         if test "x$libc_add_on_canonical" = xunknown; then
 527           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 528         fi
 529         for d in $libc_add_on_subdirs; do
 530           case "$libc_add_on" in
 531           /*) subdir_srcdir="$libc_add_on" ;;
 532           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 533           esac
 534           case "$d" in
 535           .)
 536             d="${libc_add_on_canonical:-$libc_add_on}"
 537             ;;
 538           /*)
 539             subdir_srcdir="$d"
 540             ;;
 541           *)
 542             subdir_srcdir="$subdir_srcdir/$d"
 543             ;;
 544           esac
 545           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 546           add_on_subdirs="$add_on_subdirs $d"
 547           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 548 $d-srcdir = $subdir_srcdir"
 549         done
 550         for d in $libc_add_on_config_subdirs; do
 551           case "$d" in
 552           /*) AC_MSG_ERROR(dnl
 553 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 554           esac
 555           if test ! -d "$libc_add_on_srcdir/$d"; then
 556             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 557           fi
 558           case "$libc_add_on" in
 559           /*) AC_MSG_ERROR(dnl
 560 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 561           esac
 562           subdirs="$subdirs $libc_add_on/$d"
 563         done
 564       }
 565     fi
 566     if test -n "$libc_add_on"; then
 567       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 568       use_add_ons="$use_add_ons $libc_add_on"
 569       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 570       test -z "$libc_add_on_canonical" ||
 571       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 572     fi
 573   done
 574   # Use echo to strip excess whitespace.
 575   add_ons="`echo $use_add_ons`"
 576 fi
 577 AC_SUBST(add_ons)
 578 AC_SUBST(add_on_subdirs)
 579
 580
 581 ###
 582 ### By using the undocumented --enable-hacker-mode option for configure
 583 ### one can skip this test to make the configuration not fail for unsupported
 584 ### platforms.
 585 ###
 586 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 587   case "$machine-$host_os" in
 588   *-linux* | *-gnu*)
 589     ;;
 590   *)
 591     AC_MSG_ERROR([
 592 *** The GNU C library is currently unavailable for this platform.
 593 *** If you are interested in seeing glibc on this platform visit
 594 *** the "How to submit a new port" in the wiki:
 595 ***   https://sourceware.org/glibc/wiki/#Development
 596 *** and join the community!])
 597     ;;
 598   esac
 599 fi
 600
 601 # Set base_machine if not set by a preconfigure fragment.
 602 test -n "$base_machine" || base_machine=$machine
 603 AC_SUBST(base_machine)
 604
 605 # For the multi-arch option we need support in the assembler & linker.
 606 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 607                libc_cv_ld_gnu_indirect_function, [dnl
 608 cat > conftest.S <<EOF
 609 .type foo,%gnu_indirect_function
 610 foo:
 611 .globl _start
 612 _start:
 613 .globl __start
 614 __start:
 615 .data
 616 #ifdef _LP64
 617 .quad foo
 618 #else
 619 .long foo
 620 #endif
 621 EOF
 622 libc_cv_ld_gnu_indirect_function=no
 623 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 624             -nostartfiles -nostdlib \
 625             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 626   # Do a link to see if the backend supports IFUNC relocs.
 627   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 628   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 629     libc_cv_ld_gnu_indirect_function=yes
 630   }
 631 fi
 632 rm -f conftest*])
 633
 634 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 635   if test x"$multi_arch" = xyes; then
 636     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 637   else
 638     multi_arch=no
 639   fi
 640 fi
 641 multi_arch_d=
 642 if test x"$multi_arch" != xno; then
 643   multi_arch_d=/multiarch
 644 fi
 645
 646 # Compute the list of sysdep directories for this configuration.
 647 # This can take a while to compute.
 648 sysdep_dir=$srcdir/sysdeps
 649 AC_MSG_CHECKING(sysdep dirs)
 650 dnl We need to use [ and ] for other purposes for a while now.
 651 changequote(,)dnl
 652 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 653 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 654
 655 test "x$base_os" != x || case "$os" in
 656 gnu*)
 657   base_os=mach/hurd ;;
 658 linux*)
 659   base_os=unix/sysv ;;
 660 esac
 661
 662 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 663 tail=$os
 664 ostry=$os
 665 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 666   ostry="$ostry /$o"
 667   tail=$o
 668 done
 669 o=`echo $tail | sed 's/[0-9]*$//'`
 670 if test $o != $tail; then
 671   ostry="$ostry /$o"
 672 fi
 673 # For linux-gnu, try linux-gnu, then linux.
 674 o=`echo $tail | sed 's/-.*$//'`
 675 if test $o != $tail; then
 676   ostry="$ostry /$o"
 677 fi
 678
 679 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 680 base=
 681 tail=$base_os
 682 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 683   set $b
 684   base="$base /$1"
 685   tail="$2"
 686 done
 687
 688 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 689 mach=
 690 tail=$machine${submachine:+/$submachine}
 691 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 692   set $m
 693   # Prepend the machine's FPU directory unless --without-fp.
 694   if test "$with_fp" = yes; then
 695     maybe_fpu=/fpu
 696   else
 697     maybe_fpu=/nofpu
 698   fi
 699   # For each machine term, try it with and then without /multiarch.
 700   for try_fpu in $maybe_fpu ''; do
 701     for try_multi in $multi_arch_d ''; do
 702       mach="$mach /$1$try_fpu$try_multi"
 703     done
 704   done
 705   tail="$2"
 706 done
 707
 708 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 709 changequote([,])dnl
 710
 711 # Find what sysdep directories exist.
 712 sysnames_add_ons=
 713 sysnames=
 714 for b in $base ''; do
 715   for m0 in $mach ''; do
 716     for v in /$vendor ''; do
 717       test "$v" = / && continue
 718       for o in /$ostry ''; do
 719         test "$o" = / && continue
 720         for m in $mach ''; do
 721           for d in $add_ons_pfx ''; do
 722             for a in $add_ons_sfx ''; do
 723               try_suffix="$m0$b$v$o$m"
 724               if test -n "$try_suffix"; then
 725                 try_srcdir="${srcdir}/"
 726                 case "$d" in
 727                 /*) try_srcdir= ;;
 728                 esac
 729                 try="${d}sysdeps$try_suffix$a"
 730                 test -n "$enable_debug_configure" &&
 731                 echo "$0 [DEBUG]: try $try" >&2
 732                 if test -d "$try_srcdir$try"; then
 733                   sysnames="$sysnames $try"
 734                   { test -n "$o" || test -n "$b"; } && os_used=t
 735                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 736                   case x${m0:-$m} in
 737                   x*/$submachine) submachine_used=t ;;
 738                   esac
 739                   if test -n "$d"; then
 740                     case "$sysnames_add_ons" in
 741                     *" $d "*) ;;
 742                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 743                     esac
 744                   fi
 745                 fi
 746               fi
 747             done
 748           done
 749         done
 750       done
 751     done
 752   done
 753 done
 754
 755 # If the assembler supports gnu_indirect_function symbol type and the
 756 # architecture supports multi-arch, we enable multi-arch by default.
 757 case $sysnames_add_ons$sysnames in
 758 *"$multi_arch_d"*)
 759   ;;
 760 *)
 761   test x"$multi_arch" = xdefault && multi_arch=no
 762   ;;
 763 esac
 764 if test x"$multi_arch" != xno; then
 765   AC_DEFINE(USE_MULTIARCH)
 766 fi
 767 AC_SUBST(multi_arch)
 768
 769 if test -z "$os_used" && test "$os" != none; then
 770   AC_MSG_ERROR(Operating system $os is not supported.)
 771 fi
 772 if test -z "$machine_used" && test "$machine" != none; then
 773   AC_MSG_ERROR(The $machine is not supported.)
 774 fi
 775 if test -z "$submachine_used" && test -n "$submachine"; then
 776   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 777 fi
 778 AC_SUBST(submachine)
 779
 780 # We have now validated the configuration.
 781
 782 # Expand the list of system names into a full list of directories
 783 # from each element's parent name and Implies file (if present).
 784 set $sysnames
 785 names=
 786 while test $# -gt 0; do
 787   name=$1
 788   shift
 789
 790   case " $names " in *" $name "*)
 791     # Already in the list.
 792     continue
 793   esac
 794
 795   # Report each name as we discover it, so there is no long pause in output.
 796   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 797
 798   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 799
 800   case $name in
 801     /*) xsrcdir= ;;
 802     *)  xsrcdir=$srcdir/ ;;
 803   esac
 804   test -n "$enable_debug_configure" &&
 805   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 806
 807   for implies_file in Implies Implies-before Implies-after; do
 808     implies_type=`echo $implies_file | sed s/-/_/`
 809     eval ${implies_type}=
 810     if test -f $xsrcdir$name/$implies_file; then
 811       # Collect more names from the `Implies' file (removing comments).
 812       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 813       for x in $implied_candidate; do
 814         found=no
 815         if test -d $xsrcdir$name_base/$x; then
 816           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 817           found=yes
 818         fi
 819         for d in $add_ons_pfx ''; do
 820           try="${d}sysdeps/$x"
 821           case $d in
 822            /*) try_srcdir= ;;
 823            *) try_srcdir=$srcdir/ ;;
 824           esac
 825           test -n "$enable_debug_configure" &&
 826            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 827           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 828           then
 829             eval "${implies_type}=\"\$${implies_type} \$try\""
 830             found=yes
 831             case "$sysnames_add_ons" in
 832             *" $d "*) ;;
 833             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 834             esac
 835           fi
 836         done
 837         if test $found = no; then
 838           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 839         fi
 840       done
 841     fi
 842   done
 843
 844   # Add NAME to the list of names.
 845   names="$names $name"
 846
 847   # Find the parent of NAME, using the empty string if it has none.
 848 changequote(,)dnl
 849   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 850 changequote([,])dnl
 851
 852   test -n "$enable_debug_configure" &&
 853     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 854 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 855
 856   # Add the names implied by NAME, and NAME's parent (if it has one), to
 857   # the list of names to be processed (the argument list).  We prepend the
 858   # implied names to the list and append the parent.  We want implied
 859   # directories to come before further directories inferred from the
 860   # configuration components; this ensures that for sysv4, unix/common
 861   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 862   # after sysv4).
 863   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 864   test -n "$sysnames" && set $sysnames
 865 done
 866
 867 # Add the default directories.
 868 default_sysnames="sysdeps/generic"
 869 sysnames="$names $default_sysnames"
 870 AC_SUBST(sysnames)
 871 # The other names were emitted during the scan.
 872 AC_MSG_RESULT($default_sysnames)
 873
 874 # Collect the list of add-ons that supply partial sysdeps trees.
 875 sysdeps_add_ons=
 876 for add_on in $add_ons; do
 877   case "$add_on" in
 878   /*) xsrcdir= ;;
 879   *) xsrcdir="$srcdir/" ;;
 880   esac
 881
 882   test -d "$xsrcdir$add_on/sysdeps" || {
 883     case "$configured_add_ons " in
 884     *" $add_on "*) ;;
 885     *|'')
 886       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 887       ;;
 888     esac
 889     continue
 890   }
 891
 892   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 893   case "$sysnames_add_ons" in
 894   *" $add_on/ "*) ;;
 895   *|'')
 896     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 897     continue ;;
 898   esac
 899
 900   found=no
 901   for d in $sysnames; do
 902     case "$d" in
 903     $add_on/sysdeps/*) ;;
 904     *) continue ;;
 905     esac
 906     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 907        case "$f" in
 908        sys|bits)
 909          for ff in $f/*.h; do
 910            test -d "$ff" || { test -e "$ff" && exit 88; }
 911          done
 912          ;;
 913        *)
 914          test -d "$f" || { test -e "$f" && exit 88; }
 915          ;;
 916        esac
 917      done)
 918     if test $? -eq 88; then
 919       found=yes
 920       break
 921     fi
 922   done
 923   if test $found = no; then
 924     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 925   fi
 926 done
 927 AC_SUBST(sysdeps_add_ons)
 928
 929
 930 ### Locate tools.
 931
 932 AC_PROG_INSTALL
 933 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 934   # The makefiles need to use a different form to find it in $srcdir.
 935   INSTALL='\$(..)./scripts/install-sh -c'
 936 fi
 937 AC_PROG_LN_S
 938
 939 LIBC_PROG_BINUTILS
 940
 941 # Accept binutils 2.22 or newer.
 942 AC_CHECK_PROG_VER(AS, $AS, --version,
 943                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 944                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 945                   AS=: critic_missing="$critic_missing as")
 946 AC_CHECK_PROG_VER(LD, $LD, --version,
 947                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 948                   [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 949                   LD=: critic_missing="$critic_missing ld")
 950
 951 # These programs are version sensitive.
 952 AC_CHECK_TOOL_PREFIX
 953 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 954   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 955   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 956
 957 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 958   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 959   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 960   MSGFMT=: aux_missing="$aux_missing msgfmt")
 961 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 962   [GNU texinfo.* \([0-9][0-9.]*\)],
 963   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
 964   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 965 AC_CHECK_PROG_VER(SED, sed, --version,
 966   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 967   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 968   SED=: aux_missing="$aux_missing sed")
 969 AC_CHECK_PROG_VER(AWK, gawk, --version,
 970   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 971   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
 972
 973 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
 974 AC_TRY_COMPILE([], [
 975 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 976 #error insufficient compiler
 977 #endif],
 978                [libc_cv_compiler_ok=yes],
 979                [libc_cv_compiler_ok=no])])
 980 AS_IF([test $libc_cv_compiler_ok != yes],
 981       [critic_missing="$critic_missing compiler"])
 982
 983 AC_CHECK_TOOL(NM, nm, false)
 984
 985 if test "x$maintainer" = "xyes"; then
 986   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 987   case "x$AUTOCONF" in
 988   xno|x|x:) AUTOCONF=no ;;
 989   *)
 990     AC_CACHE_CHECK(dnl
 991   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 992     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
 993       libc_cv_autoconf_works=yes
 994     else
 995       libc_cv_autoconf_works=no
 996     fi])
 997     test $libc_cv_autoconf_works = yes || AUTOCONF=no
 998     ;;
 999   esac
1000   if test "x$AUTOCONF" = xno; then
1001     aux_missing="$aux_missing autoconf"
1002   fi
1003 else
1004   AUTOCONF=no
1005 fi
1006
1007 test -n "$critic_missing" && AC_MSG_ERROR([
1008 *** These critical programs are missing or too old:$critic_missing
1009 *** Check the INSTALL file for required versions.])
1010
1011 test -n "$aux_missing" && AC_MSG_WARN([
1012 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1013 *** some features will be disabled.
1014 *** Check the INSTALL file for required versions.])
1015
1016 # if using special system headers, find out the compiler's sekrit
1017 # header directory and add that to the list.  NOTE: Only does the right
1018 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1019 if test -n "$sysheaders"; then
1020   SYSINCLUDES=-nostdinc
1021   for d in include include-fixed; do
1022     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1023     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1024   done
1025   SYSINCLUDES="$SYSINCLUDES \
1026 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1027   if test -n "$CXX"; then
1028     CXX_SYSINCLUDES=
1029     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1030     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1031       test "x$cxxheaders" != x &&
1032       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1033     done
1034   fi
1035 fi
1036 AC_SUBST(SYSINCLUDES)
1037 AC_SUBST(CXX_SYSINCLUDES)
1038
1039 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1040 # since this would lead to problems installing/building glibc.
1041 # LD_LIBRARY_PATH contains the current directory if one of the following
1042 # is true:
1043 # - one of the terminals (":" and ";") is the first or last sign
1044 # - two terminals occur directly after each other
1045 # - the path contains an element with a dot in it
1046 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1047 changequote(,)dnl
1048 case ${LD_LIBRARY_PATH} in
1049   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1050     ld_library_path_setting="contains current directory"
1051     ;;
1052   *)
1053     ld_library_path_setting="ok"
1054     ;;
1055 esac
1056 changequote([,])dnl
1057 AC_MSG_RESULT($ld_library_path_setting)
1058 if test "$ld_library_path_setting" != "ok"; then
1059 AC_MSG_ERROR([
1060 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1061 *** building glibc. Please change the environment variable
1062 *** and run configure again.])
1063 fi
1064
1065 AC_PATH_PROG(BASH_SHELL, bash, no)
1066
1067 AC_PATH_PROG(PERL, perl, no)
1068 if test "$PERL" != no &&
1069    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1070   PERL=no
1071 fi
1072 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1073              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1074 AC_CHECK_PROG_VER(BISON, bison, --version,
1075                   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1076                   [2.7*|[3-9].*|[1-9][0-9]*],
1077                   BISON=no)
1078
1079 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1080 cat > conftest.s <<EOF
1081 .text
1082 foo:
1083 .set glibc_conftest_frobozz,foo
1084 .globl glibc_conftest_frobozz
1085 EOF
1086 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1087 # (but it doesn't work), so we must do a linking check to be sure.
1088 cat > conftest1.c <<\EOF
1089 extern int glibc_conftest_frobozz;
1090 void _start() { glibc_conftest_frobozz = 1; }
1091 EOF
1092 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1093             -nostartfiles -nostdlib \
1094             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1095   libc_cv_asm_set_directive=yes
1096 else
1097   libc_cv_asm_set_directive=no
1098 fi
1099 rm -f conftest*])
1100 if test $libc_cv_asm_set_directive = yes; then
1101   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1102 fi
1103
1104 AC_CACHE_CHECK(linker support for protected data symbol,
1105                libc_cv_protected_data,
1106                [cat > conftest.c <<EOF
1107                 int bar __attribute__ ((visibility ("protected"))) = 1;
1108 EOF
1109                 libc_cv_protected_data=no
1110                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles -fPIC -shared conftest.c -o conftest.so); then
1111                   cat > conftest.c <<EOF
1112                   extern int bar;
1113                   int main (void) { return bar; }
1114 EOF
1115                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles conftest.c -o conftest conftest.so); then
1116                     libc_cv_protected_data=yes
1117                   fi
1118                 fi
1119                 rm -f conftest.*
1120                ])
1121 AC_SUBST(libc_cv_protected_data)
1122
1123 AC_CACHE_CHECK(for broken __attribute__((alias())),
1124                libc_cv_broken_alias_attribute,
1125                [cat > conftest.c <<EOF
1126                extern int foo (int x) __asm ("xyzzy");
1127                int bar (int x) { return x; }
1128                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1129                extern int dfoo;
1130                extern __typeof (dfoo) dfoo __asm ("abccb");
1131                int dfoo = 1;
1132 EOF
1133                libc_cv_broken_alias_attribute=yes
1134                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1135                  if grep 'xyzzy' conftest.s >/dev/null &&
1136                     grep 'abccb' conftest.s >/dev/null; then
1137                    libc_cv_broken_alias_attribute=no
1138                  fi
1139                fi
1140                rm -f conftest.c conftest.s
1141                ])
1142 if test $libc_cv_broken_alias_attribute = yes; then
1143   AC_MSG_ERROR(working alias attribute support required)
1144 fi
1145
1146 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1147                libc_cv_have_sdata_section,
1148                [echo "int i;" > conftest.c
1149                 libc_cv_have_sdata_section=no
1150                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1151                    | grep '\.sdata' >/dev/null; then
1152                   libc_cv_have_sdata_section=yes
1153                 fi
1154                 rm -f conftest.c conftest.so
1155                ])
1156 if test $libc_cv_have_sdata_section = yes; then
1157   AC_DEFINE(HAVE_SDATA_SECTION)
1158 fi
1159
1160 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1161                libc_cv_ctors_header, [dnl
1162   libc_cv_ctors_header=yes
1163   LIBC_TRY_LINK_STATIC([
1164 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1165 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1166 ],
1167               [dnl
1168       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1169         { gsub(/\@<:@ */, "@<:@") }
1170         $2 == ".ctors" || $2 == ".dtors" {
1171           size = strtonum("0x" $6)
1172           align = strtonum("0x" $NF)
1173           seen@<:@$2@:>@ = 1
1174           stub@<:@$2@:>@ = size == align * 2
1175         }
1176         END {
1177           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1178           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1179           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1180         }
1181       '], [libc_cv_ctors_header=no])
1182     ], [dnl
1183       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1184     ])
1185 ])
1186 if test $libc_cv_ctors_header = no; then
1187   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1188 fi
1189
1190 AC_CACHE_CHECK(for libunwind-support in compiler,
1191                libc_cv_cc_with_libunwind, [
1192   cat > conftest.c <<EOF
1193 int main (void) { return 0; }
1194 EOF
1195   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1196      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1197     libc_cv_cc_with_libunwind=yes
1198   else
1199     libc_cv_cc_with_libunwind=no
1200   fi
1201   rm -f conftest*])
1202 AC_SUBST(libc_cv_cc_with_libunwind)
1203 if test $libc_cv_cc_with_libunwind = yes; then
1204   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1205 fi
1206
1207 ASFLAGS_config=
1208 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1209                libc_cv_as_noexecstack, [dnl
1210 cat > conftest.c <<EOF
1211 void foo (void) { }
1212 EOF
1213 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1214                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1215    && grep .note.GNU-stack conftest.s >/dev/null \
1216    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1217                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1218 then
1219   libc_cv_as_noexecstack=yes
1220 else
1221   libc_cv_as_noexecstack=no
1222 fi
1223 rm -f conftest*])
1224 if test $libc_cv_as_noexecstack = yes; then
1225   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1226 fi
1227 AC_SUBST(ASFLAGS_config)
1228
1229 AC_CACHE_CHECK(for -z combreloc,
1230                libc_cv_z_combreloc, [dnl
1231 cat > conftest.c <<EOF
1232 extern int bar (int);
1233 extern int mumble;
1234 int foo (void) { return bar (mumble); }
1235 EOF
1236 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1237                         -fPIC -shared -o conftest.so conftest.c
1238                         -nostdlib -nostartfiles
1239                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1240 then
1241 dnl The following test is a bit weak.  We must use a tool which can test
1242 dnl cross-platform since the gcc used can be a cross compiler.  Without
1243 dnl introducing new options this is not easily doable.  Instead use a tool
1244 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1245 dnl look for a section named .rel.dyn.
1246   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1247     libc_cv_z_combreloc=yes
1248   else
1249     libc_cv_z_combreloc=no
1250   fi
1251 else
1252   libc_cv_z_combreloc=no
1253 fi
1254 rm -f conftest*])
1255 if test "$libc_cv_z_combreloc" = yes; then
1256   AC_DEFINE(HAVE_Z_COMBRELOC)
1257 fi
1258 AC_SUBST(libc_cv_z_combreloc)
1259
1260 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1261                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1262 AC_SUBST(libc_cv_z_execstack)
1263
1264 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1265 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1266 ])
1267
1268 AC_SUBST(libc_cv_fpie)
1269
1270 AC_CACHE_CHECK(for --hash-style option,
1271                libc_cv_hashstyle, [dnl
1272 cat > conftest.c <<EOF
1273 int _start (void) { return 42; }
1274 EOF
1275 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1276                             -fPIC -shared -o conftest.so conftest.c
1277                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1278 then
1279   libc_cv_hashstyle=yes
1280 else
1281   libc_cv_hashstyle=no
1282 fi
1283 rm -f conftest*])
1284 AC_SUBST(libc_cv_hashstyle)
1285
1286 # The linker's default -shared behavior is good enough if it
1287 # does these things that our custom linker scripts ensure that
1288 # all allocated NOTE sections come first.
1289 if test "$use_default_link" = default; then
1290   AC_CACHE_CHECK([for sufficient default -shared layout],
1291                   libc_cv_use_default_link, [dnl
1292   libc_cv_use_default_link=no
1293   cat > conftest.s <<\EOF
1294           .section .note.a,"a",%note
1295           .balign 4
1296           .long 4,4,9
1297           .string "GNU"
1298           .string "foo"
1299           .section .note.b,"a",%note
1300           .balign 4
1301           .long 4,4,9
1302           .string "GNU"
1303           .string "bar"
1304 EOF
1305   if AC_TRY_COMMAND([dnl
1306   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1307        ac_try=`$READELF -S conftest.so | sed -n \
1308          ['${x;p;}
1309           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1310           t a
1311           b
1312           : a
1313           H']`
1314   then
1315     libc_seen_a=no libc_seen_b=no
1316     set -- $ac_try
1317     while test $# -ge 2 -a "$1" = NOTE; do
1318       case "$2" in
1319       .note.a) libc_seen_a=yes ;;
1320       .note.b) libc_seen_b=yes ;;
1321       esac
1322       shift 2
1323     done
1324     case "$libc_seen_a$libc_seen_b" in
1325     yesyes)
1326       libc_cv_use_default_link=yes
1327       ;;
1328     *)
1329       echo >&AS_MESSAGE_LOG_FD "\
1330 $libc_seen_a$libc_seen_b from:
1331 $ac_try"
1332       ;;
1333     esac
1334   fi
1335   rm -f conftest*])
1336   use_default_link=$libc_cv_use_default_link
1337 fi
1338
1339 AC_CACHE_CHECK(for GLOB_DAT reloc,
1340                libc_cv_has_glob_dat, [dnl
1341 cat > conftest.c <<EOF
1342 extern int mumble;
1343 int foo (void) { return mumble; }
1344 EOF
1345 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1346                         -fPIC -shared -o conftest.so conftest.c
1347                         -nostdlib -nostartfiles
1348                         1>&AS_MESSAGE_LOG_FD])
1349 then
1350 dnl look for GLOB_DAT relocation.
1351   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1352     libc_cv_has_glob_dat=yes
1353   else
1354     libc_cv_has_glob_dat=no
1355   fi
1356 else
1357   libc_cv_has_glob_dat=no
1358 fi
1359 rm -f conftest*])
1360 AC_SUBST(libc_cv_has_glob_dat)
1361
1362 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1363 if libc_cv_output_format=`
1364 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1365 then
1366   :
1367 else
1368   libc_cv_output_format=
1369 fi
1370 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1371 AC_SUBST(libc_cv_output_format)
1372
1373 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1374 cat > conftest.c <<EOF
1375 int foo;
1376 EOF
1377 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1378                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1379 then
1380   libc_cv_fno_toplevel_reorder=yes
1381 else
1382   libc_cv_fno_toplevel_reorder=no
1383 fi
1384 rm -f conftest*])
1385 if test $libc_cv_fno_toplevel_reorder = yes; then
1386   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1387 else
1388   fno_unit_at_a_time=-fno-unit-at-a-time
1389 fi
1390 AC_SUBST(fno_unit_at_a_time)
1391
1392 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1393 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1394                    [libc_cv_ssp=yes],
1395                    [libc_cv_ssp=no])
1396 ])
1397
1398 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
1399 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
1400                    [libc_cv_ssp_strong=yes],
1401                    [libc_cv_ssp_strong=no])
1402 ])
1403
1404 stack_protector=
1405 if test "$libc_cv_ssp_strong" = "yes"; then
1406   stack_protector="-fstack-protector-strong"
1407 elif test "$libc_cv_ssp" = "yes"; then
1408   stack_protector="-fstack-protector"
1409 fi
1410 AC_SUBST(stack_protector)
1411
1412 AC_CACHE_CHECK(whether cc puts quotes around section names,
1413                libc_cv_have_section_quotes,
1414                [cat > conftest.c <<EOF
1415                 static const int foo
1416                 __attribute__ ((section ("bar"))) = 1;
1417 EOF
1418                 if ${CC-cc} -S conftest.c -o conftest.s; then
1419                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1420                     libc_cv_have_section_quotes=yes
1421                   else
1422                     libc_cv_have_section_quotes=no
1423                   fi
1424                 else
1425                   libc_cv_have_section_quotes=unknown
1426                 fi
1427                 rm -f conftest.{c,s}
1428                 ])
1429 if test $libc_cv_have_section_quotes = yes; then
1430   AC_DEFINE(HAVE_SECTION_QUOTES)
1431 fi
1432
1433 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1434 cat > conftest.c <<\EOF
1435 void zero (void *x)
1436 {
1437   __builtin_memset (x, 0, 1000);
1438 }
1439 EOF
1440 dnl
1441 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1442 then
1443   libc_cv_gcc_builtin_memset=no
1444 else
1445   libc_cv_gcc_builtin_memset=yes
1446 fi
1447 rm -f conftest* ])
1448 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1449   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1450 fi
1451
1452 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1453 cat > conftest.c <<\EOF
1454 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1455 char *foo (const char *a, const char *b)
1456 {
1457   return __builtin_strstr (a, b);
1458 }
1459 EOF
1460 dnl
1461 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1462 then
1463   libc_cv_gcc_builtin_redirection=yes
1464 else
1465   libc_cv_gcc_builtin_redirection=no
1466 fi
1467 rm -f conftest* ])
1468 if test "$libc_cv_gcc_builtin_redirection" = no; then
1469   AC_MSG_ERROR([support for the symbol redirection needed])
1470 fi
1471
1472 dnl Determine how to disable generation of FMA instructions.
1473 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1474                libc_cv_cc_nofma, [dnl
1475 libc_cv_cc_nofma=
1476 for opt in -ffp-contract=off -mno-fused-madd; do
1477   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1478 done])
1479 AC_SUBST(libc_cv_cc_nofma)
1480
1481 if test -n "$submachine"; then
1482   AC_CACHE_CHECK([for compiler option for CPU variant],
1483                  libc_cv_cc_submachine, [dnl
1484   libc_cv_cc_submachine=no
1485   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1486     LIBC_TRY_CC_OPTION([$opt], [
1487       libc_cv_cc_submachine="$opt"
1488       break], [])
1489   done])
1490   if test "x$libc_cv_cc_submachine" = xno; then
1491     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1492   fi
1493 fi
1494 AC_SUBST(libc_cv_cc_submachine)
1495
1496 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1497 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1498 cat > conftest.c <<EOF
1499 void
1500 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1501 foo (void) {}
1502 EOF
1503 libc_cv_cc_loop_to_function=no
1504 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1505 then
1506   libc_cv_cc_loop_to_function=yes
1507 fi
1508 rm -f conftest*])
1509 if test $libc_cv_cc_loop_to_function = yes; then
1510   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1511 fi
1512 AC_SUBST(libc_cv_cc_loop_to_function)
1513
1514 dnl Check whether we have the gd library available.
1515 AC_MSG_CHECKING(for libgd)
1516 if test "$with_gd" != "no"; then
1517   old_CFLAGS="$CFLAGS"
1518   CFLAGS="$CFLAGS $libgd_include"
1519   old_LDFLAGS="$LDFLAGS"
1520   LDFLAGS="$LDFLAGS $libgd_ldflags"
1521   old_LIBS="$LIBS"
1522   LIBS="$LIBS -lgd -lpng -lz -lm"
1523   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1524   CFLAGS="$old_CFLAGS"
1525   LDFLAGS="$old_LDFLAGS"
1526   LIBS="$old_LIBS"
1527 else
1528   LIBGD=no
1529 fi
1530 AC_MSG_RESULT($LIBGD)
1531 AC_SUBST(LIBGD)
1532
1533 # SELinux detection
1534 if test x$with_selinux = xno ; then
1535   have_selinux=no;
1536 else
1537   # See if we have the SELinux library
1538   AC_CHECK_LIB(selinux, is_selinux_enabled,
1539                have_selinux=yes, have_selinux=no)
1540   if test x$with_selinux = xyes ; then
1541     if test x$have_selinux = xno ; then
1542       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1543     fi
1544   fi
1545 fi
1546 # Check if we're building with SELinux support.
1547 if test "x$have_selinux" = xyes; then
1548   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1549
1550   # See if we have the libaudit library
1551   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1552                have_libaudit=yes, have_libaudit=no)
1553   if test "x$have_libaudit" = xyes; then
1554     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1555   fi
1556   AC_SUBST(have_libaudit)
1557
1558   # See if we have the libcap library
1559   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1560   if test "x$have_libcap" = xyes; then
1561     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1562   fi
1563   AC_SUBST(have_libcap)
1564 fi
1565 AC_SUBST(have_selinux)
1566
1567 CPPUNDEFS=
1568 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1569 dnl Since we are building the implementations of the fortified functions here,
1570 dnl having the macro defined interacts very badly.
1571 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1572 [AC_TRY_COMPILE([], [
1573 #ifdef _FORTIFY_SOURCE
1574 # error bogon
1575 #endif],
1576                 [libc_cv_predef_fortify_source=no],
1577                 [libc_cv_predef_fortify_source=yes])])
1578 if test $libc_cv_predef_fortify_source = yes; then
1579   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1580 fi
1581 AC_SUBST(CPPUNDEFS)
1582
1583 dnl Check for silly hacked compilers inserting -fstack-protector.
1584 dnl This breaks badly for the early startup code we compile, since
1585 dnl the compiled code can refer to a magic machine-dependent location
1586 dnl for the canary value before we have sufficient setup for that to
1587 dnl work.  It's also questionable to build all of libc with this flag
1588 dnl even when you're doing that for most applications you build, since
1589 dnl libc's code is so heavily-used and performance-sensitive.  If we
1590 dnl ever really want to make that work, it should be enabled explicitly
1591 dnl in the libc build, not inherited from implicit compiler settings.
1592 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
1593                libc_cv_predef_stack_protector, [
1594 AC_TRY_COMPILE([extern void foobar (char *);],
1595                [char large_array[2048]; foobar (large_array);], [
1596 libc_undefs=`$NM -u conftest.o |
1597   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1598     2>&AS_MESSAGE_LOG_FD` || {
1599   AC_MSG_ERROR([confusing output from $NM -u])
1600 }
1601 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1602 # On some architectures, there are architecture-specific undefined
1603 # symbols (resolved by the linker), so filter out unknown symbols.
1604 # This will fail to produce the correct result if the compiler
1605 # defaults to -fstack-protector but this produces an undefined symbol
1606 # other than __stack_chk_fail.  However, compilers like that have not
1607 # been encountered in practice.
1608 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
1609 case "$libc_undefs" in
1610 foobar) libc_cv_predef_stack_protector=no ;;
1611 '__stack_chk_fail
1612 foobar') libc_cv_predef_stack_protector=yes ;;
1613 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
1614 esac],
1615                [AC_MSG_ERROR([test compilation failed])])
1616 ])
1617 libc_extra_cflags=
1618 if test $libc_cv_predef_stack_protector = yes; then
1619   libc_extra_cflags="$libc_extra_cflags -fno-stack-protector"
1620 fi
1621 libc_extra_cppflags=
1622
1623 # Some linkers on some architectures support __ehdr_start but with
1624 # bugs.  Make sure usage of it does not create relocations in the
1625 # output (as the linker should resolve them all for us).
1626 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1627                libc_cv_ehdr_start, [
1628 old_CFLAGS="$CFLAGS"
1629 old_LDFLAGS="$LDFLAGS"
1630 old_LIBS="$LIBS"
1631 CFLAGS="$CFLAGS -fPIC"
1632 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared"
1633 LIBS=
1634 AC_LINK_IFELSE([AC_LANG_SOURCE([
1635 typedef struct {
1636   char foo;
1637   long val;
1638 } Ehdr;
1639 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1640 long ehdr (void) { return __ehdr_start.val; }
1641 ])],
1642                [if $READELF -r conftest | fgrep __ehdr_start >/dev/null; then
1643                   libc_cv_ehdr_start=broken
1644                 else
1645                   libc_cv_ehdr_start=yes
1646                 fi], [libc_cv_ehdr_start=no])
1647 CFLAGS="$old_CFLAGS"
1648 LDFLAGS="$old_LDFLAGS"
1649 LIBS="$old_LIBS"
1650 ])
1651 if test "$libc_cv_ehdr_start" = yes; then
1652   AC_DEFINE([HAVE_EHDR_START])
1653 elif test "$libc_cv_ehdr_start" = broken; then
1654   AC_MSG_WARN([linker is broken -- you should upgrade])
1655 fi
1656
1657 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1658                libc_cv_builtin_trap, [dnl
1659 libc_cv_builtin_trap=no
1660 AC_TRY_COMPILE([], [__builtin_trap ()], [
1661 libc_undefs=`$NM -u conftest.o |
1662   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1663     2>&AS_MESSAGE_LOG_FD` || {
1664   AC_MSG_ERROR([confusing output from $NM -u])
1665 }
1666 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1667 if test -z "$libc_undefs"; then
1668   libc_cv_builtin_trap=yes
1669 fi])])
1670 if test $libc_cv_builtin_trap = yes; then
1671   AC_DEFINE([HAVE_BUILTIN_TRAP])
1672 fi
1673
1674 dnl C++ feature tests.
1675 AC_LANG_PUSH([C++])
1676
1677 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1678                libc_cv_cxx_thread_local, [
1679 old_CXXFLAGS="$CXXFLAGS"
1680 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1681 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1682 #include <thread>
1683
1684 // Compiler support.
1685 struct S
1686 {
1687   S ();
1688   ~S ();
1689 };
1690 thread_local S s;
1691 S * get () { return &s; }
1692
1693 // libstdc++ support.
1694 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1695 #error __cxa_thread_atexit_impl not supported
1696 #endif
1697 ])],
1698                [libc_cv_cxx_thread_local=yes],
1699                [libc_cv_cxx_thread_local=no])
1700 CXXFLAGS="$old_CXXFLAGS"
1701 ])
1702 AC_SUBST(libc_cv_cxx_thread_local)
1703
1704 AC_LANG_POP([C++])
1705 dnl End of C++ feature tests.
1706
1707 ### End of automated tests.
1708 ### Now run sysdeps configure fragments.
1709
1710 # They also can set these variables.
1711 use_ldconfig=no
1712 ldd_rewrite_script=no
1713 libc_cv_sysconfdir=$sysconfdir
1714 libc_cv_localstatedir=$localstatedir
1715 libc_cv_gcc_unwind_find_fde=no
1716 libc_cv_idn=no
1717
1718 # Iterate over all the sysdep directories we will use, running their
1719 # configure fragments.
1720 for dir in $sysnames; do
1721   case $dir in
1722     /*) dest=$dir ;;
1723     *)  dest=$srcdir/$dir ;;
1724   esac
1725   if test -r $dest/configure; then
1726     AC_MSG_RESULT(running configure fragment for $dir)
1727     . $dest/configure
1728   fi
1729 done
1730
1731 if test x"$build_mathvec" = xnotset; then
1732   build_mathvec=no
1733 fi
1734 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1735
1736 AC_SUBST(libc_extra_cflags)
1737 AC_SUBST(libc_extra_cppflags)
1738
1739 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1740   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1741 fi
1742 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1743
1744 # A sysdeps configure fragment can reset this if IFUNC is not actually
1745 # usable even though the assembler knows how to generate the symbol type.
1746 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1747   AC_DEFINE(HAVE_IFUNC)
1748 fi
1749
1750 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1751 # configure fragment can override the value to prevent this AC_DEFINE.
1752 AC_SUBST(use_nscd)
1753 if test "x$use_nscd" != xno; then
1754   AC_DEFINE([USE_NSCD])
1755 fi
1756 if test "x$build_nscd" = xdefault; then
1757   build_nscd=$use_nscd
1758 fi
1759
1760 AC_SUBST(libc_cv_slibdir)
1761 AC_SUBST(libc_cv_rtlddir)
1762 AC_SUBST(libc_cv_complocaledir)
1763 AC_SUBST(libc_cv_sysconfdir)
1764 AC_SUBST(libc_cv_localstatedir)
1765 AC_SUBST(libc_cv_rootsbindir)
1766
1767 if test x$use_ldconfig = xyes; then
1768   AC_DEFINE(USE_LDCONFIG)
1769 fi
1770 AC_SUBST(use_ldconfig)
1771 AC_SUBST(ldd_rewrite_script)
1772
1773 AC_SUBST(static)
1774 AC_SUBST(shared)
1775
1776 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1777 [libc_cv_pic_default=yes
1778 cat > conftest.c <<EOF
1779 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1780 # error PIC is default.
1781 #endif
1782 EOF
1783 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1784   libc_cv_pic_default=no
1785 fi
1786 rm -f conftest.*])
1787 AC_SUBST(libc_cv_pic_default)
1788
1789 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1790 [libc_cv_pie_default=yes
1791 cat > conftest.c <<EOF
1792 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1793 # error PIE is default.
1794 #endif
1795 EOF
1796 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1797   libc_cv_pie_default=no
1798 fi
1799 rm -f conftest.*])
1800 AC_SUBST(libc_cv_pie_default)
1801
1802 AC_SUBST(profile)
1803 AC_SUBST(static_nss)
1804
1805 AC_SUBST(DEFINES)
1806
1807 dnl See sysdeps/mach/configure.ac for this variable.
1808 AC_SUBST(mach_interface_list)
1809
1810 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1811 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1812 AC_SUBST(VERSION)
1813 AC_SUBST(RELEASE)
1814
1815 AC_CONFIG_FILES([config.make Makefile])
1816 AC_CONFIG_COMMANDS([default],[[
1817 case $CONFIG_FILES in *config.make*)
1818 echo "$config_vars" >> config.make;;
1819 esac
1820 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1821 AC_OUTPUT