sysdeps/i386/__longjmp.S

   1 /* longjmp for i386.
   2    Copyright (C) 1995-1998,2000,2002,2005,2006,2009
   3    Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22 #include <jmpbuf-offsets.h>
  23 #include <asm-syntax.h>
  24
  25         .text
  26 ENTRY (__longjmp)
  27 #ifdef PTR_DEMANGLE
  28         movl 4(%esp), %eax      /* User's jmp_buf in %eax.  */
  29
  30         /* Save the return address now.  */
  31         movl (JB_PC*4)(%eax), %edx
  32         /* Get the stack pointer.  */
  33         movl (JB_SP*4)(%eax), %ecx
  34         PTR_DEMANGLE (%edx)
  35         PTR_DEMANGLE (%ecx)
  36         cfi_def_cfa(%eax, 0)
  37         cfi_register(%eip, %edx)
  38         cfi_register(%esp, %ecx)
  39         cfi_offset(%ebx, JB_BX*4)
  40         cfi_offset(%esi, JB_SI*4)
  41         cfi_offset(%edi, JB_DI*4)
  42         cfi_offset(%ebp, JB_BP*4)
  43         /* Restore registers.  */
  44         movl (JB_BX*4)(%eax), %ebx
  45         movl (JB_SI*4)(%eax), %esi
  46         movl (JB_DI*4)(%eax), %edi
  47         movl (JB_BP*4)(%eax), %ebp
  48         cfi_restore(%ebx)
  49         cfi_restore(%esi)
  50         cfi_restore(%edi)
  51         cfi_restore(%ebp)
  52
  53         movl 8(%esp), %eax      /* Second argument is return value.  */
  54         movl %ecx, %esp
  55 #else
  56         movl 4(%esp), %ecx      /* User's jmp_buf in %ecx.  */
  57         movl 8(%esp), %eax      /* Second argument is return value.  */
  58         /* Save the return address now.  */
  59         movl (JB_PC*4)(%ecx), %edx
  60         /* Restore registers.  */
  61         movl (JB_BX*4)(%ecx), %ebx
  62         movl (JB_SI*4)(%ecx), %esi
  63         movl (JB_DI*4)(%ecx), %edi
  64         movl (JB_BP*4)(%ecx), %ebp
  65         movl (JB_SP*4)(%ecx), %esp
  66 #endif
  67         /* Jump to saved PC.  */
  68         jmp *%edx
  69 END (__longjmp)