configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([binutils],
 131             AC_HELP_STRING([--with-binutils=PATH],
 132                            [specify location of binutils (as and ld)]),
 133             [path_binutils=$withval],
 134             [path_binutils=''])
 135 AC_ARG_WITH([selinux],
 136             AC_HELP_STRING([--with-selinux],
 137                            [if building with SELinux support]),
 138             [with_selinux=$withval],
 139             [with_selinux=auto])
 140
 141 AC_ARG_WITH([headers],
 142             AC_HELP_STRING([--with-headers=PATH],
 143                            [location of system headers to use
 144                             (for example /usr/src/linux/include)
 145                             @<:@default=compiler default@:>@]),
 146             [sysheaders=$withval],
 147             [sysheaders=''])
 148 AC_SUBST(sysheaders)
 149
 150 AC_SUBST(use_default_link)
 151 AC_ARG_WITH([default-link],
 152             AC_HELP_STRING([--with-default-link],
 153                            [do not use explicit linker scripts]),
 154             [use_default_link=$withval],
 155             [use_default_link=default])
 156
 157 AC_ARG_ENABLE([sanity-checks],
 158               AC_HELP_STRING([--disable-sanity-checks],
 159                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 160               [enable_sanity=$enableval],
 161               [enable_sanity=yes])
 162
 163 AC_ARG_ENABLE([shared],
 164               AC_HELP_STRING([--enable-shared],
 165                              [build shared library @<:@default=yes if GNU ld@:>@]),
 166               [shared=$enableval],
 167               [shared=yes])
 168 AC_ARG_ENABLE([profile],
 169               AC_HELP_STRING([--enable-profile],
 170                              [build profiled library @<:@default=no@:>@]),
 171               [profile=$enableval],
 172               [profile=no])
 173 AC_ARG_ENABLE([static-pie],
 174               AC_HELP_STRING([--enable-static-pie],
 175                              [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
 176               [static_pie=$enableval],
 177               [static_pie=no])
 178 AC_ARG_ENABLE([timezone-tools],
 179               AC_HELP_STRING([--disable-timezone-tools],
 180                              [do not install timezone tools @<:@default=install@:>@]),
 181               [enable_timezone_tools=$enableval],
 182               [enable_timezone_tools=yes])
 183 AC_SUBST(enable_timezone_tools)
 184
 185 AC_ARG_ENABLE([hardcoded-path-in-tests],
 186               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 187                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 188               [hardcoded_path_in_tests=$enableval],
 189               [hardcoded_path_in_tests=no])
 190 AC_SUBST(hardcoded_path_in_tests)
 191
 192 AC_ARG_ENABLE([stackguard-randomization],
 193               AC_HELP_STRING([--enable-stackguard-randomization],
 194                              [initialize __stack_chk_guard canary with a random number at program start]),
 195               [enable_stackguard_randomize=$enableval],
 196               [enable_stackguard_randomize=no])
 197 if test "$enable_stackguard_randomize" = yes; then
 198   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 199 fi
 200
 201 AC_ARG_ENABLE([hidden-plt],
 202               AC_HELP_STRING([--disable-hidden-plt],
 203                              [do not hide internal function calls to avoid PLT]),
 204               [hidden=$enableval],
 205               [hidden=yes])
 206 if test "x$hidden" = xno; then
 207   AC_DEFINE(NO_HIDDEN)
 208 fi
 209
 210 AC_ARG_ENABLE([bind-now],
 211               AC_HELP_STRING([--enable-bind-now],
 212                              [disable lazy relocations in DSOs]),
 213               [bindnow=$enableval],
 214               [bindnow=no])
 215 AC_SUBST(bindnow)
 216 if test "x$bindnow" = xyes; then
 217   AC_DEFINE(BIND_NOW)
 218 fi
 219
 220 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 221 dnl -fstack-protector-strong.
 222 AC_ARG_ENABLE([stack-protector],
 223               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 224                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 225               [enable_stack_protector=$enableval],
 226               [enable_stack_protector=no])
 227 case "$enable_stack_protector" in
 228 all|yes|no|strong) ;;
 229 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 230 esac
 231
 232 dnl On some platforms we cannot use dynamic loading.  We must provide
 233 dnl static NSS modules.
 234 AC_ARG_ENABLE([static-nss],
 235               AC_HELP_STRING([--enable-static-nss],
 236                              [build static NSS modules @<:@default=no@:>@]),
 237               [static_nss=$enableval],
 238               [static_nss=no])
 239 dnl Enable static NSS also if we build no shared objects.
 240 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 241   static_nss=yes
 242   AC_DEFINE(DO_STATIC_NSS)
 243 fi
 244
 245 AC_ARG_ENABLE([force-install],
 246               AC_HELP_STRING([--disable-force-install],
 247                              [don't force installation of files from this package, even if they are older than the installed files]),
 248               [force_install=$enableval],
 249               [force_install=yes])
 250 AC_SUBST(force_install)
 251
 252 AC_ARG_ENABLE([maintainer-mode],
 253               AC_HELP_STRING([--enable-maintainer-mode],
 254                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 255               [maintainer=$enableval],
 256               [maintainer=no])
 257
 258 dnl On some platforms we allow dropping compatibility with all kernel
 259 dnl versions.
 260 AC_ARG_ENABLE([kernel],
 261               AC_HELP_STRING([--enable-kernel=VERSION],
 262                              [compile for compatibility with kernel not older than VERSION]),
 263               [minimum_kernel=$enableval],
 264               [])
 265 dnl Prevent unreasonable values.
 266 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 267   # Better nothing than this.
 268   minimum_kernel=""
 269 else
 270   if test "$minimum_kernel" = current; then
 271     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 272   fi
 273 fi
 274
 275 dnl For the development we sometimes want gcc to issue even more warnings.
 276 dnl This is not the default since many of the extra warnings are not
 277 dnl appropriate.
 278 AC_ARG_ENABLE([all-warnings],
 279               AC_HELP_STRING([--enable-all-warnings],
 280                              [enable all useful warnings gcc can issue]),
 281               [all_warnings=$enableval],
 282               [])
 283 AC_SUBST(all_warnings)
 284
 285 AC_ARG_ENABLE([werror],
 286               AC_HELP_STRING([--disable-werror],
 287                              [do not build with -Werror]),
 288               [enable_werror=$enableval],
 289               [enable_werror=yes])
 290 AC_SUBST(enable_werror)
 291
 292 AC_ARG_ENABLE([multi-arch],
 293               AC_HELP_STRING([--enable-multi-arch],
 294                              [enable single DSO with optimizations for multiple architectures]),
 295               [multi_arch=$enableval],
 296               [multi_arch=default])
 297
 298 AC_ARG_ENABLE([experimental-malloc],
 299               AC_HELP_STRING([--disable-experimental-malloc],
 300                              [disable experimental malloc features]),
 301               [experimental_malloc=$enableval],
 302               [experimental_malloc=yes])
 303 AC_SUBST(experimental_malloc)
 304
 305 AC_ARG_ENABLE([crypt],
 306               AC_HELP_STRING([--disable-crypt],
 307                              [do not build nor install the passphrase hashing library, libcrypt]),
 308               [build_crypt=$enableval],
 309               [build_crypt=yes])
 310 AC_SUBST(build_crypt)
 311
 312 AC_ARG_ENABLE([nss-crypt],
 313               AC_HELP_STRING([--enable-nss-crypt],
 314                              [enable libcrypt to use nss]),
 315               [nss_crypt=$enableval],
 316               [nss_crypt=no])
 317 if test x$build_libcrypt = xno && test x$nss_crypt = xyes; then
 318   AC_MSG_WARN([--enable-nss-crypt has no effect when libcrypt is disabled])
 319   nss_crypt=no
 320 fi
 321 if test x$nss_crypt = xyes; then
 322   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 323   if test $? -ne 0; then
 324     AC_MSG_ERROR([cannot find include directory with nss-config])
 325   fi
 326   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 327   if test $? -ne 0; then
 328     AC_MSG_ERROR([cannot find include directory with nspr-config])
 329   fi
 330   old_CFLAGS="$CFLAGS"
 331   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 332   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 333 #include <hasht.h>
 334 #include <nsslowhash.h>
 335 void f (void) { NSSLOW_Init (); }])],
 336              libc_cv_nss_crypt=yes,
 337              AC_MSG_ERROR([
 338 cannot find NSS headers with lowlevel hash function interfaces]))
 339   old_LIBS="$LIBS"
 340   old_LDFLAGS="$LDFLAGS"
 341   LIBS="$LIBS -lfreebl3"
 342   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 343 #include <hasht.h>
 344 #include <nsslowhash.h>],
 345                                   [NSSLOW_Init();])],
 346                  libc_cv_nss_crypt=yes,
 347                  AC_MSG_ERROR([
 348 cannot link program using lowlevel NSS hash functions]))
 349   # Check to see if there is a static NSS cryptographic library.
 350   # If there isn't then we can't link anything with libcrypt.a,
 351   # and that might mean disabling some static tests.
 352   LDFLAGS="$LDFLAGS -static"
 353   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 354 #include <hasht.h>
 355 #include <nsslowhash.h>],
 356                                   [NSSLOW_Init();])],
 357                  libc_cv_static_nss_crypt=yes,
 358                  libc_cv_static_nss_crypt=no)
 359   LDFLAGS="$old_LDFLAGS"
 360   CFLAGS="$old_CFLAGS"
 361   LIBS="$old_LIBS"
 362 else
 363   libc_cv_nss_crypt=no
 364   libc_cv_static_nss_crypt=no
 365 fi
 366 AC_SUBST(libc_cv_nss_crypt)
 367 AC_SUBST(libc_cv_static_nss_crypt)
 368
 369
 370 AC_ARG_ENABLE([obsolete-rpc],
 371               AC_HELP_STRING([--enable-obsolete-rpc],
 372                              [build and install the obsolete RPC code for link-time usage]),
 373               [link_obsolete_rpc=$enableval],
 374               [link_obsolete_rpc=no])
 375 AC_SUBST(link_obsolete_rpc)
 376
 377 if test "$link_obsolete_rpc" = yes; then
 378   AC_DEFINE(LINK_OBSOLETE_RPC)
 379 fi
 380
 381 AC_ARG_ENABLE([obsolete-nsl],
 382               AC_HELP_STRING([--enable-obsolete-nsl],
 383                              [build and install the obsolete libnsl library and depending NSS modules]),
 384               [build_obsolete_nsl=$enableval],
 385               [build_obsolete_nsl=no])
 386 AC_SUBST(build_obsolete_nsl)
 387
 388 if test "$build_obsolete_nsl" = yes; then
 389   AC_DEFINE(LINK_OBSOLETE_NSL)
 390 fi
 391
 392 AC_ARG_ENABLE([systemtap],
 393               [AS_HELP_STRING([--enable-systemtap],
 394                [enable systemtap static probe points @<:@default=no@:>@])],
 395               [systemtap=$enableval],
 396               [systemtap=no])
 397 if test "x$systemtap" != xno; then
 398   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 399   old_CFLAGS="$CFLAGS"
 400   CFLAGS="-std=gnu11 $CFLAGS"
 401   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 402 void foo (int i, void *p)
 403 {
 404   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 405        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 406 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 407   CFLAGS="$old_CFLAGS"])
 408   if test $libc_cv_sdt = yes; then
 409     AC_DEFINE([USE_STAP_PROBE])
 410   elif test "x$systemtap" != xauto; then
 411     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 412   fi
 413 fi
 414
 415 AC_ARG_ENABLE([build-nscd],
 416               [AS_HELP_STRING([--disable-build-nscd],
 417                [disable building and installing the nscd daemon])],
 418               [build_nscd=$enableval],
 419               [build_nscd=default])
 420 AC_SUBST(build_nscd)
 421
 422 # Note the use of $use_nscd is near the bottom of the file.
 423 AC_ARG_ENABLE([nscd],
 424               [AS_HELP_STRING([--disable-nscd],
 425                [library functions will not contact the nscd daemon])],
 426               [use_nscd=$enableval],
 427               [use_nscd=yes])
 428
 429 AC_ARG_ENABLE([pt_chown],
 430               [AS_HELP_STRING([--enable-pt_chown],
 431                [Enable building and installing pt_chown])],
 432               [build_pt_chown=$enableval],
 433               [build_pt_chown=no])
 434 AC_SUBST(build_pt_chown)
 435 if test "$build_pt_chown" = yes; then
 436   AC_DEFINE(HAVE_PT_CHOWN)
 437 fi
 438
 439 AC_ARG_ENABLE([tunables],
 440               [AS_HELP_STRING([--enable-tunables],
 441                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 442               [have_tunables=$enableval],
 443               [have_tunables=yes])
 444 AC_SUBST(have_tunables)
 445 if test "$have_tunables" = yes; then
 446   AC_DEFINE(HAVE_TUNABLES)
 447 fi
 448
 449 # The abi-tags file uses a fairly simplistic model for name recognition that
 450 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 451 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 452 # This doesn't get used much beyond that, so it's fairly safe.
 453 case "$host_os" in
 454 linux*)
 455   ;;
 456 gnu*)
 457   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 458   ;;
 459 esac
 460
 461 AC_ARG_ENABLE([mathvec],
 462               [AS_HELP_STRING([--enable-mathvec],
 463               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 464               [build_mathvec=$enableval],
 465               [build_mathvec=notset])
 466
 467 # We keep the original values in `$config_*' and never modify them, so we
 468 # can write them unchanged into config.make.  Everything else uses
 469 # $machine, $vendor, and $os, and changes them whenever convenient.
 470 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 471
 472 # Don't allow vendor == "unknown"
 473 test "$config_vendor" = unknown && config_vendor=
 474 config_os="`echo $config_os | sed 's/^unknown-//'`"
 475
 476 # Some configurations imply other options.
 477 elf=yes
 478
 479 # The configure fragment of a port can modify these to supplement
 480 # or override the table in the case statement below.  No fragment should
 481 # ever change the config_* variables, however.
 482 machine=$config_machine
 483 vendor=$config_vendor
 484 os=$config_os
 485 base_os=''
 486
 487 submachine=
 488 AC_ARG_WITH([cpu],
 489             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 490             [dnl
 491   case "$withval" in
 492   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 493   no) ;;
 494   *) submachine="$withval" ;;
 495   esac
 496 ])
 497
 498 # An preconfigure script can set this when it wants to disable the sanity
 499 # check below.
 500 libc_config_ok=no
 501
 502 # A preconfigure script for a system that may or may not use fpu
 503 # sysdeps directories sets this to a preprocessor conditional for
 504 # whether to use such directories.
 505 with_fp_cond=1
 506
 507 dnl Let sysdeps/*/preconfigure act here.
 508 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 509
 510
 511 ###
 512 ### By using the undocumented --enable-hacker-mode option for configure
 513 ### one can skip this test to make the configuration not fail for unsupported
 514 ### platforms.
 515 ###
 516 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 517   case "$machine-$host_os" in
 518   *-linux* | *-gnu*)
 519     ;;
 520   *)
 521     AC_MSG_ERROR([
 522 *** The GNU C library is currently unavailable for this platform.
 523 *** If you are interested in seeing glibc on this platform visit
 524 *** the "How to submit a new port" in the wiki:
 525 ***   https://sourceware.org/glibc/wiki/#Development
 526 *** and join the community!])
 527     ;;
 528   esac
 529 fi
 530
 531 # Set base_machine if not set by a preconfigure fragment.
 532 test -n "$base_machine" || base_machine=$machine
 533 AC_SUBST(base_machine)
 534
 535 # Determine whether to use fpu or nofpu sysdeps directories.
 536 AC_CACHE_CHECK([for use of fpu sysdeps directories],
 537                libc_cv_with_fp, [dnl
 538 cat > conftest.c <<EOF
 539 #if $with_fp_cond
 540 int dummy;
 541 #else
 542 # error "no hardware floating point"
 543 #endif
 544 EOF
 545 libc_cv_with_fp=no
 546 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
 547    1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 548   libc_cv_with_fp=yes
 549 fi
 550 rm -f conftest*])
 551 AC_SUBST(libc_cv_with_fp)
 552
 553 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 554 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 555                    [libc_cv_ssp=yes],
 556                    [libc_cv_ssp=no])
 557 ])
 558
 559 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 560 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 561                    [libc_cv_ssp_strong=yes],
 562                    [libc_cv_ssp_strong=no])
 563 ])
 564
 565 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 566 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 567                    [libc_cv_ssp_all=yes],
 568                    [libc_cv_ssp_all=no])
 569 ])
 570
 571 stack_protector=
 572 no_stack_protector=
 573 if test "$libc_cv_ssp" = yes; then
 574   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 575   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 576 fi
 577
 578 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 579   stack_protector="-fstack-protector"
 580   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 581 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 582   stack_protector="-fstack-protector-all"
 583   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 584 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 585   stack_protector="-fstack-protector-strong"
 586   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 587 else
 588   stack_protector="-fno-stack-protector"
 589   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 590 fi
 591 AC_SUBST(libc_cv_ssp)
 592 AC_SUBST(stack_protector)
 593 AC_SUBST(no_stack_protector)
 594
 595 if test -n "$stack_protector"; then
 596   dnl Don't run configure tests with stack-protection on, to avoid problems with
 597   dnl bootstrapping.
 598   no_ssp=-fno-stack-protector
 599 else
 600   no_ssp=
 601
 602   if test "$enable_stack_protector" != no; then
 603     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 604   fi
 605 fi
 606
 607 # For the multi-arch option we need support in the assembler & linker.
 608 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 609                libc_cv_ld_gnu_indirect_function, [dnl
 610 cat > conftest.S <<EOF
 611 .type foo,%gnu_indirect_function
 612 foo:
 613 .globl _start
 614 _start:
 615 .globl __start
 616 __start:
 617 .data
 618 #ifdef _LP64
 619 .quad foo
 620 #else
 621 .long foo
 622 #endif
 623 EOF
 624 libc_cv_ld_gnu_indirect_function=no
 625 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 626             -nostartfiles -nostdlib $no_ssp \
 627             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 628   # Do a link to see if the backend supports IFUNC relocs.
 629   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 630   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 631     libc_cv_ld_gnu_indirect_function=yes
 632   }
 633 fi
 634 rm -f conftest*])
 635
 636 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 637 AC_CACHE_CHECK([for gcc attribute ifunc support],
 638                libc_cv_gcc_indirect_function, [dnl
 639 cat > conftest.c <<EOF
 640 extern int func (int);
 641 int used_func (int a)
 642 {
 643   return a;
 644 }
 645 static void *resolver ()
 646 {
 647   return &used_func;
 648 }
 649 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 650 EOF
 651 libc_cv_gcc_indirect_function=no
 652 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 653    2>&AS_MESSAGE_LOG_FD ; then
 654   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 655     libc_cv_gcc_indirect_function=yes
 656   fi
 657 fi
 658 rm -f conftest*])
 659
 660 # Check if gcc warns about alias for function with incompatible types.
 661 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 662                libc_cv_gcc_incompatible_alias, [dnl
 663 cat > conftest.c <<EOF
 664 int __redirect_foo (const void *s, int c);
 665
 666 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 667 __typeof (__redirect_foo) *foo_impl (void)
 668 {
 669   return 0;
 670 }
 671
 672 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 673 EOF
 674 libc_cv_gcc_incompatible_alias=yes
 675 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 676   libc_cv_gcc_incompatible_alias=no
 677 fi
 678 rm -f conftest*])
 679
 680 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 681   if test x"$multi_arch" = xyes; then
 682     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 683   else
 684     multi_arch=no
 685   fi
 686 fi
 687 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 688   # GCC 8+ emits a warning for alias with incompatible types and it might
 689   # fail to build ifunc resolvers aliases to either weak or internal
 690   # symbols.  Disables multiarch build in this case.
 691   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 692     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 693     if test x"$multi_arch" = xyes; then
 694       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 695     fi
 696     AC_MSG_WARN([Multi-arch is disabled.])
 697     multi_arch=no
 698   elif test x"$multi_arch" = xyes; then
 699     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 700 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 701   fi
 702 fi
 703 multi_arch_d=
 704 if test x"$multi_arch" != xno; then
 705   multi_arch_d=/multiarch
 706 fi
 707
 708 # Compute the list of sysdep directories for this configuration.
 709 # This can take a while to compute.
 710 sysdep_dir=$srcdir/sysdeps
 711 AC_MSG_CHECKING(sysdep dirs)
 712 dnl We need to use [ and ] for other purposes for a while now.
 713 changequote(,)dnl
 714 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 715 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 716
 717 test "x$base_os" != x || case "$os" in
 718 gnu*)
 719   base_os=mach/hurd ;;
 720 linux*)
 721   base_os=unix/sysv ;;
 722 esac
 723
 724 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 725 tail=$os
 726 ostry=$os
 727 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 728   ostry="$ostry /$o"
 729   tail=$o
 730 done
 731 o=`echo $tail | sed 's/[0-9]*$//'`
 732 if test $o != $tail; then
 733   ostry="$ostry /$o"
 734 fi
 735 # For linux-gnu, try linux-gnu, then linux.
 736 o=`echo $tail | sed 's/-.*$//'`
 737 if test $o != $tail; then
 738   ostry="$ostry /$o"
 739 fi
 740
 741 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 742 base=
 743 tail=$base_os
 744 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 745   set $b
 746   base="$base /$1"
 747   tail="$2"
 748 done
 749
 750 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 751 mach=
 752 tail=$machine${submachine:+/$submachine}
 753 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 754   set $m
 755   # Prepend the machine's FPU directory unless --without-fp.
 756   if test "$libc_cv_with_fp" = yes; then
 757     maybe_fpu=/fpu
 758   else
 759     maybe_fpu=/nofpu
 760   fi
 761   # For each machine term, try it with and then without /multiarch.
 762   for try_fpu in $maybe_fpu ''; do
 763     for try_multi in $multi_arch_d ''; do
 764       mach="$mach /$1$try_fpu$try_multi"
 765     done
 766   done
 767   tail="$2"
 768 done
 769
 770 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 771 changequote([,])dnl
 772
 773 # Find what sysdep directories exist.
 774 sysnames=
 775 for b in $base ''; do
 776   for m0 in $mach ''; do
 777     for v in /$vendor ''; do
 778       test "$v" = / && continue
 779       for o in /$ostry ''; do
 780         test "$o" = / && continue
 781         for m in $mach ''; do
 782           try_suffix="$m0$b$v$o$m"
 783           if test -n "$try_suffix"; then
 784             try_srcdir="${srcdir}/"
 785             try="sysdeps$try_suffix"
 786             test -n "$enable_debug_configure" &&
 787             echo "$0 [DEBUG]: try $try" >&2
 788             if test -d "$try_srcdir$try"; then
 789               sysnames="$sysnames $try"
 790               { test -n "$o" || test -n "$b"; } && os_used=t
 791               { test -n "$m" || test -n "$m0"; } && machine_used=t
 792               case x${m0:-$m} in
 793               x*/$submachine) submachine_used=t ;;
 794               esac
 795             fi
 796           fi
 797         done
 798       done
 799     done
 800   done
 801 done
 802
 803 # If the assembler supports gnu_indirect_function symbol type and the
 804 # architecture supports multi-arch, we enable multi-arch by default.
 805 case $sysnames in
 806 *"$multi_arch_d"*)
 807   ;;
 808 *)
 809   test x"$multi_arch" = xdefault && multi_arch=no
 810   ;;
 811 esac
 812 if test x"$multi_arch" != xno; then
 813   AC_DEFINE(USE_MULTIARCH)
 814 fi
 815 AC_SUBST(multi_arch)
 816
 817 if test -z "$os_used" && test "$os" != none; then
 818   AC_MSG_ERROR(Operating system $os is not supported.)
 819 fi
 820 if test -z "$machine_used" && test "$machine" != none; then
 821   AC_MSG_ERROR(The $machine is not supported.)
 822 fi
 823 if test -z "$submachine_used" && test -n "$submachine"; then
 824   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 825 fi
 826 AC_SUBST(submachine)
 827
 828 # We have now validated the configuration.
 829
 830 # Expand the list of system names into a full list of directories
 831 # from each element's parent name and Implies file (if present).
 832 set $sysnames
 833 names=
 834 while test $# -gt 0; do
 835   name=$1
 836   shift
 837
 838   case " $names " in *" $name "*)
 839     # Already in the list.
 840     continue
 841   esac
 842
 843   # Report each name as we discover it, so there is no long pause in output.
 844   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 845
 846   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 847
 848   case $name in
 849     /*) xsrcdir= ;;
 850     *)  xsrcdir=$srcdir/ ;;
 851   esac
 852   test -n "$enable_debug_configure" &&
 853   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 854
 855   for implies_file in Implies Implies-before Implies-after; do
 856     implies_type=`echo $implies_file | sed s/-/_/`
 857     eval ${implies_type}=
 858     if test -f $xsrcdir$name/$implies_file; then
 859       # Collect more names from the `Implies' file (removing comments).
 860       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 861       for x in $implied_candidate; do
 862         found=no
 863         if test -d $xsrcdir$name_base/$x; then
 864           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 865           found=yes
 866         fi
 867         try="sysdeps/$x"
 868         try_srcdir=$srcdir/
 869         test -n "$enable_debug_configure" &&
 870          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 871         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 872         then
 873           eval "${implies_type}=\"\$${implies_type} \$try\""
 874           found=yes
 875         fi
 876         if test $found = no; then
 877           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 878         fi
 879       done
 880     fi
 881   done
 882
 883   # Add NAME to the list of names.
 884   names="$names $name"
 885
 886   # Find the parent of NAME, using the empty string if it has none.
 887 changequote(,)dnl
 888   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 889 changequote([,])dnl
 890
 891   test -n "$enable_debug_configure" &&
 892     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 893 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 894
 895   # Add the names implied by NAME, and NAME's parent (if it has one), to
 896   # the list of names to be processed (the argument list).  We prepend the
 897   # implied names to the list and append the parent.  We want implied
 898   # directories to come before further directories inferred from the
 899   # configuration components; this ensures that for sysv4, unix/common
 900   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 901   # after sysv4).
 902   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 903   test -n "$sysnames" && set $sysnames
 904 done
 905
 906 # Add the default directories.
 907 default_sysnames="sysdeps/generic"
 908 sysnames="$names $default_sysnames"
 909 AC_SUBST(sysnames)
 910 # The other names were emitted during the scan.
 911 AC_MSG_RESULT($default_sysnames)
 912
 913
 914 ### Locate tools.
 915
 916 AC_PROG_INSTALL
 917 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 918   # The makefiles need to use a different form to find it in $srcdir.
 919   INSTALL='\$(..)./scripts/install-sh -c'
 920 fi
 921 AC_PROG_LN_S
 922
 923 LIBC_PROG_BINUTILS
 924
 925 # Accept binutils 2.25 or newer.
 926 AC_CHECK_PROG_VER(AS, $AS, --version,
 927                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 928                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 929                   AS=: critic_missing="$critic_missing as")
 930
 931 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 932   # Accept gold 1.14 or higher
 933   AC_CHECK_PROG_VER(LD, $LD, --version,
 934                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 935                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 936                     LD=: critic_missing="$critic_missing GNU gold")
 937 else
 938   AC_CHECK_PROG_VER(LD, $LD, --version,
 939                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 940                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 941                     LD=: critic_missing="$critic_missing GNU ld")
 942 fi
 943
 944 # These programs are version sensitive.
 945 AC_CHECK_TOOL_PREFIX
 946 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 947   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 948   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 949
 950 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 951   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 952   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 953   MSGFMT=: aux_missing="$aux_missing msgfmt")
 954 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 955   [GNU texinfo.* \([0-9][0-9.]*\)],
 956   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
 957   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 958 AC_CHECK_PROG_VER(SED, sed, --version,
 959   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 960   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 961   SED=: aux_missing="$aux_missing sed")
 962 AC_CHECK_PROG_VER(AWK, gawk, --version,
 963   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 964   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
 965 AC_CHECK_PROG_VER(BISON, bison, --version,
 966   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
 967   [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
 968
 969 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
 970 AC_TRY_COMPILE([], [
 971 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 9)
 972 #error insufficient compiler
 973 #endif],
 974                [libc_cv_compiler_ok=yes],
 975                [libc_cv_compiler_ok=no])])
 976 AS_IF([test $libc_cv_compiler_ok != yes],
 977       [critic_missing="$critic_missing compiler"])
 978
 979 AC_CHECK_TOOL(NM, nm, false)
 980
 981 if test "x$maintainer" = "xyes"; then
 982   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 983   case "x$AUTOCONF" in
 984   xno|x|x:) AUTOCONF=no ;;
 985   *)
 986     AC_CACHE_CHECK(dnl
 987   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 988     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
 989       libc_cv_autoconf_works=yes
 990     else
 991       libc_cv_autoconf_works=no
 992     fi])
 993     test $libc_cv_autoconf_works = yes || AUTOCONF=no
 994     ;;
 995   esac
 996   if test "x$AUTOCONF" = xno; then
 997     aux_missing="$aux_missing autoconf"
 998   fi
 999 else
1000   AUTOCONF=no
1001 fi
1002
1003 # Check for python3 if available, or else python.
1004 AC_CHECK_PROGS(PYTHON_PROG, python3 python,no)
1005 case "x$PYTHON_PROG" in
1006 xno|x|x:) PYTHON_PROG=no ;;
1007 *) ;;
1008 esac
1009
1010 if test "x$PYTHON_PROG" = xno; then
1011   aux_missing="$aux_missing python"
1012 else
1013   PYTHON="$PYTHON_PROG -B"
1014   AC_SUBST(PYTHON)
1015 fi
1016
1017 test -n "$critic_missing" && AC_MSG_ERROR([
1018 *** These critical programs are missing or too old:$critic_missing
1019 *** Check the INSTALL file for required versions.])
1020
1021 test -n "$aux_missing" && AC_MSG_WARN([
1022 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1023 *** some features or tests will be disabled.
1024 *** Check the INSTALL file for required versions.])
1025
1026 # if using special system headers, find out the compiler's sekrit
1027 # header directory and add that to the list.  NOTE: Only does the right
1028 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1029 if test -n "$sysheaders"; then
1030   SYSINCLUDES=-nostdinc
1031   for d in include include-fixed; do
1032     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1033     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1034   done
1035   SYSINCLUDES="$SYSINCLUDES \
1036 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1037   if test -n "$CXX"; then
1038     CXX_SYSINCLUDES=
1039     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1040     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1041       test "x$cxxheaders" != x &&
1042       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1043     done
1044   fi
1045 fi
1046 AC_SUBST(SYSINCLUDES)
1047 AC_SUBST(CXX_SYSINCLUDES)
1048
1049 # Obtain some C++ header file paths.  This is used to make a local
1050 # copy of those headers in Makerules.
1051 if test -n "$CXX"; then
1052   find_cxx_header () {
1053     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1054          | sed -n "\,$1:,{s/:\$//;p}"
1055   }
1056   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1057   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1058   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1059 fi
1060 AC_SUBST(CXX_CSTDLIB_HEADER)
1061 AC_SUBST(CXX_CMATH_HEADER)
1062 AC_SUBST(CXX_BITS_STD_ABS_H)
1063
1064 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1065 # since this would lead to problems installing/building glibc.
1066 # LD_LIBRARY_PATH contains the current directory if one of the following
1067 # is true:
1068 # - one of the terminals (":" and ";") is the first or last sign
1069 # - two terminals occur directly after each other
1070 # - the path contains an element with a dot in it
1071 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1072 changequote(,)dnl
1073 case ${LD_LIBRARY_PATH} in
1074   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1075     ld_library_path_setting="contains current directory"
1076     ;;
1077   *)
1078     ld_library_path_setting="ok"
1079     ;;
1080 esac
1081 changequote([,])dnl
1082 AC_MSG_RESULT($ld_library_path_setting)
1083 if test "$ld_library_path_setting" != "ok"; then
1084 AC_MSG_ERROR([
1085 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1086 *** building glibc. Please change the environment variable
1087 *** and run configure again.])
1088 fi
1089
1090 AC_PATH_PROG(BASH_SHELL, bash, no)
1091
1092 AC_PATH_PROG(PERL, perl, no)
1093 if test "$PERL" != no &&
1094    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1095   PERL=no
1096 fi
1097 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1098              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1099
1100 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1101 cat > conftest.s <<EOF
1102 .text
1103 foo:
1104 .set glibc_conftest_frobozz,foo
1105 .globl glibc_conftest_frobozz
1106 EOF
1107 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1108 # (but it doesn't work), so we must do a linking check to be sure.
1109 cat > conftest1.c <<\EOF
1110 extern int glibc_conftest_frobozz;
1111 void _start() { glibc_conftest_frobozz = 1; }
1112 EOF
1113 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1114             -nostartfiles -nostdlib $no_ssp \
1115             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1116   libc_cv_asm_set_directive=yes
1117 else
1118   libc_cv_asm_set_directive=no
1119 fi
1120 rm -f conftest*])
1121 if test $libc_cv_asm_set_directive = yes; then
1122   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1123 fi
1124
1125 AC_CACHE_CHECK(linker support for protected data symbol,
1126                libc_cv_protected_data,
1127                [cat > conftest.c <<EOF
1128                 int bar __attribute__ ((visibility ("protected"))) = 1;
1129 EOF
1130                 libc_cv_protected_data=no
1131                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1132                   cat > conftest.c <<EOF
1133                   extern int bar;
1134                   int main (void) { return bar; }
1135 EOF
1136                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1137                     libc_cv_protected_data=yes
1138                   fi
1139                 fi
1140                 rm -f conftest.*
1141                ])
1142 AC_SUBST(libc_cv_protected_data)
1143
1144 AC_CACHE_CHECK(linker support for INSERT in linker script,
1145                libc_cv_insert,
1146                [cat > conftest.c <<EOF
1147                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1148                 int test (void) { return bar; }
1149 EOF
1150                 cat > conftest.t <<EOF
1151                 SECTIONS
1152                 {
1153                   .bar : { *(.bar) }
1154                 }
1155                 INSERT AFTER .rela.dyn;
1156 EOF
1157                 libc_cv_insert=no
1158                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1159                   libc_cv_insert=yes
1160                 fi
1161                 rm -f conftest.*
1162                ])
1163 AC_SUBST(libc_cv_insert)
1164
1165 AC_CACHE_CHECK(for broken __attribute__((alias())),
1166                libc_cv_broken_alias_attribute,
1167                [cat > conftest.c <<EOF
1168                extern int foo (int x) __asm ("xyzzy");
1169                int bar (int x) { return x; }
1170                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1171                extern int dfoo;
1172                extern __typeof (dfoo) dfoo __asm ("abccb");
1173                int dfoo = 1;
1174 EOF
1175                libc_cv_broken_alias_attribute=yes
1176                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1177                  if grep 'xyzzy' conftest.s >/dev/null &&
1178                     grep 'abccb' conftest.s >/dev/null; then
1179                    libc_cv_broken_alias_attribute=no
1180                  fi
1181                fi
1182                rm -f conftest.c conftest.s
1183                ])
1184 if test $libc_cv_broken_alias_attribute = yes; then
1185   AC_MSG_ERROR(working alias attribute support required)
1186 fi
1187
1188 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1189                libc_cv_have_sdata_section,
1190                [echo "int i;" > conftest.c
1191                 libc_cv_have_sdata_section=no
1192                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1193                    | grep '\.sdata' >/dev/null; then
1194                   libc_cv_have_sdata_section=yes
1195                 fi
1196                 rm -f conftest.c conftest.so
1197                ])
1198 if test $libc_cv_have_sdata_section = yes; then
1199   AC_DEFINE(HAVE_SDATA_SECTION)
1200 fi
1201
1202 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1203                libc_cv_ctors_header, [dnl
1204   libc_cv_ctors_header=yes
1205   LIBC_TRY_LINK_STATIC([
1206 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1207 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1208 ],
1209               [dnl
1210       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1211         { gsub(/\@<:@ */, "@<:@") }
1212         $2 == ".ctors" || $2 == ".dtors" {
1213           size = strtonum("0x" $6)
1214           align = strtonum("0x" $NF)
1215           seen@<:@$2@:>@ = 1
1216           stub@<:@$2@:>@ = size == align * 2
1217         }
1218         END {
1219           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1220           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1221           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1222         }
1223       '], [libc_cv_ctors_header=no])
1224     ], [dnl
1225       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1226     ])
1227 ])
1228 if test $libc_cv_ctors_header = no; then
1229   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1230 fi
1231
1232 AC_CACHE_CHECK(for libunwind-support in compiler,
1233                libc_cv_cc_with_libunwind, [
1234   cat > conftest.c <<EOF
1235 int main (void) { return 0; }
1236 EOF
1237   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1238      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1239     libc_cv_cc_with_libunwind=yes
1240   else
1241     libc_cv_cc_with_libunwind=no
1242   fi
1243   rm -f conftest*])
1244 AC_SUBST(libc_cv_cc_with_libunwind)
1245 if test $libc_cv_cc_with_libunwind = yes; then
1246   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1247 fi
1248
1249 ASFLAGS_config=
1250 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1251                libc_cv_as_noexecstack, [dnl
1252 cat > conftest.c <<EOF
1253 void foo (void) { }
1254 EOF
1255 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1256                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1257    && grep .note.GNU-stack conftest.s >/dev/null \
1258    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1259                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1260 then
1261   libc_cv_as_noexecstack=yes
1262 else
1263   libc_cv_as_noexecstack=no
1264 fi
1265 rm -f conftest*])
1266 if test $libc_cv_as_noexecstack = yes; then
1267   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1268 fi
1269 AC_SUBST(ASFLAGS_config)
1270
1271 AC_CACHE_CHECK(for -z combreloc,
1272                libc_cv_z_combreloc, [dnl
1273 cat > conftest.c <<EOF
1274 extern int bar (int);
1275 extern int mumble;
1276 int foo (void) { return bar (mumble); }
1277 EOF
1278 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1279                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1280                         -nostdlib -nostartfiles
1281                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1282 then
1283 dnl The following test is a bit weak.  We must use a tool which can test
1284 dnl cross-platform since the gcc used can be a cross compiler.  Without
1285 dnl introducing new options this is not easily doable.  Instead use a tool
1286 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1287 dnl look for a section named .rel.dyn or .rela.dyn.
1288   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1289     libc_cv_z_combreloc=yes
1290   else
1291     libc_cv_z_combreloc=no
1292   fi
1293 else
1294   libc_cv_z_combreloc=no
1295 fi
1296 rm -f conftest*])
1297 if test "$libc_cv_z_combreloc" = yes; then
1298   AC_DEFINE(HAVE_Z_COMBRELOC)
1299 fi
1300 AC_SUBST(libc_cv_z_combreloc)
1301
1302 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1303                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1304 AC_SUBST(libc_cv_z_execstack)
1305
1306 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1307                     [-Wl,--no-dynamic-linker],
1308                     [libc_cv_no_dynamic_linker=yes],
1309                     [libc_cv_no_dynamic_linker=no])
1310 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1311
1312 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1313 LIBC_TRY_CC_OPTION([-static-pie],
1314                    [libc_cv_static_pie=yes],
1315                    [libc_cv_static_pie=no])
1316 ])
1317 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1318
1319 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1320 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1321 ])
1322
1323 AC_SUBST(libc_cv_fpie)
1324
1325 AC_CACHE_CHECK(for --hash-style option,
1326                libc_cv_hashstyle, [dnl
1327 cat > conftest.c <<EOF
1328 int _start (void) { return 42; }
1329 EOF
1330 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1331                             -fPIC -shared -o conftest.so conftest.c
1332                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1333 then
1334   libc_cv_hashstyle=yes
1335 else
1336   libc_cv_hashstyle=no
1337 fi
1338 rm -f conftest*])
1339 AC_SUBST(libc_cv_hashstyle)
1340
1341 # The linker's default -shared behavior is good enough if it
1342 # does these things that our custom linker scripts ensure that
1343 # all allocated NOTE sections come first.
1344 if test "$use_default_link" = default; then
1345   AC_CACHE_CHECK([for sufficient default -shared layout],
1346                   libc_cv_use_default_link, [dnl
1347   libc_cv_use_default_link=no
1348   cat > conftest.s <<\EOF
1349           .section .note.a,"a",%note
1350           .balign 4
1351           .long 4,4,9
1352           .string "GNU"
1353           .string "foo"
1354           .section .note.b,"a",%note
1355           .balign 4
1356           .long 4,4,9
1357           .string "GNU"
1358           .string "bar"
1359 EOF
1360   if AC_TRY_COMMAND([dnl
1361   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1362        ac_try=`$READELF -S conftest.so | sed -n \
1363          ['${x;p;}
1364           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1365           t a
1366           b
1367           : a
1368           H']`
1369   then
1370     libc_seen_a=no libc_seen_b=no
1371     set -- $ac_try
1372     while test $# -ge 2 -a "$1" = NOTE; do
1373       case "$2" in
1374       .note.a) libc_seen_a=yes ;;
1375       .note.b) libc_seen_b=yes ;;
1376       esac
1377       shift 2
1378     done
1379     case "$libc_seen_a$libc_seen_b" in
1380     yesyes)
1381       libc_cv_use_default_link=yes
1382       ;;
1383     *)
1384       echo >&AS_MESSAGE_LOG_FD "\
1385 $libc_seen_a$libc_seen_b from:
1386 $ac_try"
1387       ;;
1388     esac
1389   fi
1390   rm -f conftest*])
1391   use_default_link=$libc_cv_use_default_link
1392 fi
1393
1394 AC_CACHE_CHECK(for GLOB_DAT reloc,
1395                libc_cv_has_glob_dat, [dnl
1396 cat > conftest.c <<EOF
1397 extern int mumble;
1398 int foo (void) { return mumble; }
1399 EOF
1400 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1401                         -fPIC -shared -o conftest.so conftest.c
1402                         -nostdlib -nostartfiles $no_ssp
1403                         1>&AS_MESSAGE_LOG_FD])
1404 then
1405 dnl look for GLOB_DAT relocation.
1406   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1407     libc_cv_has_glob_dat=yes
1408   else
1409     libc_cv_has_glob_dat=no
1410   fi
1411 else
1412   libc_cv_has_glob_dat=no
1413 fi
1414 rm -f conftest*])
1415 AC_SUBST(libc_cv_has_glob_dat)
1416
1417 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1418 if libc_cv_output_format=`
1419 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1420 then
1421   :
1422 else
1423   libc_cv_output_format=
1424 fi
1425 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1426 AC_SUBST(libc_cv_output_format)
1427
1428 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1429 cat > conftest.c <<EOF
1430 int foo;
1431 EOF
1432 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1433                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1434 then
1435   libc_cv_fno_toplevel_reorder=yes
1436 else
1437   libc_cv_fno_toplevel_reorder=no
1438 fi
1439 rm -f conftest*])
1440 if test $libc_cv_fno_toplevel_reorder = yes; then
1441   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1442 else
1443   fno_unit_at_a_time=-fno-unit-at-a-time
1444 fi
1445 AC_SUBST(fno_unit_at_a_time)
1446
1447 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1448 [dnl
1449 cat > conftest.c <<EOF
1450 __thread int i;
1451 void foo (void)
1452 {
1453   i = 10;
1454 }
1455 EOF
1456 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1457                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1458 then
1459   libc_cv_mtls_dialect_gnu2=yes
1460 else
1461   libc_cv_mtls_dialect_gnu2=no
1462 fi
1463 rm -f conftest*])
1464 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1465 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1466
1467 AC_CACHE_CHECK(whether cc puts quotes around section names,
1468                libc_cv_have_section_quotes,
1469                [cat > conftest.c <<EOF
1470                 static const int foo
1471                 __attribute__ ((section ("bar"))) = 1;
1472 EOF
1473                 if ${CC-cc} -S conftest.c -o conftest.s; then
1474                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1475                     libc_cv_have_section_quotes=yes
1476                   else
1477                     libc_cv_have_section_quotes=no
1478                   fi
1479                 else
1480                   libc_cv_have_section_quotes=unknown
1481                 fi
1482                 rm -f conftest.{c,s}
1483                 ])
1484 if test $libc_cv_have_section_quotes = yes; then
1485   AC_DEFINE(HAVE_SECTION_QUOTES)
1486 fi
1487
1488 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1489 cat > conftest.c <<\EOF
1490 void zero (void *x)
1491 {
1492   __builtin_memset (x, 0, 1000);
1493 }
1494 EOF
1495 dnl
1496 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1497 then
1498   libc_cv_gcc_builtin_memset=no
1499 else
1500   libc_cv_gcc_builtin_memset=yes
1501 fi
1502 rm -f conftest* ])
1503 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1504   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1505 fi
1506
1507 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1508 cat > conftest.c <<\EOF
1509 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1510 char *foo (const char *a, const char *b)
1511 {
1512   return __builtin_strstr (a, b);
1513 }
1514 EOF
1515 dnl
1516 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1517 then
1518   libc_cv_gcc_builtin_redirection=yes
1519 else
1520   libc_cv_gcc_builtin_redirection=no
1521 fi
1522 rm -f conftest* ])
1523 if test "$libc_cv_gcc_builtin_redirection" = no; then
1524   AC_MSG_ERROR([support for the symbol redirection needed])
1525 fi
1526
1527 dnl Determine how to disable generation of FMA instructions.
1528 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1529                libc_cv_cc_nofma, [dnl
1530 libc_cv_cc_nofma=
1531 for opt in -ffp-contract=off -mno-fused-madd; do
1532   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1533 done])
1534 AC_SUBST(libc_cv_cc_nofma)
1535
1536 if test -n "$submachine"; then
1537   AC_CACHE_CHECK([for compiler option for CPU variant],
1538                  libc_cv_cc_submachine, [dnl
1539   libc_cv_cc_submachine=no
1540   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1541     LIBC_TRY_CC_OPTION([$opt], [
1542       libc_cv_cc_submachine="$opt"
1543       break], [])
1544   done])
1545   if test "x$libc_cv_cc_submachine" = xno; then
1546     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1547   fi
1548 fi
1549 AC_SUBST(libc_cv_cc_submachine)
1550
1551 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1552 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1553 cat > conftest.c <<EOF
1554 void
1555 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1556 foo (void) {}
1557 EOF
1558 libc_cv_cc_loop_to_function=no
1559 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1560 then
1561   libc_cv_cc_loop_to_function=yes
1562 fi
1563 rm -f conftest*])
1564 if test $libc_cv_cc_loop_to_function = yes; then
1565   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1566 fi
1567 AC_SUBST(libc_cv_cc_loop_to_function)
1568
1569 dnl Check whether we have the gd library available.
1570 AC_MSG_CHECKING(for libgd)
1571 if test "$with_gd" != "no"; then
1572   old_CFLAGS="$CFLAGS"
1573   CFLAGS="$CFLAGS $libgd_include"
1574   old_LDFLAGS="$LDFLAGS"
1575   LDFLAGS="$LDFLAGS $libgd_ldflags"
1576   old_LIBS="$LIBS"
1577   LIBS="$LIBS -lgd -lpng -lz -lm"
1578   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1579   CFLAGS="$old_CFLAGS"
1580   LDFLAGS="$old_LDFLAGS"
1581   LIBS="$old_LIBS"
1582 else
1583   LIBGD=no
1584 fi
1585 AC_MSG_RESULT($LIBGD)
1586 AC_SUBST(LIBGD)
1587
1588 # SELinux detection
1589 if test x$with_selinux = xno ; then
1590   have_selinux=no;
1591 else
1592   # See if we have the SELinux library
1593   AC_CHECK_LIB(selinux, is_selinux_enabled,
1594                have_selinux=yes, have_selinux=no)
1595   if test x$with_selinux = xyes ; then
1596     if test x$have_selinux = xno ; then
1597       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1598     fi
1599   fi
1600 fi
1601 # Check if we're building with SELinux support.
1602 if test "x$have_selinux" = xyes; then
1603   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1604
1605   # See if we have the libaudit library
1606   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1607                have_libaudit=yes, have_libaudit=no)
1608   if test "x$have_libaudit" = xyes; then
1609     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1610   fi
1611   AC_SUBST(have_libaudit)
1612
1613   # See if we have the libcap library
1614   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1615   if test "x$have_libcap" = xyes; then
1616     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1617   fi
1618   AC_SUBST(have_libcap)
1619 fi
1620 AC_SUBST(have_selinux)
1621
1622 CPPUNDEFS=
1623 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1624 dnl Since we are building the implementations of the fortified functions here,
1625 dnl having the macro defined interacts very badly.
1626 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1627 [AC_TRY_COMPILE([], [
1628 #ifdef _FORTIFY_SOURCE
1629 # error bogon
1630 #endif],
1631                 [libc_cv_predef_fortify_source=no],
1632                 [libc_cv_predef_fortify_source=yes])])
1633 if test $libc_cv_predef_fortify_source = yes; then
1634   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1635 fi
1636 AC_SUBST(CPPUNDEFS)
1637
1638 # Some linkers on some architectures support __ehdr_start but with
1639 # bugs.  Make sure usage of it does not create relocations in the
1640 # output (as the linker should resolve them all for us).
1641 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1642                libc_cv_ehdr_start, [
1643 old_CFLAGS="$CFLAGS"
1644 old_LDFLAGS="$LDFLAGS"
1645 old_LIBS="$LIBS"
1646 CFLAGS="$CFLAGS -fPIC"
1647 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1648 LIBS=
1649 AC_LINK_IFELSE([AC_LANG_SOURCE([
1650 typedef struct {
1651   char foo;
1652   long val;
1653 } Ehdr;
1654 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1655 long ehdr (void) { return __ehdr_start.val; }
1656 ])],
1657                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1658                   libc_cv_ehdr_start=broken
1659                 else
1660                   libc_cv_ehdr_start=yes
1661                 fi], [libc_cv_ehdr_start=no])
1662 CFLAGS="$old_CFLAGS"
1663 LDFLAGS="$old_LDFLAGS"
1664 LIBS="$old_LIBS"
1665 ])
1666 if test "$libc_cv_ehdr_start" = yes; then
1667   AC_DEFINE([HAVE_EHDR_START])
1668 elif test "$libc_cv_ehdr_start" = broken; then
1669   AC_MSG_WARN([linker is broken -- you should upgrade])
1670 fi
1671
1672 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1673                libc_cv_builtin_trap, [dnl
1674 libc_cv_builtin_trap=no
1675 AC_TRY_COMPILE([], [__builtin_trap ()], [
1676 libc_undefs=`$NM -u conftest.o |
1677   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1678     2>&AS_MESSAGE_LOG_FD` || {
1679   AC_MSG_ERROR([confusing output from $NM -u])
1680 }
1681 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1682 if test -z "$libc_undefs"; then
1683   libc_cv_builtin_trap=yes
1684 fi])])
1685 if test $libc_cv_builtin_trap = yes; then
1686   AC_DEFINE([HAVE_BUILTIN_TRAP])
1687 fi
1688
1689 dnl C++ feature tests.
1690 AC_LANG_PUSH([C++])
1691
1692 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1693                libc_cv_cxx_thread_local, [
1694 old_CXXFLAGS="$CXXFLAGS"
1695 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1696 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1697 #include <thread>
1698
1699 // Compiler support.
1700 struct S
1701 {
1702   S ();
1703   ~S ();
1704 };
1705 thread_local S s;
1706 S * get () { return &s; }
1707
1708 // libstdc++ support.
1709 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1710 #error __cxa_thread_atexit_impl not supported
1711 #endif
1712 ])],
1713                [libc_cv_cxx_thread_local=yes],
1714                [libc_cv_cxx_thread_local=no])
1715 CXXFLAGS="$old_CXXFLAGS"
1716 ])
1717 AC_SUBST(libc_cv_cxx_thread_local)
1718
1719 AC_LANG_POP([C++])
1720 dnl End of C++ feature tests.
1721
1722 ### End of automated tests.
1723 ### Now run sysdeps configure fragments.
1724
1725 # They also can set these variables.
1726 use_ldconfig=no
1727 ldd_rewrite_script=no
1728 libc_cv_sysconfdir=$sysconfdir
1729 libc_cv_localstatedir=$localstatedir
1730 libc_cv_gcc_unwind_find_fde=no
1731 libc_cv_idn=no
1732
1733 # Iterate over all the sysdep directories we will use, running their
1734 # configure fragments.
1735 for dir in $sysnames; do
1736   case $dir in
1737     /*) dest=$dir ;;
1738     *)  dest=$srcdir/$dir ;;
1739   esac
1740   if test -r $dest/configure; then
1741     AC_MSG_RESULT(running configure fragment for $dir)
1742     . $dest/configure
1743   fi
1744 done
1745
1746 if test x"$build_mathvec" = xnotset; then
1747   build_mathvec=no
1748 fi
1749 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1750
1751 AC_SUBST(libc_extra_cflags)
1752 AC_SUBST(libc_extra_cppflags)
1753
1754 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1755   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1756 fi
1757 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1758
1759 # A sysdeps configure fragment can reset this if IFUNC is not actually
1760 # usable even though the assembler knows how to generate the symbol type.
1761 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1762   AC_DEFINE(HAVE_IFUNC)
1763 fi
1764
1765 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1766   AC_DEFINE(HAVE_GCC_IFUNC)
1767 fi
1768
1769 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1770 # configure fragment can override the value to prevent this AC_DEFINE.
1771 AC_SUBST(use_nscd)
1772 if test "x$use_nscd" != xno; then
1773   AC_DEFINE([USE_NSCD])
1774 fi
1775 if test "x$build_nscd" = xdefault; then
1776   build_nscd=$use_nscd
1777 fi
1778
1779 AC_SUBST(libc_cv_slibdir)
1780 AC_SUBST(libc_cv_rtlddir)
1781 AC_SUBST(libc_cv_complocaledir)
1782 AC_SUBST(libc_cv_sysconfdir)
1783 AC_SUBST(libc_cv_localstatedir)
1784 AC_SUBST(libc_cv_rootsbindir)
1785
1786 if test x$use_ldconfig = xyes; then
1787   AC_DEFINE(USE_LDCONFIG)
1788 fi
1789 AC_SUBST(use_ldconfig)
1790 AC_SUBST(ldd_rewrite_script)
1791
1792 AC_SUBST(static)
1793 AC_SUBST(shared)
1794
1795 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1796 [libc_cv_pic_default=yes
1797 cat > conftest.c <<EOF
1798 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1799 # error PIC is default.
1800 #endif
1801 EOF
1802 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1803   libc_cv_pic_default=no
1804 fi
1805 rm -f conftest.*])
1806 AC_SUBST(libc_cv_pic_default)
1807
1808 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1809 [libc_cv_cc_pie_default=yes
1810 cat > conftest.c <<EOF
1811 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1812 # error PIE is default.
1813 #endif
1814 EOF
1815 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1816   libc_cv_cc_pie_default=no
1817 fi
1818 rm -f conftest.*])
1819 libc_cv_pie_default=$libc_cv_cc_pie_default
1820 AC_SUBST(libc_cv_cc_pie_default)
1821 AC_SUBST(libc_cv_pie_default)
1822
1823 # Set the `multidir' variable by grabbing the variable from the compiler.
1824 # We do it once and save the result in a generated makefile.
1825 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1826 AC_SUBST(libc_cv_multidir)
1827
1828 if test "$static_pie" = yes; then
1829   # The linker must support --no-dynamic-linker.
1830   if test "$libc_cv_no_dynamic_linker" != yes; then
1831     AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1832   fi
1833   # Default to PIE.
1834   libc_cv_pie_default=yes
1835   AC_DEFINE(ENABLE_STATIC_PIE)
1836 fi
1837 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1838
1839 AC_SUBST(profile)
1840 AC_SUBST(static_nss)
1841
1842 AC_SUBST(DEFINES)
1843
1844 dnl See sysdeps/mach/configure.ac for this variable.
1845 AC_SUBST(mach_interface_list)
1846
1847 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1848 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1849 AC_SUBST(VERSION)
1850 AC_SUBST(RELEASE)
1851
1852 AC_CONFIG_FILES([config.make Makefile])
1853 AC_CONFIG_COMMANDS([default],[[
1854 case $CONFIG_FILES in *config.make*)
1855 echo "$config_vars" >> config.make;;
1856 esac
1857 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1858 AC_OUTPUT