sysdeps/aarch64/__longjmp.S

   1 /* Copyright (C) 1997-2023 Free Software Foundation, Inc.
   2
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public License as
   7    published by the Free Software Foundation; either version 2.1 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <https://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <pointer_guard.h>
  21 #include <jmpbuf-offsets.h>
  22 #include <stap-probe.h>
  23
  24 /* __longjmp(jmpbuf, val) */
  25
  26 ENTRY (__longjmp)
  27         cfi_def_cfa(x0, 0)
  28         cfi_offset(x19, JB_X19<<3)
  29         cfi_offset(x20, JB_X20<<3)
  30         cfi_offset(x21, JB_X21<<3)
  31         cfi_offset(x22, JB_X22<<3)
  32         cfi_offset(x23, JB_X23<<3)
  33         cfi_offset(x24, JB_X24<<3)
  34         cfi_offset(x25, JB_X25<<3)
  35         cfi_offset(x26, JB_X26<<3)
  36         cfi_offset(x27, JB_X27<<3)
  37         cfi_offset(x28, JB_X28<<3)
  38         cfi_offset(x29, JB_X29<<3)
  39         cfi_offset(x30, JB_LR<<3)
  40
  41         cfi_offset( d8, JB_D8<<3)
  42         cfi_offset( d9, JB_D9<<3)
  43         cfi_offset(d10, JB_D10<<3)
  44         cfi_offset(d11, JB_D11<<3)
  45         cfi_offset(d12, JB_D12<<3)
  46         cfi_offset(d13, JB_D13<<3)
  47         cfi_offset(d14, JB_D14<<3)
  48         cfi_offset(d15, JB_D15<<3)
  49
  50         PTR_ARG (0)
  51
  52         ldp     x19, x20, [x0, #JB_X19<<3]
  53         ldp     x21, x22, [x0, #JB_X21<<3]
  54         ldp     x23, x24, [x0, #JB_X23<<3]
  55         ldp     x25, x26, [x0, #JB_X25<<3]
  56         ldp     x27, x28, [x0, #JB_X27<<3]
  57 #ifdef PTR_DEMANGLE
  58         ldp     x29,  x4, [x0, #JB_X29<<3]
  59         PTR_DEMANGLE (30, 4, 3, 2)
  60 #else
  61         ldp     x29, x30, [x0, #JB_X29<<3]
  62 #endif
  63         /* longjmp probe takes 3 arguments, address of jump buffer as
  64            first argument (8@x0), return value as second argument (-4@x1),
  65            and target address (8@x30), respectively.  */
  66         LIBC_PROBE (longjmp, 3, 8@x0, -4@x1, 8@x30)
  67         ldp      d8,  d9, [x0, #JB_D8<<3]
  68         ldp     d10, d11, [x0, #JB_D10<<3]
  69         ldp     d12, d13, [x0, #JB_D12<<3]
  70         ldp     d14, d15, [x0, #JB_D14<<3]
  71
  72         /* Originally this was implemented with a series of
  73            .cfi_restore() directives.
  74
  75            The theory was that cfi_restore should revert to previous
  76            frame value is the same as the current value.  In practice
  77            this doesn't work, even after cfi_restore() gdb continues
  78            to try to recover a previous frame value offset from x0,
  79            which gets stuffed after a few more instructions.  The
  80            cfi_same_value() mechanism appears to work fine.  */
  81
  82         cfi_same_value(x19)
  83         cfi_same_value(x20)
  84         cfi_same_value(x21)
  85         cfi_same_value(x22)
  86         cfi_same_value(x23)
  87         cfi_same_value(x24)
  88         cfi_same_value(x25)
  89         cfi_same_value(x26)
  90         cfi_same_value(x27)
  91         cfi_same_value(x28)
  92         cfi_same_value(x29)
  93         cfi_same_value(x30)
  94         cfi_same_value(d8)
  95         cfi_same_value(d9)
  96         cfi_same_value(d10)
  97         cfi_same_value(d11)
  98         cfi_same_value(d12)
  99         cfi_same_value(d13)
 100         cfi_same_value(d14)
 101         cfi_same_value(d15)
 102 #ifdef PTR_DEMANGLE
 103         ldr     x4, [x0, #JB_SP<<3]
 104         PTR_DEMANGLE (5, 4, 3, 2)
 105 #else
 106         ldr     x5, [x0, #JB_SP<<3]
 107 #endif
 108         mov     sp, x5
 109
 110         /* longjmp_target probe takes 3 arguments, address of jump buffer
 111            as first argument (8@x0), return value as second argument (-4@x1),
 112            and target address (8@x30), respectively.  */
 113         LIBC_PROBE (longjmp_target, 3, 8@x0, -4@x1, 8@x30)
 114         cmp     x1, #0
 115         mov     x0, #1
 116         csel    x0, x1, x0, ne
 117         /* Use br instead of ret because ret is guaranteed to mispredict */
 118         br      x30
 119 END (__longjmp)