configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37 [  --with-fp              if using floating-point hardware [default=yes]],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 AC_ARG_ENABLE(sanity-checks, dnl
  63 [  --disable-sanity-checks really do not use threads (should not be used
  64                           except in special situations) [default=yes]],
  65               enable_sanity=$enableval, enable_sanity=yes)
  66
  67 dnl Arguments to enable or disable building the shared, profiled, and
  68 dnl -fomit-frame-pointer libraries.
  69 AC_ARG_ENABLE(shared, dnl
  70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  71               shared=$enableval, shared=default)
  72 AC_ARG_ENABLE(profile, dnl
  73 [  --enable-profile        build profiled library [default=yes]],
  74               profile=$enableval, profile=yes)
  75 AC_ARG_ENABLE(omitfp, dnl
  76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  77               omitfp=$enableval, omitfp=no)
  78
  79 dnl Some gcc versions have problems with omit-frame-pointer.  Warn about this.
  80 if test $omitfp = yes; then
  81   echo "*** Not all versions of GCC compile code correctly when the"
  82   echo "*** -fomit-frame-pointer option is used.  You are on your own"
  83   echo "*** if you use it."
  84 fi
  85
  86 dnl Generic infrastructure for drop-in additions to libc.
  87 AC_ARG_ENABLE(add-ons, dnl
  88 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
  89                                   search for add-ons if no parameter given],
  90  [case "$enableval" in
  91     yes) if test "$srcdir" = "."; then
  92            add_ons=`echo */configure | sed -e 's!/configure!!g'`
  93          else
  94            add_ons=`echo $srcdir/*/configure | \
  95                     sed  -e 's!/configure!!g' -e "s!$srcdir/!!g"`
  96          fi;;
  97     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
  98    esac],
  99   [add_ons=])
 100 AC_CONFIG_SUBDIRS($add_ons)
 101 add_ons_pfx=
 102 if test x"$add_ons" != x; then
 103   for f in $add_ons; do
 104     # Test whether such a subdir really exists.
 105     if test -d $srcdir/$f; then
 106       add_ons_pfx="$add_ons_pfx $f/"
 107     else
 108       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 109     fi
 110   done
 111 fi
 112
 113 AC_CANONICAL_HOST
 114
 115 # The way shlib-versions is used to generate soversions.mk uses a
 116 # fairly simplistic model for name recognition that can't distinguish
 117 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 118 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 119 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 120 case "$host_os" in
 121 linux*)
 122   ;;
 123 gnu*)
 124   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 125   ;;
 126 esac
 127 ###
 128 ### I put this here to prevent those annoying emails from people who cannot
 129 ### read and try to compile glibc on unsupported platforms.  --drepper
 130 ###
 131 ### By using the undocumented --enable-hacker-mode option for configure
 132 ### one can skip this test to make the configuration not fail for unsupported
 133 ### platforms.
 134 ###
 135 if test -z "$enable_hacker_mode"; then
 136   case "$host_os" in
 137   linux* | gnu*)
 138     ;;
 139   *)
 140     echo "*** The GNU C library is currently not available for this platform."
 141     echo "*** So far nobody cared to port it and if there is no volunteer it"
 142     echo "*** might never happen.  So, if you have interest to see glibc on"
 143     echo "*** this platform visit"
 144     echo "***  http://www.gnu.org/software/libc/porting.html"
 145     echo "*** and join the group of porters"
 146     exit 1
 147     ;;
 148   esac
 149 fi
 150
 151
 152 # We keep the original values in `$config_*' and never modify them, so we
 153 # can write them unchanged into config.make.  Everything else uses
 154 # $machine, $vendor, and $os, and changes them whenever convenient.
 155 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 156
 157 # Some configurations imply other options.
 158 case "$host_os" in
 159 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 160   # These systems always use GNU tools.
 161   gnu_ld=yes gnu_as=yes ;;
 162 esac
 163 case "$host_os" in
 164 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 165 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 166   ;;
 167 gnu* | linux* | sysv4* | solaris2*)
 168   # These systems (almost) always use the ELF format.
 169   elf=yes
 170   ;;
 171 esac
 172
 173 machine=$config_machine
 174 vendor=$config_vendor
 175 os=$config_os
 176
 177 dnl We need to use [ and ] for other purposes for a while now.
 178 changequote(,)dnl
 179 # Expand the configuration machine name into a subdirectory by architecture
 180 # type and particular chip.
 181 case "$machine" in
 182 a29k | am29000) base_machine=a29k machine=a29k ;;
 183 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 184 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 185 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 186 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 187 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 188 m88???)         base_machine=m88k machine=m88k/$machine ;;
 189 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 190 mips*)          base_machine=mips machine=mips/$machine ;;
 191 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 192 sparc | sparcv[67])
 193                 base_machine=sparc machine=sparc/sparc32 ;;
 194 sparcv8 | supersparc | hypersparc)
 195                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 196 sparc64)        base_machine=sparc machine=sparc/sparc64 ;;
 197 esac
 198 changequote([,])dnl
 199 AC_SUBST(base_machine)
 200
 201 # Compute the list of sysdep directories for this configuration.
 202 # This can take a while to compute.
 203 sysdep_dir=$srcdir/sysdeps
 204 AC_MSG_CHECKING(sysdep dirs)
 205 dnl We need to use [ and ] for other purposes for a while now.
 206 changequote(,)dnl
 207 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 208 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 209
 210 case "$os" in
 211 gnu*)
 212   base_os=mach/hurd ;;
 213 netbsd* | 386bsd* | freebsd* | bsdi*)
 214   base_os=unix/bsd/bsd4.4 ;;
 215 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 216   base_os=unix/bsd ;;
 217 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 218   base_os=unix/sysv ;;
 219 solaris[2-9]*)
 220   base_os=unix/sysv/sysv4 ;;
 221 none)
 222   base_os=standalone ;;
 223 *)
 224   base_os='' ;;
 225 esac
 226
 227 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 228 tail=$os
 229 ostry=$os
 230 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 231   ostry="$ostry /$o"
 232   tail=$o
 233 done
 234 o=`echo $tail | sed 's/[0-9]*$//'`
 235 if test $o != $tail; then
 236   ostry="$ostry /$o"
 237 fi
 238 # For linux-gnu, try linux-gnu, then linux.
 239 o=`echo $tail | sed 's/-.*$//'`
 240 if test $o != $tail; then
 241   ostry="$ostry /$o"
 242 fi
 243
 244 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 245 base=
 246 tail=$base_os
 247 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 248   set $b
 249   base="$base /$1"
 250   tail="$2"
 251 done
 252
 253 # For sparc/sparcv9, try sparc/sparcv9 and then sparc.
 254 mach=
 255 tail=$machine
 256 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 257   set $m
 258   # Prepend the machine's FPU directory unless --without-fp.
 259   if test "$with_fp" = yes; then
 260     mach="$mach /$1/fpu"
 261   fi
 262   mach="$mach /$1"
 263   tail="$2"
 264 done
 265
 266 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 267 changequote([,])dnl
 268
 269 # Find what sysdep directories exist.
 270 sysnames=
 271 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 272 for d in $add_ons_pfx ''; do
 273   for b in $base ''; do
 274     for m0 in $mach ''; do
 275       for v in /$vendor ''; do
 276         test "$v" = / && continue
 277         for o in /$ostry ''; do
 278           test "$o" = / && continue
 279           for m in $mach ''; do
 280             if test "$m0$b$v$o$m"; then
 281               try="${d}sysdeps$m0$b$v$o$m"
 282               test -n "$enable_debug_configure" &&
 283               echo "$0 [DEBUG]: try $try" >&2
 284               case $try in
 285                 /*) dest=$try ;;
 286                 *)  dest=$srcdir/$try ;;
 287               esac
 288               if test -d $dest; then
 289                 sysnames="$sysnames $try"
 290                 { test -n "$o" || test -n "$b"; } && os_used=t
 291                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 292               fi
 293             fi
 294           done
 295         done
 296       done
 297     done
 298   done
 299 done
 300 IFS="$ac_save_ifs"
 301
 302 if test -z "$os_used" && test "$os" != none; then
 303   AC_MSG_ERROR(Operating system $os is not supported.)
 304 fi
 305 if test -z "$machine_used" && test "$machine" != none; then
 306   AC_MSG_ERROR(The $machine is not supported.)
 307 fi
 308
 309 # We have now validated the configuration.
 310
 311
 312 # If using ELF, look for an `elf' subdirectory of each machine directory.
 313 # We prepend these rather than inserting them whereever the machine appears
 314 # because things specified by the machine's ELF ABI should override
 315 # OS-specific things, and should always be the same for any OS on the
 316 # machine (otherwise what's the point of an ABI?).
 317 if test "$elf" = yes; then
 318   elf_dirs=
 319   for d in $add_ons_pfx ''; do
 320     case $d in
 321       /*) xsrcdir= ;;
 322       *)  xsrcdir=$srcdir/ ;;
 323     esac
 324     for m in $mach; do
 325       if test -d $xsrcdir${d}sysdeps$m/elf; then
 326         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 327       fi
 328     done
 329   done
 330   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 331 fi
 332
 333
 334 # Expand the list of system names into a full list of directories
 335 # from each element's parent name and Implies file (if present).
 336 set $sysnames
 337 names=
 338 while test $# -gt 0; do
 339   name=$1
 340   shift
 341
 342   case " $names " in *" $name "*)
 343     # Already in the list.
 344     continue
 345   esac
 346
 347   # Report each name as we discover it, so there is no long pause in output.
 348   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 349
 350   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 351
 352   case $name in
 353     /*) xsrcdir= ;;
 354     *)  xsrcdir=$srcdir/ ;;
 355   esac
 356   test -n "$enable_debug_configure" &&
 357   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 358
 359   if test -f $xsrcdir$name/Implies; then
 360     # Collect more names from the `Implies' file (removing comments).
 361     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 362     implied=
 363     for x in $implied_candidate; do
 364       if test -d $xsrcdir$name_base/$x; then
 365         implied="$implied $name_base/$x";
 366       else
 367         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 368       fi
 369     done
 370   else
 371     implied=
 372   fi
 373
 374   # Add NAME to the list of names.
 375   names="$names $name"
 376
 377   # Find the parent of NAME, using the empty string if it has none.
 378 changequote(,)dnl
 379   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 380 changequote([,])dnl
 381
 382   # Add the names implied by NAME, and NAME's parent (if it has one), to
 383   # the list of names to be processed (the argument list).  We prepend the
 384   # implied names to the list and append the parent.  We want implied
 385   # directories to come before further directories inferred from the
 386   # configuration components; this ensures that for sysv4, unix/common
 387   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 388   # after sysv4).
 389   sysnames="`echo $implied $* $parent`"
 390   test -n "$sysnames" && set $sysnames
 391 done
 392
 393 # Add the default directories.
 394 sysnames="$names sysdeps/generic sysdeps/stub"
 395 AC_SUBST(sysnames)
 396 # The other names were emitted during the scan.
 397 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
 398
 399
 400 ### Locate tools.
 401
 402 AC_PROG_INSTALL
 403 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 404   # The makefiles need to use a different form to find it in $srcdir.
 405   INSTALL='\$(..)./install-sh -c'
 406 fi
 407 AC_PROG_LN_S
 408 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 409 if test "$MSGFMT" != ":"; then
 410 changequote(,)dnl Need [] for regexps.
 411   if $MSGFMT --version 2>&1 | grep 'GNU gettext.*0\.[1-9][0-9]' >/dev/null 2>&1
 412 changequote([,])dnl
 413   then : # msgfmt from gettext 0.10 or greater, works.
 414   else
 415     AC_MSG_WARN([
 416 *** (g)msgfmt is too old or wrong version (need GNU gettext 0.10 or better).])
 417     MSGFMT=":"
 418   fi
 419 fi
 420
 421 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo)
 422 if test "$MAKEINFO"; then
 423 changequote(,)dnl Need [] for regexps.
 424   if $MAKEINFO --version | grep 'texinfo 3\.[1-9][1-9]' >/dev/null 2>&1
 425 changequote([,])dnl
 426   then : # Makeinfo 3.11 or greater, works.
 427   else
 428     AC_MSG_WARN([
 429 *** makeinfo is too old (need version 3.11 or better).
 430 *** You should install the needed version and re-configure since otherwise
 431 *** you won't get the info pages installed.])
 432     MAKEINFO=
 433   fi
 434 fi
 435
 436 AC_PROG_CC_LOCAL
 437 AC_CANONICAL_BUILD
 438 if test $host != $build; then
 439   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 440 fi
 441 AC_SUBST(cross_compiling)
 442 AC_PROG_CPP
 443 AC_CHECK_TOOL(AR, ar)
 444 AC_CHECK_TOOL(RANLIB, ranlib, :)
 445
 446 AC_PATH_PROG(BASH, bash, no)
 447 if test "$BASH" != no &&
 448    $BASH -c 'test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 449   libc_cv_have_bash2=yes
 450 else
 451   libc_cv_have_bash2=no
 452 fi
 453 AC_SUBST(libc_cv_have_bash2)
 454
 455 dnl We need a ksh compatible shell for tzselect.
 456 if test "$BASH" = no; then
 457   AC_PATH_PROG(KSH, ksh, no)
 458   if test "$KSH" = no; then
 459     libc_cv_have_ksh=no
 460   else
 461     libc_cv_have_ksh=yes
 462   fi
 463 else
 464   KSH="$BASH"
 465   AC_SUBST(KSH)
 466   libc_cv_have_ksh=yes
 467 fi
 468 AC_SUBST(libc_cv_have_ksh)
 469
 470 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 471 echo '#include <stddef.h>
 472 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 473 if eval "$ac_cpp conftest.c 2>/dev/null" \
 474 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 475   libc_cv_signed_size_t=no
 476 else
 477   libc_cv_signed_size_t=yes
 478 fi
 479 rm -f conftest*])
 480 if test $libc_cv_signed_size_t = yes; then
 481   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 482   cat >> confdefs.h <<\EOF
 483 #undef __SIZE_TYPE__
 484 #define __SIZE_TYPE__ unsigned
 485 EOF
 486 fi
 487
 488 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 489 AC_TRY_COMPILE(dnl
 490 [#define __need_size_t
 491 #define __need_wchar_t
 492 #include <stddef.h>
 493 #define __need_NULL
 494 #include <stddef.h>], [size_t size; wchar_t wchar;
 495 #ifdef offsetof
 496 #error stddef.h ignored __need_*
 497 #endif
 498 if (&size == NULL || &wchar == NULL) abort ();],
 499                libc_cv_friendly_stddef=yes,
 500                libc_cv_friendly_stddef=no)])
 501 if test $libc_cv_friendly_stddef = yes; then
 502   config_vars="$config_vars
 503 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 504 fi
 505
 506 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 507                libc_cv_need_minus_P, [dnl
 508 cat > conftest.S <<EOF
 509 #include "confdefs.h"
 510 /* Nothing whatsoever.  */
 511 EOF
 512 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 513   libc_cv_need_minus_P=no
 514 else
 515   libc_cv_need_minus_P=yes
 516 fi
 517 rm -f conftest*])
 518 if test $libc_cv_need_minus_P = yes; then
 519   config_vars="$config_vars
 520 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 521 fi
 522
 523 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
 524 # be told to read stdin.  This causes the compiler to hang when fed an
 525 # .s file.
 526 if test $ac_cv_prog_gcc = yes; then
 527  case `${CC-cc} -v 2>&1` in
 528   *2.7*)
 529   # We must check this even if -pipe is not given here, because the user
 530   # might do `make CFLAGS=-pipe'.
 531   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
 532    cp /dev/null conftest.s
 533    cat >conftest1.s <<EOF
 534 .nosuchdirective
 535 EOF
 536    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
 537     libc_cv_gcc_pipe_bug=no
 538    else
 539     libc_cv_gcc_pipe_bug=yes
 540    fi
 541    rm -f conftest*])
 542   if test $libc_cv_gcc_pipe_bug = yes; then
 543    makeCC="${CC-cc} -B\$(common-objpfx)"
 544    makeCFLAGS=$CFLAGS
 545    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
 546   fi;;
 547  *) libc_cv_gcc_pipe_bug=no;;
 548  esac
 549 else
 550  libc_cv_gcc_pipe_bug=no
 551 fi
 552
 553
 554 AC_CACHE_CHECK(for assembler global-symbol directive,
 555                libc_cv_asm_global_directive, [dnl
 556 libc_cv_asm_global_directive=UNKNOWN
 557 for ac_globl in .globl .global; do
 558   cat > conftest.s <<EOF
 559 .text
 560 ${ac_globl} foo
 561 foo:
 562 EOF
 563   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 564     libc_cv_asm_global_directive=${ac_globl}
 565   fi
 566   rm -f conftest*
 567   test $libc_cv_asm_global_directive != UNKNOWN && break
 568 done])
 569 if test $libc_cv_asm_global_directive = UNKNOWN; then
 570   AC_MSG_ERROR(cannot determine asm global directive)
 571 else
 572   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 573 fi
 574
 575 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 576 cat > conftest.s <<EOF
 577 .text
 578 foo: .long 0
 579 .set glibc_conftest_frobozz,foo
 580 $libc_cv_asm_global_directive glibc_conftest_frobozz
 581 EOF
 582 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 583 # (but it doesn't work), so we must do a linking check to be sure.
 584 cat > conftest1.c <<\EOF
 585 extern int glibc_conftest_frobozz;
 586 main () { printf ("%d\n", glibc_conftest_frobozz); }
 587 EOF
 588 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 589             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 590   libc_cv_asm_set_directive=yes
 591 else
 592   libc_cv_asm_set_directive=no
 593 fi
 594 rm -f conftest*])
 595 if test $libc_cv_asm_set_directive = yes; then
 596   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 597 fi
 598
 599 if test $elf = yes; then
 600   AC_CACHE_CHECK(for .previous assembler directive,
 601                  libc_cv_asm_previous_directive, [dnl
 602   cat > conftest.s <<EOF
 603 .section foo_section
 604 .previous
 605 EOF
 606   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 607     libc_cv_asm_previous_directive=yes
 608   else
 609     libc_cv_asm_previous_directive=no
 610   fi
 611   rm -f conftest*])
 612   if test $libc_cv_asm_previous_directive = yes; then
 613     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 614   else
 615     AC_CACHE_CHECK(for .popsection assembler directive,
 616                    libc_cv_asm_popsection_directive, [dnl
 617     cat > conftest.s <<EOF
 618 .pushsection foo_section
 619 .popsection
 620 EOF
 621     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 622       libc_cv_asm_popsection_directive=yes
 623     else
 624       libc_cv_asm_popsection_directive=no
 625     fi
 626     rm -f conftest*])
 627     if test $libc_cv_asm_popsection_directive = yes; then
 628       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 629     fi
 630   fi
 631 fi
 632
 633 if test $elf != yes; then
 634   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 635                  [AC_TRY_COMPILE(, [asm (".section .init");
 636                                     asm (".section .fini");
 637                                     asm (".text");],
 638                                  libc_cv_have_initfini=yes,
 639                                  libc_cv_have_initfini=no)])
 640   AC_SUBST(libc_cv_have_initfini)dnl
 641   if test $libc_cv_have_initfini = yes; then
 642     AC_DEFINE(HAVE_INITFINI)
 643   fi
 644 fi
 645
 646 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 647 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 648 [cat > conftest.$ac_ext <<EOF
 649 dnl This sometimes fails to find confdefs.h, for some reason.
 650 dnl [#]line __oline__ "[$]0"
 651 [#]line __oline__ "configure"
 652 #include "confdefs.h"
 653 void underscore_test(void) {
 654 return; }
 655 EOF
 656 if AC_TRY_EVAL(ac_compile); then
 657   if grep _underscore_test conftest* >/dev/null; then
 658     ifelse([$1], , :, [rm -f conftest*
 659     $1])
 660   else
 661     ifelse([$2], , , [rm -f conftest*
 662     $2])
 663   fi
 664 else
 665   echo "configure: failed program was:" >&AC_FD_CC
 666   cat conftest.$ac_ext >&AC_FD_CC
 667   ifelse([$2], , , [rm -f conftest*
 668   $2])
 669 fi
 670 rm -f conftest*])
 671
 672 if test $elf = yes; then
 673   libc_cv_asm_underscores=no
 674 else
 675   if test $ac_cv_prog_cc_works = yes; then
 676     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 677                   [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 678                                libc_cv_asm_underscores=yes,
 679                                libc_cv_asm_underscores=no)])
 680   else
 681     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 682                   [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 683                                            libc_cv_asm_underscores=no)])
 684   fi
 685 fi
 686 if test $libc_cv_asm_underscores = no; then
 687   AC_DEFINE(NO_UNDERSCORES)
 688 fi
 689
 690 if test $elf = yes; then
 691   libc_cv_weak_symbols=yes
 692   libc_cv_asm_weak_directive=yes
 693   libc_cv_asm_weakext_directive=no
 694 else
 695   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 696                  [dnl
 697 cat > conftest.s <<EOF
 698 .text
 699 ${libc_cv_asm_global_directive} foo
 700 foo:
 701 .weak foo
 702 .weak bar; bar = foo
 703 EOF
 704   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 705     libc_cv_asm_weak_directive=yes
 706   else
 707     libc_cv_asm_weak_directive=no
 708   fi
 709   rm -f conftest*])
 710
 711 if test $libc_cv_asm_weak_directive = no; then
 712   AC_CACHE_CHECK(for assembler .weakext directive,
 713                  libc_cv_asm_weakext_directive,
 714                  [dnl
 715 cat > conftest.s <<EOF
 716 .text
 717 ${libc_cv_asm_global_directive} foo
 718 foo:
 719 .weakext foo
 720 .weakext foo, bar
 721 EOF
 722   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 723     libc_cv_asm_weakext_directive=yes
 724   else
 725     libc_cv_asm_weakext_directive=no
 726   fi
 727   rm -f conftest*])
 728
 729   fi # no .weak
 730 fi # not ELF
 731
 732 if test $libc_cv_asm_weak_directive = yes; then
 733   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 734 elif test $libc_cv_asm_weakext_directive = yes; then
 735   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 736 fi
 737
 738 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 739 cat > conftest.c <<\EOF
 740 _start () {}
 741 int __eh_pc;
 742 __throw () {}
 743 EOF
 744 dnl No \ in command here because it ends up inside ''.
 745 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 746                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 747                             -o conftest conftest.c 1>&AC_FD_CC]); then
 748   libc_cv_ld_no_whole_archive=yes
 749 else
 750   libc_cv_ld_no_whole_archive=no
 751 fi
 752 rm -f conftest*])
 753 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 754
 755 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 756 cat > conftest.c <<\EOF
 757 _start () {}
 758 int __eh_pc;
 759 __throw () {}
 760 EOF
 761 dnl No \ in command here because it ends up inside ''.
 762 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 763                             -nostdlib -nostartfiles -fno-exceptions
 764                             -o conftest conftest.c 1>&AC_FD_CC]); then
 765   libc_cv_gcc_no_exceptions=yes
 766 else
 767   libc_cv_gcc_no_exceptions=no
 768 fi
 769 rm -f conftest*])
 770 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 771
 772 if test "$base_machine" = alpha ; then
 773 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 774 cat > conftest.c <<\EOF
 775 foo () { }
 776 EOF
 777 dnl
 778 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 779 then
 780   libc_cv_gcc_alpha_ng_prefix=yes
 781 else
 782   libc_cv_gcc_alpha_ng_prefix=no
 783 fi
 784 rm -f conftest* ])
 785 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 786   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 787 else
 788   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 789 fi
 790 fi
 791
 792 ### End of automated tests.
 793 ### Now run sysdeps configure fragments.
 794
 795 # sysdeps configure fragments may set these with files to be linked below.
 796 libc_link_dests=
 797 libc_link_sources=
 798
 799 # Iterate over all the sysdep directories we will use, running their
 800 # configure fragments, and looking for a uname implementation.
 801 uname=
 802 for dir in $sysnames; do
 803   case $dir in
 804     /*) dest=$dir ;;
 805     *)  dest=$srcdir/$dir ;;
 806   esac
 807   if test -r $dest/configure; then
 808     AC_MSG_RESULT(running configure fragment for $dest)
 809     . $dest/configure
 810   fi
 811 [
 812   if test -z "$uname"; then
 813     if test -r $sysdep_dir/$dir/uname.c ||
 814        test -r $sysdep_dir/$dir/uname.S ||
 815        { test -r $sysdep_dir/$dir/syscalls.list &&
 816          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 817       uname=$dir
 818     fi
 819   fi
 820 ]dnl
 821 done
 822
 823 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 824
 825 # If we will use the generic uname implementation, we must figure out what
 826 # it will say by examining the system, and write the results in config-name.h.
 827 if test "$uname" = generic; then
 828
 829 changequote(,)dnl
 830   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 831 changequote([,])dnl
 832   if test $uname_sysname != $config_os; then
 833     config_release=`echo $config_os | sed s/$uname_sysname//`
 834   fi
 835 dnl
 836 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 837     if test -r /vmunix; then
 838       kernel_id=`strings /vmunix | grep UNIX`
 839     elif test -r /dynix; then
 840       kernel_id=`strings /dynix | grep DYNIX`
 841     else
 842       kernel_id=
 843     fi
 844 ])dnl
 845
 846   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 847 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 848 changequote(,)dnl
 849   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 850 changequote([,])dnl
 851   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 852          != x$config_release; then
 853     # The configuration release is a substring of the kernel release.
 854     libc_cv_uname_release=$kernel_release
 855   elif test x$config_release != x; then
 856     libc_cv_uname_release=$config_release
 857   elif test x$kernel_release != x; then
 858     libc_cv_uname_release=$kernel_release
 859   else
 860     libc_cv_uname_release=unknown
 861   fi])
 862   uname_release="$libc_cv_uname_release"
 863
 864   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 865 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 866 changequote(,)dnl
 867   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 868 changequote([,])dnl
 869   if test -n "$kernel_version"; then
 870     libc_cv_uname_version="$kernel_version"
 871   else
 872     libc_cv_uname_version=unknown
 873   fi])
 874   uname_version="$libc_cv_uname_version"
 875
 876 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 877   config_uname=config-name.h:config-name.in
 878 else
 879   # For non-generic uname, we don't need to create config-name.h at all.
 880   config_uname=
 881 fi
 882
 883 AC_MSG_CHECKING(stdio selection)
 884 AC_SUBST(stdio)
 885 case $stdio in
 886 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 887 default) stdio=stdio ;;
 888 esac
 889 AC_MSG_RESULT($stdio)
 890
 891 AC_SUBST(libc_cv_slibdir)
 892 AC_SUBST(libc_cv_sysconfdir)
 893 AC_SUBST(libc_cv_rootsbindir)
 894
 895 AC_SUBST(has_ldconfig)
 896
 897 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 898 if test $gnu_ld = yes; then
 899   AC_DEFINE(HAVE_GNU_LD)
 900 fi
 901 if test $gnu_as = yes; then
 902   AC_DEFINE(HAVE_GNU_AS)
 903 fi
 904 if test $elf = yes; then
 905   AC_DEFINE(HAVE_ELF)
 906 fi
 907
 908 AC_SUBST(shared)
 909 if test $shared = default; then
 910   if test $gnu_ld = yes; then
 911     shared=$elf
 912   else
 913     # For now we do not assume shared libs are available.  In future more
 914     # tests might become available.
 915     shared=no
 916   fi
 917 fi
 918 AC_SUBST(profile)
 919 AC_SUBST(omitfp)
 920
 921 AC_SUBST(DEFINES)
 922
 923 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 924   config_makefile=
 925 else
 926   config_makefile=Makefile
 927 fi
 928
 929 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
 930 AC_SUBST(VERSION)
 931
 932 if test $libc_cv_gcc_pipe_bug = yes; then
 933   realCC="$CC"
 934   CC="$makeCC"
 935   CFLAGS="$makeCFLAGS"
 936 fi
 937 AC_OUTPUT_COMMANDS([
 938 if test "$realCC"; then
 939  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
 940  mv specsT specs
 941 fi], [realCC="$realCC"])
 942
 943 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
 944           [echo '$config_vars' >> config.make])