scripts/abilist.awk

   1 # This awk script processes the output of objdump --dynamic-syms
   2 # into a simple format that should not change when the ABI is not changing.
   3
   4 BEGIN {
   5   if (combine_fullname)
   6     combine = 1;
   7   if (combine)
   8     parse_names = 1;
   9 }
  10
  11 # Per-file header.
  12 /[^ :]+\.so\.[0-9.]+:[  ]+.file format .*$/ {
  13   emit(0);
  14
  15   seen_opd = 0;
  16
  17   sofullname = $1;
  18   sub(/:$/, "", sofullname);
  19   soname = sofullname;
  20   sub(/^.*\//, "", soname);
  21   sub(/\.so\.[0-9.]+$/, "", soname);
  22
  23   suppress = ((filename_regexp != "" && sofullname !~ filename_regexp) \
  24               || (libname_regexp != "" && soname !~ libname_regexp));
  25
  26   next
  27 }
  28
  29 suppress { next }
  30
  31 # Normalize columns.
  32 /^[0-9a-fA-F]+      / { sub(/      /, "  -   ") }
  33
  34 # Skip undefineds.
  35 $4 == "*UND*" { next }
  36
  37 # Skip locals.
  38 $2 == "l" { next }
  39
  40 # If the target uses ST_OTHER, it will be output before the symbol name.
  41 $2 == "g" || $2 == "w" && (NF == 7 || NF == 8) {
  42   weak = $2;
  43   type = $3;
  44   size = $5;
  45   sub(/^0*/, "", size);
  46   size = " 0x" size;
  47   version = $6;
  48   symbol = $NF;
  49   gsub(/[()]/, "", version);
  50
  51   # binutils versions up through at least 2.23 have some bugs that
  52   # caused STV_HIDDEN symbols to appear in .dynsym, though that is useless.
  53   if (NF > 7 && $7 == ".hidden") next;
  54
  55   if (version == "GLIBC_PRIVATE") next;
  56
  57   desc = "";
  58   if (type == "D" && $4 == ".tbss") {
  59     type = "T";
  60   }
  61   else if (type == "D" && $4 == ".opd") {
  62     type = "F";
  63     size = "";
  64     if (seen_opd < 0)
  65       type = "O";
  66     seen_opd = 1;
  67   }
  68   else if (type == "D" && NF == 8 && $7 == "0x80") {
  69     # Alpha functions avoiding plt entry in users
  70     type = "F";
  71     size = "";
  72     seen_opd = -1;
  73   }
  74   else if ($4 == "*ABS*") {
  75     next;
  76   }
  77   else if (type == "DO") {
  78     type = "D";
  79   }
  80   else if (type == "DF") {
  81     if (symbol ~ /^\./ && seen_opd >= 0)
  82       next;
  83     seen_opd = -1;
  84     type = "F";
  85     size = "";
  86   }
  87   else if (type == "iD" && ($4 == ".text" || $4 == ".opd")) {
  88     # Indirect functions.
  89     type = "F";
  90     size = "";
  91   }
  92   else {
  93     desc = symbol " " version " " weak " ? " type " " $4 " " $5;
  94   }
  95   if (size == " 0x") {
  96     desc = symbol " " version " " weak " ? " type " " $4 " " $5;
  97   }
  98
  99   # Disabled -- weakness should not matter to shared library ABIs any more.
 100   #if (weak == "w") type = tolower(type);
 101   if (desc == "")
 102     desc = symbol " " type size;
 103
 104   if (combine)
 105     version = soname " " version (combine_fullname ? " " sofullname : "");
 106
 107   # Append to the string which collects the results.
 108   descs = descs version " " desc "\n";
 109   next;
 110 }
 111
 112 # Header crapola.
 113 NF == 0 || /DYNAMIC SYMBOL TABLE/ || /file format/ { next }
 114
 115 {
 116   print "Don't grok this line:", $0
 117 }
 118
 119 function emit(end) {
 120   if (!end && (combine || ! parse_names || soname == ""))
 121     return;
 122   tofile = parse_names && !combine;
 123
 124   if (tofile) {
 125     out = prefix soname ".symlist";
 126     if (soname in outfiles)
 127       out = out "." ++outfiles[soname];
 128     else
 129       outfiles[soname] = 1;
 130     outpipe = "LC_ALL=C sort -u > " out;
 131   } else {
 132     outpipe = "LC_ALL=C sort -u";
 133   }
 134
 135   printf "%s", descs | outpipe;
 136
 137   descs = "";
 138
 139   if (tofile)
 140     print "wrote", out, "for", sofullname;
 141 }
 142
 143 END {
 144   emit(1);
 145 }