sysdeps/i386/fpu/e_hypot.S

   1 /* Compute the hypothenuse of X and Y.
   2    Copyright (C) 1998-2017 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Ulrich Drepper <drepper@cygnus.com>, 1998.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <i386-math-asm.h>
  22
  23 DEFINE_DBL_MIN
  24
  25 #ifdef PIC
  26 # define MO(op) op##@GOTOFF(%edx)
  27 #else
  28 # define MO(op) op
  29 #endif
  30
  31         .text
  32 ENTRY(__ieee754_hypot)
  33 #ifdef  PIC
  34         LOAD_PIC_REG (dx)
  35 #endif
  36         fldl    4(%esp)         // x
  37         fxam
  38         fnstsw
  39         fldl    12(%esp)        // y : x
  40         movb    %ah, %ch
  41         fxam
  42         fnstsw
  43         movb    %ah, %al
  44         orb     %ch, %ah
  45         sahf
  46         jc      1f
  47         fmul    %st(0)          // y * y : x
  48         fxch                    // x : y * y
  49         fmul    %st(0)          // x * x : y * y
  50         faddp                   // x * x + y * y
  51         fsqrt
  52         DBL_NARROW_EVAL_UFLOW_NONNEG
  53 2:      ret
  54
  55         // We have to test whether any of the parameters is Inf.
  56         // In this case the result is infinity.
  57 1:      andb    $0x45, %al
  58         cmpb    $5, %al
  59         je      3f              // jump if y is Inf
  60         andb    $0x45, %ch
  61         cmpb    $5, %ch
  62         jne     4f              // jump if x is not Inf
  63         fxch
  64 3:      fstp    %st(1)
  65         fabs
  66         jmp     2b
  67
  68 4:      testb   $1, %al
  69         jnz     5f              // y is NaN
  70         fxch
  71 5:      fstp    %st(1)
  72         jmp     2b
  73
  74 END(__ieee754_hypot)
  75 strong_alias (__ieee754_hypot, __hypot_finite)