sysdeps/riscv/setjmp.S

   1 /* setjmp for RISC-V.
   2    Copyright (C) 1996-2022 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <https://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <sys/asm.h>
  21
  22 ENTRY (_setjmp)
  23   li    a1, 0
  24   j     HIDDEN_JUMPTARGET (__sigsetjmp)
  25 END (_setjmp)
  26 ENTRY (setjmp)
  27   li    a1, 1
  28   /* Fallthrough */
  29 END (setjmp)
  30 ENTRY (__sigsetjmp)
  31         REG_S ra,  0*SZREG(a0)
  32         REG_S s0,  1*SZREG(a0)
  33         REG_S s1,  2*SZREG(a0)
  34         REG_S s2,  3*SZREG(a0)
  35         REG_S s3,  4*SZREG(a0)
  36         REG_S s4,  5*SZREG(a0)
  37         REG_S s5,  6*SZREG(a0)
  38         REG_S s6,  7*SZREG(a0)
  39         REG_S s7,  8*SZREG(a0)
  40         REG_S s8,  9*SZREG(a0)
  41         REG_S s9, 10*SZREG(a0)
  42         REG_S s10,11*SZREG(a0)
  43         REG_S s11,12*SZREG(a0)
  44         REG_S sp, 13*SZREG(a0)
  45
  46 #ifndef __riscv_float_abi_soft
  47         FREG_S fs0, 14*SZREG+ 0*SZFREG(a0)
  48         FREG_S fs1, 14*SZREG+ 1*SZFREG(a0)
  49         FREG_S fs2, 14*SZREG+ 2*SZFREG(a0)
  50         FREG_S fs3, 14*SZREG+ 3*SZFREG(a0)
  51         FREG_S fs4, 14*SZREG+ 4*SZFREG(a0)
  52         FREG_S fs5, 14*SZREG+ 5*SZFREG(a0)
  53         FREG_S fs6, 14*SZREG+ 6*SZFREG(a0)
  54         FREG_S fs7, 14*SZREG+ 7*SZFREG(a0)
  55         FREG_S fs8, 14*SZREG+ 8*SZFREG(a0)
  56         FREG_S fs9, 14*SZREG+ 9*SZFREG(a0)
  57         FREG_S fs10,14*SZREG+10*SZFREG(a0)
  58         FREG_S fs11,14*SZREG+11*SZFREG(a0)
  59 #endif
  60
  61 #if !IS_IN (libc) && IS_IN (rtld)
  62   /* In ld.so we never save the signal mask.  */
  63   li a0, 0
  64   ret
  65 #else
  66   /* Make a tail call to __sigjmp_save; it takes the same args.  */
  67   j __sigjmp_save
  68 #endif
  69
  70
  71 END (__sigsetjmp)
  72
  73 hidden_def (__sigsetjmp)
  74 weak_alias (_setjmp, __GI__setjmp)