sysdeps/powerpc/powerpc64/power7/strchrnul.S

   1 /* Optimized strchrnul implementation for PowerPC64/POWER7 using cmpb insn.
   2    Copyright (C) 2010-2013 Free Software Foundation, Inc.
   3    Contributed by Luis Machado <luisgpm@br.ibm.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22 /* int [r3] strchrnul (char *s [r3], int c [r4])  */
  23         .machine  power7
  24 ENTRY (__strchrnul)
  25         CALL_MCOUNT 2
  26         dcbt    0,r3
  27         clrrdi  r8,r3,3       /* Align the address to doubleword boundary.  */
  28
  29         /* Replicate byte to doubleword.  */
  30         rlwimi  r4,r4,8,16,23
  31         rlwimi  r4,r4,16,0,15
  32         insrdi  r4,r4,32,0
  33
  34         rlwinm  r6,r3,3,26,28 /* Calculate padding.  */
  35         ld      r12,0(r8)     /* Load doubleword from memory.  */
  36         li      r0,0          /* Doubleword with null chars to use
  37                                  with cmpb.  */
  38
  39         /* Now r4 has a doubleword of c bytes and r0 has
  40            a doubleword of null bytes.  */
  41
  42         cmpb    r10,r12,r0    /* Compare each byte against c byte.  */
  43         cmpb    r9,r12,r4     /* Compare each byte against null byte.  */
  44
  45         /* Move the doublewords left and right to discard the bits that are
  46            not part of the string and to bring them back as zeros.  */
  47         sld     r10,r10,r6
  48         sld     r9,r9,r6
  49         srd     r10,r10,r6
  50         srd     r9,r9,r6
  51         or      r5,r9,r10     /* OR the results to speed things up.  */
  52         cmpdi   cr7,r5,0      /* If r5 == 0, no c or null bytes
  53                                  have been found.  */
  54         bne     cr7,L(done)
  55
  56         mtcrf   0x01,r8
  57
  58         /* Are we now aligned to a quadword boundary?  If so, skip to
  59            the main loop.  Otherwise, go through the alignment code.  */
  60
  61         bt      28,L(loop)
  62
  63         /* Handle DWORD2 of pair.  */
  64         ldu     r12,8(r8)
  65         cmpb    r10,r12,r0
  66         cmpb    r9,r12,r4
  67         or      r5,r9,r10
  68         cmpdi   cr7,r5,0
  69         bne     cr7,L(done)
  70         b       L(loop)       /* We branch here (rather than falling through)
  71                                  to skip the nops due to heavy alignment
  72                                  of the loop below.  */
  73
  74         .p2align  5
  75 L(loop):
  76         /* Load two doublewords, compare and merge in a
  77            single register for speed.  This is an attempt
  78            to speed up the null-checking process for bigger strings.  */
  79         ld      r12,8(r8)
  80         ldu     r11,16(r8)
  81         cmpb    r10,r12,r0
  82         cmpb    r9,r12,r4
  83         cmpb    r6,r11,r0
  84         cmpb    r7,r11,r4
  85         or      r5,r9,r10
  86         or      r10,r6,r7
  87         or      r11,r5,r10
  88         cmpdi   cr7,r11,0
  89         beq     cr7,L(loop)
  90
  91         /* OK, one (or both) of the doublewords contains a c/null byte.  Check
  92            the first doubleword and decrement the address in case the first
  93            doubleword really contains a c/null byte.  */
  94
  95         cmpdi   cr6,r5,0
  96         addi    r8,r8,-8
  97         bne     cr6,L(done)
  98
  99         /* The c/null byte must be in the second doubleword.  Adjust the
 100            address again and move the result of cmpb to r10 so we can calculate
 101            the pointer.  */
 102         mr      r5,r10
 103         addi    r8,r8,8
 104
 105         /* r5 has the output of the cmpb instruction, that is, it contains
 106            0xff in the same position as the c/null byte in the original
 107            doubleword from the string.  Use that to calculate the pointer.  */
 108 L(done):
 109         cntlzd  r0,r5         /* Count leading zeros before the match.  */
 110         srdi    r0,r0,3       /* Convert leading zeros to bytes.  */
 111         add     r3,r8,r0      /* Return address of matching c/null byte.  */
 112         blr
 113 END (__strchrnul)
 114 weak_alias (__strchrnul,strchrnul)
 115 libc_hidden_builtin_def (__strchrnul)