sysdeps/unix/sysv/linux/m68k/m68k-helpers.S

   1 /* Copyright (C) 2010 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Maxim Kuvyrkov <maxim@codesourcery.com>, 2010.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library; if not, write to the Free
  34    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  35    02111-1307 USA.  */
  36
  37 #include <sysdep.h>
  38 #include <bits/m68k-vdso.h>
  39
  40         .text
  41
  42         .hidden __vdso_read_tp_stub
  43 ENTRY (__vdso_read_tp_stub)
  44         cfi_startproc
  45         move.l  #__NR_get_thread_area, %d0
  46         trap    #0
  47         move.l  %d0, %a0
  48         rts
  49         cfi_endproc
  50 END (__vdso_read_tp_stub)
  51
  52 # ifdef SHARED
  53 /* GCC will emit calls to this routine.  Linux has an
  54    equivalent helper function (which clobbers fewer registers than
  55    a normal function call) in a vdso; tail call to the
  56    helper.  */
  57 # ifdef IS_IN_rtld
  58 /* rtld gets a hidden copy of __m68k_read_tp.  */
  59         .hidden __m68k_read_tp
  60 # endif
  61 ENTRY (__m68k_read_tp)
  62         cfi_startproc
  63         move.l  #_GLOBAL_OFFSET_TABLE_@GOTPC, %a0
  64         lea     (-6, %pc, %a0), %a0
  65         move.l  M68K_VDSO_SYMBOL (__vdso_read_tp)@GOT(%a0), %a0
  66         move.l  (%a0), %a0
  67         jmp     (%a0)
  68         cfi_endproc
  69 END (__m68k_read_tp)
  70
  71 /* The following two stubs are for macros in atomic.h, they can't
  72    clobber anything.  */
  73
  74         .hidden __vdso_atomic_cmpxchg_32_stub
  75 ENTRY (__vdso_atomic_cmpxchg_32_stub)
  76         cfi_startproc
  77         move.l  %d2, -(%sp)
  78         cfi_adjust_cfa_offset (4)
  79         cfi_rel_offset (%d2, 0)
  80         move.l  %d0, %d2
  81         move.l  #SYS_ify (atomic_cmpxchg_32), %d0
  82         trap    #0
  83         move.l  (%sp)+, %d2
  84         cfi_adjust_cfa_offset (-4)
  85         cfi_restore (%d2)
  86         rts
  87         cfi_endproc
  88 END (__vdso_atomic_cmpxchg_32_stub)
  89
  90         .hidden __vdso_atomic_barrier_stub
  91 ENTRY (__vdso_atomic_barrier_stub)
  92         cfi_startproc
  93         move.l  %d0, -(%sp)
  94         cfi_adjust_cfa_offset (4)
  95         move.l  #SYS_ify (atomic_barrier), %d0
  96         trap    #0
  97         move.l  (%sp)+, %d0
  98         cfi_adjust_cfa_offset (-4)
  99         rts
 100         cfi_endproc
 101 END (__vdso_atomic_barrier_stub)
 102 # else /* !SHARED */
 103 /* If the vDSO is not available, use a syscall to get TP.  */
 104         strong_alias (__vdso_read_tp_stub, __m68k_read_tp)
 105 # endif /* SHARED */