sysdeps/powerpc/powerpc64/stpcpy.S

   1 /* Optimized stpcpy implementation for PowerPC64.
   2    Copyright (C) 1997-2013 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21 /* See strlen.s for comments on how the end-of-string testing works.  */
  22
  23 /* char * [r3] stpcpy (char *dest [r3], const char *src [r4])  */
  24
  25 EALIGN (__stpcpy, 4, 0)
  26         CALL_MCOUNT 2
  27
  28 #define rTMP    r0
  29 #define rRTN    r3
  30 #define rDEST   r3              /* pointer to previous word in dest */
  31 #define rSRC    r4              /* pointer to previous word in src */
  32 #define rWORD   r6              /* current word from src */
  33 #define rFEFE   r7              /* 0xfefefeff */
  34 #define r7F7F   r8              /* 0x7f7f7f7f */
  35 #define rNEG    r9              /* ~(word in src | 0x7f7f7f7f) */
  36 #define rALT    r10             /* alternate word from src */
  37
  38         or      rTMP, rSRC, rDEST
  39         clrldi. rTMP, rTMP, 62
  40         addi    rDEST, rDEST, -4
  41         bne     L(unaligned)
  42
  43         lis     rFEFE, -0x101
  44         lis     r7F7F, 0x7f7f
  45         lwz     rWORD, 0(rSRC)
  46         addi    rFEFE, rFEFE, -0x101
  47         addi    r7F7F, r7F7F, 0x7f7f
  48         b       L(g2)
  49
  50 L(g0):  lwzu    rALT, 4(rSRC)
  51         stwu    rWORD, 4(rDEST)
  52         add     rTMP, rFEFE, rALT
  53         nor     rNEG, r7F7F, rALT
  54         and.    rTMP, rTMP, rNEG
  55         bne-    L(g1)
  56         lwzu    rWORD, 4(rSRC)
  57         stwu    rALT, 4(rDEST)
  58 L(g2):  add     rTMP, rFEFE, rWORD
  59         nor     rNEG, r7F7F, rWORD
  60         and.    rTMP, rTMP, rNEG
  61         beq+    L(g0)
  62
  63         mr      rALT, rWORD
  64 /* We've hit the end of the string.  Do the rest byte-by-byte.  */
  65 L(g1):  rlwinm. rTMP, rALT, 8, 24, 31
  66         stbu    rTMP, 4(rDEST)
  67         beqlr-
  68         rlwinm. rTMP, rALT, 16, 24, 31
  69         stbu    rTMP, 1(rDEST)
  70         beqlr-
  71         rlwinm. rTMP, rALT, 24, 24, 31
  72         stbu    rTMP, 1(rDEST)
  73         beqlr-
  74         stbu    rALT, 1(rDEST)
  75         blr
  76
  77 /* Oh well.  In this case, we just do a byte-by-byte copy.  */
  78         .align 4
  79         nop
  80 L(unaligned):
  81         lbz     rWORD, 0(rSRC)
  82         addi    rDEST, rDEST, 3
  83         cmpwi   rWORD, 0
  84         beq-    L(u2)
  85
  86 L(u0):  lbzu    rALT, 1(rSRC)
  87         stbu    rWORD, 1(rDEST)
  88         cmpwi   rALT, 0
  89         beq-    L(u1)
  90         nop             /* Let 601 load start of loop.  */
  91         lbzu    rWORD, 1(rSRC)
  92         stbu    rALT, 1(rDEST)
  93         cmpwi   rWORD, 0
  94         bne+    L(u0)
  95 L(u2):  stbu    rWORD, 1(rDEST)
  96         blr
  97 L(u1):  stbu    rALT, 1(rDEST)
  98         blr
  99 END (__stpcpy)
 100
 101 weak_alias (__stpcpy, stpcpy)
 102 libc_hidden_def (__stpcpy)
 103 libc_hidden_builtin_def (stpcpy)